home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib37b.dsk / TM.LABEL.LIST.bas < prev    next >
BASIC Source File  |  2023-02-26  |  4KB  |  74 lines

  1. 10  REM ********************************
  2. 20  REM * TM.LABEL.LIST                *
  3. 30  REM * BY ALEXANDER LAIRD           *
  4. 40  REM * COPYRIGHT (C) 1989 BY        *
  5. 50  REM * MINDCRAFT PUBLISHING CORP.   *
  6. 60  REM * CONCORD, MA 01742            *
  7. 70  REM ********************************
  8. 80  GOTO 440
  9. 90 :
  10. 100 : REM [ READ NAME & ADDRESS ]
  11. 110  PRINT D$;"OPEN ADDRESSES,L87"
  12. 120  FOR I = 1 TO R
  13. 130  PRINT D$;"READ ADDRESSES,R";I
  14. 140  FOR F = 1 TO 5: INPUT A$(F): NEXT 
  15. 150  IF LL$ = "1"  THEN  GOSUB 230
  16. 160  IF LL$ = "2"  THEN  GOSUB 340
  17. 170  NEXT I
  18. 180  PRINT D$;"CLOSE"
  19. 190  RETURN 
  20. 200 :
  21. 210 :
  22. 220 : REM  PRINT A LABEL
  23. 230  PRINT D$: REM  SUSPENDS DISK OPERATION
  24. 240  PRINT D$;"PR# 1"
  25. 250  PRINT  CHR$(9);"100N";PT$;: REM  PRINTER CONTROLS
  26. 260  PRINT A$(1): PRINT A$(2): PRINT A$(3);", ";A$(4);" ";A$(5)
  27. 270  PRINT : PRINT : REM  SPACE TO NEXT LABEL
  28. 280  PRINT  CHR$(9);"40N"
  29. 290  PRINT D$;"PR#0"
  30. 300  RETURN 
  31. 310 :
  32. 320 :
  33. 330 : REM  PRINT A LINE
  34. 340  PRINT D$: REM  SUSPEND DISK OPERATION
  35. 350  PRINT D$;"PR#1"
  36. 360  PRINT  CHR$(9);"100N";PT$;: REM PRINTER CONTROLS
  37. 370  PRINT  LEFT$(A$(1),25);: POKE 36,26: PRINT  LEFT$(A$(2),25);: POKE 36,52: PRINT  LEFT$(A$(3),25);: POKE 36,76: PRINT  LEFT$(A$(4),2);: POKE 36,82: PRINT  LEFT$(A$(5),5);
  38. 380  PRINT  CHR$(9);"40N"
  39. 390  PRINT D$;"PR#0"
  40. 400  RETURN 
  41. 410 :
  42. 420 :
  43. 430 : REM  [ SETUP ]
  44. 440  HOME 
  45. 450  HTAB 5: PRINT "NIBBLE TINY MAILER LIST/LABELS"
  46. 460  PRINT : PRINT "THIS PROGRAM READS YOUR TINY MAILER": PRINT "ADDRESSES FILE AND PRINTS LABELS OR A": PRINT "FORMATTED LISTING OF THE ADDRESSES."
  47. 470  PRINT : PRINT "FOR PRINTING LABELS, YOU'LL NEED TO USE"
  48. 480  PRINT "ONE-UP PRESSURE SENSITIVE LABELS."
  49. 490  HTAB 1: VTAB 13: PRINT "ENTER:   1= LABELS": PRINT "         2= LIST": PRINT : PRINT "ENTER 1 OR 2:";: GET LL$: PRINT LL$: REM  3,9 SPACES
  50. 500  IF LL$ < >"1"  AND LL$ < >"2"  THEN 490
  51. 510  HTAB 1: VTAB 18: PRINT "PRINTER: 1= IMAGEWRITER": PRINT "         2= EPSON": PRINT "         3= OTHER": PRINT : PRINT "ENTER 1,2, OR 3:";: GET PT$: PRINT PT$: IF PT$ < >"1"  AND PT$ < >"2"  AND PT$ < >"3"  THEN 510: REM  9AND 9 SPACES
  52. 520  IF PT$ = "1"  THEN PT$ =  CHR$(27) + CHR$(69): REM  IMAGEWRITER PRINTER CTRLS FOR 12 CHAR/INCH
  53. 530  IF PT$ = "2"  THEN PT$ =  CHR$(27) + CHR$(77): REM  EPSON PRINTER CTRLS FOR 12 CHAR/INCH
  54. 540  IF PT$ = "3"  THEN PT$ = "": REM  SUBSTITUTE YOUR OWN PRINTER CTRL CODES FOR 12 CHAR/INCH
  55. 550 : REM [ CHECK WHETHER FILE EXISTS ]
  56. 560 D$ =  CHR$(4)
  57. 570  ONERR  GOTO 710
  58. 580  PRINT D$;"VERIFY ADDRESSES"
  59. 590  PRINT D$;"OPEN ADDRESSES,L87"
  60. 600  PRINT D$;"READ ADDRESSES,R0"
  61. 610  INPUT R
  62. 620  PRINT D$;"CLOSE ADDRESSES"
  63. 630  PRINT : PRINT "THERE ARE ";R;" RECORDS IN THE FILE":
  64. 640  IF R = 0  THEN  PRINT "WITH NO RECORDS IN THE FILE, YOU SHOULD": PRINT "CREATE SOME ADDRESS RECORDS BEFORE YOU": PRINT "RUN THIS PROGRAM.": END 
  65. 650  PRINT : PRINT "PRESS RETURN TO BEGIN:";: GET XX$: PRINT XX$
  66. 660  GOSUB 110: REM  READ DISK & PRINT
  67. 670  HOME : VTAB 10: PRINT "<RETURN>= ANOTHER LIST... E= END:";: GET XX$: PRINT XX$: IF XX$ = ""  THEN  HOME : GOTO 490
  68. 680  PRINT : PRINT "END OF JOB": END 
  69. 690 :
  70. 700 : REM NO FILE EXISTS
  71. 710  POKE 216,0: REM  RESET ERROR POINTER
  72. 720  PRINT : PRINT "THE FILE 'ADDRESSES' DOES NOT APPEAR TO": PRINT "BE ON THIS DISK.  SAVE A COPY OF THIS""
  73. 730  PRINT "PROGRAM ON THE DISK THAT CONTAINS THE": PRINT "ADDRESSES FILE, OR CREATE AN ADDRESSES": PRINT "FILE ON THIS DISK USING THE ADDRESS"
  74. 740  PRINT "PROGRAM FROM THE AUG., SEPT., OR OCT.": PRINT "1989 ISSUE OF NIBBLE.": PRINT : PRINT "PROGRAM ENDED."