home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib27b.dsk / DOUBLE.GEN.DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  90 lines
  1. 10  REM  **********************
  2. 20  REM  *  DOUBLE.GEN.DEMO   *
  3. 30  REM  * BY KENNETH ONO     *
  4. 40  REM  * COPYRIGHT (C) 1986 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  REM  INITIALIZE
  9. 90  HIMEM: 35072: REM  $8900
  10. 100  GOSUB 710: REM  READ IN GRAPH DATA
  11. 110 D$ =  CHR$(4)
  12. 120  PRINT D$;"BLOAD CHAR.NORMAL,A$9300"
  13. 130  PRINT D$;"BLOAD CHAR.GRAPHER,A$8D00"
  14. 140  PRINT D$;"BLOAD DOUBLE.GEN,A$9000"
  15. 150  IF  PEEK(48896) = 76  THEN  GOSUB 750
  16. 160  PRINT D$;"PR#3": PRINT 
  17. 170  CALL 36994: REM  TURN ON GENERATOR
  18. 180  PRINT "   Dear Mike,"
  19. 190  PRINT : PRINT "       Our sales have increased much more then we anticipated.  Here is a       graph showing our sales for 1985."
  20. 200  PRINT : PRINT "                Kenn"
  21. 210  PRINT : PRINT : PRINT "Press the space bar to continue..."
  22. 220  GET YN$: IF YN$ < >" "  THEN 220
  23. 230  CALL 37062: REM  CLEAR GRAPHICS SCREEN
  24. 240  POKE  -16302,0: REM  FULL SCREEN GRAPHICS
  25. 250  HOME 
  26. 260  POKE 36908,141: REM  141=$8D - USE GRAPHER
  27. 270  FOR J = 1 TO 12
  28. 280 XC = J *4 +8
  29. 290  GOSUB 610
  30. 300  VTAB 22: PRINT : POKE 1403,XC -1
  31. 310  POKE 36908,147: REM  147=$93 - USE NORMAL SET
  32. 320  PRINT MN$(J)
  33. 330  POKE 36908,141: REM  141=$8D - USE GRAPHER SET
  34. 340  NEXT J
  35. 350  POKE 36908,147: REM  USE NORMAL SET
  36. 360  VTAB 3: PRINT 
  37. 370  POKE 33,1
  38. 380  PRINT "SALES FOR 1985"
  39. 390  POKE 33,38: POKE 32,4
  40. 400  VTAB 4: PRINT 
  41. 410  FOR J = 9 TO 1  STEP  -1
  42. 420  PRINT J *10
  43. 430  PRINT 
  44. 440  NEXT J
  45. 450  POKE 36908,141: REM  141=$8D - USE GRAPHER
  46. 460  POKE 33,2: POKE 32,6
  47. 470  VTAB 1: PRINT 
  48. 480  FOR I = 1 TO 20
  49. 490  VTAB I
  50. 500  PRINT "IN"
  51. 510  NEXT I
  52. 520  POKE 33,72: POKE 32,7
  53. 530  VTAB 21: PRINT 
  54. 540  FOR Z = 1 TO 56: PRINT "J";: NEXT : PRINT 
  55. 550  POKE 36908,147: REM  147=$93 - USE NORMAL SET
  56. 560  VTAB 1
  57. 570  POKE 33,40: POKE 32,0
  58. 580  PRINT "                                 SALES": REM  33 SPACES
  59. 590  POKE  -16368,0: GET Z$: PRINT : CALL 37093: TEXT : PRINT  CHR$(21): HOME : END 
  60. 600  REM  DRAW GRAPH
  61. 610 Y = 20:YC = YC(J)
  62. 620  POKE 1403,XC
  63. 630  POKE 1531,Y
  64. 640  PRINT  CHR$(225): REM  LOWER-CASE A
  65. 650 Y = Y -1:YC = YC -8
  66. 660  IF YC >7  THEN 620
  67. 670  IF YC = 0  THEN  RETURN 
  68. 680  POKE 1403,XC: POKE 1531,Y
  69. 690  PRINT  CHR$(104 -YC)
  70. 700  RETURN 
  71. 710  REM  READ IN GRAPH DATA
  72. 720  DIM MN$(12),YC(12)
  73. 730  FOR I = 1 TO 12: READ MN$(I),YC(I): NEXT 
  74. 740  RETURN 
  75. 750  REM  POKE IN PRODOS PATCH
  76. 760  READ AD: FOR I = AD TO AD +8: READ X: POKE I,X: NEXT 
  77. 770  RETURN 
  78. 780  DATA  "JAN",10
  79. 790  DATA  "FEB",13
  80. 800  DATA  "MAR",23
  81. 810  DATA  "APR",18
  82. 820  DATA  "MAY",40
  83. 830  DATA  "JUN",65
  84. 840  DATA  "JUL",110
  85. 850  DATA  "AUG",99
  86. 860  DATA  "SEP",134
  87. 870  DATA  "OCT",150
  88. 880  DATA  "NOV",155
  89. 890  DATA  "DEC",159
  90. 900  DATA  37005,141,49,190,169,0,141,48,190,234