100 PRINT"[147]"SPC(11)"L E X I T R O N":DIMAR$(20,15),AR(20,15),LN(200)
110 P$="               ":FORA=0TO10:READQ(A):NEXT
120 FORA=0TO8:READD(A):NEXT:DATA 0,1,5,0,7,8,6,0,3,2,4,0,-40,-39,1,41,40,39,-1
130 DIML(200):DATA -41:PRINTSPC(3)"PLEASE WAIT WHILE LOADING WORDS"
140 S=54272:FORA=STOS+23:POKEA,0:NEXT:POKEA,15:POKES+5,28:POKE53280,6
150 SC=1274:CD=54272:PT=56320:BC=53281:W=15:BL=6:SB=53265:CS=15
160 Z=646:A1=15:A2=14:A3=1:A4=7:A5=6:A6=1
170 GOSUB1160:GOSUB1120
180 GOSUB1090
190 GW=0:FORA=0TO19:FORB=0TO14:AR(A,B)=0:NEXTB,A:FORA=0TONW:L(A)=0:NEXT:PS=SC
200 LL=7:POKEBC,W:POKEZ,A5:PRINT"[147]     USE JOYSTICK TO CHOOSE A LEVEL"
210 POKEZ,A6:PRINTSPC(10)"     1";:POKEZ,A5:PRINT"  2  3":MS=SC+5
220 PRINT"   1[146]  ALL WORDS SPELLED FORWARDS              NO DIAGONALS"
230 PRINT"   2[146]  FORWARD & REVERSED SPELLINGS            NO DIAGONALS"
240 PRINT"   3[146]  FORWARD & REVERSED SPELLINGS            DIAGONALS INCLUDED"
250 GOSUB410:IFJ=0THEN250
260 POKEMS+CD,A5:MS=MS-3*(J=3)*-(MS<SC+11)+3*(J=7)*-(MS>SC+5):POKEMS+CD,A6
270 IFJ<128THEN250
280 PRINT"[147][144]"SPC(14)"PLEASE WAIT":FORTD=1TO1000:NEXT
290 LV=(MS-(SC+5))/3+1:POKESB,PEEK(SB)AND239:POKEBC,BL:GOSUB970
300 GOSUB850:QF=1:T=1:GOSUB480:POKESB,PEEK(SB)OR16:TI$="000000":GOTO390
310 REM JOYSTICK ROUTINE
320 IFRND(1)<.003THENGOSUB670
330 IFRND(1)<.009THENGOSUB540
340 GOSUB410:IFJ=0THEN320
350 IFJ>127THENGOSUB430:GOTO320
360 POKEPS,PEEK(PS)AND127:TP=PS
370 IF(PEEK(PS+CD)ANDCS)=A3THENPOKEPS+CD,A2
380 PS=PS+D(JAND15):IFPEEK(PS)<1ORPEEK(PS)>26THENPS=TP
390 POKEPS,PEEK(PS)OR128:IF(PEEK(PS+CD)ANDCS)<>A4THENPOKEPS+CD,A3
400 GOTO320
410 J=Q(15-(PEEK(PT)AND15))-128*((PEEK(PT)AND16)=0):RETURN
420 REM PRESS FIREBUTTON
430 IF(PEEK(PS+CD)ANDCS)=A4THENRETURN
440 Y=INT((PS-SC)/40):X=PS-SC-Y*40
450 IFAR(X,Y)=0THENPRINTP$"TRY ANOTHER":GOSUB540:RETURN
460 PRINTP$"GOOD ANSWER"
470 POKEPS+CD,A4:T=AR(X,Y)-1:L(T)=L(T)+1
480 POKES+4,16:POKES+4,17:POKES+1,10+10*L(T)
490 FORA=SC+554TO(SC+554)-40*LLSTEP-40:POKEA+40,93:POKEA+71,93
500 POKEA,160:POKEA+31,160:FORTD=1TO20:NEXT:NEXT:IFQF=1THENQF=0:RETURN
510 GOSUB590:LL=LL-(LL<15):AR(X,Y)=0:IFL(T)=LN(T)THENGOSUB610
520 RETURN
530 REM ENERGY DRAIN
540 POKES+4,32:POKES+4,33:POKES+1,30:FORTD=1TO200:NEXT:POKES+1,15
550 FORA=SC-6TO(SC-6)+40*(15-LL)STEP40:POKEA-40,93:POKEA-9,93:POKEA,160
560 POKEA+31,160:FORTD=1TO20:NEXT:NEXT:GOSUB590:LL=LL-1:IFLL=-1THEN700
570 RETURN
580 REM CLEAR MESSAGE
590 PRINTP$"                   ":RETURN
600 REM GOT A WORD
610 GW=GW+1:IFGW=10THEN770
620 FORTD=1TO300:NEXT:PRINTP$"WELL DONE!"
630 POKES+4,32
640 POKES+4,35:FORA=6TO20:POKES+1,A:FORTD=30TO40:POKES+15,TD:NEXT:NEXT
650 GOSUB590:RETURN
660 REM GIVE A CLUE
670 A=RND(1)*10:IFL(A)=0THENPRINTP$"CLUE:"W$(A+M):FORT=1TO800:NEXT
680 GOSUB590:RETURN
690 REM END OF GAME
700 PRINT"[144]":FORA=0TO14:PRINT:PRINTSPC(10);:FORB=0TO19
710 IFAR(B,A)<>0THENPRINTAR$(B,A);:GOTO730
720 PRINT"";
730 NEXT:NEXT:PRINT:POKEZ,A4:PRINT "      PRESS FIREBUTTON TO CONTINUE"
740 GOSUB410:IFJ<128THEN740
750 GOSUB410:IFJ>127THEN750
760 POKEZ,A5:PRINT"[147]      SORRY, YOU DIDN'T MAKE IT":GOTO790
770 POKEZ,A5:PRINT"[147]      CONGRATULATIONS!  YOU WON"
780 PRINT"         YOUR TIME WAS "MID$(TI$,3,2)":"RIGHT$(TI$,2)
790 FORI=1TO1000:NEXT:POKEBC,W:PRINT"    PRESS FIREBUTTON TO PLAY AGAIN"
800 PRINT"          PRESS DOWN TO QUIT"
810 GOSUB410:IFJ>127THENPRINTSPC(13)"PLEASE WAIT":GOSUB1170:GOTO180
820 IFJTHENPRINT"[147]":END
830 GOTO810
840 REM PRINT ARRAY
850 PRINT"[147]    [159][161][146][161]  [161][172][162][146][190][161][146][161][161][146][161] [187][172][146] [188][187][172][146][190][161][172][187][146][187][172][172][187][146][187][161][188][161][146][161]"SPC(8);
860 PRINT"[161][146][161]  [161][188][146][187]  [187][172][146]  [161][146][161]  [161][146][161] [161][188][190][146][190][161][146][161][161][146][161][161]  [146][161]"SPC(8)"[154][161][146][161]";
870 PRINT"  [161][146][161]  [172][172][187][146][187] [161][146][161]  [161][146][161] [161][172][188][146] [161][146][161][161][146][161][161][146][161][187][146][161]"SPC(8)"[188][162][162][146][190][188]";
880 PRINT"[162][162][146][190][188][190][188][190] [162][162][146]  [188][190] [188][190][188][190] [162][162][146] [188][190][188][190]"
890 POKEZ,A1:PRINTSPC(4)"[194]    [176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174][146]    [194]"
900 PRINTSPC(4)"[194]    [194][146]";:FORA=0TO14:FORB=0TO19
910 POKEZ,A2:IFAR$(B,A)=" "THENPRINTCHR$(65+RND(1)*26);:GOTO930
920 PRINTAR$(B,A);
930 NEXT:POKEZ,A1:PRINT"[194][146]    [194]":PRINTSPC(4);"[194]    [194][146]";:NEXT
940 PRINT:PRINTSPC(4)"[145][194]    [173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189][146]    [194]"
950 RETURN
960 REM PUT WORDS IN THE ARRAY
970 B=INT(RND(1)*(NW-10))
980 M=B:FORA=0TO9:W$=W$(B+A)
990 DR=RND(1)*2^LV:DY=DY(DR):DX=DX(DR):L=LEN(W$)
1000 SX=INT(RND(1)*19+1):SY=INT(RND(1)*14+1):RX=SX:RY=SY
1010 NX=SX+(L-1)*DX:NY=SY+(L-1)*DY:IFNX<0ORNY<0ORNX>19ORNY>14THEN990
1020 FL=0:FORL=1TOLEN(W$):IFAR$(SX,SY)<>" "THENFL=1:L=LEN(W$)
1030 SX=SX+DX:SY=SY+DY
1040 NEXT:IFFLTHENA=A-1:NEXT
1050 FORL=1TOLEN(W$):AR$(RX,RY)=MID$(W$,L,1)
1060 AR(RX,RY)=A+1:RX=RX+DX:RY=RY+DY:NEXT:LN(A)=LEN(W$):NEXT
1070 RETURN
1080 REM SHUFFLE WORDS
1090 FORA=1TONW/2:B=RND(1)*NW:C=RND(1)*NW:T$=W$(B):W$(B)=W$(C):W$(C)=T$
1100 NEXT:RETURN
1110 REM READ IN WORDS
1120 DIMW$(200):NW=-1
1130 NW=NW+1:READW$:FORA=1TOLEN(W$):W$(NW)=W$(NW)+CHR$(ASC(MID$(W$,A,1))-1)
1140 NEXT:IFW$(NW)<>"END"THEN1130
1150 RETURN
1160 FORA=0TO7:READDX(A),DY(A):NEXT
1170 FORA=0TO19:FORB=0TO14:AR$(A,B)=" ":NEXTB,A
1180 RETURN
1190 DATA 0,1,1,0,0,-1,-1,0,-1,1,1,1,1,-1,-1,-1
1200 DATA DBSOJWBM,DJSDVT,DBOBEB,VOJUFE,UFMFQIPOF,NPOLFZ,DPNQVUFS
1210 DATA KPZTUJDL,NPOTUFS,TUBQMFS,NBHJDBM,TIVGGMF,FOE