      SUBROUTINE CONSLD(NRM,IAREA,IOPCRT,IDBG)
C
C  * CONSOLIDATE ENCLOSURE ELEMENTS TO A MINIMUM NO. OF ELEMENTS
C       PLUS WINDOWS PER ZONE
C  A MINIMUM N1. OF ELEMENTS IN EACH ORIENTATION, IDEXP, INCLUDES THE
C     1. THOSE ELEMENTS FOR WHICH LUMP TEMPERATURES MUST BE CALCULATED
C        AND THOSE FOR WHICH HEAT FLOWS MUST BE COMPUTED AT THE INNER
C        SURFACE FROM AN ENERGY BALANCE.
C     2. THOSE ELEMENTS WHICH ARE CONNECTED TO SEPARATE ZONES
C   NOTE: WINDOWS WILL NOT BE CONSOLIDATED BUT WILL BE LINKED TO THE
C         CONSOLIDATED ELEMENT
C  * CALCULATE TOTAL WINDOW AREA IN CONSOLIDATED OUTSIDE ENCLOSURE WALLS
C  * CALCULATE TOTAL NET WALL AREA (LESS WINDOW AREA) FOR OUTSIDE WALLS
C  * CALCULATE TOTAL ROOF AREA ABOVE EACH ATTIC
C
C  INPUTS AS FORMAL PARAMETERS
C    NRM  ZONE NO.
C    IAREA  =1, CALC WINDOW AND ROOF AREAS
C   IOPCRT = 0  ALL CONSOLID CRITERIA USED
C          = 1  ONLY 1,2 CONSOLID CRITERIA USED ON OUTSIDE WALLS
C
C  INPUT FROM BLK IZZQ
C    IZT  IZW FOR LAST ENCLOSURE ELEMENT IN PREVIOUS ZONE
C - - - CONSTANTS
CMDK NKONST
CMDK NRF
CMDK NWL
CMDK NWN
CMDK NWZN
CMDK NZN
CMDK NZW
      PARAMETER (NLMX=10)
C      NOTE:::::    IF NLMX NEEDS CHANGING, CHANGE IT IN CNSLD ALSO!      
C - - - COMMON BLOCKS
CMDK CNSTRK
CMDK ENCBK1
CMDK ENCBK2
CMDK ENCBLK
CMDK IRDFQ
CMDK IZPART
CMDK IZWQ
CMDK IZZQ
CMDK ROOF
CMDK SOILB
CMDK SURFAR
CMDK WNDBLK
C
      DIMENSION NLA(10),NEL(10,NLMX),NELI(NLMX),NK2I(NWL),NELIQ(NLMX)
     +         ,SROOFO(2), SROOFI(2)
C
      NILST=0
      NK2=0
      IF(IAREA.EQ.1)GO TO 130
C
C  BEGIN CONSOLIDATION, IF NEEDED TO REDUCE NO. OF ENCL ELEMENTS
      N2=NWALLA(NRM)
      DO 80 K2=1,N2
      IZW=NENC(NRM,K2)
C
C  DETERMINE NET SURFACE AREAS OF ENCLOSURE ELEMENTS WITHOUT WINDOWS
C  FOR USE IN AREA WEIGHTING IN SUBPROGRAM CNSLD
C  NOTE: HEIGHT AND LENGTH OF SURFACE OF ENCLOSURE ELEMENTS
C        INCLUDES WINDOWS, SO AREA OF WINDOWS MUST BE SUBTRACTED
C        FROM WALL
      ID=IDEXP(IZW)
      SWA=0.
      IF(ID.LE.4)THEN
          N4=NWNDA(IZW)
          IF(N4.EQ.0)GO TO 72
C
          DO 70 K4=1,N4
          NW=NIWND(IZW,K4)
          AWAWA(NW)=WHGTA(NW)*WWDTHA(NW)
          SWA=SWA+AWAWA(NW)
   70     CONTINUE
          ENDIF
   72 AWALLA(IZW)=HGTA(IZW)*XLENA(IZW)-SWA
   80 CONTINUE
