+---------------------------------+
|              CLEAR              |
+---------------------------------+
CLEAR
CLEAR ALL
CLEAR FIELDS
CLEAR GETS
CLEAR MACROS
CLEAR MEMORY
CLEAR MENUS
CLEAR POPUPS
CLEAR PROGRAM
CLEAR PROMPT
CLEAR READ
CLEAR TYPEAHEAD
CLEAR WINDOWS

-----------------------------------
Clears specified item.
-----------------------------------

CLEAR
        Erases screen or current output window and releases all pending GET
statements.

ALL
        Releases all memory variables and arrays, selects primary work area and
closes open databases including associated index, format and memo files.
CLEAR ALL also releases all user-defined menus bars, menu popups and
windows.  CLEAR ALL does not release system memory variables.

FIELDS
        Releases FIELDS list that was created by SET FIELDS TO. SET FIELDS OFF
is then automatically executed.  CLEAR FIELDS is distinguished from SET
FIELDS TO in that it releases all FIELDS in all work areas, not just in
the current work area.

GETS
        Releases all pending GET statements.

MACROS
        Releases ALL keyboard macros from memory, including any Function key
assignments.

MEMORY
        Releases all public and private memory variables and arrays. System
memory variables are not released.

MENUS
        Releases all menu bars from memory and clears them from  screen or
window.

POPUPS
        Releases all popups from memory and clears them from screen or window.

PROGRAM
        Releases compiled program buffer.  This command is included for
backward compatibility and should not be needed in FoxPro Version 2.0.

PROMPT
        Releases PROMPTs that were displayed on screen with @ ... PROMPT
without issuing MENU TO command.

READ [ALL]
        Terminates READ on current level and returns control to previous READ
level (if any).  Including ALL terminates all READs on all READ levels.

TYPEAHEAD
        Releases keyboard typeahead buffer.

WINDOWS
        Releases all user-defined windows from memory and removes them from
screen.

+---------------------------------+
|         Program Example         |
+---------------------------------+
SET TALK OFF
DEFINE WINDOW entry FROM 6,14 TO 14,65 ;
        TITLE 'Input Window' FLOAT SHADOW SYSTEM COLOR SCHEME 8
ACTIVATE WINDOW entry
@ 2,2 SAY 'First Name:'
@ 4,2 SAY 'Last Name:'
@ 2,16 GET firstname SIZE 1,24 DEFAULT ''
@ 4,16 GET lastname SIZE 1,24 DEFAULT ''
@ 6,14 GET button FUNCTION '*HN \?\<Clear;\!\<Exit' ;
        SIZE 1,9,2 DEFAULT '' VALID clearexit()
READ CYCLE
RELEASE WINDOW entry

FUNCTION clearexit
DO CASE
        CASE button = 'Clear'
                firstname = SPACE(10)
                lastname = SPACE(10)
                _CUROBJ = 1
                SHOW GETS
                WAIT WINDOW 'Enter Name Again' NOWAIT
        CASE button = 'Exit'
                CLEAR READ
                WAIT WINDOW  'Entry Complete' NOWAIT
ENDCASE

-----------------------------------

See Also:  @ ... SAY/GET, @ ... CLEAR, @ ... PROMPT, ACTIVATE MENU,
ACTIVATE POPUP, ACTIVATE WINDOW, CLOSE, DEFINE MENU, DEFINE POPUP,
DEFINE WINDOW, HIDE MENU, HIDE POPUP, HIDE WINDOW, PLAY MACRO,
RDLEVEL(), READ, RELEASE, RESTORE MACROS, SAVE MACROS,  SAVE WINDOW, SET
FIELDS, SET TYPEAHEAD, SHOW MENU, SHOW POPUP, SHOW WINDOW

-----------------------------------