1 REM *************
2 REM *           *
3 REM *  S K A T  *
4 REM *           *
5 REM *************
6 REM
7 Z(1)=0:Z(2)=0:Z(3)=0:S=0
8 POKE53280,14:POKE53281,14
9 IFS>0THENPRINT"[144]":GOTO21
10 PRINT"[147][144][216][216][216][216][216][216][216][216]  [193][193][193]    [193][193][193]  [211][211][211][211][211][211][211][211]  [218][218][218][218][218][218][218][218]";
11 PRINT"[144][216][216][216][216][216][216][216][216]  [193][193][193]   [193][193][193]   [211][211][211][211][211][211][211][211]  [218][218][218][218][218][218][218][218]";
12 PRINT"[144][216][216]        [193][193][193]  [193][193][193]    [211][211]    [211][211]     [218][218]  "
13 PRINT"[144][216][216]        [193][193][193] [193][193][193]     [211][211]    [211][211]     [218][218]  "
14 PRINT"[144][216][216][216][216][216][216][216][216]  [193][193][193][193][193][193]      [211][211][211][211][211][211][211][211]     [218][218]  "
15 PRINT"[144][216][216][216][216][216][216][216][216]  [193][193][193][193][193][193]      [211][211][211][211][211][211][211][211]     [218][218]  "
16 PRINT"[144]      [216][216]  [193][193][193] [193][193][193]     [211][211]    [211][211]     [218][218]  "
17 PRINT"[144]      [216][216]  [193][193][193]  [193][193][193]    [211][211]    [211][211]     [218][218]  "
18 PRINT"[144][216][216][216][216][216][216][216][216]  [193][193][193]   [193][193][193]   [211][211]    [211][211]     [218][218]  "
19 PRINT"[144][216][216][216][216][216][216][216][216]  [193][193][193]    [193][193][193]  [211][211]    [211][211]     [218][218]  "
20 GOSUB162
21 DIMA$(32),A(32),B$(2,32),Q(32),V(16),K(15),Y(12):A=RND(-TI)
22 FORT=1TO16:READV(T):NEXT
23 FORT=1TO4:READJ(T):NEXT
24 FORT=0TO15:READK(T):NEXT
25 FORT=1TO4:READU(T):NEXT
26 FORT=1TO4:READN(T):NEXT
27 FORT=0TO31:READA:POKE828+T,A:NEXT
28 FORT=1TO32:READA$(T):NEXT
29 FORY=1TO3
30 FORT=1TO10
31 A=INT(RND(1)*32)+1
32 IFA(A)>0THEN31
33 A(A)=Y:NEXTT,Y
34 IFS=0THENINPUT"[147][144]WELCHER SPIELER TEILT AUS ";S:IFS<1ORS>3THENS=0:GOTO34
35 DF=S
36 Y=1:X=-5:IFS=2THEN DE=3
37 IFS=3THENDE=2
38 GOSUB329:PRINT"SPIELER"AA"HAT DAS 1. REIZEN GEWONNEN.":GOSUB118:OP=S
39 FG=5:IFAA=1ANDS=2THENNS=-1:DE=2:GOSUB332:GOTO44
40 IFAA=1ANDS=3THENS=-1:DE=3:GOSUB332:GOTO44
41 IFAA=2ANDS=1THENS=0:DE=2:GOSUB332:GOTO44
42 IFAA=3ANDS=1THENS=0:DE=3:GOSUB332:GOTO44
43 IFAA=2ANDS=3ORAA=3ANDS=2THENS=1:GOSUB332
44 GOSUB117:S=OP:SW=SW(AA)+96:PRINT"SPIELER"AA"SPIELT ALLEINE !"
45 IFAA=1THENGOSUB118:GOTO48
46 PRINT""CHR$(SW(AA))" IST TRUMPF !":GOSUB305
47 OL=9:V=AA:GOSUB337:OL=0:GOSUB118:GOTO74
48 SYS828
49 FORT=1TO32
50 IFA(T)=0THENA(T)=AA
51 IFA(T)=1THENGOSUB163
52 NEXT:Y=1:X=-5
53 GOSUB134:INPUT"1.WELCHE KARTE SOLL WEG ";I$:GOSUB202:P$=I$
54 B$(1,1)=I$
55 GOSUB134:INPUT"2.WELCHE KARTE SOLL WEG ";I$:GOSUB202
56 B$(1,2)=I$:Q(1)=2:A=0
57 FORT=1TO28
58 IFA(T)>1THEN60
59 IFA$(T)=P$ORA$(T)=I$THENA=A+1
60 NEXT:IFA=2THEN62
61 GOSUB116:Q(1)=0:GOTO53
62 FORT=1TO28
63 IFA(T)>1THEN65
64 IFA$(T)=P$ORA$(T)=I$THENA(T)=0
65 NEXT
66 SYS828:GOSUB166
67 GOSUB134:INPUT"WILLST DU GRAND SPIELEN ";O$:IFO$<>"N"ANDO$<>"J"THEN67
68 IFO$="J"THENFG=9:V=1:GOSUB337:FG=0:SW(1)=0:SW=0:AS(1)=0:RW(1)=TY*24
69 IFO$="J"THEN74
70 GOSUB134:INPUT"WELCHE FARBE IST TRUMPF ";O$
71 IFO$<>"[193]"ANDO$<>"[211]"ANDO$<>"[218]"ANDO$<>"[216]"THEN70
72 OL=9:SW(1)=ASC(O$)-96:V=1:GOSUB337:OL=0
73 SW=ASC(O$)
74 FORTT=1TO3
75 S=S+1:IFS=4THENS=1
76 IFS=1THENGOSUB169:GOTO79
77 IFTT=1THENSYS828:Y=1:X=-5:GOSUB166:GOSUB178:GOTO79
78 GOSUB268
79 C(S)=K:K$(TT)=A$(K):L(TT)=S
80 Z$=A$(K):D=D+6:X=D:Y=16:YY=9:GOSUB143
81 NEXT
82 GOSUB118:HZ=0:GOSUB392:GOSUB421
83 IFASC(K$(1))=ASC(K$(2))ANDASC(K$(2))=ASC(K$(3))THEN111
84 T=ASC(K$(1)):TT=ASC(RIGHT$(K$(1),1))
85 V=ASC(RIGHT$(K$(2),1))
86 IFT=ASC(K$(2))ANDTT>VTHENLL=L(1)
87 IFT=ASC(K$(2))ANDTT<VTHENLL=L(2)
88 V=ASC(RIGHT$(K$(3),1))
89 IFT=ASC(K$(3))ANDTT>VTHENLL=L(1)
90 IFT=ASC(K$(3))ANDTT<VTHENLL=L(3)
91 H=0:FORV=1TO3
92 IFASC(RIGHT$(K$(V),1))=78THENH=H+1:J=V
93 NEXT:IFH>1THEN120
94 IFH=1THENLL=L(J):GOTO99
95 H=0:FORV=1TO3
96 IFASC(K$(V))=SWTHENH=H+1:J=V
97 NEXT:IFH=1THENLL=L(J)
98 IFH=2THEN128
99 IFLL=AATHENT=1:GOTO101
100 T=2
101 FORV=1TO3
102 Q(T)=Q(T)+1:B$(T,Q(T))=K$(V)
103 NEXT:D=0:IFLL=0THENS=LL:GOTO105
104 S=LL-1
105 FORV=1TO32
106 IFA$(V)=K$(1)ORA$(V)=K$(2)ORA$(V)=K$(3)THENA(V)=0
107 NEXT:A=0
108 FORV=1TO32:IFA(V)=1THENA=A+1
109 NEXT:IFA=0THEN211
110 GOTO74
111 TT=0
112 FORV=1TO3
113 QQ=ASC(RIGHT$(K$(V),1))
114 IFQQ>TTTHENTT=ASC(RIGHT$(K$(V),1)):EE=V
115 NEXT:LL=L(EE):GOTO99
116 GOSUB134:PRINT"FEHLER[146]":FORKK=1TO2000:NEXT:RETURN
117 PRINT"SPIELER"AA"HAT DAS 2. REIZEN GEWONNEN.":RETURN
118 GOSUB134:PRINT"[144]            TASTE DRUECKEN !":POKE198,0:WAIT198,1
119 GOSUB134:RETURN
120 GG=0:FORV=1TO3
121 H=ASC(K$(V)):J=ASC(RIGHT$(K$(V),1))
122 IFJ<78THEN127
123 IFH=216THENLL=L(V):GOTO99
124 IFH=193ANDGG<3THENGG=3:LL=L(V)
125 IFH=211ANDGG<2THENGG=2:LL=L(V)
126 IFH=218ANDGG<1THENGG=1:LL=L(V)
127 NEXT:GOTO99
128 FORV=1TO3
129 H=ASC(K$(V)):J=ASC(RIGHT$(K$(V),1))
130 IFH=SWANDGG<JTHENGG=J:LL=L(V)
131 IFH=SWANDGG<JTHENGG=J:LL=L(V)
132 NEXT:H=0:J=0
133 GOTO99
134 POKE211,0:POKE214,23:SYS58640:POKE781,23:SYS59903:RETURN
135 DATA18,20,22,23,24,27,30,33,36,40,44,45,48,50,55,60,1,2,4,8,0,2,2,3,3,2
136 DATA2,4,4,2,2,3,3,2,2,5,122,115,97,120,120,97,115,122,169,147,32,210,255
137 DATA162,8,169,1,157,223,219,189,82,3,157,223,7,202,16,242,96,11,18,21,12
138 DATA12,19,15,6,20,96
139 DATA"[218]7","[218]8","[218]9","[218]D","[218]K","[218]L","[218]M"
140 DATA"[211]7","[211]8","[211]9","[211]D","[211]K","[211]L","[211]M"
141 DATA"[193]7","[193]8","[193]9","[193]D","[193]K","[193]L","[193]M"
142 DATA"[216]7","[216]8","[216]9","[216]D","[216]K","[216]L","[216]M","[218]N","[211]N","[193]N","[216]N"
143 F$=RIGHT$(Z$,1)
144 Z$=LEFT$(Z$,1)
145 POKE211,0:POKE214,Y-1:SYS58640
146 IFF$="L"THENF$="Z"
147 IFF$="M"THENF$="A"
148 IFF$="N"THENF$="B"
149 IFZ$="[218]"ORZ$="[211]"THENZ$=""+Z$+"[144]":F$=""+F$+"[144]"
150 D$="":IFX<>35THEND$=CHR$(13)
151 PRINTSPC(X)"[213][192][192][192][201]"D$;
152 PRINTSPC(X)"[221]"F$" "F$"[221]"D$;
153 PRINTSPC(X)"[221]   [221]"D$;
154 PRINTSPC(X)"[221] "Z$" [221]"D$;
155 PRINTSPC(X)"[221]   [221]"D$;
156 PRINTSPC(X)"[221]"F$" "F$"[221]"D$;
157 PRINTSPC(X)"[202][192][192][192][203]"
158 IFYY<>9THENRETURN
159 IFS=AATHENPRINT"";:HZ=TT
160 YY=0:PRINTSPC(X)"S #"S""
161 RETURN
162 GOSUB134:PRINTSPC(30)"KRULLSOFT";:RETURN
163 Z$=A$(T)
164 X=X+5:IFX=40THENY=Y+7:X=0
165 GOSUB143:RETURN
166 FORT=1TO32
167 IFA(T)=1THENGOSUB163
168 NEXT:Y=1:X=-5:RETURN
169 IFTT=1THENSYS828:Y=1:X=-5:GOSUB166
170 GOSUB134:INPUT"WELCHE KARTE SOLL GESETZT WERDEN ";I$:GOSUB202
171 A=0:FORT=1TO32
172 IFA(T)<>1THEN174
173 IFI$=A$(T)THENA=9
174 NEXT:IFA=0THENGOSUB116:GOTO170
175 FORW=1TO32:IFA$(W)=I$THENK=W:GOTO177
176 NEXTW
177 RETURN
178 K=0:CC=0:RR=100:IFAA<>STHENGOSUB411:IFRR<100THENRETURN
179 IFAA<>STHEN191
180 FORT=1TO32
181 IFA(T)<>STHEN190
182 IFASC(RIGHT$(A$(T),1))=78THENK=T:RETURN
183 FORJ9=1TO4
184 FORAI=1TO3:IFS=AITHEN186
185 IFY(AI*4-4+J9)=1ANDASC(A$(T))-96=U(J9)THEN190
186 NEXTAI,J9
187 J=ASC(A$(T)):H=ASC(RIGHT$(A$(T),1))
188 IFH=77ANDJ<>SWTHENK=T:RETURN
189 IFJ<>SWANDRR>HTHENRR=H:K=T
190 NEXTT:IFRR<100THENRETURN
191 RR=100
192 FORT=1TO28
193 IFA(T)<>STHEN196
194 J=ASC(A$(T)):H=ASC(RIGHT$(A$(T),1))
195 IFJ<>SWANDRR>HTHENRR=H:K=T
196 NEXT:IFRR<100THENJ=0:H=0:RETURN
197 RR=0
198 FORT=1TO32
199 H=ASC(RIGHT$(A$(T),1))
200 IFA(T)=SANDH>RRTHENRR=H:K=T
201 NEXT:H=0:RETURN
202 Q$=RIGHT$(I$,1)
203 IFQ$="Z"THENQ$="L":GOTO207
204 IFQ$="A"THENQ$="M":GOTO207
205 IFQ$="B"THENQ$="N":GOTO207
206 RETURN
207 I$=LEFT$(I$,1)+Q$:RETURN
208 FORT=1TO28
209 IFA(T)=SANDASC(A$(T))=SWTHENK=T:RETURN
210 NEXT:RETURN
211 SYS828:PRINTSPC(15)"AUSWERTUNG"
212 IFCC<>5THENA=0
213 IFQ(1)=0THEN222
214 FORT=1TOQ(1)
215 B$=RIGHT$(B$(1,T),1)
216 IFB$="D"THENA=A+3
217 IFB$="K"THENA=A+4
218 IFB$="L"THENA=A+10
219 IFB$="M"THENA=A+11
220 IFB$="N"THENA=A+2
221 NEXT
222 GOSUB255
223 PRINT"SPIELER"AA"HAT"A"PUNKTE !"
224 PRINT"SPIELER";:N=0
225 FORT=1TO3
226 IFT=AATHEN229
227 PRINTT;:N=N+1
228 IFN=1THENPRINT"UND";
229 NEXT:PRINT"HABEN"120-A"PUNKTE!"
230 B$="    ":A$(0)="-":A$(1)="[144]":A$(2)="[144]+":
231 IFA<30THENRW(AA)=RW(AA)+AS(AA)
232 IFA<61THENRW(AA)=(0-RW(AA))*2
233 F=0-RW(AA):I(4)=RW(AA)
234 FORT=1TO3
235 IFT=AATHENZ(AA)=Z(AA)+RW(AA):GOTO237
236 Z(T)=Z(T)+F
237 NEXT
238 I(1)=Z(1):I(2)=Z(2):I(3)=Z(3)
239 H=4:C=4:GOSUB264
240 I(1)=Z(1)-Z(3):K(1)=I(1)
241 I(2)=Z(2)-Z(1):K(2)=I(2)
242 I(3)=Z(3)-Z(1):K(3)=I(3)
243 H=3:C=6:GOSUB264
244 I(1)=Z(1)-Z(2):K(1)=K(1)+I(1)
245 I(2)=Z(2)-Z(3):K(2)=K(2)+I(2)
246 I(3)=Z(3)-Z(2):K(3)=K(3)+I(3)
247 C=7:GOSUB264
248 I(1)=K(1):I(2)=K(2):I(3)=K(3)
249 C=9:GOSUB264
250 S=DF
251 S=S+1:IFS=4THENS=1
252 GOSUB118
253 PRINT"[147][153][154]7Z(1)="Z(1)"[157]:Z(2)="Z(2)"[157]:Z(3)="Z(3)"[157]:S="S
254 PRINT"RUN";:POKE631,13:POKE632,13:POKE198,2:END
255 PRINT"SPIELER:[194]  1  [221]  2  [221]  3  [221]SUMME[194]"
256 PRINT"        [171][192][192][192][192][192][219][192][192][192][192][192][219][192][192][192][192][192][219][192][192][192][192][192][179]"
257 PRINT"        [194]     [194]     [194]     [194]     [194]"
258 PRINT"        [171][192][192][192][192][192][219][192][192][192][192][192][219][192][192][192][192][192][219][192][192][192][192][192][189]"
259 PRINT"        [221]     [221]     [221]     [221]"
260 PRINT"        [221]     [221]     [221]     [221]"
261 PRINT"        [221]-----[221]-----[221]-----[221]"
262 PRINT"        [221]     [221]     [221]     [221]"
263 RETURN
264 FORA=1TOH
265 A$=STR$(I(A)):B=LEN(A$):A$=RIGHT$(A$,B-1):B=B-1
266 C$=A$(SGN(I(A))+1)+LEFT$(B$,4-B)+A$
267 POKE214,C:POKE211,9+(A-1)*6:SYS58640:PRINTC$:NEXT:RETURN
268 V=ASC(K$(1)):H2=ASC(RIGHT$(K$(1),1)):K=0:L=0:IFH2=78THENV=SW
269 FORT=1TO28
270 IFA(T)<>STHEN274
271 J=ASC(A$(T)):Q2=ASC(RIGHT$(A$(T),1))
272 IFV=JTHENL=9:IFQ2>H2THENK=T:GOSUB432:IFCC=9THENRETURN
273 IFCC=8THEN387
274 NEXT:Q3=0:Q4=0
275 IFHZ>0ANDTT=3THENQ3=ASC(RIGHT$(K$(HZ),1)):Q4=ASC(RIGHT$(K$(3-HZ),1))
276 IFL=9THEN295
277 B=100
278 FORT=32TO1STEP-1
279 IFA(T)<>STHEN282
280 J=ASC(A$(1)):Q=ASC(RIGHT$(A$(T),1))
281 IFQ<BTHENB=Q:K=T
282 NEXT
283 IFTT=3THENIFV<>SWANDQ4>Q3ANDV=ASC(K$(2))ANDS<>AATHEN384
284 IFTT=3THENIFV<>SWANDHZ=1ANDASC(K$(2))=SWANDS<>AATHEN384
285 IFTT=3THENIFHZ=1ANDASC(RIGHT$(K$(2),1))=78ANDV<>SWANDS<>AATHEN384
286 IFTT=3THENO8=ASC(RIGHT$(K$(2),1))
287 IFTT=3THENIFV=ASC(K$(2))ANDV<>SWANDO8>75ANDS=AATHENGOSUB208
288 IFH2<75ANDV<>SWTHENRETURN
289 IFV=0ANDH2<78THENRETURN
290 J7=K:IFV<>SWTHENGOSUB208:IFJ7<>KTHENRETURN
291 FORT=28TO32:IFA(T)<>STHEN293
292 IFASC(RIGHT$(A$(T),1))=78THENK=T:RETURN
293 NEXT:IFTT=3THENIFQ4>Q3ANDV=ASC(K$(2))ANDS<>AATHEN384
294 RETURN
295 IFTT=3THENIFQ4>Q3ANDV=ASC(K$(2))ANDS<>AATHEN387
296 IFTT=3THENIFV<>SWANDHZ=1ANDASC(K$(2))=SWANDS<>AATHEN387
297 IFTT=3THENIFHZ=1ANDASC(RIGHT$(K$(2),1))=78ANDV<>SWANDS<>AATHEN387
298 H=100:FORT=1TO28
299 IFA(T)<>STHEN302
300 Q=ASC(RIGHT$(A$(T),1))
301 IFV=ASC(A$(T))ANDQ<HTHENH=Q:K=T
302 NEXT:IFV=SWANDH2>74ANDH2<78THEN291
303 IFV=SWANDASC(RIGHT$(A$(K),1))>68THEN291
304 RETURN
305 FORT=1TO32:IFA(T)=0THENA(T)=AA
306 NEXT
307 FORT=1TO4:C(T)=0:NEXT
308 FORT=1TO28
309 IFA(T)<>AATHEN315
310 A=ASC(A$(T))-96
311 IFA=122THENC(1)=C(1)+1
312 IFA=115THENC(2)=C(2)+1
313 IFA=97THENC(3)=C(3)+1
314 IFA=120THENC(4)=C(4)+1
315 NEXT:A=0
316 FORT=1TO4
317 IFC(T)<3ANDC(T)>0THENC(T)=C(T)-1:GOSUB325:IFA<2THEN317
318 IFA=2THENRETURN
319 NEXT
320 FORT=1TO28:IFA(T)<>AAORASC(A$(T))-96=SW(AA)THEN324
321 H=ASC(RIGHT$(A$(T),1))
322 IFH=55ORH=56ORH=57THENA=A+1:Q(1)=Q(1)+1:B$(1,Q(1))=A$(T):A(T)=0
323 IFA=2THENRETURN
324 NEXT:RETURN
325 FORKK=1TO28:IFA(KK)<>AATHEN328
326 IFASC(A$(KK))-96=U(T)ANDASC(A$(KK))-96<>SW(AA)THENKO=9
327 IFKO=9THENKO=0:A=A+1:Q(1)=Q(1)+1:B$(1,Q(1))=A$(KK):A(KK)=0:RETURN
328 NEXT:RETURN
329 Y=1:X=-5:GOSUB166
330 PRINT" RECHNE AUS,WIE HOCH DU REIZEN KANNST !"
331 GOSUB118
332 AB=S+2:IFAB=4THENAB=1
333 IFAB=5THENAB=2
334 PRINT"[147]"SPC(17)"REIZEN"
335 IFFG=5THENFG=0:GOTO361
336 FORV=1TO3
337 FORJ=1TO8:C(J)=0:NEXT:H=0
338 FORT=1TO32
339 IFA(T)<>VTHEN346
340 IFASC(RIGHT$(A$(T),1))=78THENH=4
341 A=ASC(A$(T))-96
342 IFA=120THENC(H+1)=C(H+1)+1
343 IFA=97THENC(H+2)=C(H+2)+1
344 IFA=115THENC(H+3)=C(H+3)+1
345 IFA=122THENC(H+4)=C(H+4)+1
346 H=0:NEXT
347 FORJ=1TO4
348 IFC(J)>HTHENH=C(J):A=J
349 NEXT:IFOL=9THEN351
350 SW(V)=N(A):IFV=1THENSW(1)=120
351 A=0:FORJ=5TO8
352 IFC(J)=1THENA=A+J(J-4)
353 NEXT:A=K(A):IFV=1ANDA=0THENA=5
354 TY=A:IFFG=9THENRETURN
355 IFSW(V)=120THENRW(V)=12*A:AS(V)=12
356 IFSW(V)=97THENRW(V)=11*A:AS(V)=11
357 IFSW(V)=115THENRW(V)=10*A:AS(V)=10
358 IFSW(V)=122THENRW(V)=9*A:AS(V)=9
359 IFOL=9THENRETURN
360 NEXT
361 IFAB=1THEN374
362 IFAB=2THEN365
363 IFRW(2)>RW(3)THENAA=2:RETURN
364 AA=3:RETURN
365 IFRW(DE)=0THENPRINT"ICH REIZE NICH !":AA=1:RETURN
366 FORT=1TO16
367 IFV(T)>RW(DE)THEN373
368 PRINT"HAST DU"V(T)" PUNKTE "
369 INPUT"(J/N)";A$:IFA$<>"J"ANDA$<>"N"THENPRINT"[145]";:GOTO369
370 IFA$="N"THENAA=DE:RETURN
371 IFA$="J"ANDV(T)>RW(1)THENPRINT"SO VIEL HAST DU NICHT !":AA=DE:RETURN
372 NEXT:AA=DE:RETURN
373 PRINT"ICH HABE NICHT MEHR !":AA=1:RETURN
374 PRINT"FANGE AN ZU REIZEN (18-60)"
375 PRINT"WILLST DU NICHT MEHR WEITER REIZEN,DANN GIB 0 EIN.":H=0
376 FORT=1TO16
377 A=H:INPUT"ZAHL ";H:IFH=0THENPRINT"DANN NICHT !":AA=DE:RETURN
378 FORV=1TO16:IFV(V)=HTHEN380
379 NEXTV:PRINT"FEHLER ![146]":H=A:GOTO377
380 IFH>RW(1)THENPRINT"SO VIEL HAST DU NICHT !":AA=DE:RETURN
381 IFH<=ATHENPRINT"FEHLER ![146]":GOTO377
382 IFH>RW(DE)THENPRINT"SO VIEL HABE ICH NICHT !":AA=1:RETURN
383 NEXTT:AA=1:RETURN
384 B=0:FORT=1TO28:IFA(T)<>STHEN386
385 IFASC(RIGHT$(A$(T),1))>BTHENK=T:B=ASC(RIGHT$(A$(T),1))
386 NEXT:RETURN
387 FORT=28TO1 STEP-1
388 IFA(T)<>STHEN390
389 IFV=ASC(A$(T))THENK=T:RETURN
390 NEXT:IFV=SWANDH2>74ANDH2<78THEN291
391 RETURN
392 A=0:J1=ASC(K$(1)):J2=ASC(K$(2)):J3=ASC(K$(3)):I1=ASC(RIGHT$(K$(1),1))
393 I2=ASC(RIGHT$(K$(2),1)):I3=ASC(RIGHT$(K$(3),1)):H=0
394 IFSW=0ANDI1=78ANDI2<78THENRR(L(2))=1:RETURN
395 IFSW=0ANDI1=78ANDI3<78THENRR(L(3))=1:RETURN
396 IFJ1=SWSORI1=78THEN402
397 IFJ1<>J2THENA=2:GOSUB405
398 IFJ1<>J3THENA=3:GOSUB405
399 IFI2=78THENA=2:GOSUB405
400 IFI3=78THENA=3:GOSUB405
401 RETURN
402 IFJ2<>SWANDI2<>78THENA=2:GOSUB408
403 IFJ3<>SWANDI3<>78THENA=3:GOSUB408
404 RETURN
405 H=L(A):FORT=1TO4
406 IFU(T)=J1-96THENY(4*H-4+T)=1
407 NEXT:RETURN
408 H=L(A):FORT=1TO4
409 IFU(T)=SW-96THENY(4*H-4+T)=1
410 NEXT:RETURN
411 FORT=1TO32
412 IFA(T)<>STHEN420
413 IFASC(RIGHT$(A$(T),1))=78THENRR=0:K=T:RETURN
414 FORJ9=1TO4
415 IFY(AA*4-4+J9)=1ANDASC(A$(T))-96=U(J9)THEN420
416 NEXTJ9
417 J=ASC(A$(T)):H=ASC(RIGHT$(A$(T),1))
418 IFH=77ANDJ<>SWTHENK=T:RR=0:RETURN
419 IFJ<>SWANDRR>HTHENRR=H:K=T
420 NEXTT:RETURN
421 FORT=1TO3:IFL(T)=1THENCC=T
422 NEXT:A$=K$(CC)
423 IFRR(1)=1ANDASC(RIGHT$(A$,1))=78THEN429
424 FORT=1TO4
425 IFY(T)=1ANDASC(A$)-96=U(T)ANDASC(RIGHT$(A$,1))<78THEN428
426 IFY(T)=1ANDU(T)=SW-96ANDASC(RIGHT$(A$,1))=78THEN428
427 NEXT:RETURN
428 GOSUB134:PRINT"[145][145][145][145][145][145][145][145][145]DU HAST GEMOGELT !":GOTO430
429 GOSUB134:PRINT"[145][145][145][145][145][145][145][145][145]DU HATTEST JA DOCH NOCH EINEN BUBEN !"
430 GOSUB118:CC=5:Q(1)=0:IFAA=1THENA=0:GOTO211
431 A=120:GOTO211
432 CC=0:IFTT=2THENCC=9:RETURN
433 A1=ASC(RIGHT$(K$(1),1)):A2=ASC(RIGHT$(K$(2),1)):A3=ASC(RIGHT$(A$(K),1))
434 IFASC(K$(1))=ASC(K$(2))ANDA3>A2ANDA3>A1ANDA2<78ANDV<>SWTHENCC=8:RETURN
435 RETURN