1 POKE53269,0:S=2:S$(2)="TYPEWRITER":S$(4)="COMMODORE1"
2 OPEN1,8,15
5 POKE52,128:POKE56,128:
10 POKE56578,PEEK(56578)OR3:POKE56576,(PEEK(56576)AND252)OR1
20 POKE53272,(PEEK(53272)AND240)OR2:POKE648,132
25 POKE53280,0:POKE53281,12
40 DIM M$(12)
45 M$(1)="[202]ANUAR":M$(2)="[198]EBRUAR":M$(3)="[205][187]RZ":M$(4)="[193]PRIL":M$(5)="[205]AI"
46 M$(6)="[202]UNI":M$(7)="[202]ULI":M$(8)="[193]UGUST":M$(9)="[211]EPTEMBER":
47 M$(10)="[207]KTOBER":M$(11)="[206]OVEMBER":M$(12)="[196]EZEMBER"
50 DIMT$(15):T$(0)="[144]":T$(1)="":T$(2)="":T$(3)="[159]":T$(4)="[156]":T$(5)=""
51 T$(6)="":T$(8)="[129]":T$(9)="[149]":T$(10)="[150]":T$(11)="[151]":T$(12)="[152]":T$(13)="[153]"
52 T$(14)="[154]":T$(15)="[155]":T$(7)="[158]":T=6
90 V=53248:SP=34808:SN=160:SC=33792:DIMX$(20):DIMSJ$(99):DIMFR$(99):DIMAN$(99)
91 DIMDA$(99):DIMNR(99):CR$=CHR$(13)
100 OPEN2,8,2,"NO55.DAT,S,R":BW=1
105 INPUT#2,B$(BW):IFB$(BW)="#E#"THENCLOSE2:BW=BW-1:GOTO110
107 BW=BW+1:GOTO105
110 DH$="    ":DH=11:IC=0:AI=1:RA=0:HG=12
115 JN$(1)="[144] JA [146]  NEIN":JN$(2)=" JA   NEIN[146]"
120 OPEN2,8,2,"NO55.MISC,S,R":FORI=1TO8:INPUT#2,A$(I):NEXTI:CLOSE2
124 B$(0)="[199]AST"
130 OPEN2,8,2,"J[176]GER,S,R":INPUT#2,Q:CLOSE2
135 IFQ>1THEN150
140 POKE53280,2:PRINT"[147]";TAB(12);" [193] [195] [200] [212] [213] [206] [199] !"
142 PRINT"[144][202]AGERSTAND UNTER 1 [204]ITER !!!"
144 GETA$:IFA$<>""THENPOKE53280,0:GOTO200
146 FORI=0TO500:NEXT:POKE53280,0:FORI=0TO500:NEXT: POKE53280,2:GOTO144
150 SI=54272:FL=SI:FH=SI+1:WS=SI+4:AS=SI+5:H=SI+6:L=SI+24
152 POKEL,15:POKEAS,2*16+9:POKEH,255:POKEFH,6:POKEFL,133
197 REM +*********+
198 REM * DESKTOP *
199 REM +*********+
200 PRINTT$(T);"[147]                [196]ESKTOP                "
202 PRINTTAB(39-LEN(B$(B)));"[158]";B$(B):A=1
205 GOSUB7030
207 IFNS=0THENGOSUB7150:NS=1:GOSUB7030
210 D$=" "+TT$+" ."+M$(VAL(MM$))+" 20"+JJ$:PRINTD$;"":POKEV+21,0
220 FORI=0TO7:POKEV+39+I,IC:POKESP+I,SN+I:NEXT:FORI=1TO7STEP2:POKEV+I,96:NEXT
225 FORI=9TO15STEP2:POKEV+I,158:NEXT:FORI=0TO4STEP2:POKEV+I,(I/2)*70+55
230 POKEV+8+I,(I/2)*70+55:NEXTI:POKEV+23,255:POKEV+29,255:POKEV+16,136
232 POKEV+6,10:POKEV+14,10
235 POKEV+21,255:POKEV+39,AI:PRINT""
258 IFA<1THENA=1
260 AX=8:GOSUB7600:IFA$="_"THENGOSUB7600
280 ON A GOTO 300,600,2200,99,1900,99,3200,1300
297 REM +**********+
298 REM * ANMELDEN *
299 REM +**********+
300 POKEV+21,0:IFB<>0THEN410
305 PRINT"";TAB(13);T$(T);" [193]NMELDEN     "
306 PRINTTAB(13);"              [144] [146]"
307 FORI=0TOBW:PRINTTAB(13);"  ";B$(I);
308 R=10+LEN(B$(I)):FORJ=RTO21:PRINT" ";:NEXTJ:PRINT"[144] [146]":NEXTI
309 PRINTTAB(13);"[146]              [144] ":PRINTTAB(14);"              "
315 POKESP,SN+15:X1=136:Y1=106:AX=BW+1:GOSUB7700                               
350 A=A-1:POKEV+21,0:IFA=0ORA$="_"THEN200
355 OPEN8,8,104,B$(A):GOSUB7000
360 IFE1$="62"THENCLOSE8:GOTO450
365 GOSUB7060
367 RC=1:GOSUB8000
370 INPUT#8,Q$:IFQ$<>P$THENPOKEWS,33:FORI=0TO300:NEXT:POKEWS,0:GOTO365
373 RC=2:GOSUB8000
375 INPUT#8,DH$,RA,HG,T,DH
376 RC=3:GOSUB8000
377 INPUT#8,IC,AI,S,LM:CLOSE8
380 POKE53280,RA:POKE53281,HG:POKE53272,(PEEK(53272)AND240)ORS
400 B=A:IFLM=1THENGOSUB7030:GOSUB7050:GOTO650
405 GOTO200
410 GOSUB7220
447 REM +****************+
448 REM * NEUEN ACCOUNT  *
449 REM +****************+
450 PRINTT$(T)" [206]EUER [193]CCOUNT               "
451 PRINT"                             [144] "
452 PRINT" [197]S EXISTIERT NOCH KEIN       "
455 PRINT" [193]CCOUNT F[189]R [211]IE. [193]CCOUNT     "
456 PRINT" ANLEGEN ?                    "
457 FORI=0TO2:PRINT"                              ":NEXTI
460 PRINT"                             ":Y=1
462 PRINT""TAB(10);JN$(Y)
463 GETA$:IFA$=""THEN463
464 IFA$="[157]"THENY=Y-1:IFY<1THENY=1
465 IFA$=""THENY=Y+1:IFY>2THENY=2
466 IFA$=CHR$(13)THEN468
467 GOTO462
468 IFY=2THEN200
470 GOSUB7060:P1$=P$:GOSUB7060
475 P2$=P$:IFP1$=P2$THEN500
480 POKEW,33:FORI=0TO200:NEXT:POKEW,0:P1$="":P2$="":GOTO470
500 PRINTT$(T)" [194]EST[187]TIGUNG                "
501 PRINT"                            [144] "
502 PRINT" [210]EGISTRATION ERFOLGREICH!   "
505 PRINT" [201]M [205]ENU '[211]ETUP' K[188]NNEN [211]IE  "
510 PRINT" SICH [206][207]55 [205][193][206][193][199][197][210] [201]HREN     "
515 PRINT" [194]ED[189]RFNISSEN ANPASSEN.      "
516 PRINT"                             "
517 PRINT"         [214]IEL [211]PA[190]!          "
518 PRINT"                             "
519 PRINT"                            "
520 OPEN8,8,8,B$(A)+",L,"+CHR$(100)
525 PRINT#1,"P"+CHR$(8)+CHR$(60)+CHR$(0)+CHR$(1)
530 PRINT#8,CHR$(255)
535 RC=1:GOSUB8000:PRINT#8,P$
536 RC=2:GOSUB8000:
537 PRINT#8,"    [146]";CR$;12;CR$;12;CR$;6;CR$;11
538 RC=3:GOSUB8000:PRINT#8,0,CR$,1,CR$,2,CR$,LM
540 CLOSE8:B=A:GOTO200
597 REM +******+
598 REM * MAIL *
599 REM +******+
600 POKEV+21,7:POKESP,SN+16:POKESP+1,SN+17:POKESP+2,SN+12
605 :AX=3:GOSUB7600:IFA$="_"THEN200
635 ONAGOTO650,900,200
647 REM +*************+
648 REM * POSTEINGANG *
649 REM +*************+
650 POKEV+21,0:IFB=0THEN600
651 NP=0:OPEN2,8,2,"MAILNUMBER,S,R":INPUT#2,MG:CLOSE2:OPEN2,8,2,"MAILSERVER,S,R"
652 FORI=1TOMG:INPUT#2,FR$(I),AN$(I),SJ$(I),DA$(I)
653 IFAN$(I)=B$(B)THENNP=NP+1:NR(NP)=I
654 NEXT I:CLOSE2:IFNP>0THEN675
660 PRINT" KEINE NEUE POST..."
662 GETA$:IFA$=""THEN662
665 GOTO600
670 IFNP=0THEN200
675 PRINTT$(T);"              [208]OSTEINGANG               "
680 PRINTT$(T);"  [198]1 [204]ESEN [198]2 [204][188]SCHEN [198]3 [196]RUCKEN _ [197]SC [146]"
700 PRINT"[144][214]ON         [194]ETREFF            [196]ATUM[146]":POKEV+39,AI
701 POKESP,SN+15:Y1=74:X1=32:AX=NP
705 FORI=1TONP:PRINT"";FR$(NR(I));TAB(14);SJ$(NR(I));TAB(30);DA$(NR(I)):NEXTI
707 AM=1
710 GOSUB7700:AM=A:IFA$="_"THEN200
715 IFA$="[137]"THENGOSUB2500:GOTO650
757 REM +************+
758 REM * MAIL LESEN *
759 REM +************+
760 POKEV+21,0:I=0:PRINTT$(T)"[147]                                       "
765 PRINT"";TAB(13);SJ$(NR(AM)):PRINT"[151] [214]ON [146][144]";FR$(NR(AM));
766 PRINTTAB(15)"[151][196]ATUM [146][144]"DA$(NR(AM))
767 PRINT"---------------------------------------"
770 OPEN2,8,2,SJ$(NR(AM))+",S,R":REM GOSUB7000:IFE1$="62"THENCLOSE2:A=3:GOTO840
775 INPUT#2,X$(I):IFX$(I)="#E#"ORI>17THENCLOSE2:GOTO792
780 IFX$(I)="#LZ#"THENX$(I)="                                        "
790 PRINTX$(I);:I=I+1:GOTO775
792 PRINT"---------------------------------------"
793 PRINTD$;
795 POKESP,SN+9:POKESP+1,SN+12:POKEV+23,0:POKEV+29,0:POKEV+16,7
800 FORI=1TO5STEP2:POKEV+I,50:NEXTI:POKEV,0:POKEV+2,26:POKEV+4,52:POKEV+21,3
810 AX=2:GOSUB7600
840 IFA=2THENPRINT"[147]":GOSUB7030:POKEV+39,1:POKEV+16,0:GOTO670
845 IFA=1THENGOSUB1080:GOTO810
897 REM +****************+
898 REM * MAIL SCHREIBEN *
899 REM +****************+
900 POKEV+21,0:PRINT"";TAB(8);T$(T);" [197]MPF[187]NGER W[187]HLEN:[144]"
904 PRINTTAB(8);"                   "
905 FORI=1TOBW:PRINTTAB(8);"  ";B$(I);:R=10+LEN(B$(I)):FORJ=RTO21
906 PRINT" ";:NEXTJ:PRINT"[ ]  [146]":NEXTI
907 PRINTTAB(8);"  [193]LLE W[187]HLEN      ":PRINTTAB(8);"  [207][203]               "
908 PRINTTAB(8);"                   "
909 PRINTTAB(9);"                  "
912 FORI=1TOBW:EM(I)=0:NEXT:A=1:POKESP,SN+15:POKEV+21,1:POKEV+39,AI
913 POKEV+23,0:POKEV+29,0:POKEV,96
915 AX=BW+2:Y1=96:GOSUB7710:IFA$="_"THEN200
950 IFA=BW+1THENFORI=1TOBW:EM(I)=1:POKESC+263+I*40,88:NEXT:GOTO915
952 IFA=BW+2THENGOSUB7300:IFOK>0THEN970
953 IFA=BW+2ANDOK=0THEN915
955 EM(A)=EM(A)+1:IFEM(A)>1THENEM(A)=0
957 IFEM(A)=1THENPOKESC+263+A*40,88
958 IFEM(A)=0THENPOKESC+263+A*40,32
960 GOTO915
970 PRINTT$(T);"[147]                                       ":PRINT""TAB(13)SJ$
972 PRINT"[151][193]N [146][144] ";:FORI=1TOBW:IFEM(I)=1THENPRINTB$(I);",";
973 NEXTI:PRINTCHR$(13);"----------------------------------------"
975 PRINT"---------------------------------------"
976 PRINTD$;
980 PRINT"[144]":POKESP,SN+14:SYS33024:PRINT"":GOSUB7090
985 POKESP,SN+10:POKESP+1,SN+9:POKESP+2,SN+12
987 FORI=1TO5STEP2:POKEV+I,50:NEXT:POKEV,0:POKEV+2,26:POKEV+4,52
990 POKEV+16,7:POKEV+21,7
995 AX=3:GOSUB7600
1020 IFA=2THEN7460
1025 IFA=3THEN200
1030 PRINT"[206]ACHRICHT WIRD GESPEICHERT...    ":POKEV+21,0
1055 OPEN2,8,2,SJ$+",S,W"
1060 FORI=0TODM:PRINT#2,CHR$(34);X$(I):NEXT:PRINT#2,"#E#":CLOSE2
1062 OPEN2,8,2,"MAILNUMBER,S,R":INPUT#2,MG:CLOSE2
1065 MG=MG+OK:OPEN2,8,2,"@:MAILNUMBER,S,W":PRINT#2,MG:CLOSE2
1070 OPEN2,8,2,"MAILSERVER,S,A"
1071 FORI=1TOBW:IFEM(I)=0THEN1073
1072 PRINT#2,B$(B);CR$;B$(I);CR$;SJ$;CR$;DT$;CR$
1073 NEXTI
1075 CLOSE2:POKEV+21,7:GOTO995
1080 REM +*********+
1081 REM * DRUCKEN *
1082 REM +*********+
1085 GOSUB7400:IFA$="_"THEN1115
1095 OPEN4,4:PRINT#4,CHR$(17);"NO55 MAILSERVICE";CR$:PRINT#4,"[214]ON:     ";
1100 PRINT#4,FR$(NR(AM))CR$"[193]N:      ";B$(B);CR$;"[194][197]TREFF: ";SJ$(NR(AM))
1105 PRINT#4,"[196]ATUM:   "DA$(NR(AM));CR$;CR$
1106 I=0
1107 IFX$(I)="#E#"ORI>17THEN 1112
1110 PRINT#4,X$(I):I=I+1:GOTO1107
1112 PRINT#4,CR$;"END OF MESSAGE":CLOSE4
1115 GOTO760
1297 REM +*******+
1298 REM * SETUP *
1299 REM +*******+
1300 POKEV+21,0:PRINTT$(T);"             [211]ETUP:              ":Q$=DH$
1301 POKEV+21,0:PRINT"[144]                                  "
1302 PRINT" [210]AHMENFARBE       [146]               "
1303 PRINT" [200]INTERGRUNDFARBE  [146]               "
1304 PRINT" [212]ITELLEISTE       [146]               "
1305 PRINT" [196]ESKTOPFARBE      [146]               "
1307 PRINT" [201]CONS             [146]               "
1310 PRINT" AKTIVES [201]CON      [146]               "
1315 PRINT" [196]ESKTOPMOTIV >[158]DEFAULT     ";Q$;"[146]  [144] "
1320 PRINT" [211]CHRIFTART   >[158]";S$(S);"        [144] "
1322 PRINT" NACH [193]NMELDEN Z. [208]OSTEINGANG [ ] "
1323 PRINT"                                  "
1325 PRINT" [189]BERNEHMEN                       ":
1326 PRINT" [211]PEICHERN                        "
1330 PRINT" ZUR[189]CK                           ":POKESP,SN+15:POKEV+39,1
1331 PRINT"                                  "
1332 PRINT"                                 "
1333 POKEV,48:POKE55557,RA:POKE55597,HG:POKE55637,T:POKE55677,DH:POKE55717,IC
1334 POKE55757,AI:POKEV+23,0:POKEV+29,0:POKEV+21,1:A=1:IFLM=1THENLL=1:GOTO1455
1335 POKEV+1,90+A*8
1340 GETA$
1341 IFA$=""THEN1340
1345 IFA$=""THENA=A+1:IFA=10THENA=11
1350 IFA$="[145]"THENA=A-1:IFA=10THENA=9
1355 IFA$=""THEN1380
1360 IFA$="[157]"THEN1395
1365 IFA$=CHR$(13)THEN1410
1366 IFA<1THENA=1
1368 IFA>13THENA=13
1370 GOTO1335
1380 IFA>6THEN1335
1382 CS=55517+A*40
1383 K=PEEK(CS)AND15:K=K+1:IFK=16THENK=15
1385 POKECS,K
1390 GOTO1335
1395 IFA>6THEN1335
1396 CS=55517+A*40
1400 K=PEEK(CS)AND15:K=K-1:IFK=-1THENK=0
1402 POKECS,K
1405 GOTO1335
1410 IFA<5THEN1335
1415 ONA-6GOTO1420,1520,1450,99,1465,1480,200
1420 OPEN2,8,2,"DESKTOPMOTIVE,S,R"
1425 INPUT#2,Q$:IFQ$="#E#"THENCLOSE2:GOTO1420
1427 PRINT"[158]";TAB(18);"         [157][157][157][157][157][157][157][157][157]";Q$;
1428 INPUT#2,Q$:PRINTTAB(30);"";Q$
1430 GETA$:IFA$=""THEN1430
1435 IFA$=""THEN1425
1440 IFA$=CHR$(13)THENCLOSE2:GOTO1335
1445 GOTO1425
1450 LL=LL+1:IFLL=2THENLL=0:
1455 IFLL=1THENPRINT"[144]";TAB(34);"X"
1457 IFLL=0THENPRINT"[144]";TAB(34);" "
1460 GOTO1335
1465 RA=PEEK(55557)AND15:HG=PEEK(55597)AND15:T=PEEK(55637)AND15
1470 DH=PEEK(55677)AND15:IC=PEEK(55717)AND15:AI=PEEK(55757)AND15:ML=LL:DH$=Q$
1472 POKE53280,RA:POKE53281,HG:GOSUB7030:GOTO1300
1480 IFB=0THEN1335
1495 OPEN8,8,8,B$(B):RC=2:GOSUB8000
1505 PRINT#8,DH$;CR$;RA;CR$,HG;CR$;T;CR$;DH
1510 RC=3:GOSUB8000:PRINT#8,IC;CR$;AI;CR$;S;CR$;LM:CLOSE8:GOTO1300
1520 S=S+2:IFS>8THENS=2
1525 PRINT"[158]";TAB(18);S$(S):POKE53272,(PEEK(53272)AND240)ORS
1530 GOTO1335
1887 REM +*******+
1888 REM * JAEGER *
1889 REM +*******+
1900 POKEV+21,0:OPEN2,8,2,"J[176]GER,S,R":INPUT#2,J1$,J2$,J3$,J4$:CLOSE2
1905 PRINT"[144][197]S SIND ";J1$;" [204]ITER [144]VORR[187]TIG.":AL=0
1910 PRINT"[211]TAND VOM",J4$:PRINT"[211]IGNIERT:[158]",J3$
1915 PRINT"[144][196]IE [202][187]GERUHR STEHT AUF:":PRINT"[158]",,J2$
1920 PRINT"[144][215]AS M[188]CHTEN [211]IE ANMELDEN?"
1925 PRINT,"[214]ERLUST ([208]ROST!)":PRINT,"[218]UWACHS":PRINT,"BEST[187]TIGEN (ZUR[184]CK)"
1930 POKESP,SN+15:POKEV,96:POKEV+23,0:POKEV+29,0:POKEV+39,1:POKEV+21,1:A=1
1935 POKEV+1,154+A*8
1940 GETA$:IFA$=""THEN1940
1945 IFA$=""THENA=A+1:IFA>3THENA=3
1950 IFA$="[145]"THENA=A-1:IFA<1THENA=1
1955 IFA$=CHR$(13)THEN1965
1960 GOTO1935
1965 ONAGOTO1970,2050,200
1970 PRINT"[206]EUER [202][187]GERSTAND >        [204]ITER":N=0
1975 NJ$=""
1980 GETA$:IFA$=""THEN1980
1982 IFA$=CHR$(13)ANDAL=1THENRETURN
1985 IFA$=CHR$(13)THEN2010
1990 IFA$=CHR$(20)THENNJ$="":PRINT"[145]";TAB(22);"      ":N=0
1995 IFASC(A$)>47ANDASC(A$)<58THEN2003
2000 IFASC(A$)<>46THEN1980
2003 N=N+1:IFN>5THENN=5:GOTO1980
2005 NJ$=NJ$+A$:POKESC+742+N,ASC(A$)
2007 GOTO1980
2010 PRINT"[158][196]IESEN [211]TAND SPEICHERN":PRINT"";JN$:GOSUB7010
2015 IFA$="N"THENGOSUB7030:GOTO1900
2020 OPEN2,8,2,"@:J[176]GER,S,W":PRINT#2,NJ$:PRINT#2,J2$:PRINT#2,B$(B)
2025 PRINT#2,DT$:CLOSE2:GOSUB7030:GOTO1900
2050 PRINT"[145][145]",,,"0.25L ":PRINT,,,"0.5L  ":PRINT,,,"0.75L ":PRINT,,,"1.0L  ":
2055 PRINT,,,"1.5L  ":PRINT,,,"ANDERE":POKEV,255:A=1
2060 POKEV+1,162+A*8
2062 GETA$:IFA$=""THEN2062
2065 IFA$=""THENA=A+1:IFA>6THENA=6
2070 IFA$="[145]"THENA=A-1:IFA<1THENA=1
2075 IFA$=CHR$(13)THEN2085
2080 GOTO2060
2085 IFA=1THENX=VAL(J1$)+0.25
2086 IFA=2THENX=VAL(J1$)+0.5
2087 IFA=3THENX=VAL(J1$)+0.75
2088 IFA=4THENX=VAL(J1$)+1
2089 IFA=5THENX=VAL(J1$)+1.5
2090 IFA=6THENAL=1:PRINT"[145][145][145]";TAB(23);"     ":N=0:GOSUB1975:X=VAL(J1$)+VAL(NJ$)
2093 IFB$(B)=J2$THENGOSUB2110
2095 J1$=STR$(X):IFX<1THENJ1$="0"+RIGHT$(J1$,4)
2097 OPEN2,8,2,"@:J[176]GER,S,W":PRINT#2,J1$:PRINT#2,J2$:PRINT#2,B$(B)
2100 PRINT#2,DT$:CLOSE2:GOSUB7030:GOSUB7050:GOTO1900
2110 PRINT"[202][176]GERUHR WEITERDREHEN";JN$:GOSUB7010
2115 IFA$="N"THENRETURN
2120 N=0:
2125 IFJ2$<>B$(N)THENN=N+1:GOTO2125
2130 N=N+1:IFN=7THENN=1
2135 J2$=B$(N):RETURN
2197 REM +******+
2198 REM * PINS *
2199 REM +******+
2200 POKEV+21,0:OPEN2,8,2,"PINNUMBER,S,R":INPUT#2,PN:CLOSE2:AP=PN
2205 POKESP,SN+2:POKESP+1,SN+17:POKESP+2,SN+12:POKEV+21,7
2210 AX=3:GOSUB7600
2240 ONAGOTO2245,2340,200
2245 POKEV+21,0:I=0:OPEN2,8,2,"PIN"+STR$(AP)+",S,R"
2248 PRINTT$(T);"[147]              [208]IN [206]R.";AP;"[157]                [151]"
2250 INPUT#2,Q1$,Q2$:PRINTQ1$;" SCHRIEB AM ";Q2$
2255 PRINT"[144]---------------------------------------"
2260 INPUT#2,X$(I):IFX$(I)="#E#"THENCLOSE2:GOTO2266
2262 IFX$(I)="#LZ#"THENX$(I)="                                        "
2265 PRINTX$(I);:I=I+1:GOTO2260
2266 PRINT"---------------------------------------"
2267 PRINTD$;
2270 POKESP,SN+12:POKESP+1,SN+11:POKESP+2,SN+9:POKEV+23,0:POKEV+29,0
2275 POKEV+16,14:FORI=1TO7STEP2:POKEV+I,50:NEXT:POKEV,240:POKEV+2,10
2280 POKEV+4,36:POKEV+6,62:POKESP+3,SN+12:POKEV+21,15:A=1
2285 FORJ=0TO3:POKEV+39+J,IC:NEXTJ:POKEV+38+A,AI
2290 GETA$:IFA$=""THEN2290
2295 IFA$=""THENA=A+1:IFA>4THENA=4
2300 IFA$="[157]"THENA=A-1:IFA<1THENA=1
2305 IFA$=CHR$(13)THEN2315
2310 GOTO2285
2315 ONAGOTO2320,2325,7530,2200
2320 AP=AP-1:IFAP<1THENAP=1:GOTO2285
2322 GOTO2245
2325 AP=AP+1:IFAP>PNTHENAP=PN:GOTO2285
2330 GOTO2245
2337 REM +***************+
2338 REM * PIN SCHREIBEN *
2339 REM +***************+
2340 GOSUB 7050:PRINTT$(T)"[147]           [208]IN SCHREIBEN               [144]"
2341 PRINT"[151][197]NDE MIT ^ MARKIEREN U. MIT [198]7 BEENDEN[144]"
2342 PRINT"---------------------------------------"
2343 PRINT"---------------------------------------"
2344 PRINTD$;:POKESP,SN+14
2345 POKEV+39,1:POKEV+23,0:POKEV+29,0:POKEV+21,1:SYS33024:GOSUB7090
2360 POKESP,SN+10:POKESP+1,SN+9:POKESP+2,SN+12:POKEV+23,0:POKEV+29,0
2365 POKEV+16,7:POKEV,0:POKEV+2,26:POKEV+4,52:FORI=1TO5STEP2:POKEV+I,50:NEXTI
2370 POKEV+21,7
2375 AX=3:GOSUB7600
2405 ONAGOTO2410,2430,2200
2410 PN=PN+1:POKEV+21,0:OPEN2,8,2,"PIN"+STR$(PN)+",S,W":PRINT#2,B$(B)
2415 PRINT#2,DT$:FORI=0TODM:PRINT#2,CHR$(34);X$(I):NEXT:PRINT#2,"#E#":CLOSE2
2420 OPEN2,8,2,"@:PINNUMBER,S,W":PRINT#2,PN:CLOSE2:GOTO2370
2430 Q1$=B$(B):Q2$=DT$:XQ=1:GOSUB7530:GOTO2370
2497 REM +**************+
2498 REM * MAIL LOESCHEN*
2499 REM +**************+
2500 OPEN1,8,15,"S:"+SJ$(NR(A)):CLOSE1
2503 FORI=NR(A)TOMG:FR$(I)=FR$(I+1):AN$(I)=AN$(I+1):SJ$(I)=SJ$(I+1)
2505 DA$(I)=DA$(I+1):NEXTI:MG=MG-1
2510 OPEN2,8,2,"@:MAILNUMBER,S,W":PRINT#2,MG:CLOSE2
2515 OPEN2,8,2,"@:MAILSERVER,S,W"
2520 FORI=1TOMG:PRINT#2,FR$(I):PRINT#2,AN$(I):PRINT#2,SJ$(I):PRINT#2,DA$(I)
2525 NEXTI:CLOSE2:NP=NP-1:RETURN
2552 PRINT#4,CR$;"END OF NOTE":CLOSE4
2597 REM +**********+
2598 REM * (null)OTZPLAN *
2599 REM +**********+
2600 PRINTT$(T);"[147]                [208]OTZPLAN               "
2602 PRINT"  [215]OCHE        [194]A/[203][189] [198]L/[212]R [205][189]/[203][215] [215][195]"
2603 PRINT"[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]":END
2605 OPEN1,8,15:OPEN8,8,104,"[208]OTZPLAN"
2610 FORRC=1TO10
2615 PRINT#1,"P"+CHR$(104)+CHR$(RC)+CHR$(0)+CHR$(1)
2620 INPUT#8,Q$:PRINTQ$
2625 NEXTRC
2997 REM +**********+
2998 REM * ADRESSEN *
2999 REM +**********+
3000 POKEV+21,0:PRINTT$(T);"[147]              [193]DRESSEN                 "
3005 PRINT"[151]      [198]1-NEUE [193]DRESSE _ [197]SC"
3010 OPEN8,8,104,B$(B):RC=4
3020 GOSUB8000:INPUT#8,Q$:IFQ$<>CHR$(255)THENEND
3023 PRINT"NOCH KEINE [193]DRESSEN! [198]1 UM [193]DRESSEN":PRINT ANZULEGEN""
3025 INPUT#8,NN$,VN$,TL$,AD$,PLZ$,RT$,AT$
3030 PRINTNN$;", ";VN$,TL$:RC=RC+1:GOTO3020
3200 POKEV+21,0:PRINTT$(T)" NEUE [193]DRESSE                  "
3202 PRINT"[144]                                "
3205 PRINT" [206]ACHNAME:                      "
3210 PRINT" [214]ORNAME:                       "
3215 PRINT" [211]TRA[190]E:                        "
3220 PRINT" [208][204][218]:       [207]RT:                "
3225 PRINT" [212]ELEFON:                       "
3230 PRINT" EMAIL:                         "
3235 PRINT"                                "
3240 PRINT" [198]1 SPEICHERN [198]3 SPEICHERN UND  "
3245 PRINT" N[187]CHSTE [193]DRESSE [198]7 [193]BBR.       "
3250 PRINT"                                "
3255 PRINT"                               "
6996 END
6997 REM +*******************+
6998 REM * FEHLERKANAL LESEN *
6999 REM +*******************+
7000 INPUT#1,E1$,E2$,E3$,E4$:RETURN
7007 REM +*********+
7008 REM * JA/NEIN *
7009 REM +*********+
7010 GETA$:IFA$=""THEN7010
7015 IFA$<>"J"ANDA$<>"N"THEN7010
7020 RETURN
7027 REM +********************+
7028 REM * DESKTOPHINTERGRUND *
7029 REM +********************+
7030 PRINT" [144][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164]"
7035 FORI=0TO18:PRINT" [144] [146]";:POKE646,DH:PRINTDH$;DH$;DH$;DH$;DH$;DH$;DH$;DH$;
7040 PRINTDH$;"[144] [146]":NEXT:PRINT" [163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]":RETURN
7047 REM +******************+
7048 REM * TEXTFELD LPOSSCHEN *
7049 REM +******************+
7050 PRINT"                                        ";
7055 PRINT"                                        ";:RETURN
7057 REM +**********+
7058 REM * PASSWORT *
7059 REM +**********+
7060 PRINT"";TAB(10);T$(T);"[208]ASSWORT       ":P=0:P$=""
7062 PRINTTAB(10);"[155]               [144] ":PRINTTAB(10);"[155]  [146]             [144] "
7063 PRINTTAB(10);"[155]               [144] ":PRINTTAB(11);     "[144]               "
7064 FORI=55788TO55798:POKEI,0:NEXT
7065 GETA$:IFA$=""THEN7065
7070 IFA$=CHR$(13)THENRETURN
7075 IFA$=CHR$(20)THENPRINT"[145][145]":GOTO7060
7080 P$=P$+A$:P=P+1:IFP>11THENP=11
7085 POKESC+491+P,42:GOTO7065=
7087 REM +***************+
7088 REM * POKE -> ASCII *
7089 REM +***************+
7090 FORI=0TO18:X$(I)="":NEXT:I=0:DM=0:E=0
7092 LZ=0:FORJ=0TO39
7095 X=PEEK(33912+40*I+J):PRINT"";I;J:IFX<>32THENLZ=1
7097 IFX=30ORE=1THENE=1:DM=I:NEXTJ:RETURN
7100 IFX<32THENX=X+64:GOTO7110
7102 IFX>95ANDX<99THENX=X+64:GOTO7110
7103 IFX>122ANDX<127THENX=X+64:GOTO7110
7105 IFX>63ANDX<94THENX=X+32
7110 X$(I)=X$(I)+CHR$(X):NEXTJ
7115 IFLZ=0THENX$(I)="#LZ#"
7117 I=I+1:GOTO7092
7120 DM=18:RETURN
7147 REM +***************+
7148 REM * DATUM EINGABE *
7149 REM +***************+
7150 PRINTT$(T);" [196]ATUM                       "
7151 PRINT"[144]                              "
7152 PRINT"[144] [194]ITTE DAS HEUTIGE [196]ATUM UND  "
7153 PRINT" DIE [213]HRZEIT EINGEBEN:        "
7154 PRINT"                              "
7155 PRINT" 00.00.2002  00:00 [213]HR        "
7156 PRINT"                              "
7157 PRINT"                             "
7160 POKESP,SN+14:POKEV+39,1:POKEV+21,1
7165 POKEV,96:POKEV+1,138:POKEV+23,0:POKEV+29,0:A=1
7170 POKEV,64+A*8
7172 GETA$:IFA$=""THEN7172
7175 IFA$=CHR$(20)THENA=1:GOTO7170
7177 IFA$=CHR$(13)THEN7195
7178 IFA$=""THENGOTO7185
7180 X=ASC(A$):IFX<48ORX>57THEN7170
7182 POKESC+11*40+5+A,X
7185 A=A+1:IFA=3THENA=4
7186 IFA=6THENA=9
7187 IFA=11THENA=13
7188 IFA=15THENA=16
7189 IFA>17THENA=17
7190 GOTO7170
7195 TT$=CHR$(PEEK(34238))+CHR$(PEEK(34239)):IFVAL(TT$)>31THEN7170
7197 MM$=CHR$(PEEK(34241))+CHR$(PEEK(34242)):IFVAL(MM$)>12THEN7170
7199 JJ$=CHR$(PEEK(34246))+CHR$(PEEK(34247))
7200 HH$=CHR$(PEEK(34250))+CHR$(PEEK(34251)):IFVAL(HH$)>24THEN7170
7205 MX$=CHR$(PEEK(34253))+CHR$(PEEK(34254)):IFVAL(MI$)>59THEN7170
7210 DT$=TT$+"."+MM$+"."+JJ$:TI$=HH$+MX$+"00":RETURN
7217 REM +*************+
7218 REM * ABMELDEN    *
7219 REM +*************+
7220 POKEV+21,0:PRINT"";TAB(12);T$(T);" [193]BMELDEN        "
7225 PRINTTAB(12);"                 ":PRINTTAB(12);" [144][215]OLLEN [211]IE SICH  "
7230 PRINTTAB(12);" ABMELDEN?        ":PRINTTAB(12);"                  "
7235 PRINTTAB(12);"   ";JN$(2);"     ":PRINTTAB(12);"                  "
7240 PRINTTAB(13);"                 ":A=2
7245 GETA$:IFA$=""THEN7245
7250 IFA$=""THENA=A+1:IFA>2THENA=2
7255 IFA$="[157]"THENA=A-1:IFA<1THENA=1
7260 IFA$=CHR$(13)THEN7270
7265 PRINT"";TAB(15);JN$(A):GOTO7245
7270 IFA=1THENB=0
7275 GOTO200
7297 REM +******************+
7298 REM * BETREFF EINGABE  *
7299 REM +******************+
7300 OK=0:SJ$="":FORI=1TOBW:IFEM(I)=1THENOK=OK+1
7301 NEXT:IFOK=0THENRETURN
7302 PRINT"";TAB(9);T$(T);" [194]ETREFF          "
7305 PRINTTAB(9);"[155]                  [144] "
7310 PRINTTAB(9);"[155] [146]                 [144] "
7315 PRINTTAB(9);"[155]                  [144] "
7320 PRINTTAB(10);"                  "
7325 POKESP,SN+14:POKEV+1,128:Q=0
7330 POKEV,104+Q*8
7335 GETA$:IFA$=""THEN7335
7336 IFA$=":"THEN7335
7337 IFA$="?"THEN7335
7338 IFA$="*"THEN7335
7339 IFA$=CHR$(34)THEN7335
7340 IFA$=CHR$(20)THEN7360
7345 IFA$=CHR$(13)THEN7370
7350 Q=Q+1:IFQ>16THENQ=16:GOTO7330
7355 SJ$=SJ$+A$:PRINT"";TAB(10);SJ$:GOTO7330
7360 Q=Q-1:SJ$=LEFT$(SJ$,Q):PRINT"";TAB(10);"                "
7365 PRINT"";TAB(10);SJ$:GOTO7330
7370 OPEN2,8,2,SJ$+",S,R":CLOSE2:GOSUB7000:IFE2$="FILE NOT FOUND"THEN RETURN
7375 POKEWS,33:FORI=1TO300:NEXT:POKEWS,0:GOTO7300
7397 REM +*****************+
7398 REM * DRUCKER BEREIT  *
7399 REM +*****************+
7400 PRINT"[147]"
7405 PRINTT$(T);" [196]RUCKEN                         [155]"
7410 PRINT"[155]                                 [144] "
7415 PRINT"[155] [196]RUCKER ONLINE UND [208]APIER DRIN? [144] "
7420 PRINT"[155]                                 [144] "
7425 PRINT"[155]            [151] [207] [203] [155]                [144] "
7430 PRINT"[155]                                 [144] "
7435 PRINT"[144]                                 "
7440 GETA$:IFA$=""THEN7440
7445 IFA$="_"THENRETURN
7450 PRINT"[155] [196]RUCKVORGANG GESTARTET...       ":RETURN
7460 GOSUB7400:IFA$="_"THEN7490
7465 OPEN4,4:PRINT#4,"[206][207]55 [205]AILSERVICE";CR$
7470 PRINT#4,"[214]ON:     ";B$(B):PRINT#4,"[193]N:      ";
7475 FORI=1TOBW:IFEM(I)=1THENPRINT#4,B$(I);",";
7480 NEXTI:PRINT#4,"[194]ETREFF: ";SJ$:PRINT#4,"[196]ATUM:   ";DT$;CR$
7485 FORI=0TODM:PRINT#4,X$(I):NEXT:PRINT#4,CR$;"END OF MESSAGE":CLOSE4
7490 PRINT"[147]                                       ":PRINT" ";SJ$
7495 PRINT"[151][193]N [144][146]";:FORI=1TOBW
7500 IFEM(I)=1THENPRINTB$(I);",";
7505 NEXTI:PRINTCHR$(13);"[144]---------------------------------------"
7510 FORI=0TODM:PRINTX$(I);:NEXT
7520 GOTO995
7530 REM ---- PINS DRUCKEN A ----
7535 GOSUB7400:IFA$="_"ANDXQ=0THEN2245
7536 IFA$="_"ANDXQ=1THEN2370
7540 OPEN4,4:PRINT#4,CHR$(17);"[206][207]55 [208]INWAND";CR$;"[208]IN [206]R.";AP;CR$
7545 PRINT#4,"[214]ON   :";Q1$:PRINT#4,"[196]ATUM:";Q2$;CR$;CR$
7550 FORK=0TOI-1:PRINT#4,X$(K):NEXT:CLOSE4
7555 ONXQ+1GOTO2245,2370
7597 REM +***********+
7598 REM * ICON MENUE*
7599 REM +***********+
7600 A=1:PRINTT$(T)
7605 POKEV+38+A,AI
7607 GETA$:PRINT" "LEFT$(TI$,2)":"MID$(TI$,3,2)
7610 IFA$=""THEN7605
7612 POKEV+38+A,IC
7615 IFA$=""THENA=A+1:IFA>AXTHENA=AX
7620 IFA$="[157]"THENA=A-1:IFA<1THENA=1
7625 IFA$=""THENA=A+4:IFA>AXTHENA=AX
7630 IFA$="[145]"THENA=A-4:IFA<1THENA=1
7635 IFA$="_"THENRETURN
7640 IFA$=CHR$(13)THENRETURN
7645 GOTO7605
7697 REM +************+
7698 REM * VERT. MENU *
7699 REM +************+
7700 A=1:POKEV,X1:POKEV+23,0:POKEV+29,0:POKEV+16,0:POKEV+39,AI:POKEV+21,1
7702 POKESP,SN+15:PRINTT$(T)
7705 POKEV+1,Y1+8*A
7710 GETA$:IFA$=""THEN7710
7720 IFA$=""THENA=A+1:IFA>AXTHENA=AX
7725 IFA$="[145]"THENA=A-1:IFA<1THENA=1
7730 IFA$="_"ORA$="[137]"THENRETURN
7735 IFA$=CHR$(13)THENRETURN
7740 GOTO7705
8000 PRINT#1,"P"+CHR$(104)+CHR$(RC)+CHR$(0)+CHR$(1)
8005 INPUT#1,E1$,E2$,E3$,E4$
8010 PRINT"";E1$;E2$:RETURN
8996 END
8997 REM +*************+
8998 REM + SERVERCHECK *
8999 REM +*************+
9000 OPEN2,8,2,"MAILNUMBER,S,R":INPUT#2,Q:PRINT"[206]ACHRICHTEN:";Q:CLOSE2
9010 OPEN2,8,2,"MAILSERVER,S,R"
9015 FORI=1TOQ:INPUT#2,A$:PRINTA$:INPUT#2,A$:PRINTA$:INPUT#2,A$:PRINTA$
9020 INPUT#2,A$:PRINTA$:PRINT:NEXTI:CLOSE2:END
9050 OPEN2,8,2,"[212]ESTMAILX1,S,R"
9055 INPUT#2,Q$:PRINTQ$:IFQ$="#E#"THENCLOSE2:END
9060 GOTO9055
9070 END
9080 REM ------ SERVER RESET -------
9090 OPEN2,8,2,"@:MAILNUMBER,S,W":PRINT#2,1:CLOSE2
9100 OPEN2,8,2,"@:MAILSERVER,S,W"
9110 FORI=1TO4:PRINT#2,"DUMMY":NEXTI:CLOSE2:END
9200 OPEN2,8,2,"[200]ANNENZ,S,R":
9210 INPUT#2,Q$:PRINTQ$:GOTO9210