+---------------------------------+
|    @ ... GET - Radio Buttons    |
+---------------------------------+
@ <row, column> GET <var>
        FUNCTION <expC1>
        | PICTURE <expC2>
        [DEFAULT <expr>]
        [SIZE <expN1>, <expN2>
                [, <expN3>]]
        [ENABLE | DISABLE]
        [MESSAGE <expC3>]
        [VALID <expL1>]
        [WHEN <expL2>]
        [COLOR SCHEME <expN4>
        | COLOR <color pair list>]

-----------------------------------
Creates radio buttons.
-----------------------------------

As their name suggests, radio buttons are similar to the buttons of a
car radio - choosing a button makes your choice current and releases
your previous choice.  A bullet  in a button indicates it is the current
choice.

Radio buttons look like this on the screen:

        (.) Apples
        ( ) Apricots
        ( ) Lemons
        ( ) Oranges

The string of text to the right of the button is called a prompt.  The
text of the prompt is specified by the FUNCTION or PICTURE clause.
Issue READ to activate the buttons.

<row, column>
        Numeric coordinates (zero or greater) that specify where the first
radio button of set of buttons is placed.

GET <var>
        Memory variable, array element or database field where choice of check
box is stored.  If Escape pressed, <var> remains unchanged.

Initial Button Selection
        Value of <var> determines which radio button (if any) is initially
selected.

FUNCTION <expC1> | PICTURE <expC2>
        Permissible function codes are:

        *R      Mandatory, always first.  To create more than one radio button, add
semicolon between each button name.  If PICTURE used, precede codes with
@.

        N       Buttons don't terminate READ.

        T       Buttons terminate READ.

        H       Horizontal buttons.

        V       (default) Vertical buttons.

H and V can be combined with T and N options as NH, NV, TH or TV.

Hot Keys
        To assign a hot key, place \< before desired character of radio button
prompt.

Disabled Buttons
        To disable a radio button, place \\ before button's prompt.

DEFAULT <expr>
        Creates memory variable if one specified does not exist.

SIZE <expN1>, <expN2> [, <expN3>]
        <expN1> specifies height of object (expN1 always = 1); <expN2>
specifies width (in columns) of radio button; <expN3> specifies spacing
between radio buttons.

ENABLE | DISABLE
        Allows or prevents activation of radio buttons when READ is issued.

MESSAGE <expC3>
        Displays <expC3> when a radio button is selected.

VALID <expL1>
        Evaluated when a radio button is chosen.  Typically, <expL1> is a UDF.

WHEN <expL2>
        Allows or prohibits selection of radio buttons.  Often, <expL2> is a
UDF.

COLOR SCHEME <expN4>
| COLOR <color pair list>
        Overrides current color scheme by specifying a different pre-defined
color scheme, or by specifying a list of color pairs.

        Color Pair Controls
        1       Not used by radio buttons
        2       Not used by radio buttons
        3       Not used by radio buttons
        4       Not used by radio buttons
        5       Message
        6       Selected radio prompt
        7       Hot keys
        8       Not used by radio buttons
        9       Enabled radio prompt
        10      Disabled radio prompt

+---------------------------------+
|             Examples            |
+---------------------------------+
***** FUNCTION clause only
STORE 1 TO choice
@ 4,2 GET choice FUNCTION '*R Apples;Apricots;Lemons;Oranges'
READ

STORE 1 TO choice
STORE '*R Apples;Apricots;Lemons;Oranges' TO mfunc
@ 4,2 GET choice FUNCTION mfunc
READ

***** PICTURE clause only
STORE 1 TO choice
@ 4,2 GET choice PICTURE '@*R Apples;Apricots;Lemons;Oranges'
READ

STORE 1 TO choice
@ 4,2 GET choice PICTURE '@*R' + ' Apples;Apricots;Lemons;Oranges'
READ

***** FUNCTION and PICTURE clause together
STORE 1 TO choice
@ 4,2 GET choice FUNCTION '*R' ;
        PICTURE ' Apples;Apricots;Lemons;Oranges'
READ

STORE 1 TO choice
@ 4,2 GET choice FUNCTION '*R Apples;Apricots' ;
        PICTURE ';Lemons;Oranges'
READ

***** Hot keys
STORE 1 TO choice
@ 4,2 GET choice FUNCTION '*R' ;
        PICTURE ' \<Apples;A\<pricots;Lemons;Oranges'
READ
  The following example disables the Lemon button:

STORE 1 TO choice
@ 4,2 GET choice FUNCTION '*R' ;
        PICTURE 'Apples;Apricots;\\Lemons;Oranges'

***** Valid DEFAULT clauses
*** Example 1
@ 5,0 GET choice FUNCTION '*R' +;
  ' Apples;Apricots;Lemons;Oranges' DEFAULT 'Apricots'
READ

*** Example 2
@ 5,0 GET choice FUNCTION '*R Apples;Apricots;Lemons;Oranges';
  DEFAULT 2
READ