Nibble Magazine/nib32b.dsk/INVESTMENT.CALC.bas

BASIC Source File | 2023-02-26 | 12KB | 213 lines

10  REM ************************
20  REM * INVESTMENT.CALC      *
30  REM * BY E.L. OSHLO        *
40  REM * COPYRIGHT (C) 1987   *
50  REM * BY MICROSPARC, INC.  *
60  REM * CONCORD, MA  01742   *
70  REM ************************
80  ONERR  GOTO 2870
90  DIM CF(40):D$ =  CHR$(4):SL = 1: REM  PRINTER SLOT
100  IF  PEEK(48896) = 76  THEN  PRINT D$"PREFIX/"
110  TEXT : HOME :F$ = "":A$ = ""
120  PRINT "INVESTMENT CALCULATOR": PRINT "BY E.L. OSHLO": PRINT "COPYRIGHT 1987 BY MICROSPARC, INC.": POKE 34,4
130  VTAB 5: PRINT "PROGRAM WILL CALCULATE THE INTERNAL RATEOF RETURN OR NET PRESENT OR FUTURE VALUEOF UP TO 40 CASH FLOWS.   CASH FLOWS MAYHAVE UP TO 7 DIGITS (1234.56 OR 1234567)
140  VTAB 10: PRINT "GET DATA FROM:": PRINT : HTAB 3: INVERSE : PRINT "D";: NORMAL : PRINT "IF FILE ON DISK": PRINT : HTAB 3: INVERSE : PRINT "I";: NORMAL : PRINT "RR CALCULATOR FILE ON DISK"
150  PRINT : HTAB 3: INVERSE : PRINT "K";: NORMAL : PRINT "EYBOARD": PRINT : HTAB 3: INVERSE : PRINT "Q";: NORMAL : PRINT "UIT PROGRAM"
160  VTAB 10: HTAB 16: POKE  -16368,0: GET A$: PRINT A$: IF A$ < >"Q"  THEN 190
170  VTAB 20: CALL  -958: PRINT "ARE YOU SURE? "; CHR$(7);: POKE  -16368,0: GET A$: PRINT A$: IF A$ = "Y"  OR A$ =  CHR$(121)  THEN  POKE 216,0: TEXT : HOME : END
180  GOTO 110
190  IF A$ = "D"  THEN  GOSUB 1940: GOSUB 2170: GOSUB 1190: GOTO 230
200  IF A$ = "I"  THEN  GOSUB 1940: GOSUB 2020: GOSUB 1190: GOTO 230
210  IF A$ = "K"  THEN  GOSUB 1440: GOTO 230
220  PRINT  CHR$(7): GOTO 140
230  VTAB 23: CALL  -958: INVERSE : PRINT "C";: NORMAL : PRINT "HANGE A CASH FLOW   ";: INVERSE : PRINT "P";: NORMAL : PRINT "ROCEED   ";
240  INVERSE : PRINT "Q";: NORMAL : PRINT "UIT ";: POKE  -16368,0: GET A$: IF A$ < >"C"  AND A$ < >"P"  AND A$ < >"Q"  THEN  VTAB 22: PRINT  CHR$(7): GOTO 230
250  IF A$ = "Q"  THEN 580
260  PRINT : IF A$ = "P"  THEN 320
270  VTAB 23: CALL  -958: INPUT "CHANGE WHICH CASH FLOW #? ";I$:I =  VAL(I$): IF I$ < >"Q"  AND ((I <1  AND I$ < >"0")  OR I >39)  THEN  VTAB 22: PRINT  CHR$(7): GOTO 270
280  IF I$ = "Q"  THEN 230
290  IF I >N  THEN N = I: REM  IF I>N THEN ADDING CASH FLOWS
300  IF I$ = "0"  THEN  GOSUB 1650: GOTO 230
310 VT = 8 +I -(13 * INT((I -1)/13)): GOSUB 1580: POKE 34,2: POKE 32,0: GOTO 230
320  HOME
330  IF CF(N) < >0  THEN 350
340 N = N -1: GOTO 330: REM  TEST TO SEE IF CF LIST WAS SHORTENED
350  VTAB 7: HTAB 10: PRINT "CALCULATE:": PRINT : HTAB 10: PRINT "NET ";: INVERSE : PRINT "P";: NORMAL : PRINT "RESENT VALUE"
360  PRINT : HTAB 10: PRINT "NET ";: INVERSE : PRINT "F";: NORMAL : PRINT "UTURE VALUE": PRINT : HTAB 10: INVERSE : PRINT "I";: NORMAL : PRINT "NTERNAL RATE OF RETURN": PRINT : HTAB 10: INVERSE : PRINT "Q";: NORMAL : PRINT "UIT"
370  VTAB 7: HTAB 21: POKE  -16368,0: GET IR$: PRINT IR$: IF IR$ < >"F"  AND IR$ < >"Q"  AND IR$ < >"P"  AND IR$ < >"I"  THEN  PRINT  CHR$(7): GOTO 370
380  HOME : IF IR$ = "Q"  THEN 510
390  IF IR$ = "P"  THEN  PRINT  SPC( 5)"NET PRESENT VALUE CALCULATION"
400  IF IR$ = "F"  THEN  PRINT  SPC( 5)"NET FUTURE VALUE CALCULATION"
410  IF IR$ = "I"  THEN  PRINT  SPC( 3);"INTERNAL RATE OF RETURN CALCULATION": VTAB 9: CALL  -868: PRINT "STANDARD OR MODIFIED IRR? (S/M).......";: POKE  -16368,0: GET SM$: PRINT SM$: IF SM$ < >"S"  AND SM$ < >"M"  THEN  PRINT  CHR$(7): HOME : GOTO 410
420  VTAB 11: CALL  -868: PRINT "END OR MID YEAR DISCOUNTING? (E/M)....";: POKE  -16368,0: GET B$: PRINT B$: IF B$ < >"E"  AND B$ < >"M"  THEN  PRINT  CHR$(7): GOTO 420
430  IF B$ = "E"  THEN D = 0:M = 0
440  IF B$ = "M"  THEN D = .5:M = .5
450  IF N = 1  THEN C$ = "N": GOTO 470
460  VTAB 13: CALL  -868: PRINT "LAST CF IN SAME YR AS THE ONE BEFORE?.";: POKE  -16368,0: GET C$: PRINT C$: IF C$ < >"Y"  AND C$ < >"N"  THEN  PRINT  CHR$(7): GOTO 460
470  IF C$ = "Y"  THEN M = 1
480  IF IR$ < >"I"  THEN  GOSUB 800
490  IF SM$ = "M"  AND IR$ = "I"  THEN  GOSUB 970
500  IF SM$ = "S"  AND IR$ = "I"  THEN  GOSUB 620
510  GOSUB 1190
520  VTAB 22: CALL  -958: VTAB 23: INVERSE : PRINT "R";: NORMAL : PRINT "E-RUN  ";: INVERSE : PRINT "P";: NORMAL : PRINT "RINT  ";
530  INVERSE : PRINT "S";: NORMAL : PRINT "AVE  ";: INVERSE : PRINT "N";: NORMAL : PRINT "EW FILE  ";: INVERSE : PRINT "Q";: NORMAL : PRINT "UIT  ";: POKE  -16368,0: GET A$: PRINT A$
540  IF A$ = "R"  THEN 230
550  IF A$ = "P"  THEN 1760
560  IF A$ = "S"  THEN 2600
570  IF A$ = "N"  THEN  TEXT : RUN
580  IF A$ = "Q"  THEN  VTAB 22: CALL  -958: PRINT : PRINT "ARE YOU SURE? "; CHR$(7);: POKE  -16368,0: GET A$: PRINT A$: IF A$ = "Y"  OR A$ =  CHR$(121)  THEN  POKE 216,0: TEXT : HOME : END
590  GOTO 520
600  VTAB 22: PRINT  CHR$(7): GOTO 520
610  REM  IRR CALCULATION ROUTINE
620 R = 0: REM  CALCULATION USES THE NEWTON-RAPHSON METHOD
630  GOSUB 2830
640 X = CF(0):X1 = 0
650  IF N = 1  THEN 710
660  FOR I = 1 TO (N -1)
670 T = CF(I) * EXP( -(I -D) *R)
680 X = X +T
690 X1 = X1 +( -(I -D) *T)
700  NEXT
710 X = X +(CF(N) * EXP( -(N -M) *R))
720 X1 = X1 -(N -M) *CF(N) * EXP( -(N -M) *R)
730 R1 = R +( -X/X1)
740  IF  ABS(R1 -R) <.00005  THEN 770: REM  CALCULATE TO AN ACCURACY OF .005%
750 R = R1
760  GOTO 640
770 R =  INT(( EXP(R) -1) *10000 +.5)
780  RETURN
790  REM   NPV/NFV CALCULATION
800  IF IR$ = "P"  THEN  VTAB 15: INPUT "NPV DISCOUNT RATE? (%) ";RI$
810  IF IR$ = "F"  THEN  VTAB 15: INPUT "NFV INTEREST RATE? (%) ";RI$
820 IR =  VAL(RI$): VTAB 15: HTAB 24: PRINT IR
830  GOSUB 2830
840 NR = 1 +IR *.01
850 X = CF(0)
860  IF N = 1  THEN 900
870  FOR I = 1 TO (N -1)
880 X = X +CF(I)/(NR ^(I -D))
890  NEXT
900 X = X +CF(N)/(NR ^(N -M))
910  IF IR$ = "F"  THEN X = (X *(NR ^(N -M)))
920  IF  ABS(X) > = 10000  THEN X$ =  STR$( INT(X +.5)): GOTO 510
930 XY =  INT( ABS(X) *100 +.5) *.01:WX =  INT(XY):DX =  INT((XY -WX) *100 +.5)
940 X$ =  STR$(WX) +"." + LEFT$( RIGHT$("0" + STR$(DX),2) +"0",2): IF X <0  THEN X$ = "-" +X$
950  RETURN
960  REM  MODIFIED ROR CALCULATION
970  VTAB 15: INPUT "NEG CF DISCOUNT RATE? (%) ";RI$:NP =  VAL(RI$): VTAB 15: HTAB 27: PRINT NP
980  PRINT : INPUT "POS CF DISCOUNT RATE? (%) ";RI$:PP =  VAL(RI$): VTAB 17: HTAB 27: PRINT PP
990  GOSUB 2830
1000 NR = 1 +NP *.01:PR = 1 +PP *.01
1010 R = 0:X = 0:X1 = 0
1020  IF CF(0) <0  THEN X = CF(0)
1030  IF CF(0) >0  THEN X1 = CF(0)
1040 NX = N
1050  IF C$ = "Y"  THEN NX = NX -1
1060  IF N = 1  THEN 1110
1070  FOR I = 1 TO (N -1)
1080  IF CF(I) <0  THEN X = X +CF(I)/(NR ^(I -D))
1090  IF CF(I) >0  THEN X1 = X1 +CF(I) *PR ^(NX -I +D)
1100  NEXT
1110  IF CF(N) <0  THEN X = X +CF(N)/NR ^(N -M)
1120 MX = 0
1130  IF C$ = "N"  AND B$ = "M"  THEN MX = .5
1140  IF CF(N) >0  THEN X1 = X1 +CF(N) *PR ^(MX)
1150 R = (X1/ -X) ^(1/NX) -1
1160 R =  INT(R *10000 +.5)
1170  RETURN
1180  REM  DISPLAY & PRINTOUT FORMATTER
1190  HOME : IF F$ < >""  THEN  TEXT : HOME : PRINT  SPC( 16 -( LEN(F$) *.5));: INVERSE : PRINT " FILE: "F$" ": NORMAL : POKE 34,2: HOME
1200  IF IR$ < >"I"  THEN L =  LEN( STR$(IR) +X$) *.5
1210  IF IR$ = "P"  THEN  PRINT  SPC( 7 -L)"NET PRESENT VALUE AT "IR"% = $"X$: GOTO 1270
1220  IF IR$ = "F"  THEN  PRINT  SPC( 8 -L)"NET FUTURE VALUE AT "IR"% = $"X$: GOTO 1270
1230  IF S$ < >""  THEN S$ = "": PRINT : PRINT : PRINT : GOTO 1290: REM    SKIP IRR DISPLAY IF DATA FROM DIF FILE IS UNPROCESSED
1240 R$ =  STR$( INT( ABS(R *.01))) +"." + RIGHT$( STR$(R),2): IF R <0  THEN R$ = "-" +R$
1250  IF SM$ = "M"  THEN L =  LEN(R$) *.5: PRINT  SPC( 6 -L)"MODIFIED RATE OF RETURN IS "R$"%": GOTO 1270
1260 L =  LEN(R$) *.5: PRINT  SPC( 6 -L)"INTERNAL RATE OF RETURN IS "R$"%"
1270  PRINT : IF B$ = "E"  THEN  PRINT  SPC( 6)"END OF YEAR DISCOUNT FACTORS"
1280  IF B$ = "M"  THEN  PRINT  SPC( 7)"MID YEAR DISCOUNT FACTORS"
1290 CF = 0
1300  FOR XX = 0 TO N:CF = CF +CF(XX): NEXT XX:CF =  INT(CF *100 +.5) *.01
1310 CL =  LEN( STR$(CF)) *.5
1320  PRINT  SPC( 11 -CL)"CASH FLOWS TOTAL $"CF
1330  PRINT : PRINT "CF0"; SPC( 9 - LEN( STR$(CF(0))));CF(0)" !CF    --$-- !CF    --$--"
1340  FOR I = 1 TO 13
1350 LI =  LEN( STR$(I))
1360 LCF =  LEN( STR$(CF(I)))
1370  PRINT "!"I SPC( 11 -LI -LCF)CF(I);
1380 LCF =  LEN( STR$(CF(I +13)))
1390  PRINT " !"(I +13) SPC( 9 -LCF)CF(I +13);
1400 LCF =  LEN( STR$(CF(I +26)))
1410  PRINT " !"(I +26) SPC( 9 -LCF)CF(I +26)
1420  NEXT : RETURN
1430  REM  KEYBOARD DATA ENTRY
1440  HOME
1450  PRINT  SPC( 2);"ENTER CASH OUTLAYS AS NEGATIVE (-)"
1460  PRINT  SPC( 2);"ENTER CASH RECEIPTS AS POSITIVE (+)"
1470  PRINT  SPC( 5);"INITIAL INVESTMENT IS CF(0)": VTAB 15: PRINT  SPC( 8)"(ENTER Q FOR MAIN MENU)": VTAB 7
1480  INPUT "NUMBER OF CASH FLOWS EXCLUDING CF0? ";NU$:N =  VAL(NU$): IF NU$ = "Q"  THEN 110
1490  IF N <1  OR N >39  THEN  VTAB 14: CALL  -958: PRINT  CHR$(7)"NUMBER OF CASH FLOWS MUST BE": PRINT "BETWEEN 1 AND 39 EXCLUDING CF0": PRINT : PRINT "PRESS RETURN TO CONTINUE": GOSUB 2840: GOTO 1440
1500  GOSUB 1690
1510  GOSUB 1650
1520  PRINT : VTAB 23: PRINT " PRESS " CHR$(34)"S" CHR$(34)" FOR SAME AS PRIOR CASH FLOW"
1530  FOR I = 1 TO N
1540 VT = 8 +I -(13 * INT((I -1)/13)): GOSUB 1580
1550  NEXT : POKE 34,2: POKE 32,0
1560  RETURN
1570  REM  CASH FLOW ENTRY & EDIT
1580  POKE 33,9: POKE 34,VT -1: POKE 35,VT
1590  POKE 32,(4 +13 *( INT((I -1)/13))): GOTO 1600
1600  HOME : INPUT "";CF$: IF CF$ < >"S"  THEN CF(I) =  VAL(CF$): IF  LEN( STR$( ABS(CF(I)))) >7  THEN  PRINT  CHR$(7): GOTO 1600
1610  IF CF$ = "S"  THEN CF(I) = CF(I -1)
1620  HOME : POKE 33,40: POKE 35,24: PRINT  SPC( 8 - LEN( STR$(CF(I))))CF(I)
1630  RETURN
1640  REM  CF(0) ENTRY & EDIT
1650  POKE 33,9: POKE 32,4: POKE 34,7: POKE 35,8: HOME : INPUT "";CF$:CF(0) =  VAL(CF$): IF  LEN( STR$( ABS(CF(0)))) >7  THEN  PRINT  CHR$(7): GOTO 1510
1660  IF CF(0) >0  THEN  PRINT  CHR$(7);: GOTO 1650
1670  HOME : POKE 32,0: POKE 33,40: POKE 34,2: POKE 35,24: PRINT  SPC( 8 - LEN( STR$(CF(0))))CF(0): RETURN
1680  REM  DATA ENTRY FORM
1690  VTAB 8: CALL  -958: PRINT "CF0" SPC( 9)" !CF    --$-- !CF    --$--"
1700  FOR I = 1 TO 13
1710 LI =  LEN( STR$(I))
1720  PRINT "!"I SPC( 12 -LI)"!"(I +13) SPC( 10)"!"(I +26) SPC( 11)
1730  NEXT
1740  RETURN
1750  REM  PRINTER ROUTINE
1760  VTAB 23: CALL  -958: PRINT "WANT A TITLE? ";: POKE  -16368,0: GET A$: IF A$ < >"Y"  AND A$ < >"N"  THEN  PRINT  CHR$(7): GOTO 1760
1770  PRINT A$: IF A$ = "N"  THEN TI$ = "": GOTO 1800
1780  POKE 34,22: VTAB 23: CALL  -958: INPUT "TITLE: ";TI$: VTAB 22: CALL  -958: POKE 34,2
1790 TI =  LEN(TI$) *.5: IF TI >20  THEN TI = 20
1800  PRINT D$;"PR#"SL
1810  PRINT  CHR$(9);"80N"
1820  IF TI$ = ""  THEN TI$ = "INTERNAL RATE OF RETURN CALCULATOR":TI = 17
1830  PRINT : PRINT  SPC( 20 -TI)TI$
1840  PRINT
1850  GOSUB 1200
1860  IF SM$ = "M"  AND IR$ = "I"  THEN  PRINT : PRINT "MODIFIED RATE OF RETURN DISCOUNT FACTORS:": PRINT "NEGATIVE CASH FLOWS: ";NP;"%": PRINT "POSITIVE CASH FLOWS: ";PP;"%"
1870  PRINT : PRINT
1880  IF C$ = "Y"  THEN  PRINT "CASH FLOW ";N;" IS AT END OF PERIOD ";(N -1): GOTO 1910
1890  PRINT "CASH FLOW ";N;" IS IN PERIOD ";N
1900  IF F$ < >""  THEN  PRINT : PRINT "FILE NAME: "F$
1910  FOR I = 1 TO 6: PRINT : NEXT
1920  PRINT D$"PR#0": GOTO 520
1930  REM  INPUT FILE NAME AND DRIVE
1940  VTAB 19: CALL  -958
1950  VTAB 23: PRINT  SPC( 10)"(?=CATALOG, Q=QUIT)"
1960  VTAB 20: INPUT "FILE NAME? ";F$: IF F$ = "Q"  THEN  POP : GOTO 110
1970  VTAB 22: CALL  -958: INPUT "DRIVE NO.: ";ND$: IF ND$ = "Q"  THEN  POP : GOTO 110
1980 ND =  VAL( RIGHT$(ND$,1)): IF ND <1  OR ND >2  THEN  PRINT  CHR$(7): GOTO 1970
1990  IF F$ = "?"  THEN  HOME : PRINT D$ LEFT$("CATALOG",7 -4 *( PEEK(48896) = 76))",D"ND: GOSUB 2840: POP : GOTO 110
2000  RETURN
2010  REM   READ IRR CALCULATOR FILE
2020  PRINT D$"VERIFY"F$",D"ND:DD = 0
2030  PRINT D$"OPEN"F$
2040  PRINT D$"READ"F$
2050  INPUT TE$: IF TE$ = "IRR"  THEN 2080
2060  VTAB 21: CALL  -868: PRINT  CHR$(7)F$" IS NOT AN IRR CALCULATOR FILE"
2070  PRINT D$"CLOSE": GOTO 1960
2080  INPUT N
2090  FOR I = 0 TO N: INPUT CF(I): NEXT
2100  INPUT IR$: REM  IS STORED DATA FOR IRR OR NPV
2110  IF IR$ = "I"  THEN  INPUT R: INPUT SM$: GOTO 2130
3857 <CTRL-C>
0