10 REM"[193]RTIKEL"
20 PRINTCHR$(147):IFS%=0THENS%=1:LOAD"INPUT",8,1
30 SYS49152:J%(1)=1:J%(2)=23:J%(3)=33:J%(4)=40:V$=CHR$(29):T$="!"
40 L1$="-----":L2$="=====":BL$="[160][160][160][160][160]":DIMA$(600),B%(100):OPEN15,8,15
50 FORI=1TO4:L1$=L1$+L1$:L2$=L2$+L2$:BL$=BL$+BL$:NEXTI:L3$=LEFT$(L2$,40)
60 GOSUB400:Z=6:S=8:GOSUB800:PRINT"[197]INEN [193]UGENBLICK BITTE"
70 L5$=LEFT$(L1$,39):I%(1)=22:I%(2)=10:I%(3)=7:I%(4)=4:L$="!"+LEFT$(L2$,78)+"!"
80 EI$="[194]ITTE [208]ROGRAMMWUNSCH EINGEBEN   :":WI$="[215]EITERE [197]INGABEN  J/N    :J"
90 K$="!"+LEFT$(L1$,78)+"!":FA$="[194]ITTE [198]IRMENABKUERZUNG EINGEBEN  :"
100 OPEN2,8,2,"[193]NZAHL-[211]AETZE,S,R":GOSUB9500:IFA<>0THENA%=0:CLOSE2:GOTO1000
120 INPUT#2,A%:GOSUB9500:CLOSE2:OPEN2,8,2,"[193]RTIKEL-[206]R.,S,R":GOSUB9500
130 Z=10:S=7:GOSUB800:PRINT"[201]CH LADE"A%" [196]ATENSAETZE":IFA%=0THENCLOSE2:GOTO1000
170 FORI=1TOA%:INPUT#2,A$(I):PRINTCHR$(19)I:NEXTI:GOSUB9500:CLOSE2:GOTO1000
400 PRINTCHR$(147):Z=0:S=10:GOSUB800:PRINT"[208]ROGRAMM [193]RTIKEL":PRINTL3$;
410 PRINTLEFT$(BL$,(40-LEN(M$))/2)M$:Z=23:S=0:GOSUB800:PRINTL3$;
420 Z=23:S=0:GOSUB800:PRINTL3$;"[160][160]_ LETZTE [197]INGABE  * LETZTES [205]ENUE";:RETURN
450 B$(1)="[193]RTIKEL-[194]EZ.   :":B$(2)="[193]RTIKEL-[206]R.    :":B$(3)="[197]INKAUFSPREIS  :"
460 B$(4)="[194]ESTAND        :":DA%=2:RETURN
500 B$(1)="1. [193]LLE [193]RTIKEL":B$(2)="2. [193]LLE [193]RTIKEL EINER [198]IRMA":DA%=3:RETURN
600 B$(1)="1. [193]LLE [193]RTIKEL AUSDRUCKEN":B$(2)="2. [193]LLE [193]RTIKEL EINER [198]IRMA"
610 B$(3)="3. [201]NVENTUR DRUCKEN":RETURN
700 B$(1)="1. [206]EUEINGABE":B$(2)="2. [193]ENDERUNGEN":B$(3)="3. [194]ILDSCHIRMAUSGABE"
710 B$(4)="4. [196]RUCKERAUSGABE":B$(5)="5. [211]ORTIEREN":B$(6)="6. [211]TREICHEN"
720 B$(7)="7. [211]TUECKZAHLEINGABE":B$(8)="8. [211]TCKZ. AUF 0 SETZEN"
730 B$(9)="9. [208]ROGRAMM BEENDEN":DA%=1:RETURN
800 POKE214,Z:POKE211,S:SYS58640:RETURN
850 GOSUB400:Z=2:S=0:GOSUB800:PRINT"[211]-[206]. [193]RTIKELBEZ [193]RTIK-[206]R.  [197][203]-[208]R.  [211][212][195][203]"
870 PRINTL5$:RETURN
880 PRINT:PRINT"[212]ASTE = WEITER  - = ZURUECK * = ABBRUCH":Y$=""
890 GETY$:IFY$="*"THENHH%=1:RETURN
895 IFY$=""THEN890
896 IFY$="-"THENI=I-34:RETURN
900 RETURN
950 :
960 FORN=Z%TO71:PRINT#7:NEXTN:Z%=0:RETURN
1000 :
1010 M$="[200]AUPTMENUE":IFDA%<>1THENGOSUB700:GOSUB400
1060 FORI=1TO9 :Z=1+I*2:S=8:GOSUB800:PRINTB$(I):NEXTI:PRINT:PRINT" "EI$
1070 Z=0:S=32:GOSUB800:INPUT>1,34,21,X$:IFX$="9"THEN10000
1100 ONVAL(X$)GOSUB1200,1500,2000,2500,3000,3500,4000,4500:GOTO1000
1200 :
1210 M$="[205]AX. 600 [206]EUEINGABEN":A%=A%+1:IFDA%<>2THENGOSUB450:IFA%=601THEN1000
1260 GOSUB400:Z=3:S=0:GOSUB800:PRINT"[196]IE LETZTE [197]INGABE WAR [208]OSITION [206]R."A%-1
1265 FORI=1TO4:Z=3+I:S=0:GOSUB800:PRINTB$(I)MID$(A$(A%-1),J%(I),I%(I))"*":NEXTI
1280 PRINTL5$:S=0:FORI=1TO4:Z=8+I*2:GOSUB800:PRINTB$(I)LEFT$(BL$,I%(I))"*"
1290 NEXTI:PRINT:PRINT:PRINTWI$
1350 FORI=1TO4
1360 INPUT>I%(I),16,8+I*2,C$(I):IFLEFT$(C$(I),1)=CHR$(224)THEN1360
1370 IFI>1ANDLEFT$(C$(I),1)="_"THENI=I-1:GOTO1360
1375 IFLEFT$(C$(1),1)="*"THENA%=A%-1:RETURN
1376 IFI<3ANDASC(LEFT$(C$(I),1))<91THEN1360
1377 IFI=2THEN:IFMID$(C$(I),3,1)<>"."ORMID$(C$(I),8,1)<>"."THEN1360
1378 IFI=3ANDMID$(C$(I),5,1)<>"."THEN1360
1380 IFI=4THEN:IFASC(C$(4))>57THEN1360
1400 NEXTI:A$(A%)="":FORI=1TO4:A$(A%)=A$(A%)+C$(I):NEXTI
1450 INPUT>1,26,19,X$:IFX$="J"THENA%=A%+1:GOTO1260
1460 IFLEFT$(X$,1)="_"THEN1350
1470 GOSUB9000:RETURN
1500 :
1510 M$="[193]ENDERN":GOSUB400:IFDA%<>2THENGOSUB450
1520 Z=3:S=6:GOSUB800:PRINT"[194]ITTE ZU AENDERNDE [211]ATZ-[206]R."
1530 Z=5:S=10:GOSUB800:PRINT"EINGEBEN   :":PRINT:PRINTL5$
1540 INPUT>4,22,5,X$:IFLEFT$(X$,1)="*"THENGOSUB9000:RETURN
1550 H%=VAL(X$):IFH%=0ORH%>A%THEN1500
1560 S=0:FORI=1TO4:Z=8+I*2:GOSUB800:PRINTB$(I)MID$(A$(H%),J%(I),I%(I))"*":NEXTI
1570 PRINT:PRINT:PRINTWI$
1650 H$="":FORI=1TO4
1660 INPUT>I%(I),16,8+I*2,C$(I):IFLEFT$(C$(I),1)=CHR$(224)THEN1660
1670 IFI>1ANDLEFT$(C$(I),1)="_"THENI=I-1:GOTO1660
1675 IFI=1THEN:IFLEFT$(C$(1),1)="*"THENGOSUB9000:RETURN
1676 IFI<3ANDASC(LEFT$(C$(I),1))<91THEN1660
1677 IFI=2THEN:IFMID$(C$(I),3,1)<>"."ORMID$(C$(I),8,1)<>"."THEN1660
1678 IFI=3ANDMID$(C$(I),5,1)<>"."THEN1660
1680 IFI=4THEN:IFASC(C$(4))>57THEN1660
1690 NEXTI
1700 FORI=1TO4:H$=H$+C$(I):NEXTI:A$(H%)=H$:INPUT>1,26,19,X$:IFX$="J"THEN1500
1720 GOSUB9000:RETURN
2000 :
2010 M$="[194]ILDSCHIRM":H$="":GOSUB400:IFDA%<>3THENGOSUB500:H%=0
2020 S=6:FORI=1TO2:Z=4+I*2:GOSUB800:PRINTB$(I):NEXTI:PRINT:PRINT:PRINT"[160][160]"EI$
2030 INPUT>1,35,11,X$:IFLEFT$(X$,1)="*"THENRETURN
2040 IFX$="1"THENN%=1:GOTO2200
2050 Z=16:S=2:GOSUB800:PRINTFA$
2060 INPUT>2,36,16,X$:H$=X$:IFLEFT$(X$,1)="*"THENRETURN
2070 IFASC(LEFT$(X$,1))<91ORASC(RIGHT$(X$,1))<91THEN2060
2080 FORI=1TOA%:IFMID$(A$(I),23,2)=X$THENN%=I:I=A%
2090 NEXTI
2200 GOSUB850:FORI=N%TOA%:IFX$<>"1"THEN:IFMID$(A$(I),23,2)<>H$THEN2290
2220 PRINTRIGHT$("[160][160][160][160]"+STR$(I),4)"[160]"LEFT$(A$(I),10)"[160]"MID$(A$(I),23,10)"[160]";
2230 PRINTMID$(A$(I),33,7)"[160]"RIGHT$("[160][160][160][160]"+STR$(VAL(MID$(A$(I),40,4))),4):T%=I
2240 H%=H%+1:IFH%=17THENGOSUB880:IFHH%=1THENHH%=0:RETURN
2245 IFI<0THENI=0
2250 IFH%=17THENGOSUB850:H%=0
2290 NEXTI:H%=0:PRINT:PRINT"[160][196]ATEIENDE!  - = ZURUECK   * = [205]ENUE"
2300 GETY$:IFY$="*"THENRETURN
2305 IFY$="-"THENN%=T%-34:IFN%<0THENN%=0
2306 IFY$="-"THEN2200
2310 GOTO2300
2500 :
2510 M$="[196]RUCKEN":GOSUB400:IFDA%<>3THENGOSUB600:DA%=3
2520 S=2:FORI=1TO3:Z=4+I*2:GOSUB800:PRINTB$(I):NEXTI
2540 PRINT:PRINT:PRINT"[160][160]"EI$:INPUT>1,35,13,X$
2550 ONVAL(X$)GOSUB2570,2800,5000:GOTO1000
2570 Z=18:S=2:GOSUB800:PRINT"[194]ITTE [196]ATUM EINGEBEN    :"
2580 INPUT>8,27,18,DT$:IFMID$(DT$,3,1)<>"."ORMID$(DT$,6,1)<>"."THEN2580
2590 Z=20:S=4:GOSUB800:PRINT"[201]CH DRUCKE DIE [194]ESTANDSLISTE !"
2600 OPEN7,4,7:OPEN2,4,2:OPEN1,4,1:BL%=1:GOSUB2900
2610 F$="A9999  AAAAAAAAAAAAAAAAAAAAAA AAAAAAAAAA99999 9999.99 99999.99 "
2615 F$=F$+"9999.99 99999.99A"
2620 F1$="A AAAAAAAAAAAAA        AAAAAAAAAAAAAAAA  999999.99  "
2622 F1$=F1$+"AAAAAAAAAAAAAAAA  999999.99A":S1=0:S2=0:S3=0:S4=0:S5=0:S6=0
2628 Z1$="[218]WISCHENSUMME":Z2$="[197][203]-[218]WISCHENSUMME":Z3$="[214][203]-[218]WISCHENSUMME"
2630 FORI=1TOA%:IFX$="2"ANDMID$(A$(I),23,2)<>FI$THEN2720
2640 BZ$=LEFT$(A$(I),22):AT$=MID$(A$(I),23,10):S=VAL(MID$(A$(I),40,7))
2650 VK=VAL(MID$(A$(I),26,7)):EK=VAL(MID$(A$(I),33,7))
2660 S1=INT(S*VK*100+.05)/100:S2=INT(S*EK*100+.05)/100
2680 PRINT#2,F$:PRINT#1,"!"V$I;BZ$V$AT$V$S;EK;S2;VK;S1;"!":Z%=Z%+1
2690 S3=S3+S1:S4=S4+S2:S5=S5+S1:S6=S6+S2
2700 IFMID$(A$(I),23,2)<>MID$(A$(I+1),23,2)THENGOSUB2850
2705 IFA%-I<=3THEN2720
2710 IFZ%>=62THENPRINT#7,K$:Z%=Z%+1:GOSUB950:GOSUB2900
2720 NEXTI:PRINT#7,L$:PRINT#2,F1$
2745 PRINT#1,"!"V$"[197][206][196][194][197][212][210][193][197][199][197]"V$"[197][203]-[197][206][196][211][213][205][205][197]"V$S4;"[214][203]-[197][206][196][211][213][205][205][197]"V$S3;"!"
2760 PRINT#7,L$:CLOSE1:CLOSE2:CLOSE7:S1=0:S2=0:S3=0:S4=0:Z%=0:RETURN
2800 :
2810 Z=16:S=2:GOSUB800:PRINTFA$:INPUT>2,36,16,FI$:GOTO2570
2850 PRINT#7,K$:PRINT#2,F1$:PRINT#1,"!"V$Z1$V$Z2$V$S6;Z3$V$S5;"!":Z%=Z%+3
2860 PRINT#7,K$:S5=0:S6=0:RETURN
2900 PRINT#7,"! [193]USDRUCK DER [215]ARENBESTAENDE [203]OSMETIKBOUTIQUE [215]ERNER [196]EMUTH  ";
2910 PRINT#7,DT$" [194]L.: "RIGHT$("[160][160]"+STR$(BL%),2)"[160]!":PRINT#7,L$
2930 PRINT#7,"![211]ATZ! [193]RTIKEL-[194]EZEICHNUNG[160][160][160]! [193]RTIK.[206]R.![211]TCK!";
2940 PRINT#7,"[197][203]-[208]REIS! [211]UMME ![214][203]-[208]REIS! [211]UMME !":Z%=Z%+4:BL%=BL%+1
2950 PRINT#7,L$:RETURN
3000 :
3010 M$="[211]ORTIEREN":DA%=0:GOSUB400
3015 Z=8:S=6:GOSUB800:PRINT"[201]CH SORTIERE "A%" [196]ATENSAETZE":AZ%=A%:B=AZ%
3030 B=INT(B/3+.4):PRINTCHR$(19)AZ%-B
3040 OD=0:FORA=1TOAZ%-B
3050 IFMID$(A$(A),23,10)>MID$(A$(A+B),23,10)THENC=A+B:GOSUB3100:OD=1
3060 NEXTA:IFODTHEN3040
3070 IFB>1THEN3030
3080 GOSUB9000:RETURN
3100 X$=A$(A):A$(A)=A$(C):A$(C)=X$:RETURN
3500 :
3510 M$="[205]AX. 100 [211]AETZE STREICHEN !":H=0:GOSUB400:DA%=0:FORI=1TO100
3530 Z=3:S=1:GOSUB800:PRINT"[218]U STREICHENDE [211].-[206]R. EINGEBEN  :   "
3540 INPUT>4,34,3,X$:IFI=1ANDLEFT$(X$,1)="*"THENRETURN
3541 IFI=2ANDLEFT$(X$,1)="_"THENI=1:B%(1)=0
3542 IFLEFT$(X$,1)="*"THENI=100:GOTO3800
3545 IFI>1ANDLEFT$(X$,1)="_"THENI=I-2:GOTO3605
3548 IFVAL(X$)=0ORVAL(X$)>A%THEN3540
3550 B%(I)=VAL(X$):IFI=1THEN3605
3560 FORN=1TOI-1
3570 IFB%(N)=VAL(X$)THENH=1
3580 NEXTN:IFH=1THENH=0:I=I-1:GOTO3540
3605 A=1:IFI>14THENA=I-14
3610 Z=5:S=0:GOSUB800:FORJ=ATOI:PRINT"[197]INGABE-[206]R. :"RIGHT$("[160][160][160][160]"+STR$(J),3);
3620 PRINT"[160][160][160][211]ATZ-[206]R. :"RIGHT$("[160][160][160][160]"+STR$(B%(J)),3):NEXTJ:PRINTLEFT$(BL$,38)
3720 Z=22:S=3:GOSUB800:PRINT"[215]EITERE [211]TREICHUNGEN J/N   :J"
3730 INPUT>1,31,22,X$:IFX$="N"THENAZ%=I:I=100:H=1:GOTO3800
3740 IFX$<>"J"THEN3720
3800 X$="":NEXTI:IFH=0THENAZ%=I-1
3810 GOSUB400:Z=4:S=1:GOSUB800:PRINT"[211]OLLEN DIE [211]AETZE WIRKLICH GESTICHEN"
3820 Z=6:S=10:GOSUB800:PRINT"WERDEN   J/N   :J"
3830 B=AZ%:INPUT>1,26,6,X$:IFX$="N"THENRETURN
3860 B=INT(B/3+.4)
3870 OD=0:FORA=1TOAZ%-B
3880 IFB%(A)<B%(A+B)THENC=A+B:X=B%(A):B%(A)=B%(C):B%(C)=X:OD=1
3890 NEXTA:IFODTHEN3870
3900 IFB>1THEN3860
3940 FORN=1TOAZ%:Z=10:S=0:GOSUB800:PRINT"[193]RTIKEL "LEFT$(A$(B%(N)),32)
3945 Z=12:S=10:GOSUB800:PRINT"WIRD GESTRICHEN !"
3950 FORM=B%(N)TOA%-1:A$(M)=A$(M+1):NEXTM:A%=A%-1:NEXTN:GOSUB9000:RETURN
4000 :
4010 M$="[211][212][195][203]-[197]ING.":GOSUB400:IFDA%<>2THENGOSUB450
4020 Z=3:S=6:GOSUB800:PRINT"[194]ITTE EINZUGEBENDE [211]ATZ-[206]R."
4030 Z=5:S=10:GOSUB800:PRINT"EINGEBEN   :":PRINT:PRINTL5$
4040 INPUT>4,22,5,X$:IFLEFT$(X$,1)="*"THENGOSUB9000:RETURN
4050 H%=VAL(X$):IFH%=0ORH%>A%THEN4000
4060 S=0:FORI=1TO4:Z=8+I*2:GOSUB800:PRINTB$(I)MID$(A$(H%),J%(I),I%(I))"*":NEXTI
4170 INPUT>4,16,16,X$:IFLEFT$(X$,1)="_"THEN4040
4180 IFLEFT$(X$,1)>"9"ORLEFT$(X$,1)<"0"THEN4170
4200 A$(H%)=LEFT$(A$(H%),39)+X$:GOTO4000
4500 :
4510 M$="":GOSUB400:DA%=0
4520 Z=5:S=1:GOSUB800:PRINT"[211]OLLEN DIE [211]TUECKZAHLEN WIRKLICH AUF 0"
4530 Z=7:S=4:GOSUB800:PRINT"GESETZT WERDEN ??? J/N   :"
4540 INPUT>1,30,7,X$:IFX$<>"J"THENRETURN
4560 Z=9:S=2:GOSUB800:PRINT"[196]IE [211]TUECKZAHLEN WERDEN AUF 0 GESETZT":FORI=1TOA%
4570 A$(I)=LEFT$(A$(I),39)+"0[160][160][160]":PRINTCHR$(19)I:NEXTI:GOSUB9000:RETURN
5000 :
5010 M$="[201]NVENTUR":GOSUB400:Z=5:S=5:GOSUB800:BL%=0:S1=0:S2=0
5020 PRINT"[194]ITTE [196]ATUM EINGEBEN   :":INPUT>8,29,5,DT$
5030 IFLEFT$(X$,1)="*"THENRETURN
5040 Z=7:S=5:GOSUB800:PRINT"[194]ITTE [202]AHR EINGEBEN   :"
5045 INPUT>4,29,7,J$:IFLEFT$(J$,1)="_"THEN5020
5050 F$="A 99999   A AAAAAAAAAAAAAAAAAAAAAAAA A 99999  A 99999.99 A"
5060 F$=F$+" 999999.99   A       A"
5070 F1$="A AAAAAAAAAAAAAAAAAAAAA                                   "
5080 F1$=F1$+"9999999.99           A"
5100 OPEN7,4,7:OPEN2,4,2:OPEN1,4,1:GOSUB5400
5120 FORI=1TOA%:IFVAL(MID$(A$(I),40,7))=0THEN5210
5130 AT$=LEFT$(A$(I),24):S=VAL(MID$(A$(I),40,7))
5140 EK=INT(VAL(MID$(A$(I),33,7))*100+.05)/100:S1=INT(S*EK*100+.05)/100
5160 PRINT#2,F$:PRINT#1,T$V$I;T$V$AT$V$T$V$S;T$V$EK;T$V$S1;T$V$T$
5165 Z%=Z%+1:S2=S2+S1:IFI=A%ANDZ%=66THEN5210
5170 IFZ%<=64THEN5210
5180 PRINT#7,K$:PRINT#2,F1$:PRINT#1,T$V$"[218]WISCHENSUMME"V$S2;"!":PRINT#7,K$
5200 Z%=Z%+3:GOSUB960:GOSUB5400
5210 NEXTI:PRINT#7,L$:PRINT#2,F1$
5220 PRINT#1,T$V$"[197][206][196][211][213][205][205][197] [201][206][214][197][206][212][213][210]"V$S2;"!":PRINT#7,L$
5230 CLOSE7:CLOSE1:CLOSE2:S1=0:S2=0:BL%=0:RETURN
5400 PRINT#7,"! [203]OSMETIK - [194]OUTIQUE  [215]ERNER [196]EMUTH  [201]NVENTUR  "J$"  [196]ATUM: ";
5410 BL%=BL%+1:PRINT#7,DT$"  [194]L. "RIGHT$("[160][160][160]"+STR$(BL%),2)"[160][160]!":PRINT#7,L$
5430 PRINT#7,"! [211]ATZ-[206]R.! [193]RTIKEL-[194]EZEICHNUNG      ! [211]TUECK ! [197][203]-[208]REIS !";
5440 PRINT#7,"    [211]UMME    ![194]EMERK.!":PRINT#7,K$:Z%=4:RETURN
9000 :
9010 M$="[193]BSPEICHERN":GOSUB400:Z=6:S=6:GOSUB800
9020 PRINT"[196]ATEN ABSPEICHERN J/N  :J":INPUT>1,30,6,X$:IFX$="J"THEN9100
9030 RETURN
9100 Z=8:S=3:GOSUB800:PRINT"[201]CH SPEICHERE "A%" [196]ATENSAETZE"
9120 OPEN1,8,15,"S:[193]NZAHL-[211]AETZE":CLOSE1
9130 OPEN2,8,2,"[193]NZAHL-[211]AETZE,S,W":PRINT#2,A%CHR$(13):CLOSE2
9140 OPEN1,8,15,"S:[193]RTIKEL-[206]R.":CLOSE1
9150 OPEN2,8,2,"[193]RTIKEL-[206]R.,S,W"
9160 FORI=1TOA%:PRINT#2,A$(I):PRINTCHR$(19)I:NEXTI:CLOSE2:RETURN
9500 INPUT#15,A:IFA<>0THENCLOSE15:STOP
9510 RETURN
9990 OPEN3,4,4:PRINT#3,CHR$(66):OPEN4,4:PRINT#4,CHR$(147)
9992 OPEN7,4,7:CMD7:LIST:CLOSE3:CLOSE4:CLOSE7:END
9995 OPEN3,4,3:PRINT#3,CHR$(66):OPEN4,4:PRINT#4,CHR$(147)
9996 OPEN7,4,7:CMD7:LIST:CLOSE3:CLOSE4:CLOSE7:GOTO10000
9999 OPEN1,8,15:PRINT#1,"S:[193]RTIKEL":CLOSE1:SAVE"[193]RTIKEL",8:VERIFY"[193]RTIKEL",8
10000 CLOSE15:END