      SUBROUTINE FUEL 
C *** CALCULATES PROPERTIES OF COMBUSTION FOR GAS FURNACE PROGRAM 
      IMPLICIT REAL(A-H,M-Z)
      DIMENSION MW(14),HF(14),A(14),B(14),C(14),D(14) 
     +,NOC(13)
      PARAMETER (CPAIR=.24) 
CMDK BLKCM1
CMDK BLKCM2
CMDK FUEL1
CMDK PRT1
      PVF(Z)=EXP(16.72048-9400.7858/(Z+459.7))
      DATA A/8*0.,  -.168288E-6,  -.438419E-7,  -.509447E-7,
     +       0.,  -.536138E-7,  0./ 
      DATA B/6.09436E-3,  10.1670E-3,  14.1216E-3,  16.7486E-3, 
     +       17.4328E-3,  21.4615E-3,  21.0380E-3,  40.2128E-3, 
     +       .159751E-2,  .518974E-3,  .555976E-3,  .1488E-3, 
     +       .999914E-3,  -3.018458E-3/ 
      DATA C/6.96554,  10.8508,  15.722, 21.4222, 21.0855,
     +       26.0134,  26.1784,  29.1591,  9.46994,  6.65257, 
     +       7.05349,  6.99778,  7.52025,  -9.69913/
      DATA D/4152.99,  8577.87,  12169.23,  14986.09,  15514.83,
     +       17899.39,  18739.14,  21833.76,  3209.73,  3226.06,
     +       3150.49,  3103.78,  3703.66,  19683.4/ 
      DATA HF/-32200.,  -36425.,   -44676.,  -57870.,  -54270., 
     +        -66456.,  -63000.,  -71928.,  -169293.,  3*0.,
     +        -104036.,  -112971./
      DATA MW/16.042,  30.068,  44.094,  2*58.120,  2*72.146, 
     +        86.172,  44.010,  28.016,  32.,  2.016,2*18.016/
C *** WATER IN FUEL 
      PH2O=PVF(TAIN)
      NH2OP= PH2O/BARPSI
      NH2OF= NH2OP/(1.-NH2OP) 
C *** VOLUME OF DRY FUEL PER HOUR 
      VFDRY= (1.-NH2OP)*FUELCM*60.
C *** MOLECULAR WEIGHT OF DRY FUEL
      MWF=0.
      DO 1 I=1,12 
1     MWF= MWF+XF(I)*MW(I)
      SGFUEL=MWF/28.85
C *** MASS & MOLES OF DRY FUEL PER HOUR AND WET FUEL
      MF= SGFUEL*(.07664)*VFDRY 
      WNF= MF/MWF 
      WFUEL= MF+18.016*NH2OF*WNF
C *** AIR HUMDITY 
      WSAT= (.90029E-5*TWBI-.68134E-3)*TWBI+.01939
      W= ((1093.-.556*TWBI)*WSAT-CPAIR*(TCOMB-TWBI))/(1093.-.444*TWBI)
      IF ( IQEXT .EQ. 0) W= WSAT
C *** MOLES OF PRODUCTS OF COMBUSTION LESS THOSE DUE TO AIR 
      FNO(9)=XF(1)+2.*XF(2)+3.*XF(3)+4.*(XF(4)+XF(5))+5.*(XF(6)+XF(7))+ 
     + 6.*XF(8)+XF(9) 
      FNO(10)= XF(10) 
C  FNO(11) IS NEG. OF NO. OF MOLES OF O2/MOLE OF FUEL(=-21 A/79)
      FNO(11)= -2.*XF(1)-3.5*XF(2)-5.*XF(3)-6.5*(XF(4)+XF(5))-8.*(XF(6) 
     + +XF(7))-9.5*XF(8)-.5*XF(12)+XF(11) 
      FNO(12)=0.
      FNO(13)= NH2OF+2.*XF(1)+3.*XF(2)+4.*XF(3)+5.*(XF(4)+XF(5))+6.*
     + (XF(6)+XF(7))+7.*XF(8)+XF(12)
C *** STOICHIOMETRIC AIR
      WAIR= -FNO(11)/.21*WNF*28.85
      WSTO= WAIR*(1.+W) 
      WSA=(-1.)*FNO(11)/.21 
C        WMSA IS NO. OF MOLES OF DRY AIR/MOLE FUEL
      WMSA=WSA*(1.+EXCESS)
C *** FUEL ENERGY IN
      ENINF= 0. 
      XF(13)=NH2OF
      DO 2 I=1,13 
2     ENINF= ENINF+ (H(I,TAIN)-H(I,77.)+HF(I))*XF(I)
C *** ENTHALPY PER MOLE OF DRY AIR
      ENAIR=0.
      FN(10)=.79
      FN(11)= .21 
      FN(12)=0. 
      FN(13)= 7.622*.21*W 
      DO 3 I=10,13
3     ENAIR= ENAIR+(H(I,TCOMB)-H(I,77.)+HF(I))*FN(I)
C *** CONSTANT PORTION OF FLUE ENTHALPIES 
      AS=0. 
      BS=0. 
      CS=0. 
      DS=0. 
      DO 4 I=9,13 
      AS= AS+A(I)*FNO(I)
      BS= BS+B(I)*FNO(I)
      CS= CS+C(I)*FNO(I)
4     DS= DS+(D(I)-H(I,77.)+HF(I))*FNO(I) 
      AAIR= A(10)*.79+A(11)*.21+A(13)*FN(13)
      BAIR= B(10)*.79+ B(11)*.21+B(13)*FN(13) 
      CAIR= C(10)*.79+C(11)*.21+C(13)*FN(13)
      DAIR= (D(10)-H(10,77.)+HF(10))*.79+(D(11)-H(11,77.)+HF(11))*.2
     +1+(D(13) -H(13,77.)+HF(13))*FN(13)
