1 POKE53272,23:POKE53280,6:PRINT"[147]";:POKE53265,11
2 PRINT"[208]ROGRAMM: PRIM-FAK-ZERLEG":GOSUB47
3 PRINT"[198]UNKTION: [208]ROGRAMM ZERLEGT DIE EINGE-"
4 PRINT"          GEBENE [218]AHL IN IHRE [208]RIM-"
5 PRINT"          FAKTOREN.":GOSUB47
6 PRINT"[197]INGABE:  N, DIE ZU ZERLEGENDE [218]AHL":GOSUB47
7 PRINT"[193]USGABE:  [208]RIMFAKTOREN":GOSUB47
8 PRINT"[194]EISPIEL:"
9 PRINT"180 = 2 ^ 2 * 3 ^ 2 * 5":GOSUB47
10 PRINT"[194]ITTE DRUECKEN [211]IE EINE [212]ASTE!";:POKE53265,27
11 GETA$:IFA$=""THEN11
12 DIMT(100),AT(100),AA(100)
13 PRINT"[147][194]ITTE GEBEN [211]IE EIN:"
14 INPUT"N = ";N$:N=VAL(N$)
15 H=N
16 PRINT"[194]ITTE WARTEN!"
17 IFN<>INT(N)THENGOSUB60
18 H=N
19 IFN<=0THENPRINT"[206] MUSS GROESSER ALS [206]ULL SEIN!":PRINT:GOTO13
20 IFN<4THENI=0:GOTO28
21 I=0:T=2:GOSUB48:T=3
22 GOSUB48
23 T=T+2
24 IFT<(SQR(N)+1)THEN22
25 IFN=1THEN28
26 IFN=HTHEN28
27 I=I+1:T(I)=N
28 IFI<>0THEN30
29 PRINT"[157]";H;"IST EINE [208]RIMZAHL.":GOSUB50:GOTO13
30 IMAX=I:T(IMAX+1)=0
31 J=1:I=1
32 AT(J)=T(I):AA(J)=1
33 IFI=IMAXTHEN36
34 IFT(I)=T(I+1)THENAA(J)=AA(J)+1:I=I+1:GOTO33
35 J=J+1:I=I+1:GOTO32
36 N=1
37 FORX=1TOJ:N=N*AT(X)^AA(X):NEXT
38 IFINT(H)=INT(N)THEN41
39 PRINT"[208]ROGRAMM LIEFERT FALSCHE [218]ERLEGUNG!"
40 PRINT"[193]LGORITHMUS PRUEFEN!!!"
41 PRINT"[157]";H;"=";
42 X=1
43 PRINTAT(X);
44 IFAA(X)>1THENPRINT"^";AA(X);
45 IFX<JTHENPRINT"*";:X=X+1:GOTO43
46 PRINT"":GOSUB50:GOTO13
47 FORX=1TO40:PRINT"-";:NEXT:RETURN
48 IF(N/T)<>INT(N/T)THENRETURN
49 I=I+1:T(I)=T:N=N/T:GOTO48
50 GOSUB47
51 PRINT"[215]OLLEN [211]IE EINE WEITERE [218]AHL ZERLEGEN?"
52 PRINT"[215]ENN NEIN, DRUECKEN [211]IE '[206]', ANSONSTEN"
53 PRINT"EINE BELIEBIGE ANDERE [212]ASTE!";
54 GETA$:IFA$=""THEN54
55 IFA$="N"THEN57
56 N=0:RETURN
57 POKE53280,14:PRINT"[147]";
58 PRINT"[208]ROGRAMM 'PRIM-FAK-ZERLEG' WURDE AUF"
59 PRINT"[201]HREN [215]UNSCH ABGEBROCHEN!":END
60 N=INT(N):H=N
61 PRINT"[206] WURDE IN EINE GANZE [218]AHL VERWANDELT!":RETURN