home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib37b.dsk / TM.ADDRESSES.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  62 lines
  1. 10  REM **************************
  2. 20  REM * TM.ADDRESSES           *
  3. 30  REM * BY ALEXANDER LAIRD     *
  4. 40  REM * COPYRIGHT(C) 1989      *
  5. 50  REM * MINDCRAFT PUBL. CORP.  *
  6. 60  REM * CONCORD, MA 01742      *
  7. 70  REM **************************
  8. 80  PRINT  CHR$(9)"85N": GOTO 370
  9. 90  REM  ENTER NAME & ADDRESS
  10. 100  REM 
  11. 110  FOR F = 1 TO 5:A$(F) = "": NEXT : REM  CLEAR LAST ENTRY
  12. 120  HOME : VTAB 5: PRINT "NAME   : ";D1$: PRINT "STREET : ";D1$: PRINT "CITY   : "D1$: PRINT "STATE  : ";D2$: PRINT "ZIP    : ";D3$
  13. 130  VTAB 12: PRINT "DO NOT USE COMMAS, COLONS, OR": PRINT "QUOTATION MARKS IN YOUR ADDRESS."
  14. 140  VTAB 5:CT = 0: FOR F = 1 TO 5: REM GO BACK TO 1ST LINE & RESET CHAR COUNTER
  15. 150  HTAB 10: INPUT "";F$
  16. 160  IF F$ < >""  THEN A$(F) = F$
  17. 170  VTAB F +4: HTAB 10: CALL  -868: PRINT A$(F):CT = CT + LEN(A$(F)): REM CT= CHARACTER COUNT
  18. 180  NEXT : IF CT >(82 +5)  THEN  VTAB 20: CALL  -968: PRINT "ADDRESS TOTALS MORE THAN 82 CHARACTERS.": PRINT "RE-DO THE ENTRIES TO SHORTEN THEM.": INPUT "<RETURN> TO RE-DO:";XX$: VTAB 20: CALL  -958: GOTO 140
  19. 190  VTAB 20: CALL  -868: INPUT "<RETURN> = ACCEPT... R = RE-ENTER:";XX$: IF XX$ < >""  AND XX$ < >"R"  AND XX$ < >"r"  THEN 190
  20. 200  IF XX$ = "R"  THEN  VTAB 20: CALL  -868: PRINT "PRESS RETURN TO ACCEPT EXISTING DATA": GOTO 140
  21. 210  RETURN 
  22. 220 :
  23. 230 :
  24. 240 : REM  SAVE ADDRESS TO DISK
  25. 250  PRINT D$;"OPEN ADDRESSES,L87"
  26. 260  PRINT D$;"READ ADDRESSES,R0"
  27. 270  INPUT R:R = R +1
  28. 280  PRINT D$;"WRITE ADDRESSES,R";R
  29. 290  FOR F = 1 TO 5: PRINT A$(F): NEXT 
  30. 300  PRINT D$;"WRITE ADDRESSES,R0"
  31. 310  PRINT R
  32. 320  PRINT D$;"CLOSE"
  33. 330  RETURN 
  34. 340 :
  35. 350 :
  36. 360 : REM   SETUP 
  37. 370  HOME : VTAB 5
  38. 380  HTAB 10: PRINT "NIBBLE TINY MAILER"
  39. 390  PRINT : PRINT "THIS PROGRAM LETS YOU ENTER NAMES AND": PRINT "ADDRESSES INTO A RANDOM DISK FILE."
  40. 400  PRINT : PRINT "YOU'LL ENTER:": PRINT : PRINT "  NAME:": PRINT "  STREET:": PRINT "  CITY:": PRINT "  STATE:": PRINT "  ZIP:"
  41. 410  PRINT : PRINT "THEN YOU'LL HAVE THE CHANCE TO RE-ENTER": PRINT "AND CORRECT ANY MISTAKES BEFORE SAVING"
  42. 420  PRINT "THE NAME AND ADDRESS TO THE DISK FILE.": PRINT : PRINT "      (CHECKING THE DISK FILE)"
  43. 430 : REM  CHECK WHETHER FILE EXISTS 
  44. 440 D$ =  CHR$(4):D1$ = ".........................":D2$ = "..":D3$ = ".....": REM D1$=25 DOTS  D2$=2 DOTS  D3$=5 DOTS
  45. 450  ONERR  GOTO 560
  46. 460  PRINT D$;"VERIFY ADDRESSES"
  47. 470  PRINT : INPUT "PRESS RETURN TO BEGIN:";XX$
  48. 480  GOSUB 110: REM  ENTER ADDRESS
  49. 490  GOSUB 250: REM  SAVE ADDRESS
  50. 500  HOME : VTAB 10: INPUT "<RETURN> = ENTER ANOTHER... E = END:";XX$: IF XX$ < >""  AND XX$ < >"E"  AND XX$ < >"e"  THEN 500
  51. 510  IF XX$ = "E"  THEN  PRINT "END OF ADDRESS ENTRY": END 
  52. 520  GOTO 480: REM  ENTER ANOTHER
  53. 530 :
  54. 540 :
  55. 550 : REM  CREATE NEW FILE
  56. 560  POKE 216,0: REM  RESET ERROR POINTER
  57. 570  PRINT : INPUT "PRESS <RETURN> TO CREATE ADDRESSES FILE";XX$
  58. 580  PRINT D$;"OPEN ADDRESSES,L87"
  59. 590  PRINT D$;"WRITE ADDRESSES,R0"
  60. 600  PRINT 0
  61. 610  PRINT D$;"CLOSE"
  62. 620  GOTO 470