C
C  FIND ENCLOSURE ELEMENT NUMBERS FOR EACH IDEXP IN THIS ZONE,NRM
C   (THESE NUMBERS ARE STORED IN ARRAY NEL AND TOTAL NO. OF VALUES
C    ARE STORED IN ARRAY NLA
C
      DO 86 ID=1,10
      NLA(ID)=0
      NL=0
C
      DO 84 K2=1,N2
      IZW=NENC(NRM,K2)
      IF(ID.EQ.IDEXP(IZW))THEN
          NL=NL+1
          IF(NL.GT.NLMX)STOP 'CONSLD: INCREASE PARAMETER NLMX'
          NEL(ID,NL)=K2
          ENDIF
   84 CONTINUE
      NLA(ID)=NL
      IF(NL.NE.0.AND.IDBG.NE.0)WRITE(60,500)NRM,ID,(NEL(ID,K),K=1,NL)
   86 CONTINUE
C
C   NOW CHECK VALUES AT EACH IDEXP TO SEE IF CONSOLIDATION IS NEEDED
C     (IT IS WHEN MORE THAN ONE ELEMENT IS CONNECTED TO SAME ZONE
C      AND CONSOLIDATION CRITERIA ARE MET)
C   NK2I ARRAY HOLDS NK2 ENCLOSURE NUMBERS FOR ENCLOSURES WITH THIS ID
C   THAT ARE NO LONGER CANDIDATES FOR CONSOLIDATION.
C   NK2 IS THE CUMULATIVE NUMBER OF ENCLOSURES IN THE NK2I ARRAY.
C
      DO 110 ID=1,10
C  NL IS NO. OF NEL VALUES AT THIS ID
      NL=NLA(ID)
      IF(NL.EQ.0)GO TO 110
C  IF(NL <= 1, NO CONSOLIDATION IS NEEDED
      IF(NL.EQ.1)THEN
          K2=NEL(ID,1)
          NK2=NK2+1
          NK2I(NK2)=K2
          GO TO 110
          ENDIF
C
C  NOW FOR THIS ID, CONSOLIDATE ELEMENTS CONNECTED TO SAME ZONE
C    NI  STARTING INDICE FOR STARTING SEARCH IN NEL ARRAY FOR A
C        NEW CONNECTING ZONE (SAVED IN NELI ARRAY)
C    N   INDICE FOR NI IN NELI ARRAY
C
C  FIND ELEMENTS THAT MEET CONSOLIDATION CRITERIA:
C     1. CONNECTED TO SAME ZONE
C     2. NO. OF LAYERS OR LUMPS IN CONSTRUCTS IS THE SAME
C     3. HEIGHT OF ENCLOSURE ELEMENT IS THE SAME
C     4. ROOF OVERHANG IS THE SAME
C     5. HEIGHT FROM TOP OF WALL TO ROOF OVERHANG IS THE SAME
C     6. ABSORPTIVITY OF OUTSIDE SURFACE IS THE SAME
C     7. ALWAYS SHADED DIR OF CONSTRUCT ARE THE SAME
C     8. NOT INTERIOR PARTITION WALL BETWEEN ZONES
C     9. NOT INTERIOR PARTITION WALLS WITH DIFFERENT CONSTR
C    10. NOT BASEMENT FLOOR (ID=8)
C    11. NOT BASEMENT WALL BELOW GROUND (ID=9)
C    12. NOT AN ENCLOSURE ELEMENT WITH LEAKAGE OPENING
C
      NI=1
C  ZERO ARRAY THAT HOLD INACTIVE INDICES
C  INDICES BECOME INACTIVE WHEN:
C    1. THEY HAVE BEEN ENTERED IN NK2I ARRAY
C    2. OR THEY HAVE BEEN CONSOLIDATED
      CALL ZERVI(10,NELIQ)
       NLQ=1
      NELIQ(NLQ)=NI
C  SET K2 FOR NEXT ENCLOSURE ELE WITH NEW CONNECTING ZONE
   90 K2=NEL(ID,NI)
      NK2=NK2+1
      NK2I(NK2)=K2
      IZW=NENC(NRM,K2)
      N=1
      NELI(N)=NI
      NZONC=NZNC(IZW)
      KON=KONSTA(IZW)
      IF(ID.LE.4)IFXI=IFXL(ID,KON)
      NLUMP=NLMP(KON)
      IF(ID.LE.4)THEN
          HGT=HGTA(IZW)
          OHANG=OHANGA(IZW)
          HHANG=HHANGA(IZW)
          WALFO=WALLFO(IZW)
          ENDIF
      IF(IDBG.NE.0)WRITE(60,509)NRM,IZW,NZONC,NLUMP
      IF(ID.LE.4.AND.IDBG.NE.0)WRITE(60,511)HGT,OHANG,WALFO,HHANG
C  NOW LOOK FOR OTHER ELEMENTS MEEING CONSOLIDATION CRITERIA
C    AND STORE NL INDICE NO. IN NELI ARRAY.
C  IFG IS A FLAG THAT IS SET TO 1 WHEN AN ELEMENT CONNECTED TO A
C    NEW ZONE IS ENCOUNTERED.  THE NL INDICE OF THE ELEMENT CONNECTED
C    TO A NEW ZONE IS SAVED AS NI, SO THAT THE NEXT SEARCH CAN BEGIN
C    HERE RATHER THAN AT AN NL OF 1, SINCE NO ELMENTS IN NEL ARRAY
C    WITH I<NI WILL BE CONNECTED TO NZON
C
      IFG=0
      NISV=NI
      IST=NISV+1
      IF(IST.GT.NL)GO TO 108
      NI=0
C
      DO  98 I=NISV+1,NL
C  CHECK FOR INACTIVE INDICE
      DO 91 J=1,NLQ
      IF(NELIQ(J).EQ.I)GO TO 98
   91 CONTINUE
      IF(IDBG.NE.0)WRITE(60,513)I,NL
      K2=NEL(ID,I)
      IZW=NENC(NRM,K2)
C         DONT CONSOLIDATE AN ELEMENT W/ A LEAKAGE OPENING
      IF(WDLEAK(IZW).GT.0.)GO TO 94      
      NZON=NZNC(IZW)-8
      KONC=KONSTA(IZW)
      IF(IDBG.NE.0)THEN
      WRITE(60,515)ID,K2,IZW,NZONC,NZNC(IZW),NLUMP,NLMP(KONC)
          ENDIF
C  DONT CONSOLIDATE A MIRROR IMAGE
      DO 92 IRQ=1,NZW
   92 IF(IZSET(IRQ).EQ.IZW)GO TO 94

C  DONT CONSOLID A BASEMENT FLOOR OR BELW GRND WALL
      IF(ID.EQ.8.OR.ID.EQ.9)GO TO 94
C  IF SAME CONNECTING ZONE & SAME NO. OF LUMPS & NOT OUTSIDE WALL, THEN      
      IF(NZONC.EQ.NZNC(IZW).AND.NLUMP.EQ.NLMP(KONC).AND.ID.GT.4)THEN
C - - DONT CONSOLIDATE INTERIOR PARTITION WALLS BETWEEN ZONES
          IF(IDBG.NE.0)WRITE(60,517)NRM,ID,IZW,NZON
          IF(ID.EQ.7.AND.NZON.NE.NRM)THEN
              IF(NZNC(IZW).NE.6)THEN
C                WRITE(60,519)IZW,ID,NZON,NRM
                GO TO 94
              ENDIF
          ENDIF
C - - DONT CONSOLIDATE INTERIOR PARTITION WALLS WITH DIFFERNT
C                    CONSTRUCTS
          IF(ID.EQ.7.AND.KON.NE.KONC)THEN
C              WRITE(60,520)IZW,ID,NZON,NRM,KONC,KON
              GO TO 94
              ENDIF
          IF(IDBG.NE.0)WRITE(60,518)NRM,ID,IZW,KONC,KON
          GO TO 93
          ENDIF
C  IF SAME CONNECTING ZONE & SAME NO. OF LUMPS & OUTSIDE WALL, THEN          
      IF(NZONC.EQ.NZNC(IZW).AND.NLUMP.EQ.NLMP(KONC).AND.ID.LE.4)THEN
          IF(IDBG.NE.0)THEN
          WRITE(60,516)OHANG,OHANGA(IZW),WALFO,WALLFO(IZW),
     +                HHANG,HHANGA(IZW),HGT,HGTA(IZW),
     +                IFXI,IFXL(ID,KONC)
              ENDIF
          IF(IOPCRT.EQ.1)GO TO 93
C  MEET CONSIDATION CRITERIAS 4,6,5,3,7 ?          
          IF(OHANG.EQ.OHANGA(IZW).AND.WALFO.EQ.WALLFO(IZW))THEN
              IF(HHANG.EQ.HHANGA(IZW).AND.HGT.EQ.HGTA(IZW))THEN
              IF(IFXI.EQ.IFXL(ID,KONC))GO TO 93
                  ENDIF
              ENDIF
          ENDIF
      GO TO 94
C
C  AHA!!!!!!!! FOUND ENCLOSURE ELE TO CONSOLIDATE
  93  N=N+1
      NELI(N)=I
      NLQ=NLQ+1
      NELIQ(NLQ)=I
      IF(IDBG.NE.0)WRITE(60,501)NZONC,IZW,I,NLUMP
      IF(IDBG.NE.0)WRITE(60,512)HGT,OHANG,WALFO,HHANG
      GO TO 98
C
C  SAVE INDICE, NI, OF NEXT ENCLOSURE ELEMENT WITH NEW CONNECTING ZONE
   94 IF(IFG.EQ.0)THEN
C         CHECK FOR INACTIVE INDICE
          IQZL=0
          DO 96 J=1,NLQ
          IF(NELIQ(J).EQ.I)IQZL=1
   96     CONTINUE
          IF(IQZL.EQ.0)THEN
              NLQ=NLQ+1
              NELIQ(NLQ)=NI
              NILST=NI
              NI=I
              IF(IDBG.NE.0)WRITE(60,502)I,NZONC,IZW
              IFG=1
              ENDIF
          ENDIF
   98 CONTINUE
      IF(IDBG.NE.0)WRITE(60,514)I,NL,N,NI
      IF(NI.EQ.0)THEN
          NI=NISV
          NILST=NI
          ENDIF
C  NO CONSOLIDATION NEEDED IF ONLY ONE ENCL CONNECTED TO NEW ZONE
      IF(N.EQ.1)GO TO 108
C
C  NOW CONSOLIDATE ALL ELEMENTS CONNECTED TO SAME ZONE
C - - - - - - - - -PARAMETERS PASSED TO CNSLD
C  NRM  ZONE NO.
C  ID   IDEXP VALUE
C  N    NO. OF ENCLOSURE ELEMENTS TO CONSOLIDATE INTO FIRST ELEMENT
C  NELI NL INDICE OF NEL ARRAY FOR EACH N ELEMENTS
C  NEL  ENCLOSURE SEQUENCE NO. (K2 VALUE -- SEE CNSLD(FIRST PAGE))
      IF(IDBG.NE.0)WRITE(60,503)NRM,ID
      IF(IDBG.NE.0)WRITE(60,504)(NELI(I),I=1,N)
      IF(IDBG.NE.0)WRITE(60,505)(NEL(ID,I),I=1,NL)
      CALL CNSLD(NRM,ID,N,NELI,NEL)
      NWALLA(NRM)=NWALLA(NRM)-(N-1)
C
C  GO TO NEW ID SINCE I = NL WITHOUT FINDING NEW CONNECTING ZONE
  108 IF(IDBG.NE.0)WRITE(60,506)NI,NILST,N
      IF(NI.EQ.NILST)GO TO 110
C
      NILST=NI
      GO TO 90
C
  110 CONTINUE
C
C  NOW REDUCE ENCLOSURE ARRAYS TO ONLY EFFECTIVE ELEMENTS
C
C    CHECK FOR PROPER NO. OF ENCLOSURE ELEMENTS
      IF(NWALLA(NRM).NE.NK2)WRITE(60,508)NWALLA(NRM),NK2
C
C RESET CONSOLIDATED ELEMENTS IN ENCLOSURE ARRAYS TO REDUCE STORAGE
C
      CALL RESETE(NRM,N2,NK2,NK2I,IDBG)
      IZT2=IZT+2
      IF(NRM.EQ.NROOMS)WRITE(60,524)IZT2,NZW
      IF(IZT2.LE.NZW)GO TO 160
C       2 IS ADDED TO IZT FOR ROOF TEMPS
      WRITE(60,*)' CONSLD: NZW MUST BE INCREASED TO ',IZT2  
      STOP 'CONSLD: INCREASE NZW-- SEE TAPE6 OUTPUT'
C
C  ENTER BELOW AFTER ALL CONSOLIDATION IS COMPLETE AND IAREA=1
  130 CONTINUE
C
C  NOW CALC TOTAL WINDOW AREA (AWAW) AND TOTAL FLOOR AREA(AFLRT) IN EA
C  ZONE AND CALC NET WALL AREA FOR EACH ENCLOSURE ELEMENT
C    AND SET AREAS OF BASMT FLOOR AND BLW GRND BASMT WALL
C    AND SET MASS*CP OF EACH LAYER OF EACH ENCLOSURE ELEMENT
      IZWQ=0
      IZWR=0
C -  -  -  -  -  -  -  -
      DO 140 J=1,NROOMS
      NRM=NRMA(J)
      N2=NWALLA(NRM)
      SWA=0.
      SFA=0.
C  -  -  -  -  -  -  -  -
      DO 138 K2=1,N2
      IZW=NENC(NRM,K2)
      KON=KONSTA(IZW)
      ID=IDEXP(IZW)
      SWAW=0.
      IF(ID.EQ.6.OR.ID.EQ.8)SFA=SFA+HGTA(IZW)*XLENA(IZW)
      IF(ID.EQ.8)THEN
C             BASMT FLOOR
          IZWQ=IZWQ+1
          ABASF(IZWQ)=HGTA(IZW)*XLENA(IZW)
          IZWD(IZWQ)=IZW
          ENDIF
      IF(ID.EQ.9)THEN
C            BLW GRND BSMT WALL
          IZWR=IZWR+1
          IZWE(IZWR)=IZW
          ENDIF
      IF(ID.LE.4)THEN
          N4=NWNDA(IZW)
          IF(N4.EQ.0)GO TO 135
          DO 134 K4=1,N4
          NW=NIWND(IZW,K4)
          AWAWA(NW)=WHGTA(NW)*WWDTHA(NW)
          SWA=SWA+AWAWA(NW)
          SWAW=SWAW+AWAWA(NW)
  134     CONTINUE
  135     AWALLA(IZW)=HGTA(IZW)*XLENA(IZW)-SWAW
          ENDIF
  138 CONTINUE
      AWAWT(NRM)=SWA
      AFLRT(NRM)=SFA
  140 CONTINUE
      CLOSE(23)
      IF(IZWQ.NE.2)WRITE(60,525)IZWQ
      IF(IZWR.NE.4)WRITE(60,526)IZWR
C  SET ZERO WALL AREA  FOR USE WHEN A WALL IS NOT INCLUDED (E.G. GARAG)
      AWALLA(IZT+1)=0.
C
C  NOW CALC SURF AREA OF ROOF ABOVE EACH ATTIC
      RAREA(1)=0.
      RAREA(2)=0.
      NATC=0
      SROOFO(1)=0.
      SROOFO(2)=0.
      SROOFI(1)=0.
      SROOFI(2)=0.
      DO 150 I=1,NSECTA
      IF(NATTC(I).EQ.1)THEN
          NATC=1
          RAREA(1)=RAREA(1)+SECTAA(I)
          SROOFO(1)=SROOFO(1)+ROOFO(I)*SECTAA(I)
          SROOFI(1)=SROOFI(1)+ROOFI(I)*SECTAA(I)
          KONRF(1)=KONSTR(I)
C  NOTE: ALL ROOF SECTIONS ABOVE ONE ATTIC MUST HAVE SAME CONSTRUCT NO.
          ENDIF
      IF(NATTC(I).EQ.2)THEN
          NATC=2
          RAREA(2)=RAREA(2)+SECTAA(I)
          SROOFO(2)=SROOFO(2)+ROOFO(I)*SECTAA(I)
          SROOFI(2)=SROOFI(2)+ROOFI(I)*SECTAA(I)
          KONRF(2)=KONSTR(I)
          ENDIF
      WRITE(60,510)I,NATTC(I),RAREA(1),RAREA(2)
  150 CONTINUE
      IF(NZW.LT.(IZT+NATC))THEN
          STOP 'CONSLD: NZW MUST BE INCR TO ACCOM ROOF TEMPS'
          ENDIF
      IF(RAREA(2).EQ.0.)RAREA(2)=.0000001
      IF(RAREA(1).EQ.0.)STOP 'STRCTL: RAREA(1)=0.!!!'
      DO 152 I=1,2
      ROFOM(I)=SROOFO(I)/RAREA(I)
      ROFIM(I)=SROOFI(I)/RAREA(I)
  152 CONTINUE
  160 CONTINUE
      RETURN
  500 FORMAT(1X,'CONSLD:NRM,ID= ',2I5/
     +10X,'K2S= ',10I4)
  501 FORMAT(1X,'CONSLD:ENCL NO. CONNECTED TO ZONE ',I4,'  = ',I4/
     +10X,' INDICE I= ',I4,'  NLUMP= ',I5)
  502 FORMAT(1X,'CONSLD: INDICE OF NEXT ENCL ELE WITH NEW CONNTG ZONE=',
     +I4,'   NZONE,IZW= ',2I4)
  503 FORMAT(/,'CONSLD:NRM,ID AT CALL TO CNSLD= ',2I5)
  504 FORMAT(9X,'NELI= ',10I4)
  505 FORMAT(9X,'NEL= ',10I4)
  506 FORMAT(1X,'CONSLD(AFTER CNSLD CALL):NI,NILST,N= ',3I4)
  507 FORMAT(1X,'CONSLD(AFTER CNSLD CALL):NI,NL= ',2I4)
  508 FORMAT(/,'CONSLD:IMPROPER NO. OF ENCLOSURE ELEMENTS - - - -'/
     +1X,'       NWALLA(NRM),NK2= ',2I5)
  509 FORMAT(/,'* * * ZONE= ',I3,'   ENCL. NO.= ',I3,
     +'  IS CONNECTED TO ZONE ',I3,'  NLUMP= ',I5)
  510 FORMAT(1X,'ROOF SECTION ',I3,'  ATTIC NO.',I3,
     +'  CUMULATIVE ROOF AREA= ',2G13.5)
  511 FORMAT(5X,'HGT,OHANGA,WALLFO,HHANGA= ',4G13.5)
  512 FORMAT(10X,'HGT,OHANGA,WALLFO,HHANGA= ',4G13.5)
  513 FORMAT(15X,'SEARCH:INDICE BEING CHECKED FOR CONSOLID= ',I5/
     +       22X,'TOTAL INDICES FOR THIS ID ARE = ',I5)
  514 FORMAT(16X,'AFTER 98 CONTINUE:INDICE(I) OF NEL ARRAY,WHICH'/
     +16X,' HOLDS IZW S OF ENCLOSURE ELE AT THIS ID= ',I4/
     +16X,'NO.(NL) OF ENCLOSURE ELE S AT THIS ID= ',I4/
     +16X,'NO.(N) OF ELCLOSURE ELE S IN NELI ARRAY= ',I4/
     +16X,'STARTING INDICE NO.(NI) FOR STARTING A NEW SEARCH FOR '/
     +16X,'CONNECTING ZONES ,STORED IN NELI ARRAY,= ',I4)
  515 FORMAT(1X,'ID= ',I3,' K2= ',I4,' IZW= ',I4/
     +10X,'NZONC= ',I5,'  NZNC=',I5/10X,'NLUMP= ',I5,'  NLMP= ',I5)
  516 FORMAT(10X,'OHANG= ',G13.5,' OHANGA= ',G13.5/
     +10X,'WALFO= ',G13.5,'WALLFO= ',G13.5/10X,'HHANG= ',G13.5,
     +'  HHANGA= ',G13.5/10X,'HGT= ',G13.5,'  HGTA= ',G13.5/
     +10X,'IFXI= ',I3,'  IFXL= ',I3)
  517 FORMAT(/,'NRM,ID,IZW,NZON= ',4I5)
  518 FORMAT(/,'NRM,ID,IZW,KONC,KON= ',5I5)
C  519 FORMAT(/,'DIDNT CONSOLIDATE INTERIOR WALL--IZW,ID= ',2I4/
C     +10X,'CONNECTING ZONE= ',I4,'  THIS ZONE= ',I4)
C  520 FORMAT(/,'DIDNT CONSOLIDATE INTERIOR WALL--IZW,ID= ',2I4/
C     +10X,'CONNECTING ZONE= ',I4,'  THIS ZONE= ',I4/
C     +10X,'CONSTRUCT NO.= ',I4,'  CF CONSTRUCT FOR FIRST ELE AT',
C     +1X,'THIS ID= ',I4)
  521 FORMAT(/,'CONSLD:IZW,IZSET(IZW)--OLD,IZSET(IZW)--NEW= ',
     +3I4)
  522 FORMAT((1X,'I,IZSET(I),IZQ(I)= ',3I4))
  523 FORMAT((1X,'I,IZSET(I)= ',2I4))
  524 FORMAT(/,5(1H*),' NO. OF ENCLOSURE ELEMENTS REQD= ',I3,
     +' VS MAX ALLOWED(NZW)= ',I3)
  525 FORMAT(//,'CONSLD:--OOH,OOH!! NO. OF BSMT FLOOR ELEMENTS SHOULD',
     +' BE 2 RATHER THAN ',I3//)
  526 FORMAT(//,'CONSLD:--OH,OOH!! NO. OF BELW GRND BSMT WALL ELEMENTS',
     +' SHOULD BE 4 RATHER THAN ',I3//)
      END
