V clanku DAO - vytvoreni a smazani dotazu jsme se naucili do databaze pridat novy dotaz a pak ho odstranit. Nasledujici kod vytvori novou databazi Access a prida do ni jednu tabulku. Tabulka bude obsahovat tri pole.

Sub VytvorDB()
    Dim wrkAccess As Workspace
    Dim dbsAccess As Database
    ' Objekt pro tabulku databaze
    Dim tblAccess As TableDef
    Dim fldAccess As Field
    
    Set wrkAccess = 
       CreateWorkspace("NovaDatabaze", "admin", "", dbUseJet)
    ' Vytvorime novou databazi
    ' 1. parametr - umisteni a jmeno databaze
    ' 2. parametr - nastaveni razeni v databazi, pro cestinu dbLangCzech
    Set dbsAccess = 
       wrkAccess.CreateDatabase("c:\dokumenty\telefony.mdb", dbLangCzech)
    ' Nova databaze je prazdna, bez tabulek
    ' proto vytvorime novou tabulku pojmenovanou Seznam
    Set tblAccess = dbsAccess.CreateTableDef("Seznam")
    
    ' Tabulka nema prozatim pole
    With tblAccess
        ' Vytvorime nove pole: CreateField
        '   1. parametr - jmeno pole
        '   2. parametr - typ pole (viz. napoveda k DAO)
        ' a pridame ho do tabulky: Fields.Append
        .Fields.Append .CreateField("Jmeno", dbText)
        .Fields.Append .CreateField("Telefon", dbLong)
        .Fields.Append .CreateField("Poznamka", dbMemo)
    End With
    
    ' Tabulka je vytvorena, ale neni v databazi
    ' proto ji tam pridame
    dbsAccess.TableDefs.Append tblAccess

    dbsAccess.Close
    wrkAccess.Close
End Sub

Souvisejici clanky:
DAO - co to, hergot, je?
DAO - vytvoreni a smazani dotazu

Testovano a odladeno: MS Office 97/2000, Visual Basic 6.0, melo by pracovat i ve starsich verzich
Stepan Bechynsky, http://www.builder.cz/stepan