home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh5x
/
sh55a.d64
/
allwand_f
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
48 lines
100 REM OLIVER STILLER
110 REM
120 IF L=0 THEN POKE 56,16:CLR:L=1:LOAD "ALLWAND.C000",8,1
130 DIM NA$(144):C3$=CHR$(34)
140 PRINT"AMICA WANDLER V1.0/F"
150 PRINT"DIESES PROGRAMM WANDELT ALLE STANDARD ";
160 PRINT"BILDER AUF EINER DISK IN DAS AMICA PAINT";
170 PRINT"FORMAT UM."
171 PRINT"DIE DISKETTE DARF NUR BILDER ENTHALTEN"
180 PRINT"BITTE DISK EINLEGEN UND TASTE DRUECKEN":WAIT 198,1:GET A$
181 PRINT"BITTE WARTEN..."
190 :
200 FORT=4096+8000TO4096+8999:POKE T,152:NEXT
210 FORT=4096+9000TO4096+9999:POKE T,10:NEXT
220 POKE4096+10000,0
230 :
240 GOSUB 430
250 :
260 IF PO=0 THEN GOTO 180
270 :
280 FOR T=0 TO PO-1
290 PRINT"LADE BILD:";C3$;NA$(T);C3$
300 SYS 49152,8,NA$(T)
310 FORX=4096+8000TO4096+8192:POKE X,152:NEXT
320 PRINT"PACKE BILD ..."
330 SYS 49152+6
340 PRINT"LOESCHE ALTES BILD ..."
350 CLOSE1:OPEN1,8,15,"S:"+NA$(T):CLOSE 1
360 PRINT"SPEICHERE NEUES BILD ..."
370 SYS 49152+3,8,"[B]"+LEFT$(NA$(T)+" ",13)
380 NEXT T
390 END
400 REM
410 REM DIRECTORY ZEIGEN
420 REM
430 CLOSE1:OPEN 1,8,0,"$":GET#1,A$,A$:PO=0
440 PRINT"BILDER DER DISKETTE:"
450 FOR T=0TO7:GET#1,A$,A$,A$,A$:NEXT
460 :
470 GET#1,A$,A$,A$,A$:IF ST THEN 500
480 GET#1,X$:IF X$=C3$ THEN AN$="":GOTO 510
490 IF ST=0 THEN 480
500 CLOSE1:RETURN
510 GET#1,Z$:IF Z$<>C3$ THEN AN$=AN$+Z$:GOTO 510
520 PRINTC3$;AN$;C3$:NA$(PO)=AN$:PO=PO+1
530 GET#1,X$:IF X$<>"" AND ST=0 THEN 530
540 GOTO 470