+---------------------------------+
|             CNTBAR              |
+---------------------------------+
CNTBAR(<expC>)

-----------------------------------
Returns number of bars in popup.
Return value - Numeric
-----------------------------------

<expC>
        Popup name.

+---------------------------------+
|         Program Example         |
+---------------------------------+
In example below, named CNTBAR.PRG, a menu pad is added to system menu.
Popup ENVIRO is defined with four bars which will change status of items
indicated.  Mark is placed by each bar when associated item is turned
"ON" and removed when associated item is turned "OFF".

*** You must name this program CNTBAR.PRG ***
CLEAR
SET TALK OFF
DEFINE PAD enviro OF _MSYSMENU PROMPT 'E\<nvironment';
        KEY ALT+N, 'ALT+N'
ON PAD enviro OF _MSYSMENU ACTIVATE POPUP enviro

DEFINE POPUP enviro MARGIN RELATIVE SHADOW COLOR SCHEME 4
DEFINE BAR 1 OF enviro  PROMPT '\<Status Bar'
DEFINE BAR 2 OF enviro  PROMPT '\<Clock'
DEFINE BAR 3 OF enviro  PROMPT '\<Extended Video'
DEFINE BAR 4 OF enviro  PROMPT 'St\<icky'
ON SELECTION POPUP enviro DO enviropop IN cntbar.prg
FOR i = 1 TO CNTBAR('enviro')
        DO CASE
        CASE PRMBAR('enviro', i) = 'Status Bar'
                SET MARK OF BAR i OF enviro TO  SET('STATUS') = 'ON'
        CASE PRMBAR('enviro', i) = 'Clock'
                SET MARK OF BAR i OF enviro TO  SET('CLOCK') = 'ON'
        CASE PRMBAR('enviro', i) = 'Extended Video'
                SET MARK OF BAR i OF enviro TO  SROW() > 25
        CASE PRMBAR('enviro', i) = 'Sticky'
                SET MARK OF BAR i OF enviro TO  SET('STICKY') = 'ON'
        ENDCASE
ENDFOR

PROCEDURE enviropop
DO CASE
CASE PROMPT() = 'Status'
        IF MRKBAR('enviro', BAR())
                SET STATUS OFF
                SET MARK OF BAR BAR() OF enviro TO .F.
        ELSE
                SET STATUS ON
                SET MARK OF BAR BAR() OF enviro TO .T.
        ENDIF
CASE PROMPT() = 'Clock'
        IF MRKBAR('enviro', BAR())
                SET CLOCK OFF
                SET MARK OF BAR BAR() OF enviro TO .F.
        ELSE
                SET CLOCK ON
                SET MARK OF BAR BAR() OF enviro TO .T.
        ENDIF
CASE PROMPT() = 'Extended Video'
        IF MRKBAR('enviro', BAR())
                SET DISPLAY TO VGA25
                SET MARK OF BAR BAR() OF enviro TO .F.
        ELSE
                SET DISPLAY TO VGA50
                SET MARK OF BAR BAR() OF enviro TO .T.
        ENDIF
CASE PROMPT() = 'Sticky'
        IF MRKBAR('enviro', BAR())
                SET STICKY OFF
                SET MARK OF BAR BAR() OF enviro TO .F.
        ELSE
                SET STICKY ON
                SET MARK OF BAR BAR() OF enviro TO .T.
        ENDIF
ENDCASE

-----------------------------------

See Also:  CNTPAD(), DEFINE BAR, DEFINE POPUP

-----------------------------------