1 REM DEZIMAL-DISASSEMBLER
2 REM
3 REM STEFAN HEINE
4 REM WIESENREDDER 1
5 REM 2330 ECKERNFOERDE
6 REM
7 REM
10 POKE53280,0:POKE53281,0
20 PRINT"[147][155]         DISASSEMBLER  1.5"
30 PRINT"            BY ST.HEINE"
40 PRINT:PRINT:PRINT
50 PRINT"[158]* ADRESSEN BITTE DEZIMAL "
60 PRINT"  EINGEBEN!!!":PRINT
70 PRINT"* ADRESSEN: W=WEITER E=ENDE":PRINT
80 PRINT"* DRUCKER : 'RETURN'=NEIN"
90 PRINT:PRINT:PRINT
100 REM    COPYRIGHT * ST.HEINE *
110 DIMM$(255),L%(255),F%(255),F1$(12),F2$(12)
120 FORI=0TO255:READM$(I):NEXT:FORI=0TO255:READL%(I):NEXT:FORI=0TO255:READF%(I)
130 NEXT:FORI=0TO12:READF1$(I),F2$(I):NEXT:PC=0
140 IFIC=1THENGOSUB360:IC=0
150 INPUT"[154]# ANFANGSADRESSE";A$
160 INPUT"[155]# AUSGABE AUF DRUCKER";GC$
170 HC$=LEFT$(GC$,1)
180 IFHC$="J"THENIC=1
190 J=LEN(A$):IFJ>5THEN140
200 IFA$="W"THEN230
210 IFA$="E"THEN900
220 PC=VAL(A$)
230 FORI=1TO24:DZ=PC:PRINT"";:P1=PEEK(PC)
240 ONL%(P1)GOSUB260,270,330
250 NEXT:GOTO140
260 PRINTTAB(1)"";PC;:PRINTTAB(9)"";P1;:PRINT"";TAB(24);M$(P1):PC=PC+1:RETURN
270 PRINTTAB(1)"";PC;:PRINTTAB(9)"";P1;:P2=PEEK(PC+1):PRINTTAB(13)P2;
280 PRINT"";TAB(24)M$(P1);" [154]";
290 IFF%(P1)=9THENP2=PEEK(PC+1):IFP2<128THENP2=PC+P2+2:GOTO310
300 IFF%(P1)=9THENP2=PC-(255-P2)+1
310 PRINTF1$(F%(P1));P2;:DZ=P2:GOTO320
320 PRINTF2$(F%(P1)):PC=PC+2:RETURN
330 PRINTTAB(1)"";PC;:PRINTTAB(9)"";P1;:P2=PEEK(PC+1):PRINTTAB(14)P2;
340 P3=PEEK(PC+2):PRINTTAB(19)P3;:PRINT"";TAB(24);M$(P1)"[154]";:P4=(P3*256)+P2
350 PRINTP4;F1$(F%(P1));:DZ=P3*256+P2:PRINTF2$(F%(P1)):PC=PC+3:RETURN
360 OPEN4,4:PRINT#4,CHR$(15)
370 VB=1024:VC=55296
380 FORI=VBTOVB+999STEP40:P$=""
390 FORJ=0TO39:X=PEEK(I+J)
400 IFX<32THENX=X+64:GOTO440
410 IFX<64THEN440
420 IFX<96THENX=X+32:GOTO440
430 IFX<128THENX=X+64:GOTO440
440 P$=P$+CHR$(X)
450 NEXT:PRINT#4,P$:NEXT:CLOSE4:RETURN
460 REM*** DATAS BEFEHLSLISTE ***
470 DATABRK,ORA,???,???,???,ORA,ASL,???,PHP,ORA,ASL,???,???,ORA,ASL,???
480 DATABPL,ORA,???,???,???,ORA,ASL,???,CLC,ORA,???,???,???,ORA,ASL,???
490 DATAJSR,AND,???,???,BIT,AND,ROL,???,PLP,AND,ROL,???,BIT,AND,ROL,???
500 DATABMI,AND,???,???,???,AND,ROL,???,SEC,AND,???,???,???,AND,ROL,???
510 DATARTI,EOR,???,???,???,EOR,LSR,???,PHA,EOR,LSR,???,JMP,EOR,LSR,???
520 DATABVC,EOR,???,???,???,EOR,LSR,???,CLI,EOR,???,???,???,EOR,LSR,???
530 DATARTS,ADC,???,???,???,ADC,ROR,???,PLA,ADC,ROR,???,JMP,ADC,ROR,???
540 DATABVS,ADC,???,???,???,ADC,ROR,???,SEI,ADC,???,???,???,ADC,ROR,???
550 DATA???,STA,???,???,STY,STA,STX,???,DEY,???,TXA,???,STY,STA,STX,???
560 DATABCC,STA,???,???,STY,STA,STX,???,TYA,STA,TXS,???,???,STA,???,???
570 DATALDY,LDA,LDX,???,LDY,LDA,LDX,???,TAY,LDA,TAX,???,LDY,LDA,LDX,???
580 DATABCS,LDA,???,???,LDY,LDA,LDX,???,CLV,LDA,TSX,???,LDY,LDA,LDX,???
590 DATACPY,CMP,???,???,CPY,CMP,DEC,???,INY,CMP,DEX,???,CPY,CMP,DEC,???
600 DATABNE,CMP,???,???,???,CMP,DEC,???,CLD,CMP,???,???,???,CMP,DEC,???
610 DATACPX,SBC,???,???,CPX,SBC,INC,???,INX,SBC,NOP,???,CPX,SBC,INC,???
620 DATABEQ,SBC,???,???,???,SBC,INC,???,SED,SBC,???,???,???,SBC,INC,???
630 REM*** DATAS 1,2 ODER 3 BIT ***
640 DATA1,2,1,1,1,2,2,1,1,2,1,1,1,3,3,1,2,2,1,1,1,2,2,1,1,3,1,1,1,3,3,1
650 DATA3,2,1,1,2,2,2,1,1,2,1,1,3,3,3,1,2,2,1,1,1,2,2,1,1,3,1,1,1,3,3,1
660 DATA1,2,1,1,1,2,2,1,1,2,1,1,3,3,3,1,2,2,1,1,1,2,2,1,1,3,1,1,1,3,3,1
670 DATA1,2,1,1,1,2,2,1,1,2,1,1,3,3,3,1,2,2,1,1,1,2,2,1,1,3,1,1,1,3,3,1
680 DATA1,2,1,1,2,2,2,1,1,1,1,1,3,3,3,1,2,2,1,1,2,2,2,1,1,3,1,1,1,3,1,1
690 DATA2,2,2,1,2,2,2,1,1,2,1,1,3,3,3,1,2,2,1,1,2,2,2,1,1,3,1,1,3,3,3,1
700 DATA2,2,1,1,2,2,2,1,1,2,1,1,3,3,3,1,2,2,1,1,1,2,2,1,1,3,1,1,1,3,3,1
710 DATA2,2,1,1,2,2,2,1,1,2,1,1,3,3,3,1,2,2,1,1,1,2,2,1,1,3,1,1,1,3,3,1
720 REM*** DATAS BEFEHLART (ZEICHEN)***
730 DATA0,10,0,0,0,4,4,0,0,2,1,0,0,3,3,0
740 DATA9,11,0,0,0,5,5,0,0,8,0,0,0,7,7,0
750 DATA3,10,0,0,4,4,4,0,0,2,1,0,3,3,3,0
760 DATA9,11,0,0,0,5,5,0,0,8,0,0,0,7,7,0
770 DATA0,10,0,0,0,4,4,0,0,2,1,0,3,3,3,0
780 DATA9,11,0,0,0,5,5,0,0,8,0,0,0,7,7,0
790 DATA0,10,0,0,0,4,4,0,0,2,1,0,12,3,3,0
800 DATA9,11,0,0,0,5,5,0,0,8,0,0,0,7,7,0
810 DATA0,10,0,0,4,4,4,0,0,0,0,0,3,3,3,0
820 DATA9,11,0,0,5,5,6,0,0,8,0,0,0,7,0,0
830 DATA2,10,2,0,4,4,4,0,0,2,0,0,3,3,3,0
840 DATA9,11,0,0,5,5,6,0,0,8,0,0,7,7,8,0
850 DATA2,10,0,0,4,4,4,0,0,2,0,0,3,3,3,0
860 DATA9,11,0,0,0,5,5,0,0,8,0,0,0,7,7,0
870 DATA2,10,0,0,4,4,4,0,0,2,0,0,3,3,3,0
880 DATA9,11,0,0,0,5,5,0,0,8,0,0,0,7,7,0
890 DATA,,,,#,,,,,,,",X",,",Y",,",X",,",Y",,,(,",X)",(,"),Y",(,),
900 END