1 GOSUB 25000
10 REM ***       JUKKA-PEKKA        ***
20 REM ***          1985            ***
30 REM ***         KAIVOS           ***
40 POKE53280,54:POKE53281,54:PRINT"[147]TASSA PELISSA SINUN TAYTYY HOITAA KAIVOSTA"
50 PRINT"ALKUPAAOMAA SINULLA ON 10000$,JONKA VOIT KAYTTAA MIELESI MUKAAN"
60 PRINT"PELI PAATTYY JOS RAHASI LOPPUVAT TAI TYOLAISET TEKEVAT LAKON"
70 PRINT"LAKKO SYNTYY KUN EROTAT LIIKAA TYOLAISIATAI MAKSAT LIIAN VAHAN PALKKAA"
80 PRINT"LISAA RAHAA SAAT KUN MYYT KAIVOKSEN TUOTTAMAA MALMIA"
90 PRINT"MALMIN MAARA VAIHTELEE TYOLAISTEN INNOS TUKSEN JA MAARAN MUKAAN"
100 PRINT"PAINA NAPPIA TILASTOTIETOIHIN"
110 GET M$:IF M$=""THEN 110
120 N=10000:B=100:V=5:L=175:J=10:F=100:FF=30:X=0
200 IF JJ>2 THEN 1700
201 O=INT((33-1)*RND(1))+1
202 IF O=1 THEN 1500
204 IF B<10 THEN 1000
206 IF L<75 THEN 500
207 IF V<0 THEN 500
208 IF N<0 THEN 1000
210 PP=INT((10-1)*RND(1))+1
211 IF PP=1 AND OO=0 THEN GOSUB 1900
212 LL=INT((30-1)*RND(1))+1
213 IF LL=1 AND UU=0 THEN GOSUB 2100
216 D=INT((J-1)*RND(1))+1
217 IF D=1 THEN 1600
218 X=X+1:PRINT"[147]KAIVOS,";X;"VIIKOLTA":PRINT:PRINT:PRINT:IF PT>0 THEN X1=X1+1
219 PRINT"SUOSIOSI ON:";V
220 J=J-1
221 K=K+B*(1.3*(L/350))*(V*0.7)
222 JL=J/2
223 PRINT"KAIVOKSESI MALMIVARASTO ON:";K;"TONNIA"
224 PRINT"RAHAA SINULLA ON:";N;"$"
225 PRINT"TYOTURVALLISUUS ON:";JL
226 IF JJ>0 THEN PRINT"KAIVOKSESSASI ON OLLUT SORTUMIA:";JJ
230 C=INT((F-FF)*RND(1))+FF
231 LL=INT((30-1)*RND(1))+1
240 PRINT"MALMIN HINTA ON:";C;"$ TONNILTA"
250 PRINT"TYOLAISIA SINULLA ON:";B;"HENKEA"
260 PRINT"TYOLAISTEN PALKKA ON:";L;"$ VIIKOSSA":PRINT
300 PRINT"MONTAKO TONNIA HALUAT MYYDA MALMIA ?"
310 INPUT Q
311 IF Q<0 THEN 300
320 IF Q>K THEN 300
326 IF Q>1000 AND OO=0 THEN GOSUB 1900
327 IF Q<100 THEN YY=YY+1
328 IF YY>5 THEN GOSUB 2100
329 IF UU>0 THEN UU=UU-1
330 N=N+Q*C
331 IF UU=1 THEN GOSUB 2000
332 IF OO>0 THEN OO=OO-1
333 IF OO=1 THEN GOSUB 2000
335 K=K-Q
340 PRINT"RAHAA SINULLA ON:";N;"$"
350 PRINT"KUINKA MONTA DOLLARIA TAHDOT LASKEA TYOLAISTEN PALKKOJA ?"
360 INPUT W
365 IF W<0 THEN 350
370 IF W>25 THEN 500
380 IF W>0 THEN V=V-1
390 L=L-W
395 IF L<50  THEN 500
400 PRINT"KUINKA MONTA DOLLARIA TAHDOT NOSTAA TYOLAISTEN PALKKOJA ?"
410 INPUT E
415 IF E<0 THEN 400
420 L=L+E
430 IF E>10 THEN V=V+1
440 PRINT"MONTAKO TYOLAISTA TAHDOT IRTISANOA ?"
450 INPUT R
460 IF R>0 THEN V=V-1
462 IF R<0 THEN 440
465 B=B-R
467 IF R>50 THEN 500
470 IF B<10 THEN 1000
480 IF L<50 THEN 500
490 GOTO 600
500 PRINT"[147]TYOLAISET TEKEVAT LAKON IRTISANOMISTEN JA PALKAN ALENNUSTEN TAKIA !"
510 PRINT"UUSI PELI ALKAA NAPISTA."
520 GET T$:IF T$="" THEN 520
530 RUN 10
600 PRINT"MONTAKO UUTTA TYOLAISTA TAHDOT PALKATA ?"
610 INPUT Y
615 IF Y<0 THEN 600
620 B=B+Y
625 GOTO 1800
630 PRINT"[147]KAIVOKSEN PALKANMAKSU"
640 PRINT"SINULLA ON";B;"TYOLAISTA,JOTKA KAIKKI VAATIVAT";L;"$ PALKKAA"
645 N=N-B*L
650 PRINT"PALKAT MAKSETTUA SINULLE JAA RAHAA";N;"$"
660 PRINT"PAINA NAPPIA TILASTOIHIN"
670 GET U$:IF U$=""THEN 670
680 GOTO 200
1000 PRINT"[147]KAIVOKSESI TEKI KONKURSSIN !"
1010 PRINT"PAINA NAPPIA UUTEEN PELIIN."
1020 GET I$:IF I$="" THEN 1020
1030 RUN10
1060 PRINT"PAINA NAPPIA"
1500 PRINT"[147]    ERITYISVEROTUS"
1510 PRINT"VOIMAAN TULI ERITYISVEROTUS,JOTTA VALTIO SELVIAISI VAIKEUKSISTAAN"
1520 PRINT"VEROTUS VAHENTAA JOKAISEN KAIVOKSEN VAROISTA PUOLET"
1530 N=N/2
1540 PRINT"VEROTUKSEN JALKEEN SINULLA ON RAHAA";N;"$"
1550 PRINT"PAINA NAPPIA TILASTOTIETOIHIN"
1560 GET P$:IF P$="" THEN 1560
1565 X=X-1
1570 GOTO 200
1600 PRINT"[147]KAIVOKSESSASI TAPAHTUI SORTUMA !"
1610 PRINT"UHRIEN OMAISET HAASTOIVAT SINUT OIKEUTEEN JA JOUDUT MAKSAMAAN 25000$"
1620 N=N-25000:JJ=JJ+1:V=V-1:J=J-1:B=B-15
1625 X=X-1
1630 PRINT"RAHAA SINULLA ON";N;"$"
1640 PRINT"PAINA NAPPIA TILASTOTIETOIHIN"
1650 GET D$:IF D$=""THEN 1650
1660 GOTO 200
1700 PRINT"[147]PAKOLLINEN KAIVOKSEN UUDISTAMINEN":PRINT:PRINT
1710 PRINT"KAIVOKSESSASI ON TAPAHTUNUT USEITA ONNETTOMUUKSIA"
1720 PRINT"ONNETTOMUUDET OVAT AIHEUTTANEET HALYA,"
1730 PRINT"JONKA SEURAUKSENA SINUN TAYTYY UUDISTAA VAARALLISTA KAIVOSTASI"
1740 PRINT"UUDISTUSKULUJA TULEE N.150000$"
1750 PRINT"JOS SINULLA EI OLE RAHAA UUDISTAA KAIVOSTA SEN TOIMINTA LOPETETAAN"
1760 N=N-150000:JJ=0:J=J+7.5
1770 PRINT"SINULLE JAA RAHAA:";N;"$"
1780 PRINT"PAINA NAPPIA JATKOON"
1790 GET DD$:IF DD$=""THEN 1790
1792 X=X-1
1795 GOTO 200
1800 PRINT"KUINKA MONELLA DOLLARILLA HALUAT UUDISTAA KAIVOSTASI ?"
1810 INPUT QQ
1820 IF QQ>N THEN 1800
1825 IF QQ<0 THEN 1800
1830 N=N-QQ
1840 J=J+QQ/1000
1845 IF N>100000 OR QW=1 THEN GOSUB 10000
1847 IF QE=1 THEN GOSUB 11100
1849 IF PT>200000 AND QE=0 THEN GOSUB 11000
1850 GOTO 630
1900 PRINT"[147]LASKUSUHDANNE":PRINT:PRINT
1910 PRINT"MALMIN YLITARJONNAN TAKIA MALMIN HINNAT ROMAHTAVAT"
1920 PRINT"HINNAT ROMAHTAVAT ARVIOLTA 50%"
1930 PRINT"PAINA NAPPIA JATKOON"
1940 F=50:FF=1:OO=10
1950 GET RR$:IF RR$=""THEN 1950
1955 X=X-1
1960 PRINT"[147]":RETURN
2000 PRINT"[147]MALMIN HINNAT PALAUTUVAT NORMAALEIKSI":PRINT:PRINT
2010 PRINT"HINNAT OVAT NYT 30-100 DOLLARIA TONNILTA"
2030 F=100:FF=30:YY=0:OO=0:UU=0
2040 PRINT"PAINA NAPPIA JATKOON"
2050 GET TT$:IF TT$="" THEN 2050
2060 PRINT"[147]":RETURN
2100 PRINT"[147]NOUSUSUHDANNE":PRINT:PRINT
2110 PRINT"MALMIN ALITARJONNAN TAKIA MALMIN HINNAT NOUSEVAT"
2120 PRINT"HINNAT NOUSEVAT ARVIOLTA 35%"
2130 PRINT"PAINA NAPPIA"
2140 F=150:FF=80
2150 UU=5
2155 YY=0
2160 GET II$:IF II$=""THEN 2160
2170 PRINT"[147]":RETURN
9999 REM *** ALIOHJELMA PANKKI ***
10000 PRINT"PALJONKO RAHAA TALLETAT PANKKIIN ?":INPUTPP
10010 IFPP>NTHEN10000
10015 IFPP<0THEN10000
10020 N=N-PP:PT=PT+PP
10030 PRINT"PALJONKO NOSTAT PANKKITILILLASI OLEVASTA $";PT;"?":INPUTNN
10031 IF X1=9 THEN PT=PT*1.11:X1=0
10032 IFNN>PT THEN10030
10033 IFNN<0THEN10030
10035 PT=PT-NN
10037 N=N+NN:QW=1
10050 RETURN
11000 REM *** SISARYHTIO ***
11010 PRINT"[147]HALUATKO OSTAA MALMINRIKASTAMON (K/E) ?"
11020 PRINT"MALMINRIKASTAMON HINTA ON 200000 DOLLARIA"
11030 PRINT"HINTAAN SISALTYY KONEISTO,MALMIN KULJETUSVALINEET JA TONTTI"
11040 INPUT QR$:IF QR$="K"THEN 11045:IF QR$="E"THEN RETURN
11042 RETURN
11045 QE=1:SY=1:PT=PT-200000
11050 PRINT"[147]SINULLA ON KAIVOS,MALMINRIKASTAMO JA";N;"DOLLARIA RAHAA"
11060 PRINT"PAINA NAPPIA"
11070 GET QT$:IF QT$=""THEN 11070
11080 SU=5:NY=5:HE=100:JA=HE*0.5*SU+NY*20:PA=200:QE=1
11090 RETURN
11100 NY=NY-0.5:JA=HE*0.5*SU+NY*20:IF SU<1 THEN 12000
11110 CJ=INT((200-130)*RND(1))+130
11200 PRINT"[147]MALMINRIKASTAMO,";X;"VIIKOLTA":PRINT:PRINT
11210 PRINT"KATEISVARASI:";N;"$"
11215 PRINT"KAIVOKSEN MALMIVARASTO:";K;"TONNIA"
11220 PRINT"NYKYAIKAISUUS:";NY
11230 PRINT"HENKILOKUNTA:";HE;"HENKEA"
11240 PRINT"PALKKA:";PA;"$ VIIKOSSA"
11250 PRINT"RIKASTUSKYKY:";JA;"TONNIA"
11260 PRINT"RIKASTAMON MALMIVARASTO:";JM;"TONNIA"
11265 PRINT"RIKASTETUN MALMIN HINTA:";CJ;"$ TONNILTA"
11266 PRINT"MALMIN HINTA:";C;"$ TONNILTA"
11267 PRINT"SUOSIO:";SU
11270 PRINT"RIKASTETTUA MALMIA:";JI;"TONNIA":PRINT
11280 PRINT"KUINKA MONTA TONNIA MALMIA TUODAAN RIKASTETTAVAKSI ?"
11290 PRINT"(TUONTIKULUT 15$ TONNILTA)"
11300 INPUT QY
11310 IF QY>K THEN 11280
11320 IF QY<0 THEN 11280
11330 IF QY*15>N THEN 11280
11340 N=N-QY*5:JM=JM+QY:K=K-QY
11350 PRINT"SINULLA ON RAHAA:";N;"$"
11360 PRINT"KUINKA MONTA TONNIA MALMIA RIKASTAT ? (KULUT 30$ TONNILTA)"
11370 INPUT QU
11380 IF QU>JM THEN 11350
11390 IF QU*30>N THEN 11350
11400 IF QU>JA THEN 11350
11401 JM=JM-QU:JI=JI+QU:N=N-30*QU
11410 PRINT"SINULLA ON RAHAA:";N;"$"
11420 PRINT"KUINKA MONTA TONNIA MYYT RIKASTAMATONTA MALMIA ?"
11430 INPUT QI
11440 IF QI>JM THEN 11410
11450 IF QI<0 THEN 11410
11455 IF QI>1000 THEN GOSUB 1900
11460 JM=JM-QI
11470 N=N+QI*C
11480 PRINT"RAHAVARASI:";N;"$"
11490 PRINT"KUINKA MONTA TONNIA MYYT RIKASTETTUA MALMIA ?"
11500 INPUT QO
11510 IF QO>JI THEN 11480
11520 IF QO<0 THEN 11480
11530 N=N+QO*CJ
11540 JI=JI-QO
11550 PRINT"RAHAVARASI:";N;"$"
11560 PRINT"KUINKA MONELLA DOLLARILLA NYKYAIKAISTAT RIKASTAMOASI ?"
11570 INPUT QP
11580 IF QP<0 THEN 11550
11590 NY=NY+QP/2000
11600 PRINT"MONTAKO TYONTEKIJAA EROTAT ?"
11610 INPUT QL
11620 IF QL>25 THEN 12000
11625 IF QL>0 THEN SU=SU-1
11630 IF HE<50 THEN 13000
11640 HE=HE-QL
11650 PRINT"MONTAKO TYONTEKIJAA PALKKAAT ?"
11660 INPUT QK
11670 IF QK<0 THEN 11650
11675 IF QK>20 THEN SU=SU+1
11680 HE=HE+QK
11690 PRINT"KUINKA MONTA DOLLARIA NOSTAT PALKKOJA ?"
11700 INPUT QJ
11710 IF QJ<0 THEN 11690
11715 IF QJ>40 THEN SU=SU+1
11720 PA=PA+QJ
11730 PRINT"KUINKA MONTA DOLLARIA LASKET PALKKOJA ?"
11740 INPUT QH
11750 IF QH<0 THEN 11730
11755 IF QH>0 THEN U=U-1
11760 IF QH>15 THEN 12000
11770 PA=PA-QH
11780 PRINT"[147]RIKASTAMON PALKANMAKSU":PRINT:PRINT
11790 PRINT"MALMINRIKASTOMOSSASI ON";HE;"TYONTEKIJAA.KAIKKIEN PALKKA ON";PA;"$"
11800 PRINT"KUN OLET MAKSANUT TYONTEKIJOIDEN PALKAT,SINULLA ON RAHAA";N;"$"
11810 PRINT"PAINA NAPPIA"
11820 GET QG$:IF QG$=""THEN 11820
11830 RETURN
12000 PRINT"MALMINRIKASTAMON TYONTEKIJAT TEKEVAT LAKON"
12010 PRINT"ET SAA SYNTYMAAN SOVINTOA TYONTEKIJOIDEN KANSSA"
12020 PRINT"JOUDUT MYYMAAN RIKASTAMON PILKKAHINTAAN,"
12030 PRINT"KOSKA ET ONNISTU PALKKAAMAAN TYONTEKIJOITA"
12040 PRINT"SAAT RIKASTOMOSTA 100000$"
12050 PRINT"PAINA NAPPIA"
12060 SY=0:QE=0:N=N+100000:JA=0:HE=0:NY=0:PA=0:JT=0
12070 RETURN
13000 PRINT"[147]YRITYKSESI TEKEVAT KONKURSSIN"
13010 PRINT"PAINA NAPPIA"
13020 GET QF:IF QF=""THEN 13020
13030 RUN 10
25000 PRINT"[147]KAYTA TASSA PELISSA VAIN KOKONAISLUKUJA"
25010 PRINT"KAYTA UUDISTAMISEEN VAIN TUHANSIA"
25020 PRINT:PRINT"PS. TALLETA RAHOJASI PANKKIIN,JOS VOIT"
25030 GET J$:IF J$="" THEN 25030
25100 RETURN