home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib32b.dsk / SHADOW.DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  41 lines
  1. 10  REM  **********************
  2. 20  REM  * SHADOW.DEMO        *
  3. 30  REM  * BY IVER COOPER     *
  4. 40  REM  * COPYRIGHT (C) 1987 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  TEXT : HOME : VTAB 10: PRINT "SHADOW.DEMO BY IVER COOPER": PRINT "COPYRIGHT 1987 BY MICROSPARC, INC.": ONERR  GOTO 340
  9. 90  PRINT  CHR$(4);"BLOAD SHADOW.PLAY"
  10. 100  POKE 1013,76: POKE 1014,0: POKE 1015,112
  11. 110  VTAB 21: PRINT "PRESS RETURN TO CONTINUE";: GET A$: PRINT : HOME 
  12. 120  REM  DEMO
  13. 130  HGR 
  14. 140  HCOLOR= 6: REM  COLOR BLUE
  15. 150  REM  PLOT POINT AND CALL BKGD COLOR ROUTINE
  16. 160  HPLOT 0,0: CALL 62454
  17. 170  REM  SET COLOR TO WHITE2 AND DRAW FIRST HORIZON. WHITE2 MUST BE USED WHEN DRAWING OVER A BLUE (HI BIT SET) BKGD
  18. 180  HCOLOR= 7: HPLOT 0,120 TO 50,80 TO 100,100 TO 150,40 TO 200,70 TO 279,100
  19. 190  REM  SET COLOR TO ORANGE AND RETRACE FIRST HORIZON WITH &HPLOT, THUS CREATING AN ORANGE MOUNTAIN.
  20. 200  HCOLOR= 5: &  HPLOT 0,120 TO 50,80 TO 100,100 TO 150,40 TO 200,70 TO 279,100
  21. 210  REM  SET COLOR TO WHITE2 AND DRAW SECOND (NEARER) MOUNTAIN'S PROFILE
  22. 220  HCOLOR= 7: HPLOT 0,80 TO 35,100 TO 70,110 TO 105,60 TO 140,30 TO 175,20 TO 210,20 TO 245,80 TO 279,100
  23. 230  REM  SET COLOR TO ORANGE AND RETRACE WITH &HPLOT
  24. 240  HCOLOR= 5: &  HPLOT 0,80 TO 35,100 TO 70,110 TO 105,60 TO 140,30 TO 175,20 TO 210,20 TO 245,80 TO 279,100
  25. 250  REM  SET COLOR TO GREEN AND &HPLOT A HORIZONTAL LINE. THIS TIME WE DON'T BOTHER TO DRAW A WHITE BORDER.
  26. 260  HCOLOR= 1: &  HPLOT 0,140 TO 279,140
  27. 270  REM  SET COLOR TO BLACK2 AND &HPLOT ROOF. THEN HPLOT ROOF WITH OVERHANG. SET COLOR TO BLACK1 AND &HPLOT PART OF HOUSE BLOCKING GREEN (HI BIT CLR).
  28. 280  HCOLOR= 4: &  HPLOT 140,120 TO 160,110 TO 180,120: HPLOT 136,122 TO 160,110 TO 184,122: HCOLOR= 0: &  HPLOT 140,140 TO 180,140
  29. 290  REM  NOW DRAW A FLAG FOR FUN
  30. 300  HCOLOR= 4: HPLOT 200,20 TO 200,2 TO 196,2 TO 196,3 TO 200,3 TO 200,4 TO 196,4 TO 196,5 TO 200,5
  31. 310  REM  AND A DOOR IN WHITE1, USING &HPLOT
  32. 320  HCOLOR= 3: &  HPLOT 155,142 TO 165,142
  33. 330  HOME : VTAB 21: PRINT "RETURN TO REPEAT, ESCAPE TO QUIT";: GET Z$: PRINT : ON Z$ < > CHR$(27) GOTO 130: TEXT : HOME : GOTO 410
  34. 340 E =  PEEK(222):EL =  PEEK(218) +256 * PEEK(219): CALL  -3288: POKE 216,0
  35. 350  TEXT : HOME : VTAB 12
  36. 360  IF E = 8  THEN  PRINT "I/O ERROR--CHECK DRIVE DOOR": GOTO 390
  37. 370  IF E = 6  THEN  PRINT "SHADOW.PLAY NOT ON THIS DISK"
  38. 380  IF E < >6  AND E < >8 GOTO 400
  39. 390  PRINT "RETURN TO TRY AGAIN, ESCAPE TO QUIT";: GET Z$: PRINT : ON Z$ =  CHR$(27) GOTO 410: GOTO 80
  40. 400  PRINT "ERROR "E" IN LINE "EL
  41. 410  END