C *** TOTAL FLUE ENTHALPY PER MOLE OF DRY FUEL IS OF THE FORM: H=((AS*T+
C *** BS)*T+CS)*T +DS+(((AAIR*T+BAIR)*T+CAIR)*T+DAIR)*NAIR: H2O IS
C *** IGNORED.FOR TOTAL HEAT INPUT EVALUATE H AT TCOMB BY USING ABOVE AN
C *** H2O CONDENSED 
      HFACT= ((AS*TCOMB+BS)*TCOMB+CS)*TCOMB+DS
      HFACTA=((AAIR*TCOMB+BAIR)*TCOMB+CAIR)*TCOMB+DAIR
      HFG= (B(14)*TCOMB+C(14))*TCOMB+D(14)
      PSAT=PVF(TCOMB) 
      FA= PSAT/BARPSI 
      NOT=FNO(9)+FNO(10)+FNO(11)+FNO(13)
      FB=(FA*(NOT+WMSA*(1.+FN(13)))-FNO(13)-WMSA* 
     +FN(13))/(FA-1.)*HFG 
      IF(ISAVE.EQ.0)RETURN
C 
C  SAVE VALUES FOR FLUE CALCULATIONS
      WNFC=WNF
      WFLUE=WSTO*(1.+EXCESS)+WFUEL
      WNFWG=WNF/WFLUE 
      WMSAC=WMSA
      NOC(9)=FNO(9) 
      NOC(10)=FNO(10) 
      NOC(11)=FNO(11) 
      NOC(12)=FNO(12) 
      NOC(13)=FNO(13) 
      NO13=FNO(13)
      N13=FN(13)
      NOTC=NOT
      NOTTC=NOT+WMSA
      ASC=WMSA*AAIR 
      BSC=WMSA*BAIR 
      CSC=WMSA*CAIR 
      DSC=WMSA*DAIR 
      DO 40 I=9,12
      ASC=ASC+A(I)*NOC(I) 
      BSC=BSC+B(I)*NOC(I) 
      CSC=CSC+C(I)*NOC(I) 
   40 DSC=DSC+(D(I)-H(I,77.)+HF(I))*NOC(I)
      RETURN
C 
C * * * * * * * * * * * 
C 
      ENTRY FUELA 
C 
      PSAT=PVF(TFLUE) 
      PH2O=NO13*BARPSI/NOTTC
      IF(PSAT.GT.PH2O)THEN
C      NO CONDENSATION IN FLUE GAS
          NH2OL=0.
          NOC(13)=NO13
      ELSE
C       CONDENSATION IN FLUE GAS
C          ASSUME FLUE GAS IS SATURATED THROUGHOUT
          FA=PSAT/BARPSI
          NH2OL=(FA*(NOTC+WMSAC*(1.+N13))-NO13-WMSAC*N13)/(FA-1.) 
          NOC(13)=NO13-NH2OL
      IF(NOC(13).LT.0.)NOC(13)=0. 
          ENDIF 
      ASV=ASC+A(13)*NOC(13) 
      BSV=BSC+B(13)*NOC(13) 
      CSV=CSC+C(13)*NOC(13) 
      DSV=DSC+(D(13)-H(13,77.)+HF(13))*NOC(13)
C  QVSLOS IS SENSIBLE HEAT LOSS AT FLUE (INCLUDES COMP DUE TO WAT VAP)
C  QVLLOS IS LATENT HEAT LOSS OF UNCONDENSED WAT VAP) 
      HCMB=(((ASV*TCOMB+BSV)*TCOMB+CSV)*TCOMB+DSV)*WNFWG
      HTFLU=(((ASV*TFLUE+BSV)*TFLUE+CSV)*TFLUE+DSV)*WNFWG 
C      CPFLU=(HTFLU-HCMB)/(TFLUE-TCOMB+.0000001) 
      QVSLOS=(HTFLU-HCMB)*WFLUE 
C   AS MORE AND MORE WAT VAP IS CONDENSED FROM FLUE GAS, NOC(13) WILL 
C     APPROACH NH2OL
      QVLLOS=NOC(13)*HFG*WNFC 
      IF(QVLLOS.LT.0.)QVLLOS=0. 
      RETURN
      END 
      FUNCTION H(I,T) 
      DIMENSION A(14),B(14),C(14),D(14) 
      DATA A/8*0.,  -.168288E-6,  -.438419E-7,  -.509447E-7,
     +       0.,  -.536138E-7,  0./ 
      DATA B/6.09436E-3,  10.1670E-3,  14.1216E-3,  16.7486E-3, 
     +       17.4328E-3,  21.4615E-3,  21.0380E-3,  40.2128E-3, 
     +       .159751E-2,  .518974E-3,  .555976E-3,  .1488E-3, 
     +       .999914E-3,  -3.018458E-3/ 
      DATA C/6.96554,  10.8508,  15.722, 21.4222, 21.0855,
     +       26.0134,  26.1784,  29.1591,  9.46994,  6.65257, 
     +       7.05349,  6.99778,  7.52025,  -9.69913/
      DATA D/4152.99,  8577.87,  12169.23,  14986.09,  15514.83,
     +       17899.39,  18739.14,  21833.76,  3209.73,  3226.06,
     +       3150.49,  3103.78,  3703.66,  19683.4/ 
      H=((A(I)*T+B(I))*T+C(I))*T+D(I) 
      RETURN
      END 
