Welcome to Amiga Active

.key arg
.bra {
.ket }

This section is only run when another script needs to check that the Welcome script has already been run

; Check argument - exit if Welcome has been run, otherwise ask
If {arg} EQ "CHECK"
	Assign <NIL: AACD: EXISTS
	If NOT WARN
		Skip ABORT
	Else
		set init `:System/C/RequestChoice "Amiga Active" "Some assigns need to be made before we can proceed.*NYou can remove them later with the RemoveAssigns icon" "OK|Cancel"`
		If $init EQ 0
			Skip ABORT
			EndIf
		EndIf
	EndIf

If Welcome has already been run, this skips straight to the home page, there's no point in running it twice

; Skip to HTML if Welcome has already been run
Assign <NIL: AACD: EXISTS
If NOT WARN
	Skip HTML
	EndIf

Used only by the script

; Set up temporary assign
Assign AACDtmp: :

Much of the software needs MUI or ClassAct, this sets up any assigns needed. If you already have ClassAct MUI installed, this does nothing

; Check for some system assigns
; MUI
Assign MUI: EXISTS <NIL:
If WARN
	AACDtmp:System/C/RequestChoice <NIL: "MakeAssigns" "Some of the software on this CD requires MUI*NIf you use it regularly you should install MUI to your hard drive.*NThe installer is in the CDTools drawer of this CD" "I see"
	EndIf
; ClassAct
If NOT EXISTS LIBS:window.class
	AACDtmp:System/C/RequestChoice <NIL: "MakeAssigns" "Some of the software on this CD requires ClassAct*NIf you use it regularly you should install MUI to your hard drive.*NThe installer is in the CDTools drawer of this CD" "I see"
	EndIf

Arexx is needed in places, if you don't already have it running it is started here

; Start arexx if not running
AACDtmp:System/rexxc/rx "address command" <NIL:
If WARN
	AACDtmp:System/System/RexxMast <NIL:
	EndIf

icon.mcc and MUIrexx are needed by the AACDprefs and SearchCDs programs. AACDfile is used as the default tool for many icons, by copying it to your C: directory, these icons will still work as expected after installing any software. FlashFind is used by the search engines

; Make sure files needed by CD system are available
; icon.mcc
Version <NIL: MUI:Libs/MUI/Icon.mcc 1 1
If WARN
	Copy <NIL: AACDtmp:CDTools/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE
	EndIf
; MUIRexx
which <NIL: MUIRexx
if WARN
	copy AACDtmp:Rexxc/MUIRexx SYS:Rexxc clone quiet'
	path SYS:Rexxc ADD
	endif
; AACDfile
If NOT EXISTS C:AACDfile
	Copy <NIL: AACDtmp:System/C/AACDfile C: CLONE QUIET
	EndIf
; IDer
Version <NIL: C:IDer 1 6
If WARN
	Copy <NIL: AACDtmp:System/C/IDer C: CLONE
	EndIf
; FlashFind
which <NIL: FlashFind
if WARN
	copy AACDtmp:System/C/FlashFind C: clone quiet
	endif

If you haven't yet run AACDPrefs you are givin the option of running it now.

; Give option for setting CD preferences, if not already done
If NOT EXISTS ENV:AACD.prefs
	If NOT EXISTS S:AACD.prefs
		Version <NIL: version 39
		If NOT WARN
			Copy <NIL: AACDtmp:CDTools/S/AACD.prefs ENV:
			Copy <NIL: AACDtmp:CDTools/S/AACD.prefs ENVARC:
			set NoPrefs 1
		Else
			Copy <NIL: AACDtmp:CDTools/S/AACD.prefs_OS2 ENV:AACD.prefs
			EndIf
		EndIf
	EndIf
If NOT EXISTS ENV:AACDfile.prefs
	If NOT EXISTS S:AACDfile.prefs
		Version <NIL: version 39
		If NOT WARN
			Copy <NIL: AACDtmp:CDTools/S/AACDfile.prefs ENV:
			Copy <NIL: AACDtmp:CDTools/S/AACDfile.prefs ENVARC:
			set NoPrefs 1
		Else
			Copy <NIL: AACDtmp:CDTools/S/AACDfile.prefs_OS2 ENV:AACDfile.prefs
			EndIf
		EndIf
	EndIf
If $NoPrefs EQ 1
	set edit `RequestChoice "Amiga Active CD" "AACD has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
	If $edit EQ 1
		stack 16384
		MuiRexx AACDPrefs port AACDPREFS
	Else
		RequestChoice <NIL: "Amiga Active CD" "You can run AACD preferences at any time.*NEither from its icon or from the Setup page of the documentation." "OK"
		EndIf
	EndIf

This is where assigns specific to the software on this CD are set

; Set assigns for programs on this CD and system drawers
Execute AACDtmp:CDTools/S/ThisCD
Assign DEVS:    AACDtmp:System/Devs ADD
Assign Fonts:   AACDtmp:System/Fonts ADD
Assign Libs:    AACDtmp:System/Libs ADD
Assign L:       AACDtmp:System/L ADD
Assign S:       AACDtmp:System/S ADD
Assign LIBS:    AACDtmp:System/Classes ADD

This adds the ENV: directory of the CD ot your own ENV: directory. This is needed to let programs on the Cd find their settings. As with the other assigns made with this script, this is temporary and only lasts until you run RemoveAssigns or reboot.

; Make environment variables defined on CD available to system
Failat 21
Assign <NIL: ENV: AACDtmp:System/Prefs/Env-Archive ADD
; For HappyENV users
If FAIL
	Assign <NIL: ENVARC: AACDtmp:System/Prefs/Env-Archive ADD
	EndIf

If you are not running NewIcons, the script gives you the option to use it now. This is entirely optional, and can be permanently disabled in AACDPrefs, but the icons on the CD are set up to be displayed using the newicons system and it will not look right withiut this running.

;Check for NewIcons if not already running
	AACDtmp:System/C/isnirunning
	If NOT WARN
		Version >NIL: Version 44
		If Warn
			set RunNI `AACDtmp:System/C/RequestChoice "Amiga Active CD" "This CD is set up for use with NewIcons*NIf you do not run Newicons the icon*Nimages and layout may look strange.*N*NWould you like to run NewIcons now?" "Yes|No"`
			If $RunNI EQ 1
				Run ><NIL: AACDtmp:System/C/NewIcons
				EndIf
			EndIf
		EndIf
	EndIf

This just resets the temporary assign made earlier and informs you about the use of RemoveCD

; Clean up
RequestChoice <NIL: "MakeAssigns" "MakeAssigns has set up some
assigns to run software from the CD.*N*NIf you wish to remove the CD from the drive, doubleclick the RemoveCD icon,*Notherwise the icon will stay on your Workbench." " OK "
; Change temporary assign to permanent one
Assign AACD: AACDtmp:
Assign AACDtmp:

Finally, the Welcome page is displayed, from where you can explore the rest of the CD

; Load HTML
LAB HTML
AACD/WWW/AWeb3/AWebDemo Welcome.html local config Amigactive

LAB ABORT