NSIS Users Manual

Check http://nsis.sf.net for news, information, support, examples, tutorials and more.

Quick links:
FAQ - A list of frequently asked questions
NSIS Archive - Examples, functions, tutorials, plug-ins, software, more
Forum - Post questions or discuss NSIS features

Copyright (C) 1999-2004 Nullsoft, Inc.

  • Chapter 1: Introduction to NSIS
  • Chapter 2: Tutorial: The Basics
    • Introduction
    • Script Files
    • Scripting structure
      • Installer Attributes
      • Pages
      • Sections
      • Functions
      • Working with Scripts
        • Variables
        • Debugging Scripts
      • Compiler Commands
    • Compiler
    • Modern UI
    • Plug-ins
    • More
  • Chapter 3: MakeNSIS Usage
  • Chapter 4: Scripting Reference
    • Script File Format
    • Variables
      • User Variables
        • Var
      • Other Writable Variables
      • Constants
      • Variables Used in Strings
    • Labels
    • Relative Jumps
    • Pages
      • Ordering
      • Page Options
      • Callbacks
      • Page
      • UninstPage
      • PageEx
      • PageExEnd
      • PageCallbacks
    • Sections
      • Section Commands
        • AddSize
        • Section
        • SectionEnd
        • SectionIn
        • SubSection
        • SubSectionEnd
      • Uninstall Section
    • Functions
      • Function Commands
        • Function
        • FunctionEnd
      • Callback Functions
        • Install Callbacks
          • .onGUIInit
          • .onInit
          • .onInstFailed
          • .onInstSuccess
          • .onGUIEnd
          • .onMouseOverSection
          • .onSelChange
          • .onUserAbort
          • .onVerifyInstDir
        • Uninstall Callbacks
          • un.onGUIInit
          • un.onInit
          • un.onUninstFailed
          • un.onUninstSuccess
          • un.onGUIEnd
          • un.onUserAbort
    • Installer Attributes
      • General Attributes
        • AddBrandingImage
        • AllowRootDirInstall
        • AutoCloseWindow
        • BGGradient
        • BrandingText
        • Caption
        • ChangeUI
        • CheckBitmap
        • CompletedText
        • ComponentText
        • CRCCheck
        • DetailsButtonText
        • DirText
        • DirVar
        • DirVerify
        • FileErrorText
        • Icon
        • InstallButtonText
        • InstallColors
        • InstallDir
        • InstallDirRegKey
        • InstProgressFlags
        • InstType
        • LicenseBkColor
        • LicenseData
        • LicenseForceSelection
        • LicenseText
        • MiscButtonText
        • Name
        • OutFile
        • SetFont
        • ShowInstDetails
        • ShowUninstDetails
        • SilentInstall
        • SilentUnInstall
        • SpaceTexts
        • SubCaption
        • UninstallButtonText
        • UninstallCaption
        • UninstallIcon
        • UninstallSubCaption
        • UninstallText
        • WindowIcon
        • XPStyle
      • Compiler Flags
        • AllowSkipFiles
        • FileBufSize
        • SetCompress
        • SetCompressor
        • SetCompressorDictSize
        • SetDatablockOptimize
        • SetDateSave
        • SetOverwrite
        • SetPluginUnload
      • Version Information
        • VIAddVersionKey
        • VIProductVersion
    • Instructions
      • Basic Instructions
        • Delete
        • Exec
        • ExecShell
        • ExecWait
        • File
        • Rename
        • ReserveFile
        • RMDir
        • SetOutPath
      • Registry, INI, File Instructions
        • DeleteINISec
        • DeleteINIStr
        • DeleteRegKey
        • DeleteRegValue
        • EnumRegKey
        • EnumRegValue
        • ExpandEnvStrings
        • FlushINI
        • ReadEnvStr
        • ReadINIStr
        • ReadRegDWORD
        • ReadRegStr
        • WriteINIStr
        • WriteRegBin
        • WriteRegDWORD
        • WriteRegStr
        • WriteRegExpandStr
      • General Purpose Instructions
        • CallInstDLL
        • CopyFiles
        • CreateDirectory
        • CreateShortCut
        • GetDLLVersion
        • GetDLLVersionLocal
        • GetFileTime
        • GetFileTimeLocal
        • GetFullPathName
        • GetTempFileName
        • SearchPath
        • SetFileAttributes
        • RegDLL
        • UnRegDLL
      • Flow Control Instructions
        • Abort
        • Call
        • ClearErrors
        • GetCurrentAddress
        • GetFunctionAddress
        • GetLabelAddress
        • Goto
        • IfAbort
        • IfErrors
        • IfFileExists
        • IfRebootFlag
        • IfSilent
        • IntCmp
        • IntCmpU
        • MessageBox
        • Return
        • Quit
        • SetErrors
        • StrCmp
      • File Instructions
        • FileClose
        • FileOpen
        • FileRead
        • FileReadByte
        • FileSeek
        • FileWrite
        • FileWriteByte
        • FindClose
        • FindFirst
        • FindNext
      • Uninstaller Instructions
        • WriteUninstaller
      • Miscellaneous Instructions
        • GetInstDirError
        • InitPluginsDir
        • SetShellVarContext
        • Sleep
      • String Manipulation Instructions
        • StrCpy
        • StrLen
      • Stack Support
        • Exch
        • Pop
        • Push
      • Integer Support
        • IntFmt
        • IntOp
      • Reboot Instructions
        • Reboot
        • SetRebootFlag
      • Install Logging Instructions
        • LogSet
        • LogText
      • Section Management
        • SectionSetFlags
        • SectionGetFlags
        • SectionSetText
        • SectionGetText
        • SectionSetInstTypes
        • SectionGetInstTypes
        • SectionSetSize
        • SectionGetSize
        • SetCurInstType
        • GetCurInstType
        • InstTypeSetText
        • InstTypeGetText
      • User Interface Instructions
        • BringToFront
        • CreateFont
        • DetailPrint
        • EnableWindow
        • FindWindow
        • GetDlgItem
        • HideWindow
        • IsWindow
        • SendMessage
        • SetAutoClose
        • SetBrandingImage
        • SetDetailsView
        • SetDetailsPrint
        • SetCtlColors
        • SetSilent
        • ShowWindow
      • Multiple Languages Instructions
        • LoadLanguageFile
        • LangString
        • LicenseLangString
    • Multiple Languages
      • Language Selection
      • LangDLL Plug-in
      • RTL Languages
    • Plugin DLLs
      • Using Plugin Commands
      • Disabling Plugin Unloading
      • Calling plug-ins manually
    • Silent Installers/Uninstallers
  • Chapter 5: Compile Time Commands
    • Compiler Utility Commands
      • !include
      • !addincludedir
      • !addplugindir
      • !cd
      • !echo
      • !error
      • !packhdr
      • !system
      • !warning
      • !verbose
    • Predefines
      • ${__FILE__}
      • ${__LINE__}
      • ${__DATE__}
      • ${__TIME__}
      • ${__TIMESTAMP__}
    • Read enviroment variables
      • $%envVarName%
    • Conditional Compilation
      • !define
      • !undef
      • !ifdef
      • !ifndef
      • !ifmacrodef
      • !ifmacrondef
      • !else
      • !endif
      • !insertmacro
      • !macro
      • !macroend
  • Appendix A: Modern User Interface
  • Appendix B: Useful Functions
    • Get parent directory
    • Trim newlines
    • Get command line parameters
    • Search in a string
    • Get Windows version
    • Get Internet Explorer version
    • Is .NET Framework installed?
    • Is Macromedia Flash Player installed?
    • Add a shared DLL
    • Remove a shared DLL
    • Upgrade a DLL (macro)
    • Connect to the internet
    • More
  • Appendix C: Useful Information
    • Compiling NSIS Sources
    • Error Levels
    • Add uninstall information to Add/Remove Programs
    • How to install the VB6 runtimes
    • Calling an external DLL using the System.dll plugin
    • Dump Content of Log Window to File
    • How to Read REG_MULTI_SZ Values
  • Appendix D: Changelog and Release Notes
    • 2.0
      • Release Notes
      • Changelog
        • Changes from 1.98
        • Changes from RC4
    • 2.0 Release Candidate 4
      • Changelog
        • Major Changes
        • Minor Changes
        • Utilities and Plug-ins
    • 2.0 Release Candidate 3
      • Changelog
        • Minor Changes
        • Utilities and Plug-ins
    • 2.0 Release Candidate 2
      • Changelog
        • Minor Changes
        • Utilities and Plug-ins
    • 2.0 Release Candidate 1
      • Release Notes
      • Changelog
        • Major Changes
        • Utilities and Plug-ins
    • 2.0 Beta 4
      • Release Notes
      • Changelog
        • Major Changes
        • New/Changed Commands
        • Utilities and Plug-ins
    • 2.0 Beta 3
    • 2.0 Beta 2
    • 2.0 Beta 1
    • 2.0 Beta 0
    • 2.0 Alpha 7
    • 2.0 Alpha 6
    • 2.0 Alpha 5
    • 2.0 Alpha 4
    • 2.0 Alpha 3
    • 2.0 Alpha 2
    • 2.0 Alpha 1
    • 2.0 Alpha 0
    • Older Versions
  • Appendix E: Credits
    • Programmers
    • Designers
    • Translators
    • Writers
  • Appendix F: NSIS License


Introduction to NSIS

Previous | Contents | Next

Chapter 1: Introduction to NSIS

NSIS, which stands for "Nullsoft Scriptable Installation System", is a free scriptable win32 installer/uninstaller system that doesn't suck and isn't huge. It was originally created by Nullsoft to distribute Winamp and its plug-ins, but is now a system used to distribute hundreds of applications.

NSIS creates installers that are capable of installing, uninstalling, setting system settings, extracting files, etc. Pretty much anything. Because it's based on script files, you can fully control every part of your installers. The script language support variables, functions, string manipulation, just like a normal programming language - but designed for the creation of installers.

Even with all these features, NSIS is still the smallest installer system available. With the default options, it has an overhead of only 34 KB. NSIS installers don't bother decompressing themselves three different times, telling the user to "please wait". They get to the point and get the job done.

NSIS is released under an open source license (it is actually the zlib/libpng license, which is approved by opensource.org). What does this mean? It means that if you want to add the functionality you need to NSIS, you can. It means if you want to make your own custom version of NSIS (or some product that includes NSIS), and sell it, you can. Or if you just want to distribute your software using NSIS, you sure as hell can. NSIS 2 is now being developed by a team of open source developers.

The result of all of this is an installation system that lets you compile nice little scripts into tiny installers. Many features are supported, and the whole thing just works pretty damn well (at least, we think).

