8 PRINT"[147]":POKE53280,5:POKE53281,11:POKE646,15:GOSUB11:GOTO110
11 Q$="KAHATEINGET":QV$="01":QT$=Q$+QV$:QD$="060504":RETURN
12 GOSUB11:PRINT"G-A 8/9?[145]":GETQ:ON-(Q<>8ANDQ<>9)GOTO12:RETURN
18 GOSUB12:PRINT"   G-A"Q"[145]":OPEN15,Q,15,"S:"+QT$:CLOSE15:SAVEQT$,Q:END
61 CY=INT(C/100):CX=C-(CY*100)
62 POKE211,CX:POKE214,CY:SYS58640:RETURN
68 LC=INT(L/100):LL=L-(LC*100)
69 FORU=LCTOLL:POKE781,U:SYS59903:NEXT:RETURN
70 E0$="":EL=0
71 GOSUB61:E$="":ON-(EL=EM)GOTO72:PRINTCHR$(164);
72 GETE$:ON-(E$<>"")GOTO73:PRINT"[157]":GOTO71
73 ON-(E$=CHR$(13))-2*(E$=CHR$(20))GOTO81,78
74 IFE$<CHR$(32)ORE$>CHR$(95)THEN71
75 EL=EL+1:IFEL>EMTHEN77
76 PRINT"[157]"E$:E0$=E0$+E$:C=C+1:GOTO71
77 EL=EM:PRINT" ":GOTO71
78 PRINT"[157] ":EL=EL-1:IFEL<0THENEL=0:GOTO80
79 C=C-1
80 E0$=LEFT$(E0$,EL):GOTO71
81 GOSUB61:PRINT" ":RETURN
100 REM ---PROGRAMMABLAUF---
110 GOSUB9002:GOSUB9102:GOSUB9012
112 L=624:GOSUB68:C=600:GOSUB61
114 GOSUB9132:GOSUB9012
116 L=624:GOSUB68:C=600:GOSUB61
118 GOSUB9162:GOSUB9012:PRINT"[147]"
120 EM=35:C=302
122 GOSUB70:GOSUB510
130 GOSUB9002:C=700:GOSUB61
132 GOSUB9172:GOSUB9012
134 L=624:GOSUB68:C=600:GOSUB61
136 GOSUB9202:GOSUB9012:STOP
140 GOSUB70:GOSUB510
142 GOSUB9002:C=700:GOSUB61
144 GOSUB9208:GOSUB9016
150 GOSUB70:GOSUB510
152 GOTO142
499 STOP
510 L=2024:GOSUB68:C=2002:GOSUB61
512 PRINT"[155]ALS TEXT WURDE EINGEGEBEN:"
514 PRINT""E0$:GOTO9012
9000 REM ---TITEL---
9002 PRINT"[147][158][176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174]"
9004 PRINTTAB(5)"[221] [153]EINGABEROUTINE[158]  VON KAHATE [221]"
9006 PRINTTAB(5)"[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]":RETURN
9010 REM ---AUF TASTE WARTEN---
9012 L=2424:GOSUB68:C=2412:GOSUB61
9014 PRINT"[158]WEITER MIT TASTE[145][145][145][145][155]"
9016 POKE198,0:WAIT198,1:POKE198,0
9018 L=2424:GOSUB68:RETURN
9100 REM ---ERKLAERUNGSTEXTE---
9102 C=600:GOSUB61
9104 PRINT"[155]HALLO QUAKELI,"
9106 PRINT"FUER DICH  HABE  ICH  EINE  BASIC-"
9108 PRINT"EINGABEROUTINE  OHNE  INPUT-BEFEHL"
9110 PRINT"GESCHRIEBEN."
9112 PRINT"DU  WOLLTEST   EINE   KLEINE   UND"
9114 PRINT"SCHNELLE ROUTINE, DIE TROTZ  ALLEM"
9116 PRINT"EINE GANZE MENGE VORGABEN ERFUELLT"
9118 PRINT"UND DIE MIT VARIABLEN ARBEITET."
9120 PRINT"GUT, DU SOLLST NUN SO EINE ROUTINE"
9122 PRINT"HABEN.   ABER GANZ SO KURZ, WIE DU"
9124 PRINT"SIE  DIR   VIELLEICHT  VORGESTELLT"
9126 PRINT"HAST,  LAESST SICH  DAS  IN  BASIC"
9128 PRINT"LEIDER DOCH NICHT VERWIRKLICHEN.":RETURN
9132 PRINT"DIE  EINGABEROUTINE  BEFINDET SICH"
9134 PRINT"AM  PROGRAMMANFANG  IN DEN  ZEILEN"
9136 PRINT"NR. 70 MIT 81."
9138 PRINT"VOR DEM AUFRUF DER EINGABE-ROUTINE"
9140 PRINT"SIND ALS PARAMETER VORZUGEBEN:"
9142 PRINT"MAXIMALE  [158]EINGABE-LAENGE[155]  IN  [153]EM"
9144 PRINT"[155]DIE   [158]BILDSCHIRMPOSITION[155]   IN  [153]C"
9146 PRINT"[155]DER AUFRUF DER EINGABE-ROUTINE IN-"
9148 PRINT"NERHALB DES PROGRAMMS ERFOLGT ALSO"
9150 PRINT"Z.B. MIT DER BEFEHLSZEILE:"
9152 PRINTTAB(8)"[158]120 EM=35:C=602:GOSUB70":RETURN
9162 PRINT"[155]ES KANN  JEDER BELIEBIGE TEXT EIN-"
9164 PRINT"GEGEBEN WERDEN."
9166 PRINT"NACH DIESEM BILDSCHIRM GEHT'S LOS!":RETURN
9172 PRINT"[155]ES  SIND  SELBSTVERSTAENDLICH AUCH"
9174 PRINT"ANDERE  EINGABE-LAENGEN  UND -ORTE"
9176 PRINT"MOEGLICH."
9178 PRINT"DAZU MUESSEN NUR  DIE VARIABLE  [153]EM"
9180 PRINT"[155]UND DIE VARIABLE [153]C[155]  FUER DIE POSI-"
9182 PRINT"TIONIERUNG  DES CURSORS EINGEGEBEN"
9184 PRINT"WERDEN."
9186 PRINT"DIE  VARIABLE  [153]C[155]  WIRD ZUSAMMENGE-"
9188 PRINT"SETZT AUS DEN  ANGABEN FUER  ZEILE"
9190 PRINT"UND SPALTE DER CURSOR-POSITION."
9192 PRINT"ZEILE 21 SPALTE 8 WIRD ALSO AUSGE-"
9194 PRINT"DRUECKT DURCH:"
9196 PRINTTAB(20)"[153]C=2108":RETURN
9202 PRINT"ALSO, AUF GEHT'S!":P0$="PRINT"+CHR$(34)+CHR$(147)+CHR$(34)
9204 PRINT"IM DIREKTMODUS FOLGENDES EINGEBEN:"
9206 PRINT"[158]"P0$":EM=16:C=1220:GOTO140"
9207 RETURN
9208 PRINT"[155]FUER  JEDEN  WEITEREN TEST EINFACH"
9210 PRINT"DIE STOPTASTE DRUECKEN, DEN SCREEN"
9212 PRINT"LOESCHEN UND DIREKT EINGEBEN:"
9214 PRINTTAB(9)"[158]EM=...:C=....:GOTO150"
9216 PRINTTAB(9)"[144]RECHT VIEL SPASS [144]DABEI[155]"
9299 RETURN