home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib27b.dsk
/
SCRIBE.UTILITY.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
5KB
|
98 lines
10 REM ***********************
20 REM * SCRIBE.UTILITY *
30 REM * BY *
40 REM * TERRY M. SCHWARTZ *
50 REM * COPYRIGHT (C) 1986 *
60 REM * BY MICROSPARC, INC *
70 REM * CONCORD, MA 01742 *
80 REM ***********************
90 GOSUB 730: REM INITIALIZE
100 TEXT : HOME : HTAB 11: PRINT "** SCRIBE.UTILITY **": PRINT : HTAB 11: PRINT "BY TERRY M SCHWARTZ"
110 VTAB 22: PRINT "** COPYRIGHT 1986 BY MICROSPARC, INC. **"
120 VTAB 12: HTAB 3: PRINT "PLEASE BE SURE PRINTER IS TURNED ON.": PRINT : HTAB 14: PRINT "PRESS <RETURN> ";: GET RM$
130 HOME : HTAB 8: PRINT "PLEASE SELECT A FUNCTION:": PRINT
140 PRINT "<Q>-QUIT"
150 PRINT "<A>-PRINT DRAFT MODE"
160 PRINT "<B>-PRINT LETTER MODE"
170 PRINT "<C>-PRINT PICA TYPEFACE"
180 PRINT "<D>-PRINT ULTRA-CONDENSED TYPEFACE"
190 PRINT "<E>-PRINT LOW DENSITY"
200 PRINT "<F>-PRINT NORMAL DENSITY"
210 PRINT "<G>-PRINT SLASHED ZEROS"
220 PRINT "<H>-BEGIN HEADLINE MODE"
230 PRINT "<I>-LEAVE HEADLINE MODE"
240 PRINT "<J>-BEGIN UNDERLINE MODE"
250 PRINT "<K>-LEAVE UNDERLINE MODE"
260 PRINT "<L>-BEGIN SUPERSCRIPT MODE"
270 PRINT "<M>-BEGIN SUBSCRIPT MODE"
280 PRINT "<N>-LEAVE SUPER/SUBSCRIPT MODE"
290 PRINT "<O>-BEGIN FEEDINF SIX LINES PER INCH"
300 PRINT "<P>-BEGIN FEEDING EIGHT LINES PER INCH"
310 PRINT "<R>-BEGIN FEEDING DOUBLE SPACE"
320 PRINT "<S>-CANCEL ALL INSTRUCTIONS (RESET)"
330 PRINT "<T>-CHANGE LEFT MARGIN"
340 HTAB 5: VTAB 24: PRINT "SELECTION";: VTAB 24: HTAB 2: GET PS$: PRINT PS$
350 IF ASC(PS$) <65 OR ASC(PS$) >84 THEN PRINT CHR$(7): GOTO 130: REM ASSURE ONLY LETTERS A-T ARE ACCEPTED
360 IF PS$ = "Q" THEN POKE 216,0: HOME : END : REM CLEAR ONERR FLAG AND QUIT
370 IF PS$ = "T" THEN 610
380 PRINT D$ +X$: REM TURN PRINTER CARD ON
390 IF PS$ = "A" THEN PRINT A$
400 IF PS$ = "B" THEN PRINT B$
410 IF PS$ = "C" THEN PRINT C$
420 IF PS$ = "D" THEN PRINT DD$
430 IF PS$ = "E" THEN PRINT E$
440 IF PS$ = "F" THEN PRINT F$
450 IF PS$ = "G" THEN PRINT G$
460 IF PS$ = "H" THEN PRINT H$
470 IF PS$ = "I" THEN PRINT I$
480 IF PS$ = "J" THEN PRINT J$
490 IF PS$ = "K" THEN PRINT K$
500 IF PS$ = "L" THEN PRINT L$
510 IF PS$ = "M" THEN PRINT M$
520 IF PS$ = "N" THEN PRINT N$
530 IF PS$ = "O" THEN PRINT O$
540 IF PS$ = "P" THEN PRINT P$
550 IF PS$ = "R" THEN PRINT R$
560 IF PS$ = "S" THEN PRINT S$
570 PRINT D$ +Z$: GOTO 130: REM TURN PRINTER CARD OFF. OUTPUT TO SCREEN AGAIN
580 REM
590 REM SET LEFT MARGIN
600 REM
610 HOME
620 VTAB 20: PRINT "(PLEASE PRESS <RETURN> AFTER ENTRY)"
630 VTAB 10: PRINT "HOW MANY SPACES FROM THE LEFT DO YOU"
640 PRINT "WANT TO BEGIN PRINTING? ";: INPUT "(000-095) ";LM$
650 IF LM$ <"000" OR LM$ >"095" THEN 680
660 IF LEN(LM$) < >3 THEN 680
670 PRINT D$ +X$: PRINT CHR$(27) + CHR$(76) +LM$: PRINT D$ +Z$: GOTO 130
680 PRINT CHR$(7)
690 VTAB 12: PRINT " ": VTAB 15: PRINT "YOU MUST ENTER 3 NOS. FROM 000 TO 095": GOTO 620: REM 15 SPACES
700 REM **************
710 REM * INITIALIZE *
720 REM **************
730 ONERR GOTO 960
740 A$ = CHR$(27) + CHR$(77): REM SELECT DRAFT MODE
750 B$ = CHR$(27) + CHR$(109): REM SELECT LETTER MODE
760 C$ = CHR$(27) + CHR$(78): REM PICA FACE
770 D$ = CHR$(4): REM CONTROL D
780 DD$ = CHR$(27) + CHR$(81): REM ULTRA-CONDENSED FACE
790 E$ = CHR$(27) + CHR$(68) + CHR$(0) + CHR$(8): REM PRINT LOW DENSITY
800 F$ = CHR$(27) + CHR$(90) + CHR$(0) + CHR$(8): REM PRINT NORMAL DENSITY
810 G$ = CHR$(27) + CHR$(68) + CHR$(0) + CHR$(1) + CHR$(27) + CHR$(90) + CHR$(128) + CHR$(0): REM SLASHED ZEROS
820 H$ = CHR$(14): REM BEGIN HEADLINE MODE
830 I$ = CHR$(15): REM LEAVE HEADLINE MODE
840 J$ = CHR$(27) + CHR$(88): REM BEGIN UNDERLINE MODE
850 K$ = CHR$(27) + CHR$(89): REM LEAVE UNDERLINE MODE
860 L$ = CHR$(27) + CHR$(120): REM BEGIN SUPERSCRIPT MODE
870 M$ = CHR$(27) + CHR$(121): REM BEGIN SUBSCRIPT MODE
880 N$ = CHR$(27) + CHR$(122): REM LEAVE SUPER/SUBSCRIPT MODE
890 O$ = CHR$(27) + CHR$(65): REM BEGIN FEEDING 6 LINES/INCH
900 P$ = CHR$(27) + CHR$(84) +"18": REM BEGIN FEEDING 8 LINES/INCH
910 R$ = CHR$(27) + CHR$(84) +"48": REM BEGIN DOUBLE SPACE
920 S$ = CHR$(27) + CHR$(99): REM RESTORE STANDARD INSTRUCTIONS
930 X$ = "PR#1": REM CHANGE THIS IF YOUR CARD IS NOT IN SLOT 1
940 Z$ = "PR#0": REM CHANGE THIS IF "PR#3" IF YOU OPERATE FROM 80 COLS.
950 RETURN
960 PRINT CHR$(4);"PR#0": PRINT CHR$(7): HOME : REM CHANGE TO "PR#3" IF YOU OPERATE FROM 80 COLS.
970 IF PEEK(222) = 254 THEN PRINT "INPUT ERROR.....PLEASE REENTER DATA.": PRINT : PRINT "PRESS <RETURN> ";: GET ANS$: HOME : GOTO 690
980 IF PEEK(22) < >254 THEN PRINT "UNDEFINED ERROR....": PRINT : PRINT "PRESS <RETURN> ";: GET ANS$: GOTO 130