10 REM ****************************
20 REM *   FEIGENBAUM-DIAGRAMM    *
30 REM * 1987 BY STEFAN VILSMEIER *
40 REM ****************************
50 :
60 IF A=0 THEN A=1:LOAD "FRACTAL.OBJ",8,1
70 OPEN 1,8,15,"U9":CLOSE 1: REM DIESE ZEILE KANN BEI PROBLEMEN MIT DEM
80 REM FLOPPYSPEEDER WEGGELASSEN WERDEN!
90 POKE53280,0:POKE53281,0:DIMH%(128):PRINT"[147]"
100 INPUT "ANFANGSWERT ";X0:X=.5
110 REM ************ GRAFIK EIN *****
120 SYS 50176,14,0:SYS 50179,1:SYS 50194
130 :
140 :
150 REM ***************************
160 REM *     HAUPTSCHLEIFE       *
170 REM ***************************
180 :
190 FOR I=0 TO 319
200 :W=(4-X0)/319:A=X0+W*I
210 :FOR T=0 TO 100
220 : X=A*X*(1-X)
230 :NEXT T
240 :FOR T=0 TO 100
250 : X=A*X*(1-X)
260 : SYS50182,I,200-200*X,1
270 :NEXT T
280 NEXT I
300 SYS 50185,0,0,319,0,1:SYS 50185,319,0,319,199,1
310 SYS 50185,319,199,0,199,1:SYS 50185,0,199,0,0,1
320 GET A$:IF A$="" GOTO 320
330 SYS 50179,0:IF A$="S" THEN GOSUB 400: REM 'GRAFIK SPEICHERN'
340 GOTO 100: REM NEUSTART
350 :
360 :
370 REM ***************************
380 REM *   'GRAFIK SPEICHERN'    *
390 REM ***************************
400 :
410 INPUT "GRAFIK-NAME ";N$
420 OPEN 2,8,2,"PI."+N$+",P,W":SYS 50191:CLOSE 2
430 RETURN