[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
In the terminology of operating systems, a process is a space in which a program can execute. Emacs runs in a process. Emacs Lisp programs can invoke other programs in processes of their own. These are called subprocesses or child processes of the Emacs process, which is their parent process.
A subprocess of Emacs may be synchronous or asynchronous, depending on how it is created. When you create a synchronous subprocess, the Lisp program waits for the subprocess to terminate before continuing execution. When you create an asynchronous subprocess, it can run in parallel with the Lisp program. This kind of subprocess is represented within Emacs by a Lisp object which is also called a “process”. Lisp programs can use this object to communicate with the subprocess or to control it. For example, you can send signals, obtain status information, receive output from the process, or send input to it.
This function returns t
if object is a process,
nil
otherwise.
1.1 Functions that Create Subprocesses | Functions that start subprocesses. | |
1.2 Creating a Synchronous Process | Details of using synchronous subprocesses. | |
1.3 Creating an Asynchronous Process | Starting up an asynchronous subprocess. | |
1.4 Deleting Processes | Eliminating an asynchronous subprocess. | |
1.5 Process Information | Accessing run-status and other attributes. | |
1.6 Sending Input to Processes | Sending input to an asynchronous subprocess. | |
1.7 Sending Signals to Processes | Stopping, continuing or interrupting an asynchronous subprocess. | |
1.8 Receiving Output from Processes | Collecting output from an asynchronous subprocess. | |
1.9 Sentinels: Detecting Process Status Changes | Sentinels run when process run-status changes. | |
1.10 Transaction Queues | Transaction-based communication with subprocesses. | |
1.11 TCP | Opening network connections. |
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
There are three functions that create a new subprocess in which to run
a program. One of them, start-process
, creates an asynchronous
process and returns a process object (see section Creating an Asynchronous Process).
The other two, call-process
and call-process-region
,
create a synchronous process and do not return a process object
(see section Creating a Synchronous Process).
Synchronous and asynchronous processes are explained in following sections. Since the three functions are all called in a similar fashion, their common arguments are described here.
In all cases, the function’s program argument specifies the
program to be run. An error is signaled if the file is not found or
cannot be executed. The actual file containing the program is found by
following normal system rules: if the file name is absolute, then the
program must be found in the specified file; if the name is relative,
then the directories in exec-path
are searched sequentially for a
suitable file. The variable exec-path
is initialized when Emacs
is started, based on the value of the environment variable PATH
.
The standard file name constructs, ‘~’, ‘.’, and ‘..’,
are interpreted as usual in exec-path
, but environment variable
substitutions (‘$HOME’, etc.) are not recognized; use
substitute-in-file-name
to perform them (@pxref{File Name
Expansion}).
Each of the subprocess-creating functions has a buffer-or-name
argument which specifies where the standard output from the program will
go. If buffer-or-name is nil
, that says to discard the
output unless a filter function handles it. (See section Process Filter Functions,
and @ref{Streams}.) Normally, you should avoid having multiple
processes send output to the same buffer because their output would be
intermixed randomly.
All three of the subprocess-creating functions have a &rest
argument, args. The args must all be strings, and they are
supplied to program as separate command line arguments. Wildcard
characters and other shell constructs are not allowed in these strings,
since they are passed directly to the specified program.
Please note: the argument program contains only the name of the program; it may not contain any command-line arguments. Such arguments must be provided via args.
The subprocess gets its current directory from the value of
default-directory
(@pxref{File Name Expansion}).
The subprocess inherits its environment from Emacs; but you can
specify overrides for it with process-environment
. @xref{System
Environment}.
The value of this variable is the name of a directory (a string) that
contains programs that come with GNU Emacs, that are intended for Emacs
to invoke. The program wakeup
is an example of such a program;
the display-time
command uses it to get a reminder once per
minute.
The default value is the name of a directory whose name ends in
‘arch-lib’. We call the directory ‘emacs/arch-lib’, since its
name usually ends that way. We sometimes refer to “the directory
‘emacs/arch-lib’,” when strictly speaking we ought to say, “the
directory named by the variable exec-directory
.” Most of the
time, there is no difference.
(In earlier Emacs versions, prior to version 19, these files lived in the directory ‘emacs/etc’ instead of in ‘emacs/arch-lib’.)
The value of this variable is a list of directories to search for
programs to run in subprocesses. Each element is either the name of a
directory (i.e., a string), or nil
, which stands for the default
directory (which is the value of default-directory
).
The value of exec-path
is used by call-process
and
start-process
when the program argument is not an absolute
file name.
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
After a synchronous process is created, Emacs waits for the
process to terminate before continuing. Starting Dired is an example of
this: it runs ls
in a synchronous process, then modifies the
output slightly. Because the process is synchronous, the entire
directory listing arrives in the buffer before Emacs tries to do
anything with it.
While Emacs waits for the synchronous subprocess to terminate, the
user can quit by typing C-g, and the process is killed by sending
it a SIGKILL
signal. @xref{Quitting}.
The synchronous subprocess functions return nil
in version 18.
In version 19, they will return an indication of how the process
terminated.
This function calls program in a separate process and waits for it to finish.
The standard input for the process comes from file infile if
infile is not nil
and from ‘/dev/null’ otherwise. The
process output gets inserted in buffer buffer-or-name before point,
if that argument names a buffer. If buffer-or-name is t
,
output is sent to the current buffer; if buffer-or-name is
nil
, output is discarded.
If buffer-or-name is the integer 0, call-process
returns
nil
immediately and discards any output. In this case, the
process is not truly synchronous, since it can run in parallel with
Emacs; but you can think of it as synchronous in that Emacs is
essentially finished with the subprocess as soon as this function
returns.
If display is non-nil
, then call-process
redisplays
the buffer as output is inserted. Otherwise the function does no
redisplay, and the results become visible on the screen only when Emacs
redisplays that buffer in the normal course of events.
The remaining arguments, args, are strings that are supplied as the command line arguments for the program.
The value returned by call-process
(unless you told it not to
wait) indicates the reason for process termination. A number gives the
exit status of the subprocess; 0 means success, and any other value
means failure. If the process terminated with a signal,
call-process
returns a string describing the signal.
The examples below are both run with the buffer ‘foo’ current.
(call-process "pwd" nil t) ⇒ nil ---------- Buffer: foo ---------- /usr/user/lewis/manual ---------- Buffer: foo ----------
(call-process "grep" nil "bar" nil "lewis" "/etc/passwd") ⇒ nil ---------- Buffer: bar ---------- lewis:5LTsHm66CSWKg:398:21:Bil Lewis:/user/lewis:/bin/csh ---------- Buffer: bar ----------
The dired-readin
function contains a good example of the use of
call-process
:
(call-process "ls" nil buffer nil dired-listing-switches dirname)
This function sends the text between start to end as
standard input to a process running program. It deletes the text
sent if delete is non-nil
, which may be useful when the
output is going to be inserted back in the current buffer.
If buffer-or-name names a buffer, the output is inserted in that
buffer at point. If buffer-or-name is t
, the output is
sent to the current buffer. If buffer-or-name is nil
, the
output is discarded. If buffer-or-name is the integer 0, the
output is discarded and call-process
returns nil
immediately, just as call-process
would.
If display is non-nil
, then call-process-region
redisplays the buffer as output is inserted. Otherwise the function
does no redisplay, and the results become visible on the screen only
when Emacs redisplays that buffer in the normal course of events.
The remaining arguments, args, are strings that are supplied as the command line arguments for the program.
The return value of call-process-region
is just like that of
call-process
: nil
if you told it to return without
waiting; otherwise, a number or string which indicates how the
subprocess terminated.
In the following example, we use call-process-region
to run the
cat
utility, with standard input being the first five characters
in buffer ‘foo’ (the word ‘input’). cat
copies its
standard input into its standard output. Since the argument
buffer-or-name is t
, this output is inserted in the current
buffer.
---------- Buffer: foo ---------- input∗ ---------- Buffer: foo ----------
(call-process-region 1 6 "cat" nil t) ⇒ nil ---------- Buffer: foo ---------- inputinput∗ ---------- Buffer: foo ----------
The shell-command-on-region
command uses
call-process-region
like this:
(call-process-region
start end
shell-file-name ; Name of program.
nil ; Do not delete region.
buffer ; Send output to buffer
.
nil ; No redisplay during output.
"-c" command) ; Arguments for the shell.
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
After an asynchronous process is created, Emacs and the Lisp
program can continue running immediately. The process may thereafter
run in parallel with Emacs, and the two may communicate with each other
using the functions described in following sections. Here we describe
how to create an asynchronous process, with start-process
.
This function creates a new asynchronous subprocess and starts the program program running in it. It returns a process object that stands for the new subprocess for Emacs Lisp programs. The argument name specifies the name for the process object; if a process with this name already exists, then name is modified (by adding ‘<1>’, etc.) to be unique. The buffer buffer-or-name is the buffer to associate with the process.
The remaining arguments, args, are strings that are supplied as the command line arguments for the program.
In the example below, the first process is started and runs (rather, sleeps) for 100 seconds. Meanwhile, the second process is started, given the name ‘my-process<1>’ for the sake of uniqueness. It inserts the directory listing at the end of the buffer ‘foo’, before the first process finishes. Then it finishes, and a message to that effect is inserted in the buffer. Much later, the first process finishes, and another message is inserted in the buffer for it.
(start-process "my-process" "foo" "sleep" "100") ⇒ #<process my-process>
(start-process "my-process" "foo" "ls" "-l" "/user/lewis/bin") ⇒ #<process my-process<1>> ---------- Buffer: foo ---------- total 2 lrwxrwxrwx 1 lewis 14 Jul 22 10:12 gnuemacs --> /emacs -rwxrwxrwx 1 lewis 19 Jul 30 21:02 lemon Process my-process<1> finished Process my-process finished ---------- Buffer: foo ----------
This function is like start-process
except that it uses a shell
to execute the specified command. The argument command is a shell
command name, and command-args are the arguments for the shell
command.
This variable controls the type of device used to communicate with
asynchronous subprocesses. If it is nil
, then pipes are used.
If it is t
, then PTYs are used (or pipes if PTYs are
not supported).
PTYs are usually preferable for processes visible to the user, as in Shell mode, because they allow job control (C-c, C-z, etc.) to work between the process and its children whereas pipes do not. For subprocesses used for internal purposes by programs, it is often better to use a pipe, because they are more efficient. In addition, the total number of PTYs is limited on many systems and it is good not to waste them.
The value process-connection-type
is used when
start-process
is called, so in order to change it for just one
call of start-process
, temporarily rebind it with let
.
(let ((process-connection-type nil)) ; Use a pipe.
(start-process …))
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Deleting a process disconnects Emacs immediately from the subprocess, and removes it from the list of active processes. It sends a signal to the subprocess to make the subprocess terminate, but this is not guaranteed to happen immediately. (The process object itself continues to exist as long as other Lisp objects point to it.)
You can delete a process explicitly at any time. Processes are deleted automatically after they terminate, but not necessarily right away. If you delete a terminated process explicitly before it is deleted automatically, no harm results.
This variable controls automatic deletion of processes that have
terminated (due to calling exit
or to a signal). If it is
nil
, then they continue to exist until the user runs
list-processes
. Otherwise, they are deleted immediately after
they exit.
This function deletes the process associated with name. The
argument name may be a process, the name of a process, a buffer,
or the name of a buffer. The subprocess is killed with a SIGHUP
signal.
(delete-process "*shell*") ⇒ nil
This function declares that Emacs need not query the user if
process is still running when Emacs is exited. The process will
be deleted silently. The value is t
.
(process-kill-without-query (get-process "shell")) ⇒ t
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Several functions return information about processes.
list-processes
is provided for interactive use.
This command displays a listing of all living processes. (Any processes
listed as ‘Exited’ or ‘Signaled’ are actually eliminated after
the listing is made.) This function returns nil
.
This function returns a list of all processes that have not been deleted.
(process-list) ⇒ (#<process display-time> #<process shell>)
This function returns the process named name, or nil
if
there is none. An error is signaled if name is not a string.
(get-process "shell") ⇒ #<process shell>
This function returns the command that was executed to start process. This is a list of strings, the first string being the program executed and the rest of the strings being the arguments that were given to the program.
(process-command (get-process "shell")) ⇒ ("/bin/csh" "-i")
This function returns the exit status of process or the signal
number that killed it. (Use the result of process-status
to
determine which of those it is.) If process has not yet
terminated, the value is 0.
This function returns the PID of process. This is an integer which distinguishes the process process from all other processes running on the same computer at the current time. The PID of a process is chosen by the operating system kernel when the process is started and remains constant as long as the process exists.
This function returns the name of process.
This function returns the status of process-name as a symbol. The argument process-name must be either a process or a string. If it is a string, it need not name an actual process.
The possible values for an actual subprocess are:
run
for a process that is running.
stop
for a process that is stopped but continuable.
exit
for a process that has exited.
signal
for a process that has received a fatal signal.
open
for a network connection that is open.
closed
for a network connection that is closed. Once a connection is closed, you cannot reopen it, though you might be able to open a new connection to the same place.
nil
if process-name is not the name of an existing process.
(process-status "shell") ⇒ run
(process-status "never-existed") ⇒ nil
x ⇒ #<process xx<1>> (process-status x) ⇒ exit
For a network connection, process-status
returns one of the symbols
open
or closed
. The latter means that the other side
closed the connection, or Emacs did delete-process
.
In earlier Emacs versions (prior to version 19), the status of a network
connection was run
if open, and exit
if closed.
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Asynchronous subprocesses receive input when it is sent to them by Emacs, which is done with the functions in this section. You must specify the process to send input to, and the input data to send. The data appears on the “standard input” of the subprocess.
Some operating systems have limited space for buffered input in a PTY. On these systems, the subprocess will cease to read input correctly if you send an input line longer than the system can handle. You cannot avoid the problem by breaking the input into pieces and sending them separately, for the operating system will still have to put all the pieces together in the input buffer before it lets the subprocess read the line. The only solution is to put the input in a temporary file, and send the process a brief command to read that file.
This function sends process-name the contents of string as standard input. The argument process-name must be a process or the name of a process.
The function returns nil
.
(process-send-string "shell<1>" "ls\n") ⇒ nil
---------- Buffer: *shell* ---------- ... introduction.texi syntax-tables.texi~ introduction.texi~ text.texi introduction.txt text.texi~ ... ---------- Buffer: *shell* ----------
This function sends the text in the region defined by start and end as standard input to process-name, which is a process or a process name.
An error is signaled unless both start and end are integers or markers that indicate positions in the current buffer. (It is unimportant which number is larger.)
This function makes process-name see an end-of-file in its input. The EOF comes after any text already sent to it.
If process-name is not supplied, or if it is nil
, then
this function sends the EOF to the current buffer’s process. An
error is signaled if the current buffer has no process.
The function returns process-name.
(process-send-eof "shell") ⇒ "shell"
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Sending a signal to a subprocess is a way of interrupting its
activities. There are several different signals, each with its own
meaning. For example, the signal SIGINT
means that the user
has typed C-c, or that some analogous thing has happened.
Each signal has a standard effect on the subprocess. Most signals kill the subprocess, but some stop or resume execution instead. Most signals can optionally be handled by programs; if the program handles the signal, then we can say nothing in general about its effects.
The set of signals and their names is defined by the operating system; Emacs has facilities for sending only a few of the signals that are defined. Emacs can send signals only to its own subprocesses.
You can send signals explicitly by calling the functions in this
section. Emacs also sends signals automatically at certain times:
killing a buffer sends a SIGHUP
signal to all its associated
processes; killing Emacs sends a SIGHUP
signal to all remaining
processes. (SIGHUP
is a signal that usually indicates that the
user hung up the phone.)
Each of the signal-sending functions takes two optional arguments: process-name and current-group.
The argument process-name must be either a process, the name of
one, or nil
. If it is nil
, the process defaults to the
process associated with the current buffer. An error is signaled if
process-name does not identify a process.
The argument current-group is a flag that makes a difference
when you are running a job-control shell as an Emacs subprocess. If it
is non-nil
, then the signal is sent to the current process-group
of the terminal which Emacs uses to communicate with the subprocess. If
the process is a job-control shell, this means the shell’s current
subjob. If it is nil
, the signal is sent to the process group of
the immediate subprocess of Emacs. If the subprocess is a job-control
shell, this is the shell itself.
The flag current-group has no effect when a pipe is used to
communicate with the subprocess, because the operating system does not
support the distinction in the case of pipes. For the same reason,
job-control shells won’t work when a pipe is used. See
process-connection-type
in Creating an Asynchronous Process.
This function interrupts the process process-name by sending the
signal SIGINT
. Outside of Emacs, typing the “interrupt
character” (normally C-c on some systems, and DEL
on
others) sends this signal. When the argument current-group is
non-nil
, you can think of this function as “typing C-c”
on the terminal by which Emacs talks to the subprocess.
This function kills the process process-name by sending the
signal SIGKILL
. This signal kills the subprocess immediately,
and cannot be handled by the subprocess.
This function sends the signal SIGQUIT
to the process
process-name. This signal is the one sent by the “quit
character” (usually C-b or C-\) when you are not inside
Emacs.
This function stops the process process-name by sending the
signal SIGTSTP
. Use continue-process
to resume its
execution.
On systems with job control, the “stop character” (usually C-z)
sends this signal (outside of Emacs). When current-group is
non-nil
, you can think of this function as “typing C-z”
on the terminal Emacs uses to communicate with the subprocess.
This function resumes execution of the process process by sending
it the signal SIGCONT
. This presumes that process-name was
stopped previously.
This function sends a signal to process pid, which need not be a child of Emacs. The argument signal specifies which signal to send; it should be an integer.
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
There are two ways to receive the output that a subprocess writes to its standard output stream. The output can be inserted in a buffer, which is called the associated buffer of the process, or a function called the filter function can be called to act on the output.
1.8.1 Process Buffers | If no filter, output is put in a buffer. | |
1.8.2 Process Filter Functions | Filter functions accept output from the process. | |
1.8.3 Accepting Output from Processes | Explicitly permitting subprocess output. Waiting for subprocess output. |
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
A process can (and usually does) have an associated buffer, which is an ordinary Emacs buffer that is used for two purposes: storing the output from the process, and deciding when to kill the process. You can also use the buffer to identify a process to operate on, since in normal practice only one process is associated with any given buffer. Many applications of processes also use the buffer for editing input to be sent to the process, but this is not built into Emacs Lisp.
Unless the process has a filter function (see section Process Filter Functions),
its output is inserted in the associated buffer. The position to insert
the output is determined by the process-mark
(see section Process Information), which is then updated to point to the end of the text
just inserted. Usually, but not always, the process-mark
is at
the end of the buffer. If the process has no buffer and no filter
function, its output is discarded.
This function returns the associated buffer of the process process.
(process-buffer (get-process "shell")) ⇒ #<buffer *shell*>
This function returns the marker which controls where additional output from the process will be inserted in the process buffer. When output is inserted, the marker is updated to point at the end of the output. This causes successive batches of output to be inserted consecutively.
If process does not insert its output into a buffer, then
process-mark
returns a marker that points nowhere.
Filter functions normally should use this marker in the same fashion
as is done by direct insertion of output in the buffer. A good
example of a filter function that uses process-mark
is found at
the end of the following section.
When the user is expected to enter input in the process buffer for transmission to the process, the process marker is useful for distinguishing the new input from previous output.
This function sets the buffer associated with process to
buffer. If buffer is nil
, the process will
not be associated with any buffer.
This function returns the process associated with buffer-or-name. If there are several processes associated with it, then one is chosen. (Presently, the one chosen is the one most recently created.) It is usually a bad idea to have more than one process associated with the same buffer.
(get-buffer-process "*shell*") ⇒ #<process shell>
If the process’s buffer is killed, the actual child process is killed
with a SIGHUP
signal (see section Sending Signals to Processes).
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
A process filter function is a function that receives the standard output from the associated process. If a process has a filter, then all output from that process, that would otherwise have been in a buffer, is passed to the filter. The process buffer is used for output from the process only when there is no filter.
A filter function must accept two arguments: the associated process and a string, which is the output. The function is then free to do whatever it chooses with the output.
A filter function runs only while Emacs is waiting (e.g., for terminal
input, or for time to elapse, or for process output). This avoids the
timing errors that could result from running filters at random places in
the middle of other Lisp programs. You may explicitly cause Emacs to
wait, so that filter functions will run, by calling sit-for
,
sleep-for
or accept-process-output
(see section Accepting Output from Processes). Emacs is also waiting when the command loop is reading input.
Quitting is normally inhibited within a filter function—otherwise,
the effect of typing C-g at command level or to quit a user
command would be unpredictable. If you want to permit quitting inside a
filter function, bind inhibit-quit
to nil
.
@xref{Quitting}.
Many filter functions sometimes or always insert the text in the
process’s buffer, mimicking the actions of Emacs when there is no
filter. Such filter functions need to use set-buffer
in order to
be sure to insert in that buffer. To avoid setting the current buffer
semipermanently, these filter functions must use unwind-protect
to make sure to restore the previous current buffer. They should also
update the process marker, and in some cases update the value of point.
Here is how to do these things:
(defun ordinary-insertion-filter (proc string) (let ((old-buffer (current-buffer))) (unwind-protect (let (moving) (set-buffer (process-buffer proc)) (setq moving (= (point) (process-mark proc)))
(save-excursion
;; Insert the text, moving the process-marker.
(goto-char (process-mark proc))
(insert string)
(set-marker (process-mark proc) (point)))
(if moving (goto-char (process-mark proc))))
(set-buffer old-buffer))))
The reason to use an explicit unwind-protect
rather than letting
save-excursion
restore the current buffer is so as to preserve
the change in point made by goto-char
.
To make the filter force the process buffer to be visible whenever new
text arrives, insert the following line just before the
unwind-protect
:
(display-buffer (process-buffer proc))
To force point to move to the end of the new output no matter where
it was previously, eliminate the variable moving
and call
goto-char
unconditionally.
All filter functions that do regexp searching or matching should save
and restore the match data. Otherwise, a filter function that runs
during a call to sit-for
might clobber the match data of the
program that called sit-for
. @xref{Match Data}.
The output to the function may come in chunks of any size. A program that produces the same output twice in a row may send it as one batch of 200 characters one time, and five batches of 40 characters the next.
This function gives process the filter function filter. If
filter is nil
, then the process will have no filter.
This function returns the filter function of process, or nil
if it has none.
Here is an example of use of a filter function:
(defun keep-output (process output) (setq kept (cons output kept))) ⇒ keep-output
(setq kept nil) ⇒ nil
(set-process-filter (get-process "shell") 'keep-output) ⇒ keep-output
(process-send-string "shell" "ls ~/other\n") ⇒ nil kept ⇒ ("lewis@slug[8] % "
"FINAL-W87-SHORT.MSS backup.otl kolstad.mss~ address.txt backup.psf kolstad.psf backup.bib~ david.mss resume-Dec-86.mss~ backup.err david.psf resume-Dec.psf backup.mss dland syllabus.mss " "#backups.mss# backup.mss~ kolstad.mss ")
Here is another, more realistic example, which demonstrates how to use the process mark to do insertion in the same fashion as is done when there is no filter function:
;; Insert input in the buffer specified by my-shell-buffer
;; and make sure that buffer is shown in some window.
(defun my-process-filter (proc str)
(let ((cur (selected-window))
(pop-up-windows t))
(pop-to-buffer my-shell-buffer)
(goto-char (point-max)) (insert str) (set-marker (process-mark proc) (point-max)) (select-window cur)))
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Output from asynchronous subprocesses normally arrives only while Emacs is waiting for some sort of external event, such as elapsed time or terminal input. Occasionally it is useful in a Lisp program to explicitly permit output to arrive at a specific point, or even to wait until output arrives from a process.
This function allows Emacs to read pending output from processes. The
output is inserted in the associated buffers or given to their filter
functions. If process is non-nil
then this function does
not return until some output has been received from process.
The arguments seconds and millisec let you specify timeout
periods. The former specifies a period measured in seconds and the
latter specifies one measured in milliseconds. The two time periods
thus specified are added together, and accept-process-output
returns after that much time whether or not there has been any
subprocess output.
Not all operating systems support waiting periods other than multiples of a second; on those that do not, you get an error if you specify nonzero millisec.
The function accept-process-output
returns non-nil
if it
did get some output, or nil
if the timeout expired before output
arrived.
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
A process sentinel is a function that is called whenever the associated process changes status for any reason, including signals (whether sent by Emacs or caused by the process’s own actions) that terminate, stop, or continue the process. The process sentinel is also called if the process exits. The sentinel receives two arguments: the process for which the event occurred, and a string describing the type of event.
The string describing the event looks like one of the following:
"finished\n"
.
"exited abnormally with code exitcode\n"
.
"name-of-signal\n"
.
"name-of-signal (core dumped)\n"
.
A sentinel runs only while Emacs is waiting (e.g., for terminal input,
or for time to elapse, or for process output). This avoids the timing
errors that could result from running them at random places in the
middle of other Lisp programs. You may explicitly cause Emacs to wait,
so that sentinels will run, by calling sit-for
, sleep-for
or accept-process-output
(see section Accepting Output from Processes). Emacs is
also waiting when the command loop is reading input.
Quitting is normally inhibited within a sentinel—otherwise, the
effect of typing C-g at command level or to quit a user command
would be unpredictable. If you want to permit quitting inside a
sentinel, bind inhibit-quit
to nil
. @xref{Quitting}.
All sentinels that do regexp searching or matching should save and
restore the match data. Otherwise, a sentinel that runs during a call
to sit-for
might clobber the match data of the program that
called sit-for
. @xref{Match Data}.
This function associates sentinel with process. If
sentinel is nil
, then the process will have no sentinel.
The default behavior when there is no sentinel is to insert a message in
the process’s buffer when the process status changes.
(defun msg-me (process event) (princ (format "Process: %s had the event `%s'" process event))) (set-process-sentinel (get-process "shell") 'msg-me) ⇒ msg-me
(kill-process (get-process "shell")) -| Process: #<process shell> had the event `killed' ⇒ #<process shell>
This function returns the sentinel of process, or nil
if it
has none.
While a sentinel or filter function is running, this function returns
non-nil
if Emacs was waiting for keyboard input from the user at
the time the sentinel or filter function was called, nil
if it
was not.
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
You can use a transaction queue for more convenient communication
with subprocesses using transactions. First use tq-create
to
create a transaction queue communicating with a specified process. Then
you can call tq-enqueue
to send a transaction.
This function creates and returns a transaction queue communicating with process. The argument process should be a subprocess capable of sending and receiving streams of bytes. It may be a child process, or it may be a TCP connection to a server possibly on another machine.
This function sends a transaction to queue queue. Specifying the queue has the effect of specifying the subprocess to talk to.
The argument question is the outgoing message which starts the transaction. The argument fn is the function to call when the corresponding answer comes back; it is called with two arguments: closure, and the answer received.
The argument regexp is a regular expression to match the entire
answer; that’s how tq-enqueue
tells where the answer ends.
The return value of tq-enqueue
itself is not meaningful.
Shut down transaction queue queue, waiting for all pending transactions to complete, and then terminate the connection or child process.
Transaction queues are implemented by means of a filter function. See section Process Filter Functions.
[ << ] | [ < ] | [ Up ] | [ > ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Emacs Lisp programs can open TCP connections to other processes on the
same machine or other machines. A network connection is handled by Lisp
much like a subprocess, and is represented by a process object.
However, the process you are communicating with is not a child of the
Emacs process, so you can’t kill it or send it signals. All you can do
is send and receive data. delete-process
closes the connection,
but does not kill the process at the other end; that process must decide
what to do about closure of the connection.
You can distinguish process objects representing network connections
from those representing subprocesses with the process-status
function. See section Process Information.
This function opens a TCP connection for a service to a host. It returns a process object to represent the connection.
The name argument specifies the name for the process object. It is modified as necessary to make it unique.
The buffer-or-name argument is the buffer to associate with the
connection. Output from the connection is inserted in the buffer,
unless you specify a filter function to handle the output. If
buffer-or-name is nil
, it means that the connection is not
associated with any buffer.
The arguments host and service specify where to connect to; host is the host name (a string), and service is the name of a defined network service (a string) or a port number (an integer).
[Top] | [Contents] | [Index] | [ ? ] |
This document was generated on January 16, 2023 using texi2html 5.0.
The buttons in the navigation panels have the following meaning:
Button | Name | Go to | From 1.2.3 go to |
---|---|---|---|
[ << ] | FastBack | Beginning of this chapter or previous chapter | 1 |
[ < ] | Back | Previous section in reading order | 1.2.2 |
[ Up ] | Up | Up section | 1.2 |
[ > ] | Forward | Next section in reading order | 1.2.4 |
[ >> ] | FastForward | Next chapter | 2 |
[Top] | Top | Cover (top) of document | |
[Contents] | Contents | Table of contents | |
[Index] | Index | Index | |
[ ? ] | About | About (help) |
where the Example assumes that the current position is at Subsubsection One-Two-Three of a document of the following structure:
This document was generated on January 16, 2023 using texi2html 5.0.