10 REM ********************************
11 REM ** CMD-UHREN VON RAMLINK, HD  **
12 REM ** ODER FD AUSLESEN UND IN    **
13 REM ** BASIC WEITERVERARBEITEN    **
14 REM ********************************
15 REM ** GESCHRIEBEN 1998 VON       **
16 REM ** MATTHIAS "HONK MAN" HEYMANN**
17 REM ********************************
18 REM ** DAS BENUTZEN DIESER ROUTI- **
19 REM ** NEN IN EIGENEN PROGRAMMEN  **
20 REM ** IST ERLAUBT!               **
21 REM ********************************
22 REM **       "T-RD"-VERSION       **
23 REM ********************************
24 :
40 INPUT"[147]GERAETE-NR DES CMD-GERAETES MIT UHR";LF
45 :
46 REM **********************
47 REM ***CMD-UHR AUSLESEN***
48 REM **********************
49 :
60 OPEN15,LF,15,"T-RD"
70 FORI=0TO7:GET#15,C$:C(I)=ASC(C$+CHR$(0)):NEXT
80 CLOSE15
95 :
96 REM **********************
97 REM **DATEN KONVERTIEREN**
98 REM **********************
99 :
100 WOCHENTAG=C(0):REM 0=SO,1=MO,2=DI..
110 JAHR     =C(1)
120 MO       =C(2):REM MONAT
130 TAG      =C(3)
140 S        =C(4):REM STUNDEN
150 MINUTEN  =C(5)
160 SEKUNDEN =C(6)
170 AP       =-(C(7)<>0):REM 0=AM, 1=PM
179 :
180 FOR I=0 TO 6:READ T$(I):NEXT
181 DATA SONNTAG, MONTAG, DIENSTAG, MITTWOCH, DONNERSTAG, FREITAG, SAMSTAG
182 TAG$=T$(WOCHENTAG)
194 :
195 REM**********************
196 REM*****STUNDEN INS******
197 REM**24-STUNDEN-FORMAT***
198 REM**********************
199 :
200 S2=S+12*(AP+(S=12))
295 :
296 REM**********************
297 REM*****TI$ SETZEN*******
298 REM**********************
299 :
300 H=S2*216000+MI*3600+SE*60
310 T1=INT(H/65536):H=H-65536*T1
320 T2=INT(H/256):T3=H-256*T2
330 POKE162,0:POKE160,T1:POKE161,T2:POKE162,T3
395 :
396 REM**********************
397 REM****DATEN AUSGEBEN****
398 REM**********************
399 :
400 PRINT"WO =";WO
410 PRINT"JA =";JA
420 PRINT"MO =";MO
430 PRINT"TA =";TA
440 PRINT"S  =";S
450 PRINT"MI =";MI
460 PRINT"SE =";SE
470 PRINT"AP =";AP:PRINT
480 PRINT"TA$=";TA$:PRINT
490 PRINT"S2 =";S2:PRINT
500 PRINT"TI$=";TI$