home *** CD-ROM | disk | FTP | other *** search
/ Education Sampler 1992 [NeXTSTEP] / Education_1992_Sampler.iso / NeXT / GnuSource / cc-61.0.1 / cc / listing < prev    next >
Text File  |  1990-10-08  |  4KB  |  160 lines
  1. #!/bin/sh -f
  2. # Generate a source code listing for C or C++ code with assembler code. The
  3. # listing is always written to stdout.
  4. # Author: Igor Metz <metz@iam.unibe.ch>
  5.  
  6. # $Author: metz $
  7. # $Log:    lister,v $
  8. # Revision 1.3  89/12/18  13:58:27  metz
  9. # lister must now be configured before it can be used. This is done in the
  10. # /bin/sh part of the code.
  11. # 
  12. # 
  13. # Revision 1.2  89/08/16  17:35:02  metz
  14. # Support for SPARC added.
  15. # 
  16. # Revision 1.1  89/08/16  16:49:22  metz
  17. # Initial revision
  18. # 
  19.  
  20. # Requires: gawk (may be it works also with nawk)
  21.  
  22. # usage:  lister filename [compiler-options]
  23.  
  24. # Method:
  25. # compile the source with -g option to assembler code, then merge the
  26. # generated assembler code with the source code. Compiler options
  27. # can be supplied on the command line (for example -O)
  28.  
  29. # To install lister, assign one of the supported values to the variable MYSYS:
  30. # mc68020  for Motorola 68020 (Sun-3, ..)
  31. # mc68030  for Motorola 68030 (Sun-3, ..)
  32. # sparc    for SPARC (SUN-4, ..)
  33. # i386     for i386 (Sun i386, ...)
  34.  
  35. # uncomment the line you need:
  36. # MYSYS=mc68020
  37. # MYSYS=mc68030
  38. # MYSYS=sparc
  39. # MYSYS=i386
  40. # MYSYS=`mach`  # this will work on Suns with SunOS > 4.0.0
  41.  
  42. exec gawk -vsys=$MYSYS '
  43. # commandline arguments:
  44. #  ARGV[0] = "gawk"
  45. #  ARGV[1] = processid
  46. #  ARGV[2] = filename
  47. #  ARGV[3] .. ARGV[ARGC-1] = compiler options
  48. BEGIN {
  49.   if (ARGC < 3) {
  50.     usage()
  51.     exit 1
  52.   }
  53.  
  54.   # Declaration of global variables
  55.   c_filename = ""
  56.   asm_filename = ""
  57.   cmdline = ""
  58.   asm_code = ""
  59.   c_code = ""
  60.   c_lineno = 0
  61.   oldlineno = 0
  62.   newlineno = 0
  63.   ignore_stabd = 0
  64.   num_of_fields = 0
  65.  
  66.   # check processor architecture and set sourcecode line_hint accordingly
  67.   if (sys == "sparc" || sys == "i386") {
  68.     line_hint = "^[ \t]*\.stabn.*"
  69.   }
  70.   else if (sys == "mc68020" || sys == "mc68030") {
  71.     line_hint = "^[ \t]*\.stabd.*"
  72.   }
  73.   else {
  74.     error("Processor type " sys " is not supported yet, sorry")
  75.   }
  76.  
  77.   parse_cmdline()
  78.  
  79.   printf("compiling %s to asm code\n", c_filename ) > "/dev/stderr"
  80.  
  81.   if (system(cmdline) != 0 ) {
  82.     error("Compilation of " c_filename " failed")
  83.   }
  84.  
  85.   printf("generating listing\n") > "/dev/stderr"
  86.  
  87.  
  88.   while ( getline asm_code < asm_filename > 0 ) {
  89.     if ( (ignore_stabd==0) && (asm_code ~ line_hint)) {
  90.       # source line hint found. Split the line into fields seperated by commas.
  91.       # num_of_fields is 4 for sparc, 3 for m68k
  92.       num_of_fields = split(asm_code, fields, ",")
  93.       newlineno = fields[3] + 0 # the line number we are looking for is field 3
  94.  
  95.       if (newlineno > oldlineno) {
  96.         while ( newlineno > c_lineno ) {
  97.       getline c_code < c_filename
  98.       c_lineno++
  99.       printf("%4d %s\n", c_lineno, c_code)
  100.     }
  101.     oldlineno = newlineno
  102.       }
  103.     }
  104.     else if ( asm_code ~ ".*Ltext[ \t]*$" ) {
  105.       # filename hint found
  106.       if ( match(asm_code, c_filename)) {
  107.         ignore_stabd = 0
  108.       }
  109.       else {
  110.         ignore_stabd = 1
  111.       }
  112.     }
  113.     printf("\t\t\t%s\n", asm_code)
  114.   }
  115.  
  116.   # general cleanup
  117.   system("/bin/rm " asm_filename)
  118. }
  119.  
  120. function usage() {
  121.     printf("usage: %s filename compiler-options\n", argv[0]) > "/dev/stderr"
  122. }
  123.  
  124. function error(s) {
  125.     printf("error: %s\n", s) > "/dev/stderr"
  126.     exit 1
  127. }
  128.  
  129. function parse_cmdline(    i) {
  130.   # construct filenames to use
  131.   asm_filename = "/tmp/lister" ARGV[1] ".s"
  132.   ARGV[1] = ""
  133.   c_filename = ARGV[2]
  134.   ARGV[2] = ""
  135.  
  136.   # construct commandline to use
  137.   if ( match(c_filename, ".C") || match(c_filename, ".cc") ) {
  138.     cmdline = "g++"
  139.   }
  140.   else if (match(c_filename, ".c")) {
  141.     cmdline = "gcc"
  142.   }
  143.   else {
  144.     error("unknown extension for file " c_filename)
  145.   }
  146.  
  147.   cmdline = cmdline " -g -S -o " asm_filename
  148.  
  149.   # now we append the compiler options specified by the user
  150.   for (i = 3; i < ARGC; i++) {
  151.     cmdline = cmdline " " ARGV[i]
  152.     ARGV[i] = "" # we do not want to treat it as an inputfile
  153.   }
  154.  
  155.   # last but not least: the name of the file to compile
  156.   cmdline = cmdline " " c_filename
  157. }
  158.  
  159. ' $$ $*
  160.