home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib32b.dsk
/
WIPEOUTS.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
30 lines
10 REM **********************
20 REM * WIPEOUTS *
30 REM * BY DAVID SIGETICH *
40 REM * COPYRIGHT (C) 1987 *
50 REM * BY MICROSPARC, INC *
60 REM * CONCORD, MA 01742 *
70 REM **********************
80 X = RND(1) *255: IF X <33 OR (X >127 AND X <160) THEN 80
90 FOR I = 1 TO 960: PRINT CHR$(X);: NEXT : GOSUB 120: IF PEEK( -16384) < = 127 THEN POKE -16368,0: GOTO 80
100 POKE -16368,0: TEXT : END
110 REM SCREEN WIPES
120 ZZ% = INT(( RND(1) *10) +1)
130 ON ZZ% GOTO 140,150,160,170,180,240,250,260,270,300: CALL -936: RETURN
140 FOR Z1 = 1 TO 40: POKE 33,Z1: CALL -936: NEXT : POKE 33,40: CALL -936: RETURN
150 FOR Z1 = PEEK(35) TO PEEK(34) +1 STEP -1: HTAB 1: VTAB Z1: CALL -868: FOR Z2 = 1 TO 20: NEXT : NEXT : CALL -936: RETURN
160 POKE 33,1: FOR Z1 = 39 TO 0 STEP -1: POKE 32,Z1: CALL -936: NEXT : POKE 33,40: CALL -936: RETURN
170 FOR Z1 = PEEK(34) +1 TO PEEK(35): HTAB 1: VTAB Z1: CALL -868: FOR Z2 = 1 TO 20: NEXT : NEXT : CALL -936: RETURN
180 Z1 = 0:Z3 = PEEK(34):Z4 = PEEK(35)
190 Z2 = Z1: IF Z2 >11 THEN Z2 = 11
200 POKE 33,15 +(Z1 *2): POKE 32,13 -Z1: POKE 34,11 -Z2: IF Z3 >11 -Z2 THEN POKE 34,Z3
210 POKE 35,12 +Z2 -(Z2 >11): IF PEEK(35) >Z4 THEN POKE 35,Z4
220 CALL -936:Z1 = Z1 +1: IF Z1 >13 THEN TEXT : POKE 34,Z3: POKE 35,Z4: HOME : RETURN
230 GOTO 190
240 Z3 = PEEK(34): FOR Z1 = Z3 +1 TO PEEK(35): INVERSE : VTAB Z1: HTAB 1: PRINT SPC( 40): NORMAL : CALL -998: HTAB 1: PRINT SPC( 40): NEXT : HOME : RETURN
250 Z3 = PEEK(34): FOR Z1 = PEEK(35) TO Z3 +1 STEP -1: INVERSE : VTAB Z1: HTAB 1: PRINT SPC( 40): NORMAL : CALL -998: HTAB 1: PRINT SPC( 40): NEXT : HOME : RETURN
260 VTAB ( PEEK(35)): HTAB 1: FOR Z1 = 1 TO 24: PRINT : FOR Z2 = 1 TO 20: NEXT : NEXT : HOME : RETURN
270 Z3 = PEEK(34):Z4 = PEEK(35): HTAB 1: FOR ZZ = 12 TO 24:Z1 = ZZ: IF Z1 >Z4 THEN Z1 = Z4
280 VTAB Z1: CALL -868: FOR Z2 = 1 TO 10: NEXT : IF 25 -Z1 <Z3 THEN Z1 = Z1 -Z3
290 VTAB 25 -Z1: CALL -868: FOR Z2 = 1 TO 10: NEXT : NEXT : HOME : RETURN
300 POKE 33,1: FOR ZZ = 19 TO 40: POKE 32,ZZ: CALL -936: POKE 32,40 -ZZ: CALL -936: NEXT : POKE 32,0: POKE 33,40: HOME : RETURN