Here's a short list of some of NSIS' features:

  • SuperPiMP™ technology (so advanced, so amazing, we won't even tell you what it is)
  • Generates self contained executable installers
  • Support for ZLib, BZip2 and LZMA data compression (files can be compressed individually or together)
  • Uninstall support (installer can generate an uninstaller)
  • Customizable user interface (dialogs, fonts, backgrounds, icons, text, checkmarks, images etc.)
  • Classic and Modern wizard interface
  • Fully multilingual, support for multiple languages in one installer. More than 35 translations are available, but you can also create your own
  • Page system: You can add standard wizard pages or custom pages
  • User selection of installation components, tree for component selection
  • Multiple install configurations (usually Minimal, Typical, Full), and custom configuration
  • Installer self-verification using a CRC32 checksum
  • Small overhead over compressed data size (34 KB with default options)
  • Ability to display a license agreement in text or RTF format
  • Ability to detect destination directory from the registry
  • Easy to use plug-in system (lots of plug-ins for creation of custom dialogs, internet connections, HTTP downloading, file patching, Win32 API calls etc. are included)
  • Installers can be as large as 2GB
  • Optional silent mode for automated installations
  • A preprocessor with support for defined symbols, macro's, conditional compilation, standard predefines
  • A lovely coding experience with elements of PHP and assembly (includes user variables, a stack, real flow control, etc.)
  • Installers have their own VMs that let you write code that can support:

    • File extraction (with configurable overwrite parameters)
    • File/directory copying, renaming, deletion, searching
    • Plug-in DLL calling
    • DLL/ActiveX control registration/deregistration
    • Executable execution (shell execute and wait options)
    • Shortcut creation
    • Registry key reading/setting/enumerating/deleting
    • INI file reading/writing
    • Generic text file reading/writing
    • Powerful string and integer manipulation
    • Window finding based on class name or title
    • User interface manipulation (font/text setting)
    • Window message sending
    • User interaction with message boxes or custom pages
    • Branching, comparisons, etc.
    • Error checking
    • Reboot support, including delete or rename on reboot
    • Installer behaviour commands (such as show/hide/wait/etc)
    • User functions in script
    • Callback functions for user actions

  • Completely free for any use. See license.
  • More

Previous | Contents | Next


Tutorial: The Basics

Chapter 2: Tutorial: The Basics

  • Introduction
  • Script Files
  • Scripting structure
    • Installer Attributes
    • Pages
    • Sections
    • Functions
    • Working with Scripts
    • Compiler Commands
  • Compiler
  • Modern UI
  • Plug-ins
  • More


Introduction

2.1 Introduction

Most software packages you download or buy come with an installer. The installer copies and/or updates files, writes registry keys, writes configuration, creates shortcuts, etc. All of this is done automatically for the user. All the user needs to do is supply some information and the installer will do the rest. The user goes through a wizard, makes the appropriate choices and waits until the installer finishes. After the installer has finished the user is left only with the simple task of starting the program. The user doesn't have to worry about things he might have forgotten because all of the necessary steps were done by the installer.

NSIS is a tool for developers to create such installers. NSIS allows you to create everything from basic installers that just copy files to very complex installers that handle a lot of advanced tasks such as writing registry keys, settings environment variables, downloading the latest files from the internet, customizing the configuration file and more. NSIS is very flexible and its scripting language is easy to learn.

NSIS compiles all of the files and the installation script into one executable file, so your application will be easy to distribute. NSIS adds only about 34KB of code of its own (for the default configuration) to the data. NSIS has the smallest overhead available and still have a lot of options thanks to its powerful scripting language and support of external plug-ins.


Script Files

2.2 Script Files

To create a NSIS installer, you first have to write a NSIS script. A NSIS script is just a regular text file with a special syntax. You can edit scripts with every text editor. It's recommended you use a text editor that shows line numbers because NSIS uses line numbers to indicate where errors lay, and to warn you about where errors might lay. An editor that supports syntax highlighting is also recommended. You can download editors made especially for NSIS and files for syntax highlighting at the NSIS Archive.

In a NSIS script every line is treated as a command. If your command is too long for one line you can use a back-slash - '\' - at the end of the line. The compiler will treat the new line as an addition to the previous line and will not expect a new command. For example:

Messagebox MB_OK|MB_ICONINFORMATION \
"This is a sample that shows how to use line breaks for larger commands in NSIS scripts"

If you want to use a double-quote in a string you can either use \$" to escape the quote or quote the string with a different type of quote such as ` or '.

For more details about the script format, see Script File Format.

The default extension for a script file is .nsi. Header files have the .nsh extension. Header files can help you arrange your script by dividing it to more than one block of code, you can also put functions or macros in header files and include the header files in multiple installers. This makes updating easier and it also makes your scripts easier to read. To include a header file in your script use !include. Header files that reside in the Include directory under your NSIS directory can be included just by their name. For example:

!include Sections.nsh


Scripting structure

2.3 Scripting structure

A NSIS script can contain Installer Attributes and Sections/Functions. You can also use Compiler Commands for compile-time operations. Required is the OutFile instruction, which tells NSIS where to write the installer, and one section.

2.3.1 Installer Attributes

Installer Attributes determine the behavior and the look and feel of your installer. With these attributes you can change texts that will be shown during the installation, the number of installation types etc. Most of these commands can only be set and are not changeable during runtime.

Other basic instructions are Name and InstallDir.

For more information about installer attributes, have a look at Installer Attributes.

2.3.2 Pages

An non-silent installer has a set of wizard pages to let the user configure the installer. You can set which pages to display using the Page command (or PageEx for more advanced settings). A typical set of pages looks like this:

Page license
Page components
Page directory
Page instfiles
UninstPage uninstConfirm
UninstPage instfiles

2.3.3 Sections

In a common installer there are several things the user can install. For example in the NSIS distribution installer you can choose to install the source code, additional plug-ins, examples and more. Each of these components has its own piece of code. If the user selects to install this component, then the installer will execute that code. In the script, that code is in sections. Each visible section is a component for the user to choose from. We will not discuss invisible sections in this tutorial. It is possible to build your installer with only one section, but if you want to use the components page and let the user choose what to install you'll have to use more than one section.

Uninstallers can also have multiple sections. Uninstaller section names are prefixed with 'un.'. For example:

Section "Installer Section"
SectionEnd

Section "un.Uninstaller Section"
SectionEnd

The instructions that can be used in sections are very different from the installer attributes instructions, they are executed at runtime on the user's computer. Those instructions can extract files, read from and write to the registry, INI files or normal files, create directories, create shortcuts and a lot more. You can find out more in Instructions.

The most basic instructions are SetOutPath which tells the installer where to extract files and File which extracts files.

Example:

Section "My Program"
  SetOutPath $INSTDIR
  File "My Program.exe"
  File "Readme.txt"
SectionEnd

For more information about sections see Sections.

2.3.4 Functions

Functions can contain script code, just like sections. The difference between sections and functions is the way they are called. There are two types of functions, user functions and callback functions.

User functions are called by the user from within sections or other functions using the Call instruction. User functions will not execute unless you call them. After the code of the function will be executed the installer will continue executing the instructions that came after the Call instruction, unless you have aborted the installation inside the function. User functions are very useful if you have a set of instructions that need to be executed at several locations in the installers. If you put the code into a function you can save the copying time and you can maintain the code more easily.

Callback functions are called by the installer upon certain defined events such as when the installer starts. Callbacks are optional. If for example you want to welcome the user to your installer you will define a function called .onInit. The NSIS compiler will recognize this function as a callback function by the name and will call it when the installer starts.

Function .onInit
  MessageBox MB_YESNO "This will install My Program. Do you wish to continue?" IDYES gogogo
    Abort
  gogogo:
FunctionEnd

Abort has a special meaning in callback functions. Each callback function has its own meaning for it, have a look at Callback Functions for more information. In the above example Abort tells the installer to stop initializing the installer and quit immediately.

For more information about functions see Functions.

2.3.5 Working with Scripts

2.3.5.1 Variables

You can declare your own variables ($VARNAME) with the Var command. Variables are global and can be used in any Section or Function.

Declaring and using a user variable:

Var BLA ;Declare the variable

Section bla

  StrCpy $BLA "123" ;Now you can use the variable $BLA

SectionEnd

In addition there is a Stack, which can also be used for temporary storage. To access the stack use the commands Push and Pop. Push adds a value to the stack, Pop removes one and sets the variable.

For shared code, there are 20 registers avaibable (like $0 and $R0). These static variables don't have to be declared and you won't get any name conflicts. If you want to use these variables in shared code, store the original values on the stack and restore the original values afterwards.

After calling the function, the variables contain the same value as before. Note the order when using multiple variables (last-in first-out):

Function bla

  Push $R0
  Push $R1

    ...code...

  Pop $R1
  Pop $R0

FunctionEnd

2.3.5.2 Debugging Scripts

The more you work with NSIS the more complex the scripts will become. This will increase the potential of mistakes, especially when dealing with lots of variables. There are a few possibilities to help you debugging the code. To display the contents of variables you should use MessageBoxes or DetailPrint. To get a brief overview about all variables you should use the plugin Dumpstate. By default all actions of the Installer are printed out in the Log Window. You can access the log if you right-click in the Log Window and select "Copy Details To Clipboard". There is also a way to write it directly to a file, see here.

2.3.6 Compiler Commands

Compiler commands will be executed on compile time on your computer. They can be used for conditional compilation, to include header files, to execute applications, to change the working directory and more. The most common usage is defines. Defines are compile time constants. You can define your product's version number and use it in your script. For example:

!define VERSION "1.0.3"
Name "My Program ${VERSION}"
OutFile "My Program Installer - ${VERSION}.exe"

For more information about defines see Conditional Compilation.

Another common use is macros. Macros are used to insert code on compile time, depending on defines and using the values of the defines. An example of a macro is UpgradeDLL, which you can use to upgrade a DLL file. The macro's commands are inserts at compile time. This allows you to write a general code only once and use it a lot of times but with a few changes. For example:

!macro MyFunc UN
Function ${UN}MyFunc
  Call ${UN}DoRegStuff
  ReadRegStr $0 HKLM Software\MyProgram key
  DetailPrint $0
FunctionEnd

!insertmacro MyFunc ""
!insertmacro MyFunc "un."

This macro helps you avoid writing the same code for both the installer and the uninstaller. The two !insertmacros insert two functions, one for the installer called MyFunc and one for the uninstaller called un.MyFunc and both do exactly the same thing.

For more information see Compile Time Commands.


Compiler

2.4 Compiler

The second thing you need to do in order to create your installer after you have created your script is to compile your script. MakeNSIS.exe is the NSIS compiler. It reads your script, parses it and creates an installer for you.

To compile you have to right-click your .nsi file and select Compile NSI or Compile NSIS (with bz2). This will cause MakeNSISw to launch and call MakeNSIS to compile your script. MakeNSISw will get the output of MakeNSIS and present it to you in a window where you can see it, copy it, test the installer, browse for it and more. If you don't have the Compile NSI entry in the context (right-click) menu you have probably unselected Shell Extensions in the NSIS installer. You can either use MakeNSIS.exe from a command prompt window (DOS) or reinstall NSIS with Shell Extensions selected.

The compiler will check your script and give you warnings or an error. If an errors occurs (i.e. 2 parameters required but only 1 given) the compiler will abort and a short error message including the line number will be displayed. For non-critical error the compiler will give a warning (i.e. two DirText commands in one script). If your script has no errors the compiler will output an installer for you to distribute.

NSIS supports different compression methods zlib and bzip2. zlib is fast and is very efficient in resources consumption. bzip2 usually gives better results for large installers, but requires a bit more memory and is a little slower. To set the compressor use SetCompressor.


Modern UI

2.5 Modern UI

A popular user interface for NSIS is the Modern User Interface, it has an interface like the wizards of recent Windows versions. The Modern UI is not only a customized resource file, it has a lots of new interface elements. It features a white header to describe the current step, a description area on the component page, a welcome page, a finish page that allows the user to run the application or reboot the system and more.

For more information, check the Modern UI Readme and the Modern UI Examples.


Plug-ins

2.6 Plug-ins

NSIS support plug-ins that can be called from the script. Plug-ins are DLL files written in C, C++, Delphi or another programming language and therefore provide a more powerful code base to NSIS.

A plug-in call looks like this:

DLLName::FunctionName "parameter number 1" "parameter number 2" "parameter number 3"

Every plug-in's function has its own requirements when it comes to parameters, some will require none, some will accept as many parameters as you want to send. Examples:

nsExec::ExecToLog '"${NSISDIR}\makensis.exe" /CMDHELP'
InstallOptions::dialog "$PLUGINSDIR\test.ini"
NSISdl::download http://download.nullsoft.com/winamp/client/winamp291_lite.exe $R0

The plug-ins that NSIS knows of are listed at the top of the output of the compiler. NSIS searches for plug-ins in the Plugins folder under your NSIS directory and lists all of their available functions. You can use !addPluginDir to tell NSIS to search in other directories too.

The NSIS distribution already included many plug-ins. InstallOptions is a popular plug-in that allows you to create custom pages, in combination with the NSIS Page commands (See Pages). The Startmenu plug-in provides a page that allows the user to choose a Start Menu folder. There are a lot of plug-ins for different purposes, have a look at the Contrib folder for help files and examples. You can find additional plug-ins on-line: NSIS Archive.

You can also create a plug-in in yourself. C/C++ and Delphi header files are already available, see ExDLL for a basic plug-in example. Source code of included plug-ins can also be found in the Contrib folder.


More

2.7 More

This tutorial has described the basic NSIS features, to learn more about everything NSIS can do, take some time to read this manual.


MakeNSIS Usage

Chapter 3: MakeNSIS Usage

NSIS installers are generated by using the 'MakeNSIS' program to compile a NSIS script (.NSI) into an installer executable. The NSIS development kit installer sets up your computer so that you can compile a .nsi file by simply right-clicking on it in explorer, and selecting 'compile'.

If you want to use MakeNSIS on the command line, the syntax of the makensis command is:

Makensis [/Vx] [/Olog] [/LICENSE] [/PAUSE] [/NOCONFIG] [/CMDHELP [command]] [/HDRINFO] [/NOCD]
         [/Ddefine[=value] ...] ["/XCommand parameter" ...] [Script.nsi | - [...]]
  • /LICENSE displays a keen license page.
  • The /V switch followed by a number between 0 and 4 will set the verbosity of output accordingly. 0=no output, 1=errors only, 2=warnings and errors, 3=info, warnings, and errors, 4=all output.
  • The /O switch followed by a filename tells the compiler to print its log to that file (instead of the screen)
  • /PAUSE makes Makensis pause before quitting, which is useful when executing directly from Windows (the auto-installed shell extensions use it).
  • /NOCONFIG disables inclusion of [path to makensis.exe]\nsisconf.nsh . Without this parameter, installer defaults are set from nsisconf.nsi. See NSIS Configuration File.
  • /CMDHELP prints basic usage information for command (if specified), or all commands (if command is not specified).
  • /HDRINFO prints out information on what options Makensis was compiled with.
  • /NOCD disabled the current directory change to that of the .nsi file
  • Using the /D switch one or more times will add to symbols to the globally defined list (See !define).
  • Using the /X switch one or more times will execute the code you specify following it. Example: "/XAutoCloseWindow false"
  • Specifying a dash (-) for the script name will tell Makensis to use the standard input as a source.
  • If multiple scripts are specified, they are treated as one concatenated script.


Scripting Reference

Chapter 4: Scripting Reference

  • Script File Format
  • Variables
    • User Variables
    • Other Writable Variables
    • Constants
    • Variables Used in Strings
  • Labels
  • Relative Jumps
  • Pages
    • Ordering
    • Page Options
    • Callbacks
    • Page
    • UninstPage
    • PageEx
    • PageExEnd
    • PageCallbacks
  • Sections
    • Section Commands
    • Uninstall Section
  • Functions
    • Function Commands
    • Callback Functions
  • Installer Attributes
    • General Attributes
    • Compiler Flags
    • Version Information
  • Instructions
    • Basic Instructions
    • Registry, INI, File Instructions
    • General Purpose Instructions
    • Flow Control Instructions
    • File Instructions
    • Uninstaller Instructions
    • Miscellaneous Instructions
    • String Manipulation Instructions
    • Stack Support
    • Integer Support
    • Reboot Instructions
    • Install Logging Instructions
    • Section Management
    • User Interface Instructions
    • Multiple Languages Instructions
  • Multiple Languages
    • Language Selection
    • LangDLL Plug-in
    • RTL Languages
  • Plugin DLLs
    • Using Plugin Commands
    • Disabling Plugin Unloading
    • Calling plug-ins manually
  • Silent Installers/Uninstallers


Script File Format

4.1 Script File Format

A NSIS Script File (.nsi) is just a text file with script code.

Commands

Commands lines are in the format 'command [parameters]'

File "myfile"

Comments

Lines beginning with ; or # are comments. You can put comments after commands. You can also use C-style comments to comment one or more lines.

; Comment
# Comment

/*
Comment
Comment
*/

File "myfile" ; Comment

If want a parameter to start with ; or # put it in quotes.

Plug-ins

To call a plugin, use 'plugin::command [parameters]'. For more info see Plugin DLLs.

nsExec::Exec "myfile"

Numbers

For parameters that are treated as numbers, use decimal (the number) or hexadecimal (with 0x prepended to it, i.e. 0x12345AB), or octal (numbers beginning with a 0 and no x).

Colors should be set in hexadecimal RGB format, like HTML but without the #.

IntCmp 1 0x1 lbl_equal

SetCtlColors $HWND CCCCCC

Strings

To represent strings that have spaces, use quotes:

MessageBox MB_OK "Hi there!"

Quotes only have the property of containing a parameter if they begin the parameter. They can be either single quotes, double quotes, or the backward single quote.

You can escape quotes using $\:

MessageBox MB_OK "I'll be happy" ; this one puts a ' inside a string
MessageBox MB_OK 'And he said to me "Hi there!"' ; this one puts a " inside a string
MessageBox MB_OK `And he said to me "I'll be fucked!"` ; this one puts both ' and "s inside a string
MessageBox MB_OK "$\"A quote from a wise man$\" said the wise man" ; this one shows escaping of quotes

It is also possible to put newlines, tabs etc. in a string using $\r, $\n, $\t etc. More information...

Variables

Variables start with $. User variables should be declared and are case-sensitive.

Var MYVAR

StrCpy $MYVAR "myvalue"

More information...

Long commands

To extend a command over multiple lines, use a backslash (\) at the end of the line, and the next line will effectively be concatenated the end of it. For example:

CreateShortCut "$SMPROGRAMS\NSIS\ZIP2EXE project workspace.lnk" \
    "$INSTDIR\source\zip2exe\zip2exe.dsw"

MessageBox MB_YESNO|MB_ICONQUESTION \
    "Do you want to remove all files in the folder? \
    (If you have anything you created that you want \
     to keep, click No)" \
    IDNO NoRemoveLabel

Configuration file

If a file named "nsisconf.nsh" in the same directory as makensis.exe exists, it will be included by default before any scripts (unless the /NOCONFIG command line parameter is used).


Variables

4.2 Variables

All variables are global and can be used in Sections or Functions.

4.2.1 User Variables

$VARNAME

User variables can be declared with the Var command. You can use these variables to store values, work with string manipulation etc. Unlike constants these variables are case-sensitive.

4.2.1.1 Var

var_name

Declare a user variable. Allowed characters for variables names: [a-z][A-Z][0-9] and '_'.

4.2.2 Other Writable Variables

$0, $1, $2, $3, $4, $5, $6, $7, $8, $9, $R0, $R1, $R2, $R3, $R4, $R5, $R6, $R7, $R8, $R9

Registers. These variables can be used just like user variables, but are usually used in shared functions or macro's. You don't have to declare these variables, so you won't get any name conflicts when using them in shared code. When using these variables in shared code, it's recommended that you use the stack to save and restore their original values. These variables can also be used for communication with plug-ins, because they can be read and written by the plug-in DLL's.

$INSTDIR

The installation directory ($INSTDIR is modifiable using StrCpy, ReadRegStr, ReadINIStr, etc. - This could be used, for example, in the .onInit function to do a more advanced detection of install location).

$OUTDIR

The current output directory (set implicitly via SetOutPath or explicitly via StrCpy, ReadRegStr, ReadINIStr, etc)

$CMDLINE

The command line of the installer. The format of the command line can be one of the following:

  • "full\path to\installer.exe" PARAMETER PARAMETER PARAMETER
  • installer.exe PARAMETER PARAMETER PARAMETER
  • For parsing out the PARAMETER portion, see GetParameters on the useful functions appendix. If /D= is specified on the command line (to override the install directory) it won't show up in $CMDLINE.

$LANGUAGE

The identifier of the language that is currently used. For example, English is 1033. You can change this variable in .onInit.

4.2.3 Constants

Constants can also be used in the InstallDir attribute.

Note that some of the new constants will not work on every OS. For example, $CDBURN_AREA will only work on Windows XP and above. If it's used on Windows 98, it'll be empty. Unless mentioned otherwise, a constant should be available on every OS.

$PROGRAMFILES

The program files directory (usually C:\Program Files but detected at runtime).

$COMMONFILES

The common files directory. This is a directory for components that are shared across applications (usually C:\Program Files\Common Files but detected at runtime).

$DESKTOP

The windows desktop directory (usually C:\windows\desktop but detected at runtime). The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

$EXEDIR

The location of the installer executable. (technically you can modify this variable, but it is probably not a good idea)

${NSISDIR}

A symbol that contains the path where NSIS is installed. Detected at compile time. Useful if you want to call resources that are in NSIS directory e.g. Icons, UIs...

$WINDIR

The windows directory (usually C:\windows or C:\winnt but detected at runtime)

$SYSDIR

The windows system directory (usually C:\windows\system or C:\winnt\system32 but detected at runtime)

$TEMP

The system temporary directory (usually C:\windows\temp but detected at runtime)

$STARTMENU

The start menu folder (useful in adding start menu items using CreateShortCut). The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

$SMPROGRAMS

The start menu programs folder (use this whenever you want $STARTMENU\Programs). The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

$SMSTARTUP

The start menu programs / startup folder. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

$QUICKLAUNCH

The quick launch folder for IE4 active desktop and above. If quick launch is not available, simply returns the same as $TEMP.

$DOCUMENTS

The documents directory. A typical path for the current user is C:\Documents and Settings\Foo\My Documents. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

This constant is not available on Windows 95 with Internet Explorer 4 not installed.

$SENDTO

The directory that contains Send To menu shortcut items.

$RECENT

The directory that contains shortcuts to the user's recently used documents.

$FAVORITES

The directory that contains shortcuts to the user's favorite websites, documents, etc. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

This constant is not available on Windows 95 with Internet Explorer 4 not installed.

$MUSIC

The user's music files directory. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

This constant is available on Windows XP, ME and above.

$PICTURES

The user's picture files directory. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

This constant is available on Windows 2000, XP, ME and above.

$VIDEOS

The user's video files directory. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

This constant is available on Windows XP, ME and above.

$NETHOOD

The directory that contains link objects that may exist in the My Network Places/Network Neighborhood folder.

This constant is not available on Windows 95 with Internet Explorer 4 and Active Desktop not installed.

$FONTS

The system's fonts directory.

$TEMPLATES

The document templates directory. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

$APPDATA

The application data directory. Detection of the current user path requires Internet Explorer 4 and above. Detection of the all users path requires Internet Explorer 5 and above. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

This constant is not available on Windows 95 with Internet Explorer 4 and Active Desktop not installed.

$PRINTHOOD

The directory that contains link objects that may exist in the Printers folder.

This constant is not available on Windows 95 and Windows 98.

$INTERNET_CACHE

Internet Explorer's temporary internet files directory.

This constant is not available on Windows 95 and Windows NT with Internet Explorer 4 and Active Desktop not installed.

$COOKIES

Internet Explorer's cookies directory.

This constant is not available on Windows 95 and Windows NT with Internet Explorer 4 and Active Desktop not installed.

$HISTORY

Internet Explorer's history directory.

This constant is not available on Windows 95 and Windows NT with Internet Explorer 4 and Active Desktop not installed.

$PROFILE

The user's profile directory. A typical path is C:\Documents and Settings\Foo.

This constant is available on Windows 2000 and above.

$ADMINTOOLS

A directory where administrative tools are kept. The context of this constant (All Users or Current user) depends on the SetShellVarContext setting. The default is the current user.

This constant is available on Windows 2000, ME and above.

$RESOURCES

The resources directory that stores themes and other Windows resources (usually C:\Windows\Resources but detected at runtime).

This constant is available on Windows XP and above.

$RESOURCES_LOCALIZED

The localized resources directory that stores themes and other Windows resources (usually C:\Windows\Resources\1033 but detected at runtime).

This constant is available on Windows XP and above.

$CDBURN_AREA

A directory where files awaiting to be burned to CD are stored.

This constant is available on Windows XP and above.

$HWNDPARENT

The decimal HWND of the parent window.

$PLUGINSDIR

The path to a temporary folder created upon the first usage of a plugin or a call to InitPluginsDir. This folder is automatically deleted when the installer exits. This makes this folder the ideal folder to hold INI files for InstallOptions, bitmaps for the splash plugin, or any other file that a plugin needs to work.

4.2.4 Variables Used in Strings

$$

Use to represent $.

$\r

Use to represent a carriage return (\r).

$\n

Use to represent a newline (\n).

$\t

Use to represent a tab (\t).

${SYMBOL}

Where SYMBOL is the name of something globally defined, this will be replaced with the value of that symbol. The order of calling Symbols in the script is important.

Name "Test Program ${VERSION}"
!define VERSION "V.1.0"

This code will set the name of the installer to "Test Program ${VERSION}". The Same happens if the Symbol has not been defined.

!define VERSION "V.1.0"
Name "Test Program ${VERSION}"

This code sets the name of the installer to "Test Program V.1.0"

For more info, see Conditional Compilation.


Labels

4.3 Labels

Labels are the targets of Goto instructions, or of the various branching instructions (such as IfErrors, MessageBox, IfFileExists, and StrCmp). Labels must be within a Section or a Function. Labels are local in scope, meaning they are only accessible from within the Section or Function that they reside in. To declare a label, simply do:

MyLabel:

Labels cannot begin with a -, +, !, $, or 0-9. When specifying labels for the various instructions that require them, remember that both an empty string ("") and 0 both represent the next instruction (meaning no Goto will occur). Labels beginning with a period (.) are global, meaning you can jump to them from any function or section (though you cannot jump to an uninstall global label from the installer, and vice versa).


Relative Jumps

4.4 Relative Jumps

Unlike labels, relative jumps are, as the name suggests, relative to the place they are called from. You can use relative jumps wherever you can use labels. Relative jumps are marked by numbers. +1 jumps to the next instruction (the default advancement), +2 will skip one instruction and go to the second instruction from the current instruction, -2 will jump two instructions backward, and +10 will skip 9 instructions, jumping to the tenth instruction from the current instruction.

An instruction is every command that is executed at run-time, when the installer is running. MessageBox, Goto, GetDLLVersion, FileRead, SetShellVarContext are all instructions. AddSize, Section, SubSection, SectionEnd, SetOverwrite (and everything under Compiler Flags), Name, SetFont, LangString, are not instructions because they are executed at compile time.

Examples:

 Goto +2
   MessageBox MB_OK "You will never ever see this message box"
 MessageBox MB_OK "The last message was skipped, this one should be shown"

 Goto +4
 MessageBox MB_OK "The following message will be skipped"
 Goto +3
 MessageBox MB_OK "You will never ever see this message box"
 Goto -3
 MessageBox MB_OK "Done"

Note: relative jumps don't work with Exch, File, plug-ins (Plugin::Function), InitPluginsDir, GetFileTimeLocal or GetDLLVersionLocal. Do not try to jump over them using relative jumps, you will not get the result you were expecting.


Pages

4.5 Pages

Each (non-silent) NSIS installer has a set of pages. Each page can be a NSIS built-in page or a custom page created by a user's function (with InstallOptions for example).

Using the script you can control the pages' order, appearance, and behavior. You can skip pages, paint them white, force the user to stay in a certain page until a certain condition is met, show a readme page, show custom designed pages for input and more. In this section, you will learn how to control all of the above.

There are two basic commands regarding pages, Page and UninstPage. The first adds a page to the installer, the second adds a page to the uninstaller. On top of those two there is the PageEx command which allows you to add a page to either one and with greater amount of options. PageEx allows you to set options to the specific page you are adding instead of using the default that's set outside of PageEx.

4.5.1 Ordering

The page order is set simply by the order Page, UninstPage and PageEx appear in the script. For example:

 Page license
 Page components
 Page directory
 Page instfiles
 UninstPage uninstConfirm
 UninstPage instfiles

This code will tell NSIS to first show the license page, then the components selection page, then the directory selection page and finally the install log where sections are executed, just like in old installers. The uninstaller will first show the uninstall confirmation page and then the uninstallation log.

You can specify the same page type more than once.

For backwards compatibility with old NSIS scripts, the following installer pages will be added if no installer page commands are used: license (if LicenseText and LicenseData were specified), components (if ComponentText was specified and there is more than one visible section), directory (if DirText was specified) and instfiles. When there are no uninstaller page commands, the following uninstaller pages will be added: uninstall confirmation page (if UninstallText was specified) and instfiles. This method is deprecated, converting scripts to use page commands is highly recommended because you can use the new standard language strings.

4.5.2 Page Options

Each page has its unique set of data that defines how it will look and act. This section describes what data each type of page uses and how you can set it. Callback functions are described below and are not dealt with in this section.

The list below lists what commands affect the certain page type. Unless mentioned otherwise, these commands can be used both in and out of a PageEx block. If used inside a PageEx block they will only affect the current page being set by PageEx, else they will set the default for every other page.

License page

  • LicenseText
  • LicenseData
  • LicenseForceSelection

Components selection page

  • ComponentText

Directory selection page

  • DirText
  • DirVar - can only be used in PageEx

Un/Installation log page

  • DetailsButtonText
  • CompletedText

Uninstall confirmation page

  • DirVar - can only be used in PageEx
  • UninstallText

To set the page caption use Caption.

4.5.3 Callbacks

Each built-in page has three callback functions. The pre-function, the show-creation function and the leave-function. The pre-function is called right before the page is created, the show-function is called right after it is created and before it is shown and the leave-function is called right after the user has pressed the next button and before the page is left.

  • The pre-function allows you to skip the page using Abort.
  • The show-function allows you to tweak the page's user interface with CreateFont, SetCtlColors, SendMessage and others.
  • The leave-function allows you to force the user to stay on the current page using Abort.

A custom page only has two callback functions, one that creates it which is mandatory, and one leave-function that acts just like the leave-function for built-in pages.

Examples:

 Page license skipLicense "" stayInLicense
 Page custom customPage "" ": custom page"
 Page instfiles

 Function skipLicense
   MessageBox MB_YESNO "Do you want to skip the license page?" IDNO no
     Abort
   no:
 FunctionEnd

 Function stayInLicense
   MessageBox MB_YESNO "Do you want to stay in the license page?" IDNO no
     Abort
   no:
 FunctionEnd

 Function customPage
   GetTempFileName $R0
   File /oname=$R0 customPage.ini
   InstallOptions::dialog $R0
   Pop $R1
   StrCmp $R1 "cancel" done
   StrCmp $R1 "back" done
   StrCmp $R1 "success" done
   error: MessageBox MB_OK|MB_ICONSTOP "InstallOptions error:$\r$\n$R1"
   done:
 FunctionEnd

4.5.4 Page

custom [creator_function] [leave_function] [caption]
  OR
(license|components|directory|instfiles|uninstConfirm) [pre_function] [show_function] [leave_function]

Adds an installer page. See the above sections for more information about built-in versus custom pages and about callback functions.

4.5.5 UninstPage

custom [creator_function] [leave_function] [caption]
  OR
(license|components|directory|instfiles|uninstConfirm) [pre_function] [show_function] [leave_function]

Adds an uninstaller page. See the above sections for more information about built-in versus custom pages and about callback functions.

4.5.6 PageEx

[un.](custom|uninstConfirm|license|components|directory|instfiles)

Adds an installer page or an uninstaller page if the un. prefix was used. Every PageEx must have a matching PageExEnd. In a PageEx block you can set options that are specific to this page and will not be used for other pages. Options that are not set will revert to what was set outside the PageEx block or the default if nothing was set. To set the sub-caption for a page use Caption or SubCaption to set the default. To set the callback functions for a page set with PageEx use PageCallbacks. See the above sections for more information about built-in versus custom pages.

Example usage:

 PageEx license
   LicenseText "Readme"
   LicenseData readme.rtf
 PageExEnd

 PageEx license
   LicenseData license.txt
   LicenseForceSelection checkbox
 PageExEnd

4.5.7 PageExEnd

Ends a PageEx block.

4.5.8 PageCallbacks

([creator_function] [leave_function]) | ([pre_function] [show_function] [leave_function])

Sets the callback functions for a page defined using PageEx. Can only be used inside a PageEx block. See the above sections for more information about callback functions.


Sections

4.6 Sections

Each NSIS installer contains one or more Sections. Each These sections are created, modified, and ended with the following commands.

  • Each section contains zero or more instructions.
  • Sections are executed in order by the resulting installer, and if ComponentText is set, the user will have the option of disabling/enabling each visible section.
  • If a section's name is 'Uninstall' or is prefixed with 'un.', then it is a an uninstaller section.

4.6.1 Section Commands

4.6.1.1 AddSize

size_kb

Tells the installer that the current section needs an additional "size_kb" kilobytes of disk space. Only valid within a section (will have no effect outside of a section or in a function).

4.6.1.2 Section

[/o] [([!]|[-])section_name] [section index output]

Begins and opens a new section. If section_name is empty, omitted, or begins with a -, then it is a hidden section and the user will not have the option of disabling it. If the section name is 'Uninstall' or is prefixed with 'un.', then it is a an uninstaller section. If section index output is specified, the parameter will be !defined with the section index (that can be used for SectionSetText etc). If the section name begins with a !, the section will be displayed as bold. If the /o switch is specified, the section will be unselected by default.

4.6.1.3 SectionEnd

This command closes the current open section.

4.6.1.4 SectionIn

insttype_index [insttype_index] [RO]

This command specifies which install types (see InstType) the current section defaults to the enabled state in. Multiple SectionIn commands can be specified (they are combined). If you specify RO as a parameter, then the section will be read-only, meaning the user won't be able to change its state.

4.6.1.5 SubSection

[/e] Caption [subsection_name index output]

This command inserts a subsection. The subsection must be closed with SubSectionEnd, and should contain 1 or more Sections. If the subsection name begins with a !, the subsection will be displayed as bold. If /e is present, the sub sections of the sub section will be expanded by default. If section index output is specified, the parameter will be !defined with the section index (that can be used for SectionSetText etc). If the name is prefixed with 'un.' the subsection is an uninstaller subsection.

4.6.1.6 SubSectionEnd

Closes a subsection opened with SubSection.

4.6.2 Uninstall Section

A special Section named 'Uninstall' must be created in order to generate an uninstaller. This section should remove all files, registry keys etc etc that were installed by the installer, from the system. Here is an example of a simple uninstall section:

Section "Uninstall"
  Delete $INSTDIR\Uninst.exe ; delete self (see explanation below why this works)
  Delete $INSTDIR\myApp.exe
  RMDir $INSTDIR
  DeleteRegKey HKLM SOFTWARE\myApp
SectionEnd

The first Delete instruction works (deleting the uninstaller), because the uninstaller is transparently copied to the system temporary directory for the uninstall.


Functions

4.7 Functions

Functions are similar to Sections in that they contain zero or more instructions. User functions are not called by the installer directly, instead they are called from Sections using the Call instruction. Callback functions will be called by the installer when a certain event occurs.

Functions must be declared outside of Sections or other Functions.

4.7.1 Function Commands

4.7.1.1 Function

[function_name]

Begins and opens a new function. Function names beginning with "." (e.g. ".Whatever") are generally reserved for callback functions. Function names beginning with "un." are functions that will be generated in the Uninstaller. Hence, normal install Sections and functions cannot call uninstall functions, and the Uninstall Section and uninstall functions cannot call normal functions.

4.7.1.2 FunctionEnd

This command closes the current open function.

4.7.2 Callback Functions

You can create callback functions which have special names, that will be called by the installer at certain points in the install. Below is a list of currently available callbacks:

4.7.2.1 Install Callbacks

4.7.2.1.1 .onGUIInit

This callback will be called just before the first page is loaded and the installer dialog is shown, allowing you to tweak the user interface.

Example:

 !include "${NSISDIR}\Include\WinMessages.nsh"

 Function .onGUIInit
   # 1028 is the id of the branding text control
   GetDlgItem $R0 $HWNDPARENT 1028
   CreateFont $R1 "Tahoma" 10 700
   SendMessage $R0 ${WM_SETFONT} $R1 0
   # set background color to white and text color to red
   SetCtlColors $R0 FFFFFF FF0000
 FunctionEnd
4.7.2.1.2 .onInit

This callback will be called when the installer is nearly finished initializing. If the '.onInit' function calls Abort, the installer will quit instantly.

Here are two examples of how this might be used:

 Function .onInit
   MessageBox MB_YESNO "This will install. Continue?" IDYES NoAbort
     Abort ; causes installer to quit.
   NoAbort:
 FunctionEnd

or:

 Function .onInit
   ReadINIStr $INSTDIR $WINDIR\wincmd.ini Configuration InstallDir
   StrCmp $INSTDIR "" 0 NoAbort
     MessageBox MB_OK "Windows Commander not found. Unable to get install path."
     Abort ; causes installer to quit.
   NoAbort:
 FunctionEnd
4.7.2.1.3 .onInstFailed

This callback is called when the user hits the 'cancel' button after the install has failed (if it could not extract a file, or the install script used the Abort command).

Example:

  Function .onInstFailed
    MessageBox MB_OK "Better luck next time."
  FunctionEnd
4.7.2.1.4 .onInstSuccess

This callback is called when the install was successful, right before the install window closes (which may be after the user clicks 'Close' if AutoCloseWindow or SetAutoClose is set to false).

Example:

  Function .onInstSuccess
    MessageBox MB_YESNO "Congrats, it worked. View readme?" IDNO NoReadme
      Exec notepad.exe ; view readme or whatever, if you want.
    NoReadme:
  FunctionEnd
4.7.2.1.5 .onGUIEnd

This callback is called right after the installer window closes. Use it to free any user interface related plug-ins if needed.

4.7.2.1.6 .onMouseOverSection

This callback is called whenever the mouse position over the sections tree has changed. This allows you to set a description for each section for example. The section id on which the mouse is over currently is stored, temporarily, in $0.

Example:

  Function .onMouseOverSection
    FindWindow $R0 "#32770" "" $HWNDPARENT
    GetDlgItem $R0 $R0 1043 ; description item

    StrCmp $0 0 "" +2
      SendMessage $R0 ${WM_SETTEXT} 0 "first section description"

    StrCmp $0 1 "" +2
      SendMessage $R0 ${WM_SETTEXT} 0 "second section description"
  FunctionEnd
4.7.2.1.7 .onSelChange

Called when the selection changes on the component page. Useful for using with SectionSetFlags and SectionGetFlags.

4.7.2.1.8 .onUserAbort

This callback is called when the user hits the 'cancel' button, and the install hasn't already failed. If this function calls Abort, the install will not be aborted.

Example:

 Function .onUserAbort
   MessageBox MB_YESNO "Abort install?" IDYES NoCancelAbort
     Abort ; causes installer to not quit.
   NoCancelAbort:
 FunctionEnd
4.7.2.1.9 .onVerifyInstDir

This callback enables control over whether or not an installation path is valid for your installer. This code will be called every time the user changes the install directory, so it shouldn't do anything crazy with MessageBox or the likes. If this function calls Abort, the installation path in $INSTDIR is deemed invalid.

Example:

  Function .onVerifyInstDir
    IfFileExists $INSTDIR\Winamp.exe PathGood
      Abort ; if $INSTDIR is not a winamp directory, don't let us install there
    PathGood:
  FunctionEnd

4.7.2.2 Uninstall Callbacks

4.7.2.2.1 un.onGUIInit

This callback will be called just before the first page is loaded and the installer dialog is shown, allowing you to tweak the user interface.

Have a look at .onGUIInit for an example.

4.7.2.2.2 un.onInit

This callback will be called when the uninstaller is nearly finished initializing. If the 'un.onInit' function calls Abort, the uninstaller will quit instantly. Note that this function can verify and/or modify $INSTDIR if necessary.

Here are two examples of how this might be used:

  Function un.onInit
    MessageBox MB_YESNO "This will uninstall. Continue?" IDYES NoAbort
      Abort ; causes uninstaller to quit.
    NoAbort:
  FunctionEnd

or:

  Function un.onInit
    IfFileExists $INSTDIR\myfile.exe found
      Messagebox MB_OK "Uninstall path incorrect"
      Abort
    found:
  FunctionEnd
4.7.2.2.3 un.onUninstFailed

This callback is called when the user hits the 'cancel' button after the uninstall has failed (if it used the Abort command or otherwise failed).

Example:

  Function un.onUninstFailed
    MessageBox MB_OK "Better luck next time."
  FunctionEnd
4.7.2.2.4 un.onUninstSuccess

This callback is called when the uninstall was successful, right before the install window closes (which may be after the user clicks 'Close' if SetAutoClose is set to false)..

Example:

  Function un.onUninstSuccess
    MessageBox MB_OK "Congrats, it's gone."
  FunctionEnd
4.7.2.2.5 un.onGUIEnd

This callback is called right after the uninstaller window closes. Use it to free any user interface related plug-ins if needed.

4.7.2.2.6 un.onUserAbort

This callback is called when the user hits the 'cancel' button and the uninstall hasn't already failed. If this function calls Abort, the install will not be aborted.

Example:

  Function un.onUserAbort
    MessageBox MB_YESNO "Abort uninstall?" IDYES NoCancelAbort
      Abort ; causes uninstaller to not quit.
    NoCancelAbort:
  FunctionEnd


Installer Attributes

4.8 Installer Attributes

4.8.1 General Attributes

The commands below all adjust attributes of the installer. These attributes control how the installer looks and functions, including which pages are present in the installer, as what text is displayed in each part of each page, how the installer is named, what icon the installer uses, the default installation directory, what file it writes out, and more. Note that these attributes can be set anywhere in the file except in a Section or Function. With the exception of InstallDir, none of these attributes allow use of Variables other than $\r and $\n in their strings.

Defaults are bold and underlined

4.8.1.1 AddBrandingImage

(left|right|top|bottom) (width|height) [padding]

Adds a branding image on the top, bottom, left, or right of the installer. Its size will be set according to the width/height specified, the installer width/height and the installer font. The final size will not always be what you requested; have a look at the output of the command for the actual size. Because this depends on the installer font, you should use SetFont before AddBrandingImage. The default padding value is 2.

4.8.1.2 AllowRootDirInstall

true|false

Controls whether or not installs are enabled to the root directory of a drive, or directly into a network share. Set to 'true' to change the safe behavior, which prevents users from selecting C:\ or \\Server\Share as an install (and later on, uninstall) directory. For additional directory selection page customizability, see .onVerifyInstDir.

4.8.1.3 AutoCloseWindow

true|false

Sets whether or not the install window automatically closes when completed. This is overrideable from a section using SetAutoClose.

4.8.1.4 BGGradient

[off|(topc botc [textcolor|notext])]

Specifies whether or not to use a gradient background window. If 'off', the installer will not show a background window, if no parameters are specified, the default black to blue gradient is used, and otherwise the top_color or bottom_color are used to make a gradient. Top_color and bottom_color are specified using the form RRGGBB (in hexadecimal, as in HTML, only minus the leading '#', since # can be used for comments). 'textcolor' can be specified as well, or 'notext' can be specified to turn the big background text off.

4.8.1.5 BrandingText

/TRIM(LEFT|RIGHT|CENTER) text

Sets the text that is shown (by default it is 'Nullsoft Install System vX.XX') in the bottom of the install window. Setting this to an empty string ("") uses the default; to set the string to blank, use " " (a space). If it doesn't matter to you, leave it the default so that everybody can know why the installer didn't suck. heh. Use /TRIMLEFT, /TRIMRIGHT or /TRIMCENTER to trim down the size of the control to the size of the string.

4.8.1.6 Caption

caption

When used outside a PageEx block: Sets the text for the titlebar of the installer. the By default, it is 'Name Setup', where Name is specified with the Name instruction. You can, however, override it with 'MyApp Installer' or whatever. If you specify an empty string (""), the default will be used (you can however specify " " to achieve a blank string).

When used inside a PageEx block: Sets the subcaption of the current page.

4.8.1.7 ChangeUI

dialog ui_file.exe

Replaces dialog (IDD_LICENSE, IDD_DIR, IDD_SELCOM, IDD_INST, IDD_INSTFILES, IDD_UNINST or IDD_VERIFY) by a dialog with the same resource ID in ui_file.exe. You can also specify 'all' as the dialog if you wish to load replace all 7 of the dialogs at once from the same UI file. For some example UIs look at Contrib\UIs under your NSIS directory.

  • IDD_LICENSE must contain IDC_EDIT1 (RICHEDIT control).
  • IDD_DIR must contain IDC_DIR (edit box), IDC_BROWSE (button) and IDC_CHECK1 (checkbox).
  • IDD_SELCOM must contain IDC_TREE1 (SysTreeView32 control), and IDC_COMBO1 (combo box).
  • IDD_INST must contain IDC_BACK (button), IDC_CHILDRECT (static control the size of all other dialogs), IDC_VERSTR (static), IDOK (button), and IDCANCEL (button). If an image control (static with SS_BITMAP style) will be found in this dialog it will be used as the default for SetBrandingImage.
  • IDD_INSTFILES must contain IDC_LIST1 (SysListView32 control), IDC_PROGRESS (msctls_progress32 control), and IDC_SHOWDETAILS (button).
  • IDD_UNINST must contain IDC_EDIT1 (edit box).
  • IDD_VERIFY must contain IDC_STR (static).

4.8.1.8 CheckBitmap

bitmap.bmp

Specifies the bitmap with the images used for the checks of the component-selection page treeview.

This bitmap should have a size of 96x16 pixels, no more than 8bpp (256 colors) and contain six 16x16 images for the different states (in order: selection mask, not checked, checked, greyed out, unchecked & read-only, checked & read-only). Use magenta as mask color (this area will be transparent).

4.8.1.9 CompletedText

text

Replaces the default text ("Completed") that is printed at the end of the install if parameter is specified. Otherwise, the default is used.

4.8.1.10 ComponentText

[text [subtext] [subtext2]]

Used to change the default text on the component page.

text: Text above the controls, to the right of the installation icon.

subtext: Text next to the installation type selection.

subtext2: Text to the left of the components list and below the installation type.

The default string will be used if a string is empty ("").

4.8.1.11 CRCCheck

on|off|force

Specifies whether or not the installer will perform a CRC on itself before allowing an install. Note that if the user uses /NCRC on the command line when executing the installer, and you didn't specify 'force', the CRC will not occur, and the user will be allowed to install a (potentially) corrupted installer.

4.8.1.12 DetailsButtonText

show details text

Replaces the default details button text of "Show details", if parameter is specified (otherwise the default is used).

4.8.1.13 DirText

[text] [subtext] [browse_button_text] [browse_dlg_text]

Used to change the default text on the directory page.

text: Text above the controls, to the right of the installation icon.

subtext: Text on the directory selection frame.

browse_button_text: Text on the Browse button.

browse_dlg_text: Text on the "Browse For Folder" dialog, appears after clicking on "Browse" button.

The default string will be used if a string is empty ("").

4.8.1.14 DirVar

user_var(dir input/output)

Specifies which variable is to be used to contain the directory selected. This variable should contain the default value too. This allows to easily create two different directory pages that will not require you to move values in and out of $INSTDIR. The default variable is $INSTDIR. This can only be used in PageEx and for directory and uninstConfirm pages.

4.8.1.15 DirVerify

auto|leave

If `DirVerify leave' is used, the Next button will not be disabled if the installation directory is not valid or there is not enough space and a flag that you can read in the leave function using GetInstDirError will be set instead.

4.8.1.16 FileErrorText

file error text

Replaces the default text that comes up when a file cannot be written to. This string can contain a reference to $0, which is the filename ($0 is temporarily changed to this value). Example: "Can not write to file $\r$\n$0$\r$\ngood luck, bitch.".

4.8.1.17 Icon

[path\]icon.ico

Sets the icon of the installer. Every icon in the icon file will be included in the installer. Note that if you use different icons for installer and uninstaller the file size and structure of the icons has to match otherwise the build of your installer will fail.

4.8.1.18 InstallButtonText

install button text

If parameter is specified, overrides the default install button text (of "Install") with the specified text.

4.8.1.19 InstallColors

/windows | (foreground_color background_color)

Sets the colors to use for the install info screen (the default is 00FF00 000000. Use the form RRGGBB (in hexadecimal, as in HTML, only minus the leading '#', since # can be used for comments). Note that if "/windows" is specified as the only parameter, the default windows colors will be used.

4.8.1.20 InstallDir

definstdir

Sets the default installation directory is. See the variables section for variables that can be used to make this string (especially $PROGRAMFILES). Note that the part of this string following the last \ will be used if the user selects 'browse', and may be appended back on to the string at install time (to disable this, end the directory with a \ (which will require the entire parameter to be enclosed with quotes)). If this doesn't make any sense, play around with the browse button a bit.

4.8.1.21 InstallDirRegKey

root_key subkey key_name

This attribute tells the installer to check a string in the registry, and use it for the install dir if that string is valid. If this attribute is present, it will override the InstallDir attribute if the registry key is valid, otherwise it will fall back to the InstallDir default. When querying the registry, this command will automatically remove any quotes. If the string ends in ".exe", it will automatically remove the filename component of the string (i.e. if the string is "C:\program files\poop\poop.exe", it will know to use "C:\program files\poop"). For more advanced install directory configuration, set $INSTDIR in .onInit.

4.8.1.22 InstProgressFlags

[flag [...]]

Valid values for flag are "smooth" (smooth the progress bar) or "colored" (color the progress bar with the colors set by InstallColors. Examples: "InstProgressFlags" (default old-school windows look), "InstProgressFlags smooth" (new smooth look), "InstProgressFlags smooth colored" (colored smooth look whee). Note: neither "smooth" or "colored" work with XPStyle on when the installer runs on Windows XP with a modern theme.

4.8.1.23 InstType

install_type_name | /NOCUSTOM | /CUSTOMSTRING=str | /COMPONENTSONLYONCUSTOM

Adds an install type to the install type list, or disables the custom install type. There can be as many as 32 types, each one specifying the name of the install type. If the name is prefixed with 'un.' it is an uninstaller install type. Instead of an "hard-coded" name you can use user variables which are processed at runtime. This allows you to change InstType name dynamically. Another way of changing the InstType name during runtime is the InstTypeSetText command. The difference is that with InstTypeSetText you are saving your precious user variables. The first type is the default (generally 'Typical'). Each type is numbered, starting at 1. See SectionIn for information on how those numbers are used. If the /NOCUSTOM switch is specified, then the "custom" install type is disabled, and the user has to choose one of the pre-defined install types. Alternatively, if the /CUSTOMSTRING switch is specified, the parameter will override the "Custom" install type text. Alternatively, if the /COMPONENTSONLYONCUSTOM flag is specified, the component list will only be show n if the "Custom" install type is selected.

4.8.1.24 LicenseBkColor

color | /gray | /windows

Sets the background color of the license data. Color is specified using the form RRGGBB (in hexadecimal, as in HTML, only minus the leading '#', since # can be used for comments). Default is '/gray'. You can also use the Windows OS defined color by using '/windows'.

4.8.1.25 LicenseData

licdata.(txt|rtf)

Specifies a text file or a RTF file to use for the license that the user can read. Omit this to not have a license displayed. Note that the file must be in the evil DOS text format (\r\n, yeah!). To define a multilingual license data use LicenseLangString.

If you make your license file a RTF file it is recommended you edit it with WordPad and not MS Word. Using WordPad will result in a much smaller file.

4.8.1.26 LicenseForceSelection

(checkbox [accept_text] | radiobuttons [accept_text] [decline_text] | off)

Specifies if the displayed license must be accept explicit or not. This can be done either by a checkbox or by radiobuttons. By default the "next button" is disabled and will only be enabled if the checkbox is enabled or the right radio button is selected. If off is specified the "next button" is enabled by default.

4.8.1.27 LicenseText

[text [button_text]]

Used to change the default text on the license page.

text: Text above the controls, to the right of the installation icon.

button_text: Text on the "I Agree" button.

The default string will be used if a string is empty ("").

4.8.1.28 MiscButtonText

[back button text [next button text] [cancel button text] [close button text]]

Replaces the default text strings for the four buttons (< Back, Next >, Cancel and Close). If parameters are omitted, the defaults are used.

4.8.1.29 Name

name [name_doubled_ampersands]

Sets the name of the installer. The name is usually simply the product name such as 'MyApp' or 'CrapSoft MyApp'. If you have one or more ampersands (&) in the name, set the second parameter to the same name, only with doubled ampersands. For example, if your product's name is "Foo & Bar", use:

 Name "Foo & Bar" "Foo && Bar"

If you have ampersands in the name and use a LangString for the name, you will have to create another one with doubled ampersands to use as the second parameter.

4.8.1.30 OutFile

[path\]install.exe

Specifies the output file that the MakeNSIS should write the installer to. This is just the file that MakeNSIS writes, it doesn't affect the contents of the installer.

4.8.1.31 SetFont

font_face_name font_size

Sets the installer font. Please remember that the font you choose must be present on the user's machine as well. Don't use rare fonts that only you have.

4.8.1.32 ShowInstDetails

hide|show|nevershow

Sets whether or not the details of the install are shown. Can be 'hide' to hide the details by default, allowing the user to view them, or 'show' to show them by default, or 'nevershow', to prevent the user from ever seeing them. Note that sections can override this using SetDetailsView.

4.8.1.33 ShowUninstDetails

hide|show|nevershow

Sets whether or not the details of the uninstall are shown. Can be 'hide' to hide the details by default, allowing the user to view them, or 'show' to show them by default, or 'nevershow', to prevent the user from ever seeing them. Note that sections can override this using SetDetailsView.

4.8.1.34 SilentInstall

normal|silent|silentlog

Specifies whether or not the installer should be silent. If it is 'silent' or 'silentlog', all sections that have the SF_SELECTED flag are installed quietly (you can set this flag using see SectionSetFlags), with no screen output from the installer itself (the script can still display whatever it wants, use MessageBox's /SD to specify a default for silent installers). Note that if this is set to 'normal' and the user runs the installer with /S (case sensitive) on the command line, it will behave as if SilentInstall 'silent' was used. Note: see also LogSet.

See section 4.12 for more information.

4.8.1.35 SilentUnInstall

normal|silent

Specifies whether or not the uninstaller should be silent. If it is 'silent' or 'silentlog', the uninstall section will run quietly, with no screen output from the uninstaller itself (the script can still display whatever it wants, use MessageBox's /SD to specify a default for silent installers). Note that if this is set to 'normal' and the user runs the uninstaller with /S on the command line, it will behave as if SilentUnInstall 'silent' was used. Note: see also LogSet.

See section 4.12 for more information.

4.8.1.36 SpaceTexts

[req text [avail text]]

If parameters are specified, overrides the space required and space available text ("Space required: " and "Space available: " by default). If 'none' is specified as the required text no space texts will be shown.

4.8.1.37 SubCaption

[page_number subcaption]

Overrides the subcaptions for each of the installer pages (0=": License Agreement",1=": Installation Options",2=": Installation Directory", 3=": Installing Files", 4=": Completed"). If you specify an empty string (""), the default will be used (you can however specify " " to achieve a blank string).

You can also set a subcaption (or override the default) using Caption inside a PageEx block.

4.8.1.38 UninstallButtonText

text

Changes the text of the button that by default says "Uninstall" in the uninstaller. If no parameter is specified, the default text is used. See also WriteUninstaller (replaces UninstallEXEName).

4.8.1.39 UninstallCaption

caption

Sets what the titlebars of the uninstaller will display. By default, it is 'Name Uninstall', where Name is specified with the Name command. You can, however, override it with 'MyApp uninstaller' or whatever. If you specify an empty string (""), the default will be used (you can however specify " " to achieve a blank string)

4.8.1.40 UninstallIcon

[path\]icon.ico

Sets the icon of the uninstaller. This icon file must have the exact same structure as the installer icon file.

4.8.1.41 UninstallSubCaption

page_number subcaption

Sets the default subcaptions for the uninstaller pages (0=": Confirmation",1=": Uninstalling Files",2=": Completed"). If you specify an empty string (""), the default will be used (you can however specify " " to achieve a blank string).

You can also set a subcaption (or override the default) using Caption inside a PageEx block.

4.8.1.42 UninstallText

text [subtext]

Specifies the texts on the uninstaller confirm page.

text: Text above the controls

subtext: Text next to the uninstall location

4.8.1.43 WindowIcon

on|off

Sets whether or not the installer's icon is being displayed.

4.8.1.44 XPStyle

on|off

Sets whether or not an XP manifest will be added to the installer. An XP manifest makes the installer controls use the new XP style when running on Windows XP. This affects the uninstaller too.

4.8.2 Compiler Flags

The following commands change how the compiler generates code and compresses data. These commands are valid anywhere in the script, and effect every line below where each one is placed (until overridden by another command).

4.8.2.1 AllowSkipFiles

on|off

This command specifies whether the user should be able to skip a file or not. A user has an option to skip a file if SetOverwrite is set to on (default) and the installer fails to open a file for writing when trying to extract a file. If off is used the ignore button which allows the user to skip the file will not show and the user will only have an option to abort the installation (Cancel button) or retry opening the file for writing (Retry button). If on is used the user will have an option to skip the file (error flag will be set - see SetOverwrite).

4.8.2.2 FileBufSize

buffer_size_in_mb

This command sets the size of the compiler's internal file buffers. This command allows you to control the compiler's memory usage by limiting how much of a given file it will load into memory at once. Since the compiler needs both input and output, twice the memory size specified could be used at any given time for file buffers. This command does not limit the compression buffers which could take another couple of MB, neither does it limit the compiler's other internal buffers, but those shouldn't normally top 1MB anyway. Specifying a very small number could decrease performance. Specifying a very large number could exhaust system resources and force the compiler to cancel the compilation process. The default value is 32MB.

4.8.2.3 SetCompress

auto|force|off

This command sets the compress flag which is used by the installer to determine whether or not data should be compressed. Typically the SetCompress flag will effect the commands after it, and the last SetCompress command in the file also determines whether or not the install info section and uninstall data of the installer is compressed. If compressflag is 'auto', then files are compressed if the compressed size is smaller than the uncompressed size. If compressflag is set to 'force', then the compressed version is always used. If compressflag is 'off' then compression is not used (which can be faster).

Note that this option has no effect when solid compression is used, which is enabled for BZIP2 and LZMA by default.

4.8.2.4 SetCompressor

zlib|bzip2|lzma

This command sets the compression algorithm used to compress files/data in the installer.

Three compression methods are supported: ZLIB, BZIP2 and LZMA.

ZLIB (the default) uses the deflate algorithm, it is a quick and simple method. With the default compression level it uses about 300 KB of memory.

BZIP2 usually gives better compression ratios than ZLIB, but it is a bit slower and uses more memory. With the default compression level it uses about 4 MB of memory.

LZMA is a new compression method that gives very good compression ratios. The decompression speed is high (10-20 MB/s on a 2 GHz CPU), the compression speed is lower. The memory size that will be used for decompression is the dictionary size plus a few KBs, the default is 8 MB.

4.8.2.5 SetCompressorDictSize

dict_size_mb

Sets the dictionary size in megabytes (MB) used by the LZMA compressor (default is 8 MB).

4.8.2.6 SetDatablockOptimize

on|off

This command tells the compiler whether or not to do datablock optimizations. Datablock optimizations have the compiler check to see if any data being added to the data block is already in the data block, and if so, it is simply referenced as opposed to added (can save a little bit of size). It is highly recommended to leave this option on.

4.8.2.7 SetDateSave

on|off

This command sets the file date/time saving flag which is used by the File command to determine whether or not to save the last write date and time of the file, so that it can be restored on installation. Valid flags are 'on' and 'off'. 'on' is the default.

4.8.2.8 SetOverwrite

on|off|try|ifnewer|ifdiff|lastused

This command sets the overwrite flag which is used by the File command to determine whether or not the file should overwrite any existing files that are present. If overwriteflag is 'on', files are overwritten (this is the default). If overwriteflag is 'off', files that are already present are not overwritten. If overwriteflag is 'try', files are overwritten if possible (meaning that if the file is not able to be written to, it is skipped without any user interaction). If overwriteflag is 'ifnewer', then files are only overwritten if the existing file is older than the new file. If overwriteflag is 'ifdiff', then files are only overwritten if the existing file is older or newer than the new file. Note that when in 'ifnewer' or 'ifdiff' mode, the destination file's date is set, regardless of what SetDateSave is set to.

4.8.2.9 SetPluginUnload

manual|alwaysoff

This command sets the unload plugin flag which is by CallInstDLL and plugin calls (dll::func). Setting this to always off will behave as if you have added the /NOUNLOAD to every CallInstDLL and plugin call. Setting this to manual will only not unload if you specifically use /NOUNLOAD.

4.8.3 Version Information

4.8.3.1 VIAddVersionKey

 [/LANG=lang_id] keyname value

Adds a field in the Version Tab of the File Properties. This can either be a field provided by the system or a user defined field. The following fields are provided by the System:

  • ProductName
  • Comments
  • CompanyName
  • LegalCopyright
  • FileDescription
  • FileVersion
  • ProductVersion
  • InternalName
  • LegalTrademarks
  • OriginalFilename
  • PrivateBuild
  • SpecialBuild

The name of these fields are translated on the target system, whereas user defined fields remain untranslated.

4.8.3.2 VIProductVersion

[version_string_X.X.X.X]

Adds the Product Version on top of the Version Tab in the Properties of the file.


Instructions

4.9 Instructions

4.9.1 Basic Instructions

The instructions that NSIS uses for scripting are sort of a cross between PHP and assembly. There are no real high level language constructs, but the instructions themselves are (for the most part) high level, and you have handy string capability (i.e. you don't have to worry about concatenating strings, etc). You essentially have 25 registers (20 general purpose, 5 special purpose), and a stack.

4.9.1.1 Delete

[/REBOOTOK] file

Delete file (which can be a file or wildcard, but should be specified with a full path) from the target system. If /REBOOTOK is specified and the file cannot be deleted then the file is deleted when the system reboots -- if the file will be deleted on a reboot, the reboot flag will be set. The error flag is set if files are found and cannot be deleted. The error flag is not set from trying to delete a file that does not exist.

4.9.1.2 Exec

command

Execute the specified program and continue immediately. Note that the file specified must exist on the target system, not the compiling system. $OUTDIR is used for the working directory. The error flag is set if the process could not be launched. Note, if the command could have spaces, you should put it in quotes to delimit it from parameters. e.g.: Exec '"$INSTDIR\command.exe" parameters'. If you don't put it in quotes it will not work on Windows 9x with or without parameters.

4.9.1.3 ExecShell

action command [parameters] [SW_SHOWNORMAL | SW_SHOWMAXIMIZED | SW_SHOWMINIMIZED]

Execute the specified program using ShellExecute. Note that action is usually "open", "print", etc, but can be an empty string to use the default action. Parameters and the show type are optional. $OUTDIR is used for the working directory. The error flag is set if the process could not be launched.

4.9.1.4 ExecWait

command [user_var(exit code)]

Execute the specified program and wait for the executed process to quit. See Exec for more information. If no output variable is specified ExecWait sets the error flag if the program executed returns a nonzero error code, or if there is an error. If an output variable is specified, ExecWait sets the variable with the exit code (and only sets the error flag if an error occurs; if an error occurs the contents of the user variable are undefined). Note, if the command could have spaces, you should put it in quotes to delimit it from parameters. e.g.: ExecWait '"$INSTDIR\command.exe" parameters'. If you don't put it in quotes it will not work on Windows 9x with or without parameters.

4.9.1.5 File

[/nonfatal] [/a] ([/r] (file|wildcard) [...] | /oname=file.dat infile.dat)

Adds file(s) to be extracted to the current output path ($OUTDIR).

  • Note that the output file name is $OUTDIR\filename_portion_of_file.
  • If the /oname=X switch is used, the output name becomes $OUTDIR\X. When using the /oname= switch, only one file can be specified, and the file name can contain variables (or a fully qualified path, e.g. $SYSDIR\whatever.dll).
  • Wildcards are supported.
  • If the /r switch is used, files and directories are added recursively. If is no trailing wildcard (e.g. File /r C:\whatever\mydir), then the whole tree of mydir will go in $OUTDIR\mydir. To put it in $OUTDIR, use File /r C:\whatever\mydir\*.*
  • If the /a switch is used, the attributes of the file(s) added will be preserved.
  • The File command sets the error flag if overwrite mode is set to 'try' and the file could not be overwritten, or if the overwrite mode is set to 'on' and the file could not be overwritten and the user selects ignore.
  • If the /nonfatal switch is used, a warning will be issued if no files found instead of an error.

4.9.1.6 Rename

[/REBOOTOK] source_file dest_file

Rename source_file to dest_file. You can use it to move a file from anywhere on the system to anywhere else and you can move a directory to somewhere else on the same drive. The destination file must not exist or the move will fail (unless you are using /REBOOTOK). If /REBOOTOK is specified, and the file cannot be moved (if, for example, the destination exists), then the file is moved when the system reboots. If the file will be moved on a reboot, the reboot flag will be set. The error flag is set if the file cannot be renamed (and /REBOOTOK is not used) or if the source file does not exist.

If no absolute path is specified the current folder will be used. The current folder is the folder set using the last SetOutPath instruction. If you have not used SetOutPath the current folder is $EXEDIR.

4.9.1.7 ReserveFile

[/nonfatal] [/r] file [file...]

Reserves a file in the data block for later use. As files are added in the order they are used in the script files that are used in the .onInit function, for example, might be added last and slow the loading of the installer. This is where this command comes useful, allowing you to speed up the loading process by including the file at the top of the data block instead of letting NSIS seek all the way down to the bottom of the compressed data block.

See File for more information about the parameters.

4.9.1.8 RMDir

[/r|/REBOOTOK] directory_name

Remove the specified directory (which should be a full path). Without /r, the directory will only be removed if it is completely empty. If /r is specified, the directory will be removed recursively, so all directories and files in the specified directory will be removed. If /REBOOTOK is specified, and the directory cannot be overwritten, then the directory will be deleted when the system reboots -- if the directory will be removed on a reboot, the reboot flag will be set. The error flag is set if the directory cannot be removed.

4.9.1.9 SetOutPath

outpath

Sets the output path ($OUTDIR) and creates it (recursively if necessary), if it does not exist. Must be a full pathname, usually is just $INSTDIR (you can specify $INSTDIR if you are lazy with a single "-").

4.9.2 Registry, INI, File Instructions

In all of the below registry instructions use an empty string (just two quotes with nothing between them - "") as the key name to specify the default key which is shown as (Default) in regedit.exe.

4.9.2.1 DeleteINISec

ini_filename section_name

Deletes the entire section [section_name] from ini_filename. If the section could not be removed from the ini file, the error flag is set. It does not set the error flag if the section could not be found.

4.9.2.2 DeleteINIStr

ini_filename section_name str_name

Deletes the string str_name from section [section_name] from ini_filename. If the string could not be removed from the ini file, the error flag is set. It does not set the error flag if the string could not be found.

4.9.2.3 DeleteRegKey

[/ifempty] root_key subkey

Deletes a registry key. If /ifempty is specified, the registry key will only be deleted if it has no subkeys (otherwise, the whole registry tree will be removed). Valid values for root_key are listed under WriteRegStr. The error flag is set if the key could not be removed from the registry (or if it didn't exist to begin with).

4.9.2.4 DeleteRegValue

root_key subkey key_name

Deletes a registry value. Valid values for root_key are listed under WriteRegStr. The error flag is set if the value could not be removed from the registry (or if it didn't exist to begin with).

4.9.2.5 EnumRegKey

user_var(output) root_key subkey index

Set user variable $x with the name of the 'index'th registry key in root_key\Subkey. Valid values for root_key are listed under WriteRegStr. Returns an empty string if there are no more keys, and returns an empty string and sets the error flag if there is an error.

4.9.2.6 EnumRegValue

user_var(output) root_key subkey index

Set user variable $x with the name of the 'index'th registry value in root_key\Subkey. Valid values for root_key are listed under WriteRegStr. Returns an empty string if there are no more values, and returns an empty string and sets the error flag if there is an error.

4.9.2.7 ExpandEnvStrings

user_var(output) string

Expands environment variables in "string" into the user variable $x. If error, the variable is set to empty, and the error flag is set.

4.9.2.8 FlushINI

ini_filename

Flushes the INI file's buffers. Windows 9x keeps all changes to the INI file in memory. This command causes the changes to be written to the disk immediately. Use it if you edit the INI manually, delete it, move it or copy it right after you change it with WriteINIStr, DeleteINISec or DeleteINStr.

4.9.2.9 ReadEnvStr

user_var(output) name

Reads from the environment string "name" and sets the value into the user variable $x. If there is an error reading the string, the user variable is set to empty, and the error flag is set.

4.9.2.10 ReadINIStr

user_var(output) ini_filename section_name entry_name

Reads from entry_name in [section_name] of ini_filename and stores the value into user variable $x. The error flag will be set and $x will be assigned to an empty string if the entry is not found.

4.9.2.11 ReadRegDWORD

user_var(output) root_key sub_key name

Reads a 32 bit DWORD from the registry into the user variable $x. Valid values for root_key are listed under WriteRegStr. The error flag will be set and $x will be set to an empty string ("" which is 0) if the DWORD is not present. If the value is present, but is not a DWORD, it will be read as a string and the error flag will be set.

4.9.2.12 ReadRegStr

user_var(output) root_key sub_key name

Reads from the registry into the user variable $x. Valid values for root_key are listed under WriteRegStr. The error flag will be set and $x will be set to an empty string ("") if the string is not present. If the value is present, but is of type REG_DWORD, it will be read and converted to a string and the error flag will be set.

4.9.2.13 WriteINIStr

ini_filename section_name entry_name value

Writes entry_name=value into [section_name] of ini_filename. The error flag is set if the string could not be written to the ini file.

4.9.2.14 WriteRegBin

root_key subkey key_name valuedata

This command writes a block of binary data to the registry. Valid values for root_key are listed under WriteRegStr. Valuedata is in hexadecimal (e.g. DEADBEEF01223211151). The error flag is set if the binary data could not be written to the registry. If the registry key doesn't exist it will be created.

4.9.2.15 WriteRegDWORD

root_key subkey key_name value

This command writes a dword (32 bit integer) to the registry (a user variable can be specified). Valid values for root_key are listed under WriteRegStr. The error flag is set if the dword could not be written to the registry. If the registry key doesn't exist it will be created.

4.9.2.16 WriteRegStr

root_key subkey key_name value

Write a string to the registry. See WriteRegExpandStr for more details.

4.9.2.17 WriteRegExpandStr

root_key subkey key_name value

Write a string to the registry. root_key must be one of:

  • HKCR or HKEY_CLASSES_ROOT
  • HKLM or HKEY_LOCAL_MACHINE
  • HKCU or HKEY_CURRENT_USER
  • HKU or HKEY_USERS
  • HKCC or HKEY_CURRENT_CONFIG
  • HKDD or HKEY_DYN_DATA
  • HKPD or HKEY_PERFORMANCE_DATA

The error flag is set if the string could not be written to the registry. The type of the string will be REG_SZ for WriteRegStr, or REG_EXPAND_STR for WriteRegExpandStr. If the registry key doesn't exist it will be created.

4.9.3 General Purpose Instructions

4.9.3.1 CallInstDLL

dllfile [/NOUNLOAD] function_name

Calls a function_name inside a NSIS extension DLL. See Contrib\ExDLL for an example of how to make one. Extension DLLs can access the stack and variables. Use /NOUNLOAD to force the installer to leave the DLL loaded. Note: To automatically extract and call plug-in DLLs, use a plug-in command instead of CallInstDLL.

4.9.3.2 CopyFiles

[/SILENT] [/FILESONLY] filespec_on_destsys destination_path [size_of_files_in_kb]

Copies files from the source to the destination on the installing system. Useful with $EXEDIR if you want to copy from installation media, or to copy from one place to another on the system. You might see a Windows status window of the copy operation if the operation takes a lot of time (to disable this, use /SILENT). The last parameter can be used to specify the size of the files that will be copied (in kilobytes), so that the installer can approximate the disk space requirements. On error, or if the user cancels the copy (only possible when /SILENT was omitted), the error flag is set. If /FILESONLY is specified, only files are copied.

If no absolute path is specified the current folder will be used. The current folder is the folder set using the last SetOutPath instruction. If you have not used SetOutPath the current folder is usually $EXEDIR.

4.9.3.3 CreateDirectory

path_to_create

Creates (recursively if necessary) the specified directory. The error flag is set if the directory couldn't be created.

You should always specify an absolute path.

4.9.3.4 CreateShortCut

link.lnk target.file [parameters [icon.file [icon_index_number [start_options [keyboard_shortcut [description]]]]]]

Creates a shortcut 'link.lnk' that links to 'target.file', with optional parameters 'parameters'. The icon used for the shortcut is 'icon.file,icon_index_number'; for default icon settings use empty strings for both icon.file and icon_index_number. start_options should be one of: SW_SHOWNORMAL, SW_SHOWMAXIMIZED, SW_SHOWMINIMIZED, or an empty string. keyboard_shortcut should be in the form of 'flag|c' where flag can be a combination (using |) of: ALT, CONTROL, EXT, or SHIFT. c is the character to use (a-z, A-Z, 0-9, F1-F24, etc). Note that no spaces are allowed in this string. A good example is "ALT|CONTROL|F8". $OUTDIR is used for the working directory. You can change it by using SetOutPath before creating the Shortcut. description should be the description of the shortcut, or comment as it is called under XP. The error flag is set if the shortcut cannot be created (i.e. the path does not exist, or some other error).

4.9.3.5 GetDLLVersion

filename user_var(high dword output) user_var(low dword output)

Gets the version information from the DLL (or any other executable containing version information) in "filename". Sets the user output variables with the high and low dwords of version information on success; on failure the outputs are empty and the error flag is set. The following example reads the DLL version and copies a human readable version of it into $0:

GetDllVersion "$INSTDIR\MyDLL.dll" $R0 $R1
IntOp $R2 $R0 / 0x00010000
IntOp $R3 $R0 & 0x0000FFFF
IntOp $R4 $R1 / 0x00010000
IntOp $R5 $R1 & 0x0000FFFF
StrCpy $0 "$R2.$R3.$R4.$R5"

4.9.3.6 GetDLLVersionLocal

localfilename user_var(high dword output) user_var(low dword output)

This is similar to GetDLLVersion, only it acts on the system building the installer (it actually compiles into two StrCpy commands). Sets the two output variables with the DLL version information of the DLL on the build system.

4.9.3.7 GetFileTime

filename user_var(high dword output) user_var(low dword output)

Gets the last write time of "filename". Sets the user output variables with the high and low dwords of the timestamp on success; on failure the outputs are empty and the error flag is set.

4.9.3.8 GetFileTimeLocal

localfilename user_var(high dword output) user_var(low dword output)

This is similar to GetFileTime, only it acts on the system building the installer (it actually compiles into two StrCpy commands). Sets the two output variables with the file timestamp of the file on the build system.

4.9.3.9 GetFullPathName

[/SHORT] user_var(output) path_or_file

Assign to the user variable $x, the full path of the file specified. If the path portion of the parameter is not found, the error flag will be set and $x will be empty. If /SHORT is specified, the path is converted to the short filename form.

4.9.3.10 GetTempFileName

user_var(output) base_dir

Assign to the user variable $x, the name of a temporary file. The file will have been created, so you can then overwrite it with what you please. The name of the temporary file is guaranteed to be unique. If to want the temporary file to be created in another directory than the Windows temp directory, specify a base_dir. Delete the file when done with it.

4.9.3.11 SearchPath

user_var(output) filename

Assign to the user variable $x, the full path of the file named by the second parameter. The error flag will be set and $x will be empty if the file cannot be found. Uses SearchPath() to search the system paths for the file.

4.9.3.12 SetFileAttributes

filename attribute1|attribute2|...

Sets the file attributes of 'filename'. Valid attributes can be combined with | and are:

  • NORMAL or FILE_ATTRIBUTE_NORMAL (you can use 0 to abbreviate this)
  • ARCHIVE or FILE_ATTRIBUTE_ARCHIVE
  • HIDDEN or FILE_ATTRIBUTE_HIDDEN
  • OFFLINE or FILE_ATTRIBUTE_OFFLINE
  • READONLY or FILE_ATTRIBUTE_READONLY
  • SYSTEM or FILE_ATTRIBUTE_SYSTEM
  • TEMPORARY or FILE_ATTRIBUTE_TEMPORARY

The error flag will be set if the file's attributes cannot be set (i.e. the file doesn't exist, or you don't have the right permissions). You can only set attributes. It's not possible to unset them. If you want to remove an attribute use NORMAL. This way all attributes are erased. This command doesn't support wildcards.

4.9.3.13 RegDLL

dllfile [entrypoint_name]

Loads the specified DLL and calls DllRegisterServer (or entrypoint_name if specified). The error flag is set if an error occurs (i.e. it can't load the DLL, initialize OLE, find the entry point, or the function returned anything other than ERROR_SUCCESS (=0)).

Use SetOutPath to set the current directory for DLLs that depend on other DLLs that are now in the path or in the Windows directory. For example, if foo.dll depends on bar.dll which is located in $INSTDIR use:

 SetOutPath $INSTDIR
 RegDLL $INSTDIR\foo.dll

4.9.3.14 UnRegDLL

dllfile

Loads the specified DLL and calls DllUnregisterServer. The error flag is set if an error occurs (i.e. it can't load the DLL, initialize OLE, find the entry point, or the function returned anything other than ERROR_SUCCESS (=0)).

4.9.4 Flow Control Instructions

4.9.4.1 Abort

user_message

Cancels the install, stops execution of script, and displays user_message in the status display. Note: you can use this from Callback functions to do special things. Page callbacks also uses Abort for special purposes.

4.9.4.2 Call

function_name | :label_name

Calls the function named function_name. If in the Uninstall section, Call can only be used with function names beginning with "un.". If the parameter starts with a ':' it will be treated as a label (so you can call to a label in your function - this is probably not going to be used most of the time).

4.9.4.3 ClearErrors

Clears the error flag.

4.9.4.4 GetCurrentAddress

user_var(output)

Gets the address of the current instruction (the GetCurrentAddress) and stores it in the output user variable. This user variable then can be passed to Call or Goto.

4.9.4.5 GetFunctionAddress

user_var(output) function_name

Gets the address of the function and stores it in the output user variable. This user variable then can be passed to Call or Goto. Note that if you Goto an address which is the output of GetFunctionAddress, your function will never be returned to (when the function you Goto'd to returns, you return instantly).

4.9.4.6 GetLabelAddress

user_var(output) label

Gets the address of the label and stores it in the output user variable. This user variable then can be passed to Call or Goto. Note that you may only call this with labels accessible from your function, but you can call it from anywhere (which is potentially dangerous). Note that if you Call the output of GetLabelAddress, code will be executed until it Return's (explicitly or implicitly at the end of a function), and then you will be returned to the statement after the Call.

4.9.4.7 Goto

label_to_jump_to | +offset| -offset| user_var(target)

If label is specified, goto the label 'label_to_jump_to:'.

If +offset or -offset is specified, jump is relative by offset instructions. Goto +1 goes to the next instruction, Goto -1 goes to the previous instruction, etc.

If a user variable is specified, jumps to absolute address (generally you will want to get this value from a function like GetLabelAddress). Compiler flag commands and SectionIn aren't instructions so jumping over them has no effect.

4.9.4.8 IfAbort

label_to_goto_if_abort [label_to_goto_if_no_abort]

If abort is called it will "return" true. This can happen if the user choose abort on a file that failed to create (or overwrite) or if the user aborted by hand. This function can only be called from the leave function of the instfiles page.

4.9.4.9 IfErrors

jumpto_iferror [jumpto_ifnoerror]

Checks and clears the error flag, and if it is set, it will goto jumpto_iferror, otherwise it will goto jumpto_ifnoerror. The error flag is set by other instructions when a recoverable error (such as trying to delete a file that is in use) occurs.

4.9.4.10 IfFileExists

file_to_check_for jump_if_present [jump_otherwise]

Checks for existence of file(s) file_to_check_for (which can be a wildcard, or a directory), and Gotos jump_if_present if the file exists, otherwise Gotos jump_otherwise. If you want to check to see if a file is a directory, use IfFileExists DIRECTORY\*.*

4.9.4.11 IfRebootFlag

[jump_if_set] [jump_if_not_set]

Atleast one parameter is required. Checks the reboot flag, and jumps to jump_if_set if the reboot flag is set, otherwise jumps to jump_if_not_set. The reboot flag can be set by Delete and Rename, or manually with SetRebootFlag.

4.9.4.12 IfSilent

[jump_if_silent] [jump_if_not]

Atleast one parameter is required. Checks the silent flag, and jumps to jump_if_silent if the installer is silent, otherwise jumps to jump_if_not. The silent flag can be set by SilentInstall, SilentUninstall, SetSilent and by the user passing /S on the command line.

4.9.4.13 IntCmp

val1 val2 jump_if_equal [jump_if_val1_less] [jump_if_val1_more]

Compares two integers val1 and val2. If val1 and val2 are equal, Gotos jump_if_equal, otherwise if val1 < val2, Gotos jump_if_val1_less, otherwise if val1 > val2, Gotos jump_if_val1_more.

4.9.4.14 IntCmpU

val1 val2 jump_if_equal [jump_if_val1_less] [jump_if_val1_more]

Compares two unsigned integers val1 and val2. If val1 and val2 are equal, Gotos jump_if_equal, otherwise if val1 < val2, Gotos jump_if_val1_less, otherwise if val1 > val2, Gotos jump_if_val1_more. Performs the comparison as unsigned integers.

4.9.4.15 MessageBox

mb_option_list messagebox_text [/SD return] [return_check jumpto] [return_check_2 jumpto_2]

Displays a MessageBox containing the text "messagebox_text". mb_option_list must be one or more of the following, delimited by |s (e.g. MB_YESNO|MB_ICONSTOP).

  • MB_OK - Display with an OK button
  • MB_OKCANCEL - Display with an OK and a cancel button
  • MB_ABORTRETRYIGNORE - Display with abort, retry, ignore buttons
  • MB_RETRYCANCEL - Display with retry and cancel buttons
  • MB_YESNO - Display with yes and no buttons
  • MB_YESNOCANCEL - Display with yes, no, cancel buttons
  • MB_ICONEXCLAMATION - Display with exclamation icon
  • MB_ICONINFORMATION - Display with information icon
  • MB_ICONQUESTION - Display with question mark icon
  • MB_ICONSTOP - Display with stop icon
  • MB_TOPMOST - Make messagebox topmost
  • MB_SETFOREGROUND - Set foreground
  • MB_RIGHT - Right align text
  • MB_DEFBUTTON1 - Button 1 is default
  • MB_DEFBUTTON2 - Button 2 is default
  • MB_DEFBUTTON3 - Button 3 is default
  • MB_DEFBUTTON4 - Button 4 is default

Return_check can be 0 (or empty, or left off), or one of the following:

  • IDABORT - Abort button
  • IDCANCEL - Cancel button
  • IDIGNORE - Ignore button
  • IDNO - No button
  • IDOK - OK button
  • IDRETRY - Retry button
  • IDYES - Yes button

If the return value of the MessageBox is return_check, the installer will Goto jumpto.

Use the /SD parameter with one of the return_check values above to specify the option that will be used when the installer is silent. See section 4.12 for more information.

4.9.4.16 Return

Returns from a function or section.

4.9.4.17 Quit

Causes the installer to exit as soon as possible. After Quit is called, the installer will exit (no callback functions will get a chance to run).

4.9.4.18 SetErrors

Sets the error flag.

4.9.4.19 StrCmp

str1 str2 jump_if_equal [jump_if_not_equal]

Compares (case insensitively) str1 to str2. If str1 and str2 are equal, Gotos jump_if_equal, otherwise Gotos jump_if_not_equal.

4.9.5 File Instructions

4.9.5.1 FileClose

handle

Closes a file handle opened with FileOpen.

4.9.5.2 FileOpen

user_var(handle output) filename openmode

Opens a file named "filename", and sets the handle output variable with the handle. The openmode should be one of "r" (read) "w" (write, all contents of file are destroyed) or "a" (append, meaning opened for both read and write, contents preserved). In all open modes, the file pointer is placed at the beginning of the file. If the file cannot be opened, the handle output is set to empty, and the error flag is set.

If no absolute path is specified the current folder will be used. The current folder is the folder set using the last SetOutPath instruction. If you have not used SetOutPath the current folder is $EXEDIR.

4.9.5.3 FileRead

handle user_var(output) [maxlen]

Reads a string from a file opened with FileOpen. The string is read until either a newline (or carriage return newline pair) occurs, or until a null byte is read, or until maxlen is met (if specified). Strings are limited to 1024 characters. If the end of file is read and no more data is available, the output string will be empty, and the error flag will be set.

4.9.5.4 FileReadByte

handle user_var(output)

Reads a byte from a file opened with FileOpen. The byte is stored in the output as an integer (0-255). If the end of file is read and no more data is available, the output will be empty, and the error flag will be set.

4.9.5.5 FileSeek

handle offset [mode] [user_var(new position)]

Seeks a file opened with FileOpen. If mode is omitted or specified as SET, the file is positioned to "offset". If mode is specified as CUR, then the file pointer is moved by offset. If mode is specified as END, the file pointer is set to a position relative to EOF. If the final parameter "new position" is specified, the new file position will be stored to that variable.

4.9.5.6 FileWrite

handle string

Writes a string to a file opened with FileOpen. If an error occurs writing, the error flag will be set.

4.9.5.7 FileWriteByte

handle string

Writes the integer interpretation of 'string' to a file opened with FileOpen. Of course you can enter the integer value directly. The following code writes a "Carriage Return / Line Feed" - Enter to the file.

FileWriteByte file_handle "13"
FileWriteByte file_handle "10"

You can If an error occurs writing, the error flag will be set. Note that the low byte of the integer is used, i.e. writing 256 is the same as writing 0, etc.

4.9.5.8 FindClose

handle

Closes a search opened with FindFirst.

4.9.5.9 FindFirst

user_var(handle output) user_var(filename output) filespec

Performs a search for 'filespec', placing the first file found in filename_output (a user variable). It also puts the handle of the search into handle_output (also a user variable). If no files are found, both outputs are set to empty, and the error flag is set. Best used with FindNext and FindClose. Note that the filename output is without path.

4.9.5.10 FindNext

handle user_var(filename_output)

Continues a search began with FindFirst. handle should be the handle_output_variable returned by FindFirst. If the search is completed (there are no more files), filename_output is set to empty, and the error flag is set. Note that the filename output is without path.

4.9.6 Uninstaller Instructions

4.9.6.1 WriteUninstaller

[Path\]exename.exe

Writes the uninstaller to the filename (and optionally path) specified. Only valid from within an install section or function, and requires that you have an uninstall section in your script. See also Uninstall configuration. You can call this one or more times to write out one or more copies of the uninstaller.

4.9.7 Miscellaneous Instructions

4.9.7.1 GetInstDirError

user_var(error output)

Use in the leave function of a directory page. Reads the flag set if 'DirVerify leave' is used. Possible values:

0: No error

1: Invalid installation directory

2: Not enough space on installation drive

4.9.7.2 InitPluginsDir

Initializes the plugins dir ($PLUGINSDIR) if not already initialized.

4.9.7.3 SetShellVarContext

current|all

Sets the context of $SMPROGRAMS and other shell folders. If set to 'current' (the default), the current user's shell folders are used. If set to 'all', the 'all users' shell folder is used. The all users folder may not be supported on all OSes. If the all users folder is not found, the current user folder will be used. Please take into consideration that a "normal user" has no rights to write in the all users area. Only admins have full access rights to the all users area. You can check this by using the UserInfo Plugin. See Contrib\UserInfo\UserInfo.nsi for an example.

4.9.7.4 Sleep

sleeptime_in_ms

Pauses execution in the installer for sleeptime_in_ms milliseconds. sleeptime_in_ms can be a variable, e.g. "$0" or a number, i.e. "666".

4.9.8 String Manipulation Instructions

4.9.8.1 StrCpy

user_var(destination) str [maxlen] [start_offset]

Sets the user variable $x with str. Note that str can contain other variables, or the user variable being set (concatenating strings this way is possible, etc). If maxlen is specified, the string will be a maximum of maxlen characters (if maxlen is negative, the string will be truncated abs(maxlen) characters from the end). If start_offset is specified, the source is offset by it (if start_offset is negative, it will start abs(start_offset) from the end of the string).

4.9.8.2 StrLen

user_var(length output) str

Sets user variable $x with the length of str.

4.9.9 Stack Support

4.9.9.1 Exch

[user_var | stack_index]

When no parameter is specified, exchanges the top two elements of the stack. When a parameter is specified and is a user variable, exchanges the top element of the stack with the parameter. When a parameter is specified and is a positive integer, Exch will swap the item on the top of the stack with the item that is specified by the offset from the top of the stack in the parameter. If there are not enough items on the stack to accomplish the exchange, a fatal error will occur (to help you debug your code :).

4.9.9.2 Pop

user_var(out)

Pops a string off of the stack into user variable $x. If the stack is empty, the error flag will be set.

4.9.9.3 Push

string

Pushes a string onto the stack. The string can then be Popped off of the stack.

4.9.10 Integer Support

4.9.10.1 IntFmt

user_var(output) format numberstring

Formats the number in "numberstring" using the format "format", and sets the output to user variable $x. Example format strings include "%08X" "%u"

4.9.10.2 IntOp

user_var(output) value1 OP [value2]

Combines value1 and (depending on OP) value2 into the user variable $x. OP is defined as one of the following:

  • + ADDs value1 and value2
  • - SUBTRACTs value2 from value1
  • * MULTIPLIEs value1 and value2
  • / DIVIDEs value1 by value2
  • % MODULUSs value1 by value2
  • | BINARY ORs value1 and value2
  • & BINARY ANDs value1 and value2
  • ^ BINARY XORs value1 and value2
  • ~ BITWISE NEGATEs value1 (i.e. 7 becomes 4294917288)
  • ! LOGICALLY NEGATEs value1 (i.e. 7 becomes 0)
  • || LOGICALLY ORs value1 and value2
  • && LOGICALLY ANDs value1 and value2

4.9.11 Reboot Instructions

4.9.11.1 Reboot

Reboots the computer. Be careful with this one. If there is an error rebooting, this function sets the error flag and continues. If the reboot is successful, this instruction does not return.

4.9.11.2 SetRebootFlag

true|false

Sets the reboot flag to either true or false.

4.9.12 Install Logging Instructions

4.9.12.1 LogSet

on|off

Sets whether install logging to $INSTDIR\install.log will happen. $INSTDIR must have a value before you call this function or it will not work. Note that NSIS_CONFIG_LOG must be set in the compile configuration file (config.h) on compile time (it is not by default) to support this. See Compiling NSIS Sources for more information about recompiling NSIS.

4.9.12.2 LogText

text

If installer logging is enabled, inserts text "text" into the log file.

4.9.13 Section Management

4.9.13.1 SectionSetFlags

section_index section_flags

Sets the section's flags. The flag is a 32 bit integer. The first bit (lowest) represents whether the section is currently enabled, the second bit represents whether the section is a subsection (don't modify this unless you really know what you are doing), the third bit represents whether the section is a subsection end (again, don't modify), the fourth bit represents whether the section is shown in bold or not, the fifth bit represents whether the section is read-only and the sixth bit represents whether the sub-section is to be automatically expanded. The error flag will be set if an out of range section is specified.

For an example of usage please see the one-section.nsi example.

4.9.13.2 SectionGetFlags

section_index user_var(output)

Retrieves the section's flags. See above for a description of the flag. The error flag will be set if an out of range section is specified.

4.9.13.3 SectionSetText

section_index section_text

Sets the description for the section section_index. To set a subsection, you must use - at the beginning of the text. If the Text is set to "" than the section will be hidden. The error flag will be set if an out of range section is specified.

4.9.13.4 SectionGetText

section_index user_var(output)

Stores the text description of the section section_index into the output. If the section is hidden, stores an empty string. The error flag will be set if an out of range section is specified.

4.9.13.5 SectionSetInstTypes

section_index inst_types

Sets the install types the section specified by section_index defaults to the enabled state in. Note that the section index starts with zero. Every bit of inst_types is a flag that tells if the section is in that install type or not. For example, if you have 3 install types and you want the first section to be included in install types 1 and 3, then the command should look like this:

SectionSetInstTypes 0 5

because the binary value for 5 is "00000101". The error flag will be set if the section index specified is out of range.

4.9.13.6 SectionGetInstTypes

section_index user_var(output)

Retrieves the install types flags array of a section. See above explanation about SectionSetInstTypes for a description of how to deal with the output. The error flag will be set if the section index specified is out of range.

4.9.13.7 SectionSetSize

section_index new_size

Sets the Size of the section specified by section_index. Note that the Index starts with Zero. The Value for Size must be entered in KiloByte and supports only whole numbers.

4.9.13.8 SectionGetSize

section_index user_var

Gets the Size of the section specified by section_index and stores the value in the given User Variable. Note that the Index starts with Zero.

4.9.13.9 SetCurInstType

inst_type_idx

Sets the current InstType. The Error Flag is not set if an out of range InstType was used.

SetCurInstType currently only works when the there is a components page.

4.9.13.10 GetCurInstType

user_var

Get the current InstType and stores the Value in the given User Variable. The value of ${NSIS_MAX_INST_TYPES} (32 by default) means that the custom installation type was selected.

4.9.13.11 InstTypeSetText

inst_type_idx text

Sets the Text of the specified InstType. If the Text is empty than the InstType is removed. By using a previously unused inst_type_idx number you can create new InstTypes. To add/remove Sections to this new InstType see SectionSetInstTypes. Unlike SectionIn the index is zero based, which means the first installation type's index is 0.

4.9.13.12 InstTypeGetText

inst_type_idx user_var

Gets the Text of the specified InstType.

4.9.14 User Interface Instructions

4.9.14.1 BringToFront

Makes the installer window visible and brings it to the top of the window list. If an application was executed that shows itself in front of the installer, a BringToFront would bring the installer back in focus.

Recent Windows versions restrict the setting of foreground windows. If the user if working with another application during installation, the user may be notifed using a different method.

4.9.14.2 CreateFont

user_var(handle output) face_name [height] [weight] [/ITALIC] [/UNDERLINE] [/STRIKE]

Creates a font and puts its handle into user_var. For more information about the different parameters have a look at MSDN's page about the Win32 API function CreateFont().

4.9.14.3 DetailPrint

user_message

Adds the string "user_message" to the details view of the installer.

4.9.14.4 EnableWindow

hwnd (1|0)

Enables or disables mouse and keyboard input to the specified window or control. Possible states are 0 (disabled) or 1 (enabled).

4.9.14.5 FindWindow

user_var(hwnd output) windowclass [windowtitle] [windowparent] [childafter]

Searches for a window. Behaves like the win32 FindWindowEx(). Searches by windowclass (and/or windowtitle if specified). If windowparent or childafter are specified, the search will be restricted as such. If windowclass or windowtitle is specified as "", they will not be used for the search. If the window is not found, the user variable returned is 0. To accomplish old-style FindWindow behavior, use FindWindow with SendMessage.

4.9.14.6 GetDlgItem

user_var(output) dialog item_id

Retrieves the handle of a control identified by item_id in the specified dialog box dialog. If you want to get the handle of a control on the inner dialog, first use FindWindow user_var(output) "#32770" "" $HWNDPARENT to get the handle of the inner dialog.

4.9.14.7 HideWindow

Hides the installer.

4.9.14.8 IsWindow

HWND jump_if_window [jump_if_not_window]

If HWND is a window, Gotos jump_if_window, otherwise, Gotos jump_if_not_window (if specified).

4.9.14.9 SendMessage

HWND msg wparam lparam [user_var(return value)] [/TIMEOUT=time_in_ms]

Sends a message to HWND. If a user variable $x is specified as the last parameter (or one before the last if you use /TIMEOUT), the return value of SendMessage will be stored to it. Note that when specifying 'msg' you must just use the integer value of the message. If you wish to send strings use "STR:a string" as wParam or lParam where needed.

  • WM_CLOSE 16
  • WM_COMMAND 273
  • WM_USER 1024

Include WinMessages.nsh to have all of Windows messages defined in your script.

To send a string param, put STR: before the parameter, for example: "STR:Some string".

Use /TIMEOUT=time_in_ms to specify the duration, in milliseconds, of the time-out period.

4.9.14.10 SetAutoClose

true|false

Overrides the default auto window-closing flag (specified for the installer using AutoCloseWindow, and false for the uninstaller). Specify 'true' to have the install window immediately disappear after the install has completed, or 'false' to make it require a manual close.

4.9.14.11 SetBrandingImage

[/IMGID=item_id_in_dialog] [/RESIZETOFIT] path_to_bitmap_file.bmp

Sets the current bitmap file displayed as the branding image. If no IMGID is specified, the first image control found will be used, or the image control created by AddBrandingImage. Note that this bitmap must be present on the user's machine. Use File first to put it there. If /RESIZETOFIT is specified the image will be automatically resized (very poorly) to the image control size. If you used AddBrandingImage you can get this size, by compiling your script and watching for AddBrandingImage output, it will tell you the size. SetBrandingImage will not work when called from .onInit!

4.9.14.12 SetDetailsView

show|hide

Shows or hides the details, depending on which parameter you pass. Overrides the default details view, which is set via ShowInstDetails.

4.9.14.13 SetDetailsPrint

none|listonly|textonly|both|lastused

Sets mode at which commands print their status. None has commands be quiet, listonly has status text only added to the listbox, textonly has status text only printed to the status bar, and both enables both (the default). For extracting many small files, textonly is recommended (especially on win9x with smooth scrolling enabled).

4.9.14.14 SetCtlColors

hwnd [/BRANDING] [text_color] [transparent|bg_color]

Sets a background color and the text color for a static control, edit control, button or a dialog. Use GetDlgItem to get the handle (HWND) of the control. To make the control transparent specify "transparent" as the background color value. You can also specify /BRANDING with or without text color and background color to make the control completely gray (or any other color you choose). This is used by the branding text control in the MUI.

4.9.14.15 SetSilent

silent | normal

Sets the installer to silent mode or normal mode. See SilentInstall for more information about silent installations. Can only be used in .onInit.

Sets the installer

4.9.14.16 ShowWindow

hwnd show_state

Sets the visability of a window. Possible show_states are the same as Windows ShowWindow function. SW_* constants are defined in Include\WinMessages.nsh.

4.9.15 Multiple Languages Instructions

4.9.15.1 LoadLanguageFile

language_file.nlf

Loads a language file for the construction of a language table. All of the language files that come with NSIS are in Contrib\Language Files

After you have inserted the language file ${LANG_langfile} will be defined as the language id (for example, ${LANG_ENGLISH} will be defined as 1033). Use it with LangString, LicenseLangString, LangDLL and VIAddVersionKey.

4.9.15.2 LangString

name language_id string

Defines a multilingual string. This means the its value will be different (or not, it's up to you) for every language. It allows you to easily make your installer multilingual without the need to add massive switches to the script.

Each language string has a name that identifies it and a value for each language used by the installer. They can be used in any runtime string in the script. To use a language string all you need to add to the string is $(LangString_name_here) where you want the LangString to be inserted.

Notes:

  • Unlike defines that use curly braces - {}, language strings use parenthesis - ().
  • If you change the langauge in the .onInit function, note that language strings in .onInit will still use the detected language based on the user's default Windows language, because the language is initialized after .onInit.
  • Always set langauge strings for every language in your script.
  • If you set the language ID to 0 the last used language by LangString or LoadLanguageFile will be used.

Example of usage:

 LangString message ${LANG_ENGLISH} "English message"
 LangString message ${LANG_FRENCH} "French message"
 LangString message ${LANG_KOREAN} "Korean message"

 MessageBox MB_OK "A translated message: $(message)"

4.9.15.3 LicenseLangString

name language_id license_path

Does the same as LangString only it loads the string from a text/RTF file and defines a special LangString that can be used only by LicenseData.


Multiple Languages

4.10 Multiple Languages

As of version 2 NSIS fully supports multiple languages. The interface of one installer can support multiple languages.

Use LoadLanguageFile for every langauge to load the default interface texts and language properties.

The default interface texts can easily be changed using instructions like ComponentText etc.

You can also use the contents of the standard language strings in your own strings (for example, $(^Name) contains the installer's name set using the Name instruction). The names of all standard langauges strings are listed as comments just above the strings in the language files. The language files are located in Contrib\Language Files.

To create your own langauge strings, use LangString.

For an example of an installer with multiple langauges, see languages.nsi.

4.10.1 Language Selection

When the installer starts up it goes through these steps to select the interface language:

  1. Get user's default Windows language
  2. Find a perfect match for the langauge
  3. If there is no perfect match, find a primary language match
  4. If there is no match, use the first language defined in the script (make sure your first language is a common one like English)
  5. If the langauge variable $LANGUAGE has changed during .onInit, NSIS goes through steps 2 to 4 again.

4.10.2 LangDLL Plug-in

The LangDLL plug-in allows you to give the user an option to choose the language of the installer. Just push the language id (${LANG_langfile}) and its name for every language in your installer, then the number of languages pushed, the caption, and the text that tells the user to select the language, call the plug-in function named LangDialog, pop the returned value into $LANGUAGE and you're good to go. If the user clicks on the cancel button the return value will be "cancel".

For an example of usage see languages.nsi.

4.10.3 RTL Languages

RTL languages are languages that are written from the right to the left (like Arabic and Hebrew). NSIS fully supports RTL languages. In the language file there is a place to specify if the language is RTL or not. To find out on runtime if the the current langaugeis RTL or not check the value of the $(^RTL) language string. It will be 1 if the language is RTL and 0 otherwise. This can be useful when using plug-ins that create dialogs, they usually have RTL settings too.


Plugin DLLs

4.11 Plugin DLLs

The abilities of the NSIS scripting language can be extended by utilising functionality provided in a DLL file. Probably the best known example of this is the InstallOptions.dll bundled with every NSIS release.

When the NSIS compiler starts it scans the plugins directory for DLLs and makes a list of the plugins found and their exported functions. During compilation if a sequence such as fred::flintstone is encountered where the compiler expected to find a language keyword the compiler will look through this list. If a list entry specifies that fred.dll exports function flintstone NSIS will pack the fred.dll file into the created installer binary.

During execution of a plugin command NSIS will unpack the necessary DLL to a temporary folder ($PLUGINSDIR), push all of the arguments specified (right-to-left order), and then execute the DLL function. If the /NOUNLOAD option is specified the DLL will not be unloaded until the installer exits or the next time you use the DLL without /NOUNLOAD. Please note that the last call to the plugin must not have the /NOUNLOAD flag or the plugin will not be deleted from $PLUGINSDIR, thus garbage will be left on the user's machine.

4.11.1 Using Plugin Commands

A plug-in call looks like this:

InstallOptions::dialog "ini_file_location.ini"

All parameters are pushed onto the stack (in this case, the plug-in function only needs one parameter). Some plugin commands may not need any parameters on the stack, others might require more of them. To use a plug-in command you will need to read the documentation for the plug-in so that you know what parameters its functions require.

4.11.2 Disabling Plugin Unloading

If you don't want to unload the DLL after calling a function, use /NOUNLOAD as the first parameter. For example:

dll:function /NOUNLOAD "param"

You can also use SetPluginUnload alwaysoff to avoid writing /NOUNLOAD each and every time you use the same plugin.

4.11.3 Calling plug-ins manually

If you want to call a plug-in that is stored on user's hard drive or somewhere else, use CallInstDLL. Almost all plug-ins provide installer functionality, so using plug-in commands is way easier. Using CallInstDLL can be useful when you have created plug-ins that should be linked to a certain version of your application and are being copied to the installation folder.


Silent Installers/Uninstallers

4.12 Silent Installers/Uninstallers

Silent installers are installers which require no user intervention and have no user interface. The user doesn't see any dialog and isn't ask any questions. This is useful for network administrators who wish to install or uninstall something without user intervention so they can preform the operation quickly over multiple number of computers. It is also useful for other developers who wish to embed another installer in their own and collect all of the required information on their installer instead of showing two installers.

NSIS installers and uninstallers can be both silent and not silent. When an installer or an uninstaller is silent, not all callback functions are called. .onGUIInit, .onGUIEnd, their uninstaller equivalents and any callback related to a specific page or page type will not be called.

There are several methods to make an installer or an uninstaller silent:

  1. SilentInstall and SilentUninstall
  2. SetSilent
  3. Passing /S on the command line (case sensitive)

To check if the installer/uninstaller is silent use IfSilent.

To make sure your installer will be silent when it needs to, you should check with IfSilent before each command that might require user intervention or create a window. The MessageBox command, which is the most common culprit in silent installers, has the /SD switch to set a default answer for silent installers. If you want your installer/uninstaller to be able to be completely silent you should use this switch. All internal NSIS message boxes have defaults for silent installers. The silent.nsi example demonstrates all aspects of this topic.

Since the directory page can not be shown on silent installers, the user has an option to specify the installation directory on the command line (this also works on non-silent installers/uninstallers). To do that, the user uses the /D switch as in the following example:

foo.exe /S /D=C:\Program Files\Foo

If your installer/uninstaller requires some more information that can not be gathered when silent, you can allow the user to specify that information on the command line and process it in .onInit. For example:

Function .onInit
  Call GetParameters
  Pop $2
  # search for quoted /USERNAME
  StrCpy $1 '"'
  Push $2
  Push '"/USERNAME='
  Call StrStr
  Pop $0
  StrCpy $0 $0 "" 1 # skip quote
  StrCmp $0 "" "" next
    # search for non quoted /USERNAME
    StrCpy $1 ' '
    Push $2
    Push '/USERNAME='
    Call StrStr
    Pop $0
next:
  StrCmp $0 "" done
    # copy the value after /USERNAME=
    StrCpy $0 $0 "" 10
  # search for the next parameter
  Push $0
  Push $1
  Call StrStr
  Pop $1
  StrCmp $1 "" done
  StrLen $1 $1
  StrCpy $0 $0 -$1
done:
FunctionEnd

The above example will copy the value the user passes on after /USRNAME= into $0. This allows the user to specify the required information on the command line instead of using the interactive user interface. The user can use:

foo.exe /S /USERNAME=Bar /D=C:\Program Files\Foo

or:

foo.exe /S "/USERNAME=string with spaces" /D=C:\Program Files\Foo

GetParameters and StrStr can be found in appendix B.

If your installer/uninstaller requires a lot of information and you want it to be able to be silent, you should allow the user to pass on a path to an answers file. This would be much more comfortable than writing all of the information on the command line.


Compile Time Commands

Chapter 5: Compile Time Commands

  • Compiler Utility Commands
    • !include
    • !addincludedir
    • !addplugindir
    • !cd
    • !echo
    • !error
    • !packhdr
    • !system
    • !warning
    • !verbose
  • Predefines
    • ${__FILE__}
    • ${__LINE__}
    • ${__DATE__}
    • ${__TIME__}
    • ${__TIMESTAMP__}
  • Read enviroment variables
    • $%envVarName%
  • Conditional Compilation
    • !define
    • !undef
    • !ifdef
    • !ifndef
    • !ifmacrodef
    • !ifmacrondef
    • !else
    • !endif
    • !insertmacro
    • !macro
    • !macroend


Compiler Utility Commands

5.1 Compiler Utility Commands

These commands are similar to the C preprocessor in terms of purpose and functionality. They allow file inclusion, conditional compilation, executable header packing, and processes execution during the build process. Note: none of these commands allow use of variables.

5.1.1 !include

file

This command will include 'file' as if it was part of the original script. Note that if a file is included in another directory, the current directory is still where the script was compiled from (not where the included file resides). If the compiler can't find the file it will look for it in every include directory. See !addincludedir for more information.

5.1.2 !addincludedir

directory

Adds another include directory to the include directories list. This list is searched when !include is used. This list's initial value is ${NSISDIR}\Include alone.

5.1.3 !addplugindir

directory

Causes the NSIS compiler to scan the given directory for Plugin DLLs.

5.1.4 !cd

new_path

This command will change the compiler to the new directory, new_path. new_path can be relative or absolute.

5.1.5 !echo

message

This command will echo a message to the user compiling the script.

5.1.6 !error

[message]

This command will issue an error to the script compiler and will stop execution of the script. You can also add a message to this error.

5.1.7 !packhdr

tempfile command

This option makes the compiler an external EXE packer (such as Petite or UPX) to compress the executable header. Specify a temporary file name (such as "temp.dat") and a command line (such as "C:\program files\upx\upx -9 temp.dat") to compress the header.

5.1.8 !system

command [compare comparevalue]

This command will execute 'command' using a call to system(), and if the return value compared (using 'compare') to 'comparevalue' is false, execution will halt. 'compare' can be '<' or '>' or '<>' or '='.

5.1.9 !warning

[message]

This command will issue a warning to the script compiler. You can also add a message to this warning.

5.1.10 !verbose

level | push | pop

This command will set the level of verbosity. 4=all, 3=no script, 2=no info, 1=no warnings, 0=none.

Passing push will cause !verbose to push the current verbosity level on a special stack. Passing pop will cause !verbose to pop the current verbosity level from the same stack and use it.


Predefines

5.2 Predefines

You can use these standard predefines to automatically add the build time to the title of development versions, add the date to the version number, etc.

5.2.1 ${__FILE__}

Current script name.

5.2.2 ${__LINE__}

Current line number.

5.2.3 ${__DATE__}

Date according to the current locale.

5.2.4 ${__TIME__}

Time according to the current locale.

5.2.5 ${__TIMESTAMP__}

Date & time according to the current locale.


Read enviroment variables

5.3 Read enviroment variables

5.3.1 $%envVarName%

$%envVarName% will be replaced on compile time by the enviroment variable envVarName.


Conditional Compilation

5.4 Conditional Compilation

The compiler maintains a list of defined symbols, which can be defined using !define or the /D command line switch. These defined symbols can be used for conditional compilation (using !ifdef) or for symbol replacement (a simple form of macros). To replace a symbol with its value, use ${SYMBOL} (if SYMBOL is not defined, no translation will occur). The translation is first-come-first-served, meaning if you do:

!define symbol1 ${symbol2}

If symbol2 is defined when that line occurs, it will be replaced. Otherwise, any replacing will occur when ${symbol1} is referenced.

Define/conditional compilation related commands:

5.4.1 !define

gflag [value]

This command will add 'gflag' to the global define list. This will have a similar effect as using the /D switch on the command line (only the define only becomes effective after the !define command).

5.4.2 !undef

gflag

Removes an item from the global define list. Note that ${SYMBOL} where SYMBOL is undefined will be translated to "${SYMBOL}".

5.4.3 !ifdef

gflag [bcheck [gflag [...]]]

This command, when paired with an !endif command, will tell the compiler whether or not to compile the lines in between the two lines. If gflag is globally defined (using !define or the /D switch), then the contained lines will be compiled. Otherwise, they will be skipped. 'bcheck' can be specified as & (boolean and) or | (boolean or) along with more gflags -- precedence is simple, left to right.

5.4.4 !ifndef

gflag [bcheck [gflag [...]]]

The opposite of !ifdef. The lines will be compiled when the gflag has not been defined.

5.4.5 !ifmacrodef

gflag [bcheck [gflag [...]]]

This command, when paired with an !endif command, will tell the compiler whether or not to compile the lines in between the two lines. If the macro gflag exists, then the contained lines will be compiled. Otherwise, they will be skipped. 'bcheck' can be specified as & (boolean and) or | (boolean or) along with more gflags -- precedence is simple, left to right.

5.4.6 !ifmacrondef

gflag [bcheck [gflag [...]]]

The opposite of !ifmacrodef. The lines will be compiled when the macro gflag does not exist.

5.4.7 !else

[ifdef|ifndef|ifmacrodef|ifmacrondef [...]]

This command allows to easily insert different code when different defines or macros are set. You can create blocks like !ifdef/!else/!endif, !ifdef/!else ifdef/!else/!endif etc.

5.4.8 !endif

This command closes a block started with !ifdef, !ifndef, !ifmacrodef or !ifmacrondef.

5.4.9 !insertmacro

macro_name [parameter] [...]

Inserts the contents of a macro that was created with !macro. If the macro was created with parameters, then you must pass as many parameters to the macro as it requires.

5.4.10 !macro

macro_name [parameter][...]

Creates a macro named 'macro_name'. All lines between the !macro and the !macroend will be saved. To insert the macro later on, use !insertmacro. !macro definitions can have one or more parameters defined. The parameters may be accessed the same way a !define would (e.g. ${PARMNAME}) from inside the macro.

5.4.11 !macroend

Ends a macro that was started with !macro.


Modern User Interface

Appendix A: Modern User Interface

NSIS 2 makes it is possible to create installers with a custom user interface. The Modern UI is an interface with a style like the wizards of recent Windows versions. This new interface also features new pages (Welcome, Finish, Start Menu) and a description area on the components page. The interface and the graphics can be customized using the provided settings. Using the Modern UI macros and language files, writing scripts with a modern interface is easy.

For more information and documentation see the Modern UI Readme.


Useful Functions

Appendix B: Useful Functions

  • Get parent directory
  • Trim newlines
  • Get command line parameters
  • Search in a string
  • Get Windows version
  • Get Internet Explorer version
  • Is .NET Framework installed?
  • Is Macromedia Flash Player installed?
  • Add a shared DLL
  • Remove a shared DLL
  • Upgrade a DLL (macro)
  • Connect to the internet
  • More


Get parent directory

B.1 Get parent directory

 ; GetParent
 ; input, top of stack  (e.g. C:\Program Files\Poop)
 ; output, top of stack (replaces, with e.g. C:\Program Files)
 ; modifies no other variables.
 ;
 ; Usage:
 ;   Push "C:\Program Files\Directory\Whatever"
 ;   Call GetParent
 ;   Pop $R0
 ;   ; at this point $R0 will equal "C:\Program Files\Directory"

 Function GetParent

   Exch $R0
   Push $R1
   Push $R2
   Push $R3

   StrCpy $R1 0
   StrLen $R2 $R0

   loop:
     IntOp $R1 $R1 + 1
     IntCmp $R1 $R2 get 0 get
     StrCpy $R3 $R0 1 -$R1
     StrCmp $R3 "\" get
     Goto loop

   get:
     StrCpy $R0 $R0 -$R1

     Pop $R3
     Pop $R2
     Pop $R1
     Exch $R0

 FunctionEnd


Trim newlines

B.2 Trim newlines

 ; TrimNewlines
 ; input, top of stack  (e.g. whatever$\r$\n)
 ; output, top of stack (replaces, with e.g. whatever)
 ; modifies no other variables.

 Function TrimNewlines
   Exch $R0
   Push $R1
   Push $R2
   StrCpy $R1 0

 loop:
   IntOp $R1 $R1 - 1
   StrCpy $R2 $R0 1 $R1
   StrCmp $R2 "$\r" loop
   StrCmp $R2 "$\n" loop
   IntOp $R1 $R1 + 1
   IntCmp $R1 0 no_trim_needed
   StrCpy $R0 $R0 $R1

 no_trim_needed:
   Pop $R2
   Pop $R1
   Exch $R0
 FunctionEnd


Get command line parameters

B.3 Get command line parameters

 ; GetParameters
 ; input, none
 ; output, top of stack (replaces, with e.g. whatever)
 ; modifies no other variables.

 Function GetParameters

   Push $R0
   Push $R1
   Push $R2
   Push $R3

   StrCpy $R2 1
   StrLen $R3 $CMDLINE

   ;Check for quote or space
   StrCpy $R0 $CMDLINE $R2
   StrCmp $R0 '"' 0 +3
     StrCpy $R1 '"'
     Goto loop
   StrCpy $R1 " "

   loop:
     IntOp $R2 $R2 + 1
     StrCpy $R0 $CMDLINE 1 $R2
     StrCmp $R0 $R1 get
     StrCmp $R2 $R3 get
     Goto loop

   get:
     IntOp $R2 $R2 + 1
     StrCpy $R0 $CMDLINE 1 $R2
     StrCmp $R0 " " get
     StrCpy $R0 $CMDLINE "" $R2

   Pop $R3
   Pop $R2
   Pop $R1
   Exch $R0

 FunctionEnd


Search in a string

B.4 Search in a string

 ; StrStr
 ; input, top of stack = string to search for
 ;        top of stack-1 = string to search in
 ; output, top of stack (replaces with the portion of the string remaining)
 ; modifies no other variables.
 ;
 ; Usage:
 ;   Push "this is a long ass string"
 ;   Push "ass"
 ;   Call StrStr
 ;   Pop $R0
 ;  ($R0 at this point is "ass string")

 Function StrStr
   Exch $R1 ; st=haystack,old$R1, $R1=needle
   Exch    ; st=old$R1,haystack
   Exch $R2 ; st=old$R1,old$R2, $R2=haystack
   Push $R3
   Push $R4
   Push $R5
   StrLen $R3 $R1
   StrCpy $R4 0
   ; $R1=needle
   ; $R2=haystack
   ; $R3=len(needle)
   ; $R4=cnt
   ; $R5=tmp
   loop:
     StrCpy $R5 $R2 $R3 $R4
     StrCmp $R5 $R1 done
     StrCmp $R5 "" done
     IntOp $R4 $R4 + 1
     Goto loop
 done:
   StrCpy $R1 $R2 "" $R4
   Pop $R5
   Pop $R4
   Pop $R3
   Pop $R2
   Exch $R1
 FunctionEnd


Get Windows version

B.5 Get Windows version

 ; GetWindowsVersion
 ;
 ; Based on Yazno's function, http://yazno.tripod.com/powerpimpit/
 ; Updated by Joost Verburg
 ;
 ; Returns on top of stack
 ;
 ; Windows Version (95, 98, ME, NT x.x, 2000, XP, 2003)
 ; or
 ; '' (Unknown Windows Version)
 ;
 ; Usage:
 ;   Call GetWindowsVersion
 ;   Pop $R0
 ;   ; at this point $R0 is "NT 4.0" or whatnot

 Function GetWindowsVersion

   Push $R0
   Push $R1

   ReadRegStr $R0 HKLM \
   "SOFTWARE\Microsoft\Windows NT\CurrentVersion" CurrentVersion

   IfErrors 0 lbl_winnt

   ; we are not NT
   ReadRegStr $R0 HKLM \
   "SOFTWARE\Microsoft\Windows\CurrentVersion" VersionNumber

   StrCpy $R1 $R0 1
   StrCmp $R1 '4' 0 lbl_error

   StrCpy $R1 $R0 3

   StrCmp $R1 '4.0' lbl_win32_95
   StrCmp $R1 '4.9' lbl_win32_ME lbl_win32_98

   lbl_win32_95:
     StrCpy $R0 '95'
   Goto lbl_done

   lbl_win32_98:
     StrCpy $R0 '98'
   Goto lbl_done

   lbl_win32_ME:
     StrCpy $R0 'ME'
   Goto lbl_done

   lbl_winnt:

   StrCpy $R1 $R0 1

   StrCmp $R1 '3' lbl_winnt_x
   StrCmp $R1 '4' lbl_winnt_x

   StrCpy $R1 $R0 3

   StrCmp $R1 '5.0' lbl_winnt_2000
   StrCmp $R1 '5.1' lbl_winnt_XP
   StrCmp $R1 '5.2' lbl_winnt_2003 lbl_error

   lbl_winnt_x:
     StrCpy $R0 "NT $R0" 6
   Goto lbl_done

   lbl_winnt_2000:
     Strcpy $R0 '2000'
   Goto lbl_done

   lbl_winnt_XP:
     Strcpy $R0 'XP'
   Goto lbl_done

   lbl_winnt_2003:
     Strcpy $R0 '2003'
   Goto lbl_done

   lbl_error:
     Strcpy $R0 ''
   lbl_done:

   Pop $R1
   Exch $R0

 FunctionEnd


Get Internet Explorer version

B.6 Get Internet Explorer version

 ; GetIEVersion
 ;
 ; Based on Yazno's function, http://yazno.tripod.com/powerpimpit/
 ; Returns on top of stack
 ; 1-6 (Installed IE Version)
 ; or
 ; '' (IE is not installed)
 ;
 ; Usage:
 ;   Call GetIEVersion
 ;   Pop $R0
 ;   ; at this point $R0 is "5" or whatnot

 Function GetIEVersion
 Push $R0
   ClearErrors
   ReadRegStr $R0 HKLM "Software\Microsoft\Internet Explorer" "Version"
   IfErrors lbl_123 lbl_456

   lbl_456: ; ie 4+
     Strcpy $R0 $R0 1
   Goto lbl_done

   lbl_123: ; older ie version
     ClearErrors
     ReadRegStr $R0 HKLM "Software\Microsoft\Internet Explorer" "IVer"
     IfErrors lbl_error

       StrCpy $R0 $R0 3
       StrCmp $R0 '100' lbl_ie1
       StrCmp $R0 '101' lbl_ie2
       StrCmp $R0 '102' lbl_ie2

       StrCpy $R0 '3' ; default to ie3 if not 100, 101, or 102.
       Goto lbl_done
         lbl_ie1:
           StrCpy $R0 '1'
         Goto lbl_done
         lbl_ie2:
           StrCpy $R0 '2'
         Goto lbl_done
     lbl_error:
       StrCpy $R0 ''
   lbl_done:
   Exch $R0
 FunctionEnd


Is .NET Framework installed?

B.7 Is .NET Framework installed?

 ; IsDotNETInstalled
 ;
 ; Usage:
 ;   Call IsDotNETInstalled
 ;   Pop $0
 ;   StrCmp $0 1 found.NETFramework no.NETFramework

 Function IsDotNETInstalled
   Push $0
   Push $1
   Push $2
   Push $3
   Push $4

   ReadRegStr $4 HKEY_LOCAL_MACHINE \
     "Software\Microsoft\.NETFramework" "InstallRoot"
   # remove trailing back slash
   Push $4
   Exch $EXEDIR
   Exch $EXEDIR
   Pop $4
   # if the root directory doesn't exist .NET is not installed
   IfFileExists $4 0 noDotNET

   StrCpy $0 0

   EnumStart:

     EnumRegKey $2 HKEY_LOCAL_MACHINE \
       "Software\Microsoft\.NETFramework\Policy"  $0
     IntOp $0 $0 + 1
     StrCmp $2 "" noDotNET

     StrCpy $1 0

     EnumPolicy:

       EnumRegValue $3 HKEY_LOCAL_MACHINE \
         "Software\Microsoft\.NETFramework\Policy\$2" $1
       IntOp $1 $1 + 1
        StrCmp $3 "" EnumStart
         IfFileExists "$4\$2.$3" foundDotNET EnumPolicy

   noDotNET:
     StrCpy $0 0
     Goto done

   foundDotNET:
     StrCpy $0 1

   done:
     Pop $4
     Pop $3
     Pop $2
     Pop $1
     Exch $0
 FunctionEnd


Is Macromedia Flash Player installed?

B.8 Is Macromedia Flash Player installed?

 ; IsFlashInstalled
 ;
 ; By Yazno, http://yazno.tripod.com/powerpimpit/
 ; Returns on top of stack
 ; 0 (Flash is not installed)
 ; or
 ; 1 (Flash is installed)
 ;
 ; Usage:
 ;   Call IsFlashInstalled
 ;   Pop $R0
 ;   ; $R0 at this point is "1" or "0"

 Function IsFlashInstalled
  Push $R0
  ClearErrors
  ReadRegStr $R0 HKCR "CLSID\{D27CDB6E-AE6D-11cf-96B8-444553540000}" ""
  IfErrors lbl_na
    StrCpy $R0 1
  Goto lbl_end
  lbl_na:
    StrCpy $R0 0
  lbl_end:
  Exch $R0
 FunctionEnd


Add a shared DLL

B.9 Add a shared DLL

 ; AddSharedDLL
 ;
 ; Increments a shared DLLs reference count.
 ; Use by passing one item on the stack (the full path of the DLL).
 ;
 ; Usage:
 ;   Push $SYSDIR\myDll.dll
 ;   Call AddSharedDLL
 ;

 Function AddSharedDLL
   Exch $R1
   Push $R0
   ReadRegDword $R0 HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1
   IntOp $R0 $R0 + 1
   WriteRegDWORD HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1 $R0
   Pop $R0
   Pop $R1
 FunctionEnd


Remove a shared DLL

B.10 Remove a shared DLL

 ; un.RemoveSharedDLL
 ;
 ; Decrements a shared DLLs reference count, and removes if necessary.
 ; Use by passing one item on the stack (the full path of the DLL).
 ; Note: for use in the main installer (not the uninstaller), rename the
 ; function to RemoveSharedDLL.
 ;
 ; Usage:
 ;   Push $SYSDIR\myDll.dll
 ;   Call un.RemoveSharedDLL
 ;

 Function un.RemoveSharedDLL
   Exch $R1
   Push $R0
   ReadRegDword $R0 HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1
   StrCmp $R0 "" remove
     IntOp $R0 $R0 - 1
     IntCmp $R0 0 rk rk uk
     rk:
       DeleteRegValue HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1
     goto Remove
     uk:
       WriteRegDWORD HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1 $R0
     Goto noremove
   remove:
     Delete /REBOOTOK $R1
   noremove:
   Pop $R0
   Pop $R1
 FunctionEnd


Upgrade a DLL (macro)

B.11 Upgrade a DLL (macro)

There is also a copy of this macro in the Include folder, so you only have to include UpgradeDLL.nsh to use it.

; Macro - Upgrade DLL File
; Written by Joost Verburg
; ------------------------
;
; Parameters:
; LOCALFILE   - Location of the new DLL file (on the compiler system)
; DESTFILE    - Location of the DLL file that should be upgraded (on the user's system)
; TEMPBASEDIR - Directory on the user's system to store a temporary file when the system has
;               to be rebooted.
;               For Win9x support, this should be on the same volume as the DESTFILE!
;               The Windows temp directory could be located on any volume, so you cannot use
;               this directory.
;
; Define UPGRADEDLL_NOREGISTER if you want to upgrade a DLL that does not have to be registered.
;
; Note: If you want to support Win9x, you can only use short filenames (8.3).
;
; Example of usage:
; !insertmacro UpgradeDLL "dllname.dll" "$SYSDIR\dllname.dll" "$SYSDIR"
;

!macro UpgradeDLL LOCALFILE DESTFILE TEMPBASEDIR

  Push $R0
  Push $R1
  Push $R2
  Push $R3
  Push $R4
  Push $R5

  ;------------------------
  ;Unique number for labels

  !define UPGRADEDLL_UNIQUE ${__LINE__}

  ;------------------------
  ;Copy the parameters used on run-time to a variable
  ;This allows the usage of variables as paramter

  StrCpy $R4 "${DESTFILE}"
  StrCpy $R5 "${TEMPBASEDIR}"

  ;------------------------
  ;Check file and version

  IfFileExists $R4 0 upgradedll.copy_${UPGRADEDLL_UNIQUE}

  ClearErrors
    GetDLLVersionLocal "${LOCALFILE}" $R0 $R1
    GetDLLVersion $R4 $R2 $R3
  IfErrors upgradedll.upgrade_${UPGRADEDLL_UNIQUE}

  IntCmpU $R0 $R2 0 upgradedll.done_${UPGRADEDLL_UNIQUE} upgradedll.upgrade_${UPGRADEDLL_UNIQUE}
  IntCmpU $R1 $R3 upgradedll.done_${UPGRADEDLL_UNIQUE} upgradedll.done_${UPGRADEDLL_UNIQUE} \
    upgradedll.upgrade_${UPGRADEDLL_UNIQUE}

  ;------------------------
  ;Let's upgrade the DLL!

  SetOverwrite try

  upgradedll.upgrade_${UPGRADEDLL_UNIQUE}:
    !ifndef UPGRADEDLL_NOREGISTER
      ;Unregister the DLL
      UnRegDLL $R4
    !endif

  ;------------------------
  ;Try to copy the DLL directly

  ClearErrors
    StrCpy $R0 $R4
    Call :upgradedll.file_${UPGRADEDLL_UNIQUE}
  IfErrors 0 upgradedll.noreboot_${UPGRADEDLL_UNIQUE}

  ;------------------------
  ;DLL is in use. Copy it to a temp file and Rename it on reboot.

  GetTempFileName $R0 $R5
    Call :upgradedll.file_${UPGRADEDLL_UNIQUE}
  Rename /REBOOTOK $R0 $R4

  ;------------------------
  ;Register the DLL on reboot

  !ifndef UPGRADEDLL_NOREGISTER
    WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\RunOnce" \
      "Register $R4" '"$SYSDIR\rundll32.exe" "$R4",DllRegisterServer'
  !endif

  Goto upgradedll.done_${UPGRADEDLL_UNIQUE}

  ;------------------------
  ;DLL does not exist - just extract

  upgradedll.copy_${UPGRADEDLL_UNIQUE}:
    StrCpy $R0 $R4
    Call :upgradedll.file_${UPGRADEDLL_UNIQUE}

  ;------------------------
  ;Register the DLL

  upgradedll.noreboot_${UPGRADEDLL_UNIQUE}:
    !ifndef UPGRADEDLL_NOREGISTER
      RegDLL $R4
    !endif

  ;------------------------
  ;Done

  upgradedll.done_${UPGRADEDLL_UNIQUE}:

  Pop $R5
  Pop $R4
  Pop $R3
  Pop $R2
  Pop $R1
  Pop $R0

  ;------------------------
  ;End

  Goto upgradedll.end_${UPGRADEDLL_UNIQUE}

  ;------------------------
  ;Called to extract the DLL

  upgradedll.file_${UPGRADEDLL_UNIQUE}:
    File /oname=$R0 "${LOCALFILE}"
    Return

  upgradedll.end_${UPGRADEDLL_UNIQUE}:

 ;------------------------
 ;Restore settings

 SetOverwrite lastused

 !undef UPGRADEDLL_UNIQUE

!macroend


Connect to the internet

B.12 Connect to the internet

 ; ConnectInternet (uses Dialer plugin)
 ; Written by Joost Verburg
 ;
 ; This function attempts to make a connection to the internet if there is no
 ; connection available. If you are not sure that a system using the installer
 ; has an active internet connection, call this function before downloading
 ; files with NSISdl.
 ;
 ; The function requires Internet Explorer 3, but asks to connect manually if
 ; IE3 is not installed.

 Function ConnectInternet

   Push $R0

     ClearErrors
     Dialer::AttemptConnect
     IfErrors noie3

     Pop $R0
     StrCmp $R0 "online" connected
       MessageBox MB_OK|MB_ICONSTOP "Cannot connect to the internet."
       Quit ;This will quit the installer. You might want to add your own error handling.

     noie3:

     ; IE3 not installed
     MessageBox MB_OK|MB_ICONINFORMATION "Please connect to the internet now."

     connected:

   Pop $R0

 FunctionEnd


More

B.13 More

You can find more useful functions at the NSIS Archive, the NSIS forum and NSIS development page.


Useful Information

Appendix C: Useful Information

  • Compiling NSIS Sources
  • Error Levels
  • Add uninstall information to Add/Remove Programs
  • How to install the VB6 runtimes
  • Calling an external DLL using the System.dll plugin
  • Dump Content of Log Window to File
  • How to Read REG_MULTI_SZ Values


Compiling NSIS Sources

C.1 Compiling NSIS Sources

The NSIS source files are shipped with every official NSIS distribution as well with the development snapshots. The binary files distributed with the NSIS releases are compiled with the Microsoft Visual C++ 6.0 compiler. The source has also been tested to be compatible with the Microsoft Visual C++ .NET 2002/2003 compiler. The NSIS distribution includes Microsoft Visual C++ 6.0 project files, Microsoft Visual C++ .NET 2002/2003 automatically convert these files to a new format.

If you don't have Microsoft Visual C++, you can download the free .NET Framework SDK (requires Windows 2000/XP/Server 2003), which includes the latest Microsoft compiler. This SDK does not include the Win32 API headers/libraries, so you should also download the latest Platform SDK. See the Microsoft documentation for information about using the command line compiler and linker tools.

Previous versions of NSIS have been reported to work with the MinGW compiler, however we don't have an up-to-date makefile. If you are working with MinGW or another compiler like Borland C++ Builder or Open Watcom C/C++ and want to provide makefiles or project files please drop a line on the NSIS Forum.

Important notes for Microsoft Visual C++ 6.0 users: You should install the latest Platform SDK. Because of flaws in the libraries distributed with Microsoft Visual C++ 6.0, not installing the Platform SDK will result in crashes when using the CopyFiles command, see this forum topic for more information. Installing the Processor Pack is also highly recommended to decrease the size of the installer overhead.


Error Levels

C.2 Error Levels

Like other applications installers made by NSIS return error levels as a result of their execution. Checking the error level can be useful if you call an NSIS installer from another application or installer.

Normal installers:

  • 0 - Normal execution (no error)
  • 1 - Installation aborted by user
  • 2 - Installation aborted by script

Silent installers:

  • 0 - Normal execution (no error)
  • 1 - Installation aborted by user
  • 1 - Installation aborted by script


Add uninstall information to Add/Remove Programs

C.3 Add uninstall information to Add/Remove Programs

Create a key with your product name under HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall to add entries to the "Add/Remove Programs" section in the Control Panel. For Windows NT (NT4/2000/XP), it's also possible to create the key in the HKCU hive, so it will only appear for the current user. There are several values you can write to key to give information about your application and the uninstaller. Write a value using the WriteRegStr command (for strings) or WriteRegDWORD command (for DWORD values). Example:

WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Product" "DisplayName" "Application Name"

Required values

DisplayName (string) - Name of the application
UninstallString (string) - Path and filename of the uninstaller. You should always quote the path to make sure spaces in the path will not disrupt Windows to find the uninstaller.

Optional values

Some of the following values will not be used by older Windows versions.

InstallLocation (string) - Installation directory ($INSTDIR)
DisplayIcon (string) - Path, filename and index of the icon that will be displayed next to your application name

Publisher (string) - (Company) name of the publisher

ModifyPath (string) - Path and filename of the application modify program
InstallSource (string) - Location where the application was installed from

ProductID (string) - Product ID of the application
RegOwner (string) - Registered owner of the application
RegCompany (string) - Registered company of the application

HelpLink (string) - Link to the support website
HelpTelephone (string) - Telephone number for support

URLUpdateInfo (string) - Link to the website for application updates
URLInfoAbout (string) - Link to the application home page

DisplayVersion (string) - Displayed version of the application
VersionMajor (DWORD) - Major version number of the application
VersionMinor (DWORD) - Minor version number of the application

NoModify (DWORD) - 1 if uninstaller has no option to modify the installed application
NoRepair (DWORD) - 1 if the uninstaller has no option to repair the installation

If both NoModify and NoRepair are set to 1, the button displays "Remove" instead of "Modify/Remove".


How to install the VB6 runtimes

C.4 How to install the VB6 runtimes

The best way to install the VB6 runtimes is to use the UpgradeDLL macro to upgrade the DLL files and the AddSharedDLL function to increment the shared DLL count.

Use the Modern UI with a Finish page to ask for a reboot if required or use IfRebootFlag and make your own page or messagebox.

To get the VB6 runtime files, you can extract the files from vbrun60sp5.exe using any archiver that supports CAB compression or, if you have installed the latest version, copy the the files from the System folder. You need the following files:

Asycfilt.dll
Comcat.dll
Msvbvm60.dll
Oleaut32.dll
Olepro32.dll
Stdole2.tlb

During the uninstallation, use the un.DecrementSharedDLL function below to decrement the shared DLL count (never remove the files, because the shared DLL count is not reliable enough for such imporant files).

!include "UpgradeDLL.nsh"

!define VBFILESDIR "C:\Windows\System" ;Location of VB6 runtime files

Section "Install VB DLLs"

  !insertmacro UpgradeDLL ${VBFILESDIR}\Comcat.dll $SYSDIR\Comcat.dll $SYSDIR
  !insertmacro UpgradeDLL ${VBFILESDIR}\Msvbvm60.dll $SYSDIR\Msvbvm60.dll $SYSDIR
  !insertmacro UpgradeDLL ${VBFILESDIR}\Oleaut32.dll $SYSDIR\Oleaut32.dll $SYSDIR
  !insertmacro UpgradeDLL ${VBFILESDIR}\Olepro32.dll $SYSDIR\Olepro32.dll $SYSDIR

  !define UPGRADEDLL_NOREGISTER
    !insertmacro UpgradeDLL ${VBFILESDIR}\Asycfilt.dll $SYSDIR\Asycfilt.dll $SYSDIR
    !insertmacro UpgradeDLL ${VBFILESDIR}\Stdole2.tlb $SYSDIR\Stdole2.tlb $SYSDIR
  !undef UPGRADEDLL_NOREGISTER

  ;Only iease DLL count on new installation
  ;Replace myprog.exe or use another detection method
  IfFileExists $INSTDIR\myprog.exe skipAddSharedDLL
    Push $SYSDIR\Asycfilt.dll
    Call AddSharedDLL
    Push $SYSDIR\Comcat.dll
    Call AddSharedDLL
    Push $SYSDIR\Msvbvm60.dll
    Call AddSharedDLL
    Push $SYSDIR\Oleaut32.dll
    Call AddSharedDLL
    Push $SYSDIR\Olepro32.dll
    Call AddSharedDLL
    Push $SYSDIR\Stdole2.tlb
    Call AddSharedDLL
  skipAddSharedDLL:

SectionEnd

Section "Uninstall"

  Push $SYSDIR\Asycfilt.dll
  Call un.DecrementSharedDLL
  Push $SYSDIR\Comcat.dll
  Call un.DecrementSharedDLL
  Push $SYSDIR\Msvbvm60.dll
  Call un.DecrementSharedDLL
  Push $SYSDIR\Oleaut32.dll
  Call un.DecrementSharedDLL
  Push $SYSDIR\Olepro32.dll
  Call un.DecrementSharedDLL
  Push $SYSDIR\Stdole2.tlb
  Call un.DecrementSharedDLL

SectionEnd

Function AddSharedDLL
  Exch $R1
  Push $R0
    ReadRegDword $R0 HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1
    IntOp $R0 $R0 + 1
    WriteRegDWORD HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1 $R0
   Pop $R0
   Pop $R1
 FunctionEnd

Function un.DecrementSharedDLL
  Exch $R1
  Push $R0
  ReadRegDword $R0 HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1
  StrCmp $R0 "" done
    IntOp $R0 $R0 - 1
    IntCmp $R0 0 rk rk uk
    rk:
      DeleteRegValue HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1
      Goto done
    uk:
      WriteRegDWORD HKLM Software\Microsoft\Windows\CurrentVersion\SharedDLLs $R1 $R0
  done:
  Pop $R0
  Pop $R1
FunctionEnd


Calling an external DLL using the System.dll plugin

C.5 Calling an external DLL using the System.dll plugin

Some install processes are required to call functions contained inside third party DLLs. A prime example of this is when installing a Palm(TM) conduit.

Some background about System.dll
The System.dll plug-in (by Brainsucker) enables calling of external DLLs by providing the 'Call' function. There are a number of other functions provided by System.dll, but they will not be covered here. For more details about the other functions, lock the doors, take the phone off the hook, screw your head on *real* tight and head on over to the Contrib/System directory and read the doco there.

Data Types
System.dll recognises the following data types:

  • v - void (generally for return)
  • i - int (includes char, byte, short, handles, pointers and so on)
  • l - long & large integer (know as int64)
  • t - text, string (LPCSTR, pointer to first character)
  • b - boolean (needs/returns 'true':'false') - by the fact this type is senseless -> usual integer can be used ('0':'1')
  • k - callback. See Callback section in system.txt.
  • * - pointer specifier -> the proc needs the pointer to type, affects next char (parameter) [ex: '*i' - pointer to int]

Mapping System.dll variables to NSIS script variables
There's not much point in being able to call an external function if you can't get any data back. System.dll maps function variables to NSIS script variables in the following way:

NSIS $0..$9 become System.dll r0..r9 NSIS $R0..$R9 become System.dll r10..r19

Each parameter is specified by type, input and output. To skip input or output use a dot. Examples:

String (pointer to a characters array), input is 'happy calling':

t 'happy calling'

String (pointer to a characters array), input is taken from $5 and changes to the array made by the call are saved into $R8:

t r5R8

Pointer to an integer, value taken from $1 and put into $2:

*i r1r2

Pointer to a 64-bit integer, output pushed on stack, no input:

*l .s

Using System.dll::Call To call a function in a third party DLL, the Call function is used like this:

System::Call 'YourDllName::YourDllFunction(i, *i, t) i(r0, .r1, r2) .r3'

The '(r0, .r1, r2) .r3' section at the end are the parameters that are passed between your DLL and your NSIS script. As can be seen in this parameters list type and input/output can be seperated. Each block of "(parms list) return value" overrides and/or adds to the last one. In this case, the first block specifies the types and the second specifies input and output.

Before starting to code the NSIS script
Before you start to code any NSIS code, you need to know the full prototype of the function you are going to call. For the purposes of this example, we will use the 'CmGetHotSyncExecPath' function from the Palm 'CondMgr.dll'. This function is used to return the full path of 'HotSync.exe'.

Function Definition

int CmGetHotSyncExecPath(TCHAR *pPath, int *piSize);

where

  • pPath is a pointer to a character buffer. Upon return, this is the path & file name of the installed HotSync manager.
  • piSize is a pointer to an integer that specifies the size (in TCHAR's), of the buffer referenced by the pPath parameter.

return values:

  • 0: No error
  • -1: A non-specific error occurred
  • ERR_REGISTRY_ACCESS(-1006):Unable to access the Palm configuration entries
  • ERR_BUFFER_TOO_SMALL(-1010): The buffer is too small to hold the requested information
  • ERR_INVALID_POINTER(-1013):The specified pointer is not a valid pointer

Also, if the buffer is too small the value in *int is the size (in TCHARs) that the buffer should be.

This function definition maps to the following System.dll definition:

CmGetHotSyncExecPath(t, *i) i

i.e. It takes a text variable, a pointer to int, and returns an int value.

Using the external dll function
Now that we've sorted out what the function does, and how it maps to the System.dll format, we can use the function in a NSIS script.

First, it is recommended to turn 'PluginUnload' off before making multiple calls to System.dll. According to Brainsucker (and others), this will speed up execution of the installer package.

Second, you have to change the output directory to that where the DLL you want to use is. It may also work if the DLL is on the system path, but this hasn't been tested.

The following code fragment will install 'condmgr.dll' to a temporary directory, execute the CmGetHotSyncExecPath function, display returned data and finally unload the System.dll plug-in. Save this script

; **** snip ****
SetPluginUnload  alwaysoff

Function loadDll

  SetOutPath $TEMP\eInspect             ; create temp directory
  File bin\CondMgr.dll                  ; copy dll there
  StrCpy $1 ${NSIS_MAX_STRLEN}          ; assign memory to $0
  System::Call 'CondMgr::CmGetHotSyncExecPath(t, *i) i(.r0, r1r1).r2'
  DetailPrint 'Path: "$0"'
  DetailPrint "Path length: $1"
  DetailPrint "Return value: $2"

; last plugin call must not have /NOUNLOAD so NSIS will be able to delete
; the temporary DLL

  SetPluginUnload manual
; do nothing (but let the installer unload the System dll)
  System::Free 0
FunctionEnd
; **** snip ****

and this function produces the following output in the 'details' page:

Output folder: c:\windows\TEMP\eInspect
Extract: CondMgr.dll
Path: "C:\Dave\palm\Hotsync.exe"
Path length: 24
Return value: 0

Written by djc

Acknowledgements & Thanks
Lots of thanks go to kichik and Sunjammer for spending a lot of time assisting in solving this problem. Also to brainsucker for creating the System.dll plug-in in the first place. Good Luck!


Dump Content of Log Window to File

C.6 Dump Content of Log Window to File

This function will dump the log of the installer (installer details) to a file of your choice. I created this function for Afrow_UK who requested a way to dump the log to a file in this forum thread.

To use it push a file name and call it. It will dump the log to the file specified. For example:

GetTempFileName $0
Push $0
Call DumpLog

Here is the function:

!define LVM_GETITEMCOUNT 0x1004
!define LVM_GETITEMTEXT 0x102D

Function DumpLog
  Exch $5
  Push $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $6

  FindWindow $0 "#32770" "" $HWNDPARENT
  GetDlgItem $0 $0 1016
  StrCmp $0 0 error
  FileOpen $5 $5 "w"
  StrCmp $5 0 error
    SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
    System::Alloc ${NSIS_MAX_STRLEN}
    Pop $3
    StrCpy $2 0
    System::Call "*(i, i, i, i, i, i, i, i, i) i \
      (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
    loop: StrCmp $2 $6 done
      System::Call "User32::SendMessageA(i, i, i, i) i \
        ($0, ${LVM_GETITEMTEXT}, $2, r1)"
      System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
      FileWrite $5 "$4$\r$\n"
      IntOp $2 $2 + 1
      Goto loop
    done:
      FileClose $5
      System::Free $1
      System::Free $3
      Goto exit
  error:
    MessageBox MB_OK error
  exit:
    Pop $6
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
    Exch $5
FunctionEnd

written by KiCHiK


How to Read REG_MULTI_SZ Values

C.7 How to Read REG_MULTI_SZ Values

I wrote this script to help rpetges in this forum thread. It reads a registry value of the type REG_MULTI_SZ and prints it out. Don't forget to edit where it says "Edit this!" when you test this script. The values must point to a REG_MULTI_SZ value or the example will spit out an error.

OutFile "REG_MULTI_SZ Reader.exe"

Name "REG_MULTI_SZ Reader"

ShowInstDetails show

!define HKEY_CLASSES_ROOT        0x80000000
!define HKEY_CURRENT_USER        0x80000001
!define HKEY_LOCAL_MACHINE       0x80000002
!define HKEY_USERS               0x80000003
!define HKEY_PERFORMANCE_DATA    0x80000004
!define HKEY_PERFORMANCE_TEXT    0x80000050
!define HKEY_PERFORMANCE_NLSTEXT 0x80000060
!define HKEY_CURRENT_CONFIG      0x80000005
!define HKEY_DYN_DATA            0x80000006

!define KEY_QUERY_VALUE          0x0001
!define KEY_ENUMERATE_SUB_KEYS   0x0008

!define REG_NONE                 0
!define REG_SZ                   1
!define REG_EXPAND_SZ            2
!define REG_BINARY               3
!define REG_DWORD                4
!define REG_DWORD_LITTLE_ENDIAN  4
!define REG_DWORD_BIG_ENDIAN     5
!define REG_LINK                 6
!define REG_MULTI_SZ             7

!define RegOpenKeyEx     "Advapi32::RegOpenKeyExA(i, t, i, i, i) i"
!define RegQueryValueEx  "Advapi32::RegQueryValueExA(i, t, i, i, i, i, i) i"
!define RegCloseKey      "Advapi32::RegCloseKeyA(i) i"

####### Edit this!

!define ROOT_KEY         ${HKEY_CURRENT_USER}
!define SUB_KEY          "Software\Joe Software"
!define VALUE            "Strings"

####### Stop editing

Section "Read"
  StrCpy $0 ""
  StrCpy $1 ""
  StrCpy $2 ""
  StrCpy $3 ""
  SetPluginUnload alwaysoff
  System::Call "*(i) i (0) .r0"
  System::Call "*(i) i (0) .r1"
  System::Call "*(i) i (0) .r2"
  System::Call "${RegOpenKeyEx}(${ROOT_KEY}, '${SUB_KEY}', \
    0, ${KEY_QUERY_VALUE}|${KEY_ENUMERATE_SUB_KEYS}, r0) .r3"

  StrCmp $3 0 goon
    MessageBox MB_OK|MB_ICONSTOP "Can't open registry key! ($3)"
    Goto done
goon:

  System::Call "*$0(&i4 .r4)"
  System::Call "${RegQueryValueEx}(r4, '${VALUE}', 0, r1, 0, r2) .r3"

  StrCmp $3 0 read
    MessageBox MB_OK|MB_ICONSTOP "Can't query registry value! ($3)"
    Goto done

read:

  System::Call "*$1(&i4 .r3)"

  StrCmp $3 ${REG_MULTI_SZ} multisz
    MessageBox MB_OK|MB_ICONSTOP "Registry value no SZ_MULTI_SZ! ($3)"
    Goto done

multisz:

  System::Call "*$2(&i4 .r3)"

  StrCmp $3 0 0 multiszalloc
    MessageBox MB_OK|MB_ICONSTOP "Registry value empty! ($3)"
    Goto done

multiszalloc:

  System::Free $1
  System::Alloc $3
  Pop $1

  StrCmp $1 0 0 multiszget
    MessageBox MB_OK|MB_ICONSTOP "Can't allocate enough memory! ($3)"
    Goto done

multiszget:

  System::Call "${RegQueryValueEx}(r4, 'bla', 0, 0, r1, r2) .r3"

  StrCmp $3 0 multiszprocess
    MessageBox MB_OK|MB_ICONSTOP "Can't query registry value! ($3)[2]"
    Goto done

multiszprocess:

  StrCpy $4 $1

  loop:

    System::Call "*$4(&t${NSIS_MAX_STRLEN} .r3)"
    StrCmp $3 "" done
    DetailPrint $3
    StrLen $5 $3
    IntOp $4 $4 + $5
    IntOp $4 $4 + 1
    Goto loop

done:

  System::Free $2
  System::Free $1

  StrCmp $0 0 noClose
    System::Call "${RegCloseKey}(r0)"

noClose:

  SetPluginUnload manual
  System::Free $0
SectionEnd

written by KiCHiK


Changelog and Release Notes

Appendix D: Changelog and Release Notes

  • 2.0
    • Release Notes
    • Changelog
  • 2.0 Release Candidate 4
    • Changelog
  • 2.0 Release Candidate 3
    • Changelog
  • 2.0 Release Candidate 2
    • Changelog
  • 2.0 Release Candidate 1
    • Release Notes
    • Changelog
  • 2.0 Beta 4
    • Release Notes
    • Changelog
  • 2.0 Beta 3
  • 2.0 Beta 2
  • 2.0 Beta 1
  • 2.0 Beta 0
  • 2.0 Alpha 7
  • 2.0 Alpha 6
  • 2.0 Alpha 5
  • 2.0 Alpha 4
  • 2.0 Alpha 3
  • 2.0 Alpha 2
  • 2.0 Alpha 1
  • 2.0 Alpha 0
  • Older Versions


2.0

D.1 2.0

Released on February 7th, 2004

D.1.1 Release Notes

  • Finnish, Bulgarian and Thai language files are outdated and do not contain all needed translations

D.1.2 Changelog

D.1.2.1 Changes from 1.98

  • Multiple languages in one installer support (with RTL support)
  • Easier plug-in system
  • Modern User Interface (optional)
  • LZMA compression which provides installers 20% smaller than bzip2
  • Easier paging system (no more .onNextPage, .onPrevPage)
  • Components are presented as a tree which allows sub components
  • User variables ($VARNAME)
  • Icon and UninstallIcon support any color depth and sizes, not just 32x32x16
  • CheckBitmap supports any color depth
  • Improved large files handling
  • License data can be RTF
  • CHM documentation for easy browsing
  • Better silent support
  • New include files for easier scripting: LogicLib, StrFunc and Sections
  • Improved plug-ins: InstallOptions, NSISdl and Splash
  • New plug-ins: AdvSplash, Banner, BgImage, Dialer, LangDLL, Math, nsExec, StartMenu, System, UserInfo and VPatch
  • New and improved utilities: MakeNSISw, NSIS Menu (NSIS.exe), NSIS Update (Bin\NSIS Update.exe) and zip2exe (Bin\zip2exe.exe)
  • New commands: !AddPluginDir, !echo, !ifmacrodef, !ifmacrondef, !verbose, AddBrandingImage, AllowSkipFiles, ChangeUI, CheckBitmap, CreateFont, DirVar, DirVerify, EnableWindow, FileBufSize, FlushINI, GetCurInstType, GetDlgItem, GetInstDirError, IfAbort, IfSilent, InitPluginsDir, InstTypeGetText, InstTypeSetText, LangString, LicenseBkColor, LicenseForceSelection, LicenseLangString, LoadLanguageFile, LockWindow, Page, PageEx, ReserveFile, SectionGetInstTypes, SectionGetSize, SectionSetInstTypes, SectionSetSize, SetBrandingImage, SetCompressionLevel, SetCompressor, SetCompressorDictSize, SetCtlColors, SetCurInstType, SetPluginUnload, SetSilent, ShowWindow, SubSection, SubSectionEnd, Var, VIAddVersionKey, VIProductVersion and XPStyle
  • Removed commands: DisabledBitmap, EnabledBitmap and SectionDivider
  • All this and a smaller overhead! =)
  • A lot more... See below for more information

D.1.2.2 Changes from RC4

  • Command line parser ignored any switches after tokens that are not switches
  • Last part of the path specified in InstallDir was appended even if selected folder name was the same
  • Modern UI 1.70: Improved documentation, new Init custom function for Welcome and Finish page
  • Added StrFunc by deguix
  • Updated and fixed language files
  • Updated, fixed and improved documentation


2.0 Release Candidate 4

D.2 2.0 Release Candidate 4

Released on February 2nd, 2004

D.2.1 Changelog

D.2.1.1 Major Changes

  • Fixed MBCS mishandling in exehead, InstallOptions and nsExec

D.2.1.2 Minor Changes

  • Language files updates and fixes
  • Fixed logging (NSIS_CONFIG_LOG)
  • Fixed compile errors caused by removing some config.h options
  • NSIS compiles without PSDK again
  • Documentation fixes

D.2.1.3 Utilities and Plug-ins

  • NSISdl: All potential and rare crashes should be completely fixed now
  • InstallOptions: Fixed a rare crash related to ListItems and a small memory leak when using ValidateText


2.0 Release Candidate 3

D.3 2.0 Release Candidate 3

Released on January 26th, 2004

D.3.1 Changelog

D.3.1.1 Minor Changes

  • Fixed some bugs with LZMA/bzip2 and non-solid compression
  • Fixed a bug that caused escaping not to be ignored on extended !define lines
  • Language files updates and fixes
  • Fixed installer crash when certain language strings were not referenced in all languages
  • Some new and improved graphics
  • Made CreateShortcut case insensitive when parsing hot key
  • Some documentation improvements and fix-ups
  • Modern UI 1.69: Made all uninstaller pages work without installer pages and fixed top text on uninstaller license page

D.3.1.2 Utilities and Plug-ins

  • MakeNSISW: Fixed resize bug, fixed some UI issues in the settings dialog
  • NSIS Update: Improved UI
  • InstallOptions: Fixed minor problems with the new NOTIFY flag


2.0 Release Candidate 2

D.4 2.0 Release Candidate 2

Released on January 5th, 2004

D.4.1 Changelog

D.4.1.1 Minor Changes

  • Set focus to the main control in each page to ease keyboard control (plug-ins too)
  • LangStrings and user variables limit is now 16383 and is enforced
  • Fixed control colors set using SetCtlColors not changing when the system colors were changed
  • Log window now responds to the context menu key
  • Fixed a bug which caused beeping when the space key is hit on the components tree
  • Added code to prevent weird usage of WM_COMMAND which can cause weird behavior
  • Fixed compile errors when NSIS_CONFIG_COMPONENTPAGE, NSIS_CONFIG_PLUGIN_SUPPORT or NSIS_SUPPORT_HWNDS are not defined
  • More language files updated to the latest version
  • Fixed CHM's script errors
  • Documentation improvements

D.4.1.2 Utilities and Plug-ins

  • InstallOptions 2.4: NOTIFY for link, drop list and list box; UI fixes and improvements. See IO's change log for a complete list
  • MakeNSISW: Improved user interface, added support for named symbol sets and fixed best compressor selector


2.0 Release Candidate 1

D.5 2.0 Release Candidate 1

Released on Decemeber 27th, 2003

D.5.1 Release Notes

  • Trying the LZMA compression method for your installer is recommended. It often gives a 20% better compression ratio.
  • Modern UI 1.68: The setting to change the title size on the Welcome page and Finish page has been changed

D.5.2 Changelog

D.5.2.1 Major Changes

  • LZMA compression support. Added SetCompresssorDictSize.
  • Modern UI 1.68: New settings for extra space for title and text on Welcome page and Finish page, improved handling of verbose settings, language file string for uninstaller reboot information, more
  • Shell folders are now detected using shell API functions and not the registry. This is the recommended method by Microsoft. New constants have been added in the process ($FONTS, $SENDTO and more...). See section 4.2.3 for more details.
  • Added LogicLib to distribution (easier conditional execution etc.)
  • Added DirVerify and GetInstDirError to allow custom error checking when the installation directory is invalid or the drive does not have enough space
  • Support for reading environmental variables on compile time: $%envVarName%
  • Added /SD parameter for MessageBox. Allows to set default for silent installers.
  • New conditional compilation options: !ifmacrodef and !ifmacrondef.
  • New sections macros for mutually exclusive section selection
  • Improved RTL support by adding WS_EX_RTLREADING wherever possible

D.5.2.2 Utilities and Plug-ins

  • InstallOptions 2.3: Added new control type "Button", added new flag "NOTIFY", added new flag "NOWORDWRAP" for multi-line text boxes, reduced size down to 12K
  • MakeNSISW: More options to set the compression method
  • Zip2Exe 0.31: Fixed compression setting, LZMA compression support
  • VPatch 2.1: Better error handling and exit code for GenPat


2.0 Beta 4

D.6 2.0 Beta 4

Released on November 19th, 2003

D.6.1 Release Notes

  • The /LANG parameter is no longer available for any text setting instructions. You must use a LangString if you want to make a certain text multilingual. This means you can also set one text for all languages. To make the license data multilingual you should use LicenseLangString.
  • Modern UI 1.67: Because of the new syntax for pages, renaming of settings and variable names etc., you have to make some changes to your scripts, see the Modern UI Readme for details.
  • Custom Pages now have a leave function. As this parameter is placed before the caption you have to add another "" empty string for the title to work.
  • .onSelChange is no longer called when the components page is created.
  • The icons folder has been renamed to Graphics and was reorganized. If you were using any files from Contrib\Icons in your script, you should update it to point to the new image or icon path.
  • UpgradeDLL has been changed, it's highly recommend that you include the new version in your script using !include "UpgradeDLL.nsh" instead of the old one.

D.6.2 Changelog

D.6.2.1 Major Changes

  • CHM documentation - searchable and comes with an index
  • User variables ($VARNAME) that can be declared with the Var command
  • Support for all pages in both installer and uninstaller. Components, directory and license pages can be used for the uninstaller
  • Improved large files handling (way lower requirements to compile a 2GB installer now)
  • Added IfSilent and SetSilent to allow better /S interaction
  • Full support for RTL languages, including support for LTR and RTL languages in one installer
  • Modern UI 1.67: New system & syntax for pages, settings (support for multiple pages of the same type, page specific settings, more customization options etc.), Welcome/Finish pages for uninstaller, LicenseForceSelection support, new options for Finish page / language selection dialog, fixes, more
  • Extraction progress
  • Better installation directory verification
  • Fixed all known problems with temporary files and directoroes
  • No more unprocessed strings, variables can be used everywhere
  • Leave function for custom pages: Input on InstallOptions pages can be validated using script code
  • Better ClearType support
  • No more flickering
  • OnMouseOver text is only displayed when mouse over section
  • RO sections can now be in InstTypes too (defaults to old behavior)
  • Improved AddBrandingImage: doesn't depend on the UI, can set image on the bottom and on the right, support for custom padding value
  • Increased limit of InstTypes to 32
  • Improved macros & functions: UpgradeDLL, GetParent, GetParameters. Using the new versions is recommended.
  • NLF language files (v6): language specific fonts, RTL and more strings
  • Inner LangStrings can be used in the script
  • No more /LANG, only LangStrings - easier to set one string to all languages
  • LangStrings are no longer installer/uninstaller specific (no un.)
  • Fixed SetOutPath not setting current directory if the directory didn't exist before
  • Components tree: fixed problems with sub-sections with RO sections as children, SF_EXPAND now refreshes the components tree and added SF_PSELECTED for partially selected sub-sections
  • Documentation fixes
  • Minor bug fixes
  • Code clean-ups and some more comments
  • More...

D.6.2.2 New/Changed Commands

  • Added PageEx, PageCallbacks and DirVar - it's now a lot easier to add the same page type twice
  • Added FileBufSize
  • Added VIAddVersionKey: add version information resource to the installer
  • Added AllowSkipFiles: set whether the user should be able to skip a file when overwriting failed
  • Added LicenseForceSelection: checkbox or radio buttons on license page to let user agree with license or not
  • Added SectionSetSize, SectionGetSize, SetCurInstType and GetCurInstType
  • Replaced SetBkColor with SetCtlColors which can set text color too
  • Added support for standard predefines: ${__DATE__}, ${__TIME__}, ${__TIMESTAMP__}, ${__FILE__}, ${__LINE__}
  • Added ifdiff and lastusd for SetOverwrite
  • /o Switch for Section provides ability to unselect the section by default
  • New parameter for DirText to set the browse dialog text
  • Added RMDir /REBOOTOK: remove folders on reboot
  • InstType /NOCUSTOM and /COMPONENTSONLYONCUSTOM work together
  • Added base_dir for GetTempFileName

D.6.2.3 Utilities and Plug-ins

  • MakeNSISW 2.0: UI to define symbols, easy access to recent scripts, toolbar and more
  • Zip2Exe 0.3: based on header files, improved interface, Modern UI support, new script code, improved folder detection
  • InstallOptions 2.2: added LINK control, added EXTENDEDSELECT flag for list boxes which replaces MULTISELECT that now acts exactly as the real style flag ([double] click turns on or off selection), fixes
  • BgImage plug-in stability fixes
  • Added vPatch: patch generator and plug-in that applies the patches
  • Banner plug-in improvements: responds to messages and some new /set tricks by brainsucker
  • AdvSpalsh plug-in improvements: smaller, better transparency support and a possible bug fix
  • System plug-in improvements: Unicode, GUID and COM support
  • nsExec plug-in improvments: ability to run 16 bit code and tabs to spaces conversion
  • Math plug-in
  • Delphi unit for NSIS plug-ins


2.0 Beta 3

D.7 2.0 Beta 3

Released on March 16th, 2003

  • Modern UI 1.63: Header bitmap support, new defines to change the description area, single macro for language selection dialog, more!
  • New tutorial in the documentation
  • define_if_last in Page command also works when a define has not been specified for all Page commands.
    This fixes the problem with the Modern UI "Click Next" / "Click Install" texts.
  • Added SectionSetInstTypes and SectionGetInstTypes
  • Reboot command does not force a reboot anymore (allows the user to save work)
  • !if[n]def/!else fixes
  • LogSet on now really starts logging
  • Cancel button available on all pages after the instfiles page but the last page unless /ENABLECANCEL was used in its Page command
  • License page: No more limit on RTF size
  • LangDLL: Option to auto-count number of languages, shell font support
  • Page and UninstPage can not be used inside sections/functions
  • CreateDirectory now uses the error flag
  • EnumRegKey/Value output_var check fixed
  • Updated translations
  • Dreaded BSOD after plug-ins enumeration finally banished
  • Minimize button and BGGradient and BGImage compatibility fixes
  • WriteINIStr with empty value works again
  • Added FlushINI


2.0 Beta 2

D.8 2.0 Beta 2

Released on February 26th, 2003

  • NSIS Menu: links to all NSIS utilities, documentation and websites
  • NSIS Update: check for new releases, download latest development files
  • Dialer plugin to connect to the internet
  • Improved filename validation
  • VC7 compiler compatibility issues fixed
  • CreateDirectory sets error flag
  • InstallOptions: INI File State value fixed
  • Updated translations
  • Minor fixes


2.0 Beta 1

D.9 2.0 Beta 1

Released on February 9th, 2003

  • User interface improvements: better order/grouping of controls, button selection problems fixed, added minimize box, transparent BrandingText
  • LangString improvements: can be used before they have been defined, warning if not present in all language tables
  • New version of the Modern User Interface with UI improvements, bugfixes and some small new features
  • InstallOptions 2.0 with support for custom font and DPI settings, groupboxes, grouped controls, lots of bugfixes etc.
  • No more random compression ratios
  • SetOutPath now sets the working directory
  • File names are validated, directory given by the user will now always work
  • $QUICKLAUNCH now works with SetShellVarContext all
  • Automatically appended directory name in the directory selection dialog will no longer contain squares if not all characters are ASCII.
  • Fixed a bug with remote drives and available space (\\remote\drive)
  • Plug-in function's names are now case insensitive
  • Fixed a bug with specifying Icon twice
  • Include dirs (!addincludedir)
  • On leave function for pages
  • Installers can now really contain more than one branding image
  • All !if/!else/!endif problems should be solved now
  • SetFont "MS Shell Dlg" adds the DS_SHELLFONT style
  • Win9x rename on reboot now also works when the destination file does not exist
  • DeleteRegKey works on default value
  • nsExec can be called from an installer executed by CreateProcess
  • WriteUninstaller sets error code
  • Banner.dll compatible with Modern UI
  • Fixed focus problems in MakeNSISw
  • Updated and new translations
  • Some new bitmaps for the MUI by Virtlink
  • Faster and better MakeNSISw integration
  • New .NET Framework detection function
  • Minor bugfixes
  • Code clean-ups (compiles on VC7)


2.0 Beta 0

D.10 2.0 Beta 0

Released on December 6th, 2002

  • New paging system
  • Added Page and UninstPage
  • Removed .onNextPage, .onPrevPage, .onInitDialog
  • New easier version of the Modern User Interface with better multilanguage support, InstallOptions integration, welcome and finish page etc.
  • Custom pages no longer flicker when created
  • Added accelerator keys
  • Added LangString and LangStringUP for user defined multilingual strings
  • Added support for transparent check marks
  • Added InitPluginsDir
  • Renamed nsisconf.nsi to nsisconf.nsh
  • Added CreateShortcut comment/description parameter
  • Splash.exe is now a plugin (splash.dll)
  • Added new plugins: System, AdvSplash, nsExec, UserInfo, BgImage, Banner and StartMenu
  • !ifdef and friends can now be used in macros
  • SendMessage can send strings (put STR: before a param) and supports timeouts
  • Right mouse button "Copy to clipboard" context menu for the Details window
  • Plugin syntax now requires dll name, e.g. dll::func not just func
  • Licence text receives initial focus (page up & down work immediately, return key still works)
  • Made win9x move/delete on reboot support proper and function like on win2k
  • Now always loads RichEdit v2 if present (links work on Win9x)
  • DeleteRegKey now complains if given a third parameter (other than /ifempty)
  • RegDLL now works with DLLs dependent on DLLs from the same directory
  • ${LANG_langName} defined as the language id when loading a NLF
  • Fixed a few bugs that caused the installer to load slower than before
  • Uninstall can now get command line parameters too
  • Added ReserveFile
  • Added ExDLL.h
  • Included makensisw 1.9 (lots of changes)
  • Updated InstallOptions
  • Updated ZIP2EXE
  • Updated HTTP download plugin, NSIS-dl (timeout added, better proxy detection)
  • A lot of new language files
  • A lot of new icons and check marks
  • Changed section flags values
  • SectionSetFlags can now set bold too
  • SectionSetFlags now works in silent installers too
  • SectionSetName for sub sections doesn't need '-' in front of the name
  • Added SetPluginUnload
  • Hidden section can now use SectionIn too
  • File /nonfatal switch added
  • Plugins no longer add size to their containing section
  • Defines can now be used inside define names (${bla${blo}})
  • New docs format (WOOHA!)
  • EXE header size a lot smaller, 33.5KB for bzip2 and 34KB for zlib
  • Lots of other bugs fixed...


2.0 Alpha 7

D.11 2.0 Alpha 7

Released on August 29th, 2002

  • Can now select the language from .onInit ($LANGUAGE is a variable)
  • Added CreateFont
  • Added .onMouseOverSection
  • Added .onInitDialog and un.onInitDialog
  • Added SetStaticBkColor
  • Disabled UseOuterUIItem
  • SendMessage WM_SETTEXT treats lParam as a string and not a number
  • CopyFiles script message no longer always prints (silent)
  • Custom install type text can now be changed
  • ChangeUI can now change IDD_VERIFY
  • Default license color now fits the user system
  • Summary reports the right number of required sections
  • Checkbox is only required in IDD_DIR if logging is enabled
  • Not using /LANG now really causes the script compiler to use the last used language
  • Fixed a bug with MBCS and the uninstaller text
  • MBCS to Unicode and Unicode to MBCS conversion bugs fixed
  • Fixed a bug that caused RTF not to show on Windows 9x
  • Added a dialog that shows up if compress whole is used and initial decompressing lasts longer than a second
  • Updated to InstallOptions 1.3
  • MakeNSISw 1.7 included
  • Added modern UI by Joost Verburg (Examples\Modern UI)
  • Added new full color icons by adni18
  • Added Dutch, Korean, Russian, Swedish and Traditional Chinese language files
  • Updated Spanish language file version (thanks to LsMoNKi)
  • Added /TRIM(LEFT|RIGHT|CENTER) for BrandingText
  • EXE header size down to 36.5KB
  • Added yi-pixel.ico and yi-pixel-uninstall.ico by Jan T. Sott
  • Fixed a bug with macros at the end of the file
  • Sub-sections can now have defined names too
  • Added LangDLL.dll plugin
  • CallInstDLL /NOUNLOAD added (works on plugin calls too)


2.0 Alpha 6

D.12 2.0 Alpha 6

Released on August 10th, 2002

  • Fixed two bugs with the plug-in mechanism
  • Fixed infinite loop bug


2.0 Alpha 5

D.13 2.0 Alpha 5

Released on August 9th, 2002

  • Added UseOuterUIItem
  • Enhanced ChangeUI
  • Enhanced SetDlgItemText
  • Added one-section.nsi example file
  • Optimized Ximon's code for plug-in DLLs (back to 37KB)
  • If default user language doesn't fit exactly, will try to find primary language match
  • Fixed some strings that got replaced (space available and required etc.)
  • Compiles without MS Platform SDK
  • Included Spanish.nlf
  • Included MagicLime.exe by snowchyld


2.0 Alpha 4

D.14 2.0 Alpha 4

Released on August 5th, 2002

  • Added automatic detection, packing, unpacking and deletion of plugin dlls
  • Added simplified calling syntax for plugin dlls
  • Added PluginDir


2.0 Alpha 3

D.15 2.0 Alpha 3

Released on August 4th, 2002

  • Added LoadLanguageFile
  • Added $LANGUAGE
  • Added /LANG option to string setters (Name, Caption, etc.)
  • 'LogSet on' now builds a log file if not already created


2.0 Alpha 2

D.16 2.0 Alpha 2

Released on July 31st, 2002

  • Added ${NSISDIR}
  • Added XPStyle
  • Added SetFont
  • Added ChangeUI
  • Added AddBrandingImage, and SetBrandingImage
  • Added SetCompressor (no more makensis-bz2.exe)
  • Added LicenseBkColor
  • 'SpaceTexts none' now causes no space texts to appear
  • Icon and UninstallIcon now support icons of any type
  • CheckBitmap now support bitmaps with any color table/depth
  • Unused resources are removed before writing out the installer
  • Documented !error and !warning
  • Added !echo and !verbose
  • Added force option for CRCCheck
  • Updated to Makensisw 1.6
  • Updated to InstallOptions 1.2
  • Installer can now be compressed using UPX
  • A hint is shown if a line is longer than the detail window
  • Modern style folder select dialog
  • License data can now be RTF
  • WindowIcon is now handled in the compiler
  • Removed debug version (it never worked anyway)
  • Faster compile time (WIN32_LEAN_AND_MEAN)


2.0 Alpha 1

D.17 2.0 Alpha 1

Released on July 9th, 2002

  • Added expand node option to Section and SubSection
  • Added preserve file attribute option to File command
  • Copy-All bug fix in Makensisw
  • Added NSISDIR to the define list
  • Reorganized NSIS directory structure


2.0 Alpha 0

D.18 2.0 Alpha 0

Released on May 22nd, 2002

  • TreeView component list (care of Jeff Doozan)
  • No more SectionDivider, but SubSection and SubSectionEnd.
  • No more EnabledBitmap/DisabledBitmap, just CheckBitmap. (with tons of button states)
  • Bugfixes of brokenness.
  • Added ! for Section/SubSection to make bold.
  • Made config.h have hacks for easier building for me. :)


Older Versions

D.19 Older Versions

NSIS 1.x version history


Credits

Appendix E: Credits

  • Programmers
  • Designers
  • Translators
  • Writers


Programmers

E.1 Programmers

Justin Frankel aka 0xDEADBEEF

  • Creating the all mighty NSIS

Amir "make me stop" Szekely aka KiCHiK

  • Multilingual NSIS
  • RTF license text
  • The new paging system
  • Full color support for icons and bitmaps
  • Branding image
  • Customizable UI
  • One makensis.exe for both zlib and bzip2

Joost Verburg

  • Modern User Interface
  • NSIS Menu
  • NSIS Update for NSIS distribution (original version by Nathan Purciful)

Robert Rainwater

  • MakeNSISw
  • New documentation format
  • Enhancing the TreeView
  • Reorganizing NSIS directory structure

Dave "bit-by-bit" Laundon aka eccles

  • Massive optimizing

Ximon Eighteen aka Sunjammer

  • The new plug-ins system
  • "Copy to clipboard" context menu for the Details window
  • License text initial focus

Ramon aka Ramon18

  • Version information resource commands
  • Named user variables
  • Lots of UI fixes
  • InstallOptions improvements

nnop@newmail.ru

Ryan Geiss

Andras Varga

Drew Davidson

Peter Windridge

Yaroslav Faybishenko

Jeff Doozan

  • NSIS 2's new TreeView

Nike (nike@sendmail.ru)

  • HTML Help support for Halibut


Designers

E.2 Designers

Nikos Adamamas

  • The new modern icons

Jan T. Sott / whyEye.org

  • Lots of icons and check marks


Translators

E.3 Translators

Arabic - TuW@nNu (asdfuae)

Bulgarian - Asparouh Kalyandjiev

Catalan - falanko

Croatian - Vedran "RIV@NVX" Miletic

Czech - T.V. Zuggy

Danish - Christopher, Casper Bergenstoff

Dutch - Hendri Adriaens, Joost Verburg

Estonian - izzo

Farsi - FzerorubigD

Finnish - AKX, Eclipser

French - veekee, Sébastien Delahaye, Jerome Charaoui

German - L.King, K. Windszus, R. Bisswanger, Tim Kosse

Greek - Makidis N. Michael

Hebrew - Amir Szekely (aka KiCHiK) and Yaron Shahrabani

Hungarian - Soft-Trans Bt., Jozsef Tamas Herczeg, Lajos Molnar (Orfanik)

Italian - Orfanik, sanface, Alessandro Staltari

Japanese - Dnanako, Takahiro Yoshimura

Korean - dTomoyo, linak, koder

Lithuanian - NorCis, Vytautas Krivickas

Macedonian - Sasko Zdravkin

Norwegian - Jonas Christoffer Lindstrøm

Polish - Piotr Murawski & Rafa³ Lampe, cube

Portuguese - DragonSoull, Dre', Ramon

Portuguese Brasil - Layout do Brasil, Diego Marcos

Romanian - Sorin Sbarnea, Cristian Pirvu

Russian - Sergey `Timon` Kusnetsov, Nik Medved, Scam

Serbian - Vladan Obradovic

Slovak - trace, Kypec

Slovenian - Janez Dolinar

Spanish - MoNKi, dark_boy

Swedish - Peter Gustafsson, Magnus Bonnevier, Rickard Angbratt

Thai - TuW@nNu (asdfuae)

Traditional & Simplified Chinese - Kii Ali

Turkish - Bertan Kodamanoglu

Ukrainian - Yuri Holubow, Nash-Soft


Writers

E.4 Writers

Sebastian Armbrust aka flizebogen

  • Tutorial


NSIS License

Appendix F: NSIS License

 Copyright (C) 1999-2004 Nullsoft, Inc.

 This software is provided 'as-is', without any express or implied
 warranty.  In no event will the authors be held liable for any damages
 arising from the use of this software.

 Permission is granted to anyone to use this software for any purpose,
 including commercial applications, and to alter it and redistribute it
 freely, subject to the following restrictions:

 1. The origin of this software must not be misrepresented; you must not
    claim that you wrote the original software. If you use this software
    in a product, an acknowledgment in the product documentation would be
    appreciated but is not required.
 2. Altered source versions must be plainly marked as such, and must not be
    misrepresented as being the original software.
 3. This notice may not be removed or altered from any source distribution.