home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib22b.dsk / PRINTLOG.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  64 lines
  1. 10  REM  **********************
  2. 20  REM  *      PRINTLOG      *
  3. 30  REM  *  BY VICTOR FRICKE  *
  4. 40  REM  * COPYRIGHT (C) 1984 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA. 01742 *
  7. 70  REM  **********************
  8. 80  REM  PRINT HARD COPY OF CONSULTING LOG
  9. 90 D$ =  CHR$(4)
  10. 100  HOME : PRINT "PRINTING WORK LOG - PLEASE MAKE SURE"
  11. 110  PRINT "PRINTER IS TURNED ON."
  12. 120  REM  RETRIEVE NUMBER OF RECORDS
  13. 130  REM  # OF RECS = POINTER-1
  14. 140  PRINT D$;"OPEN LOG,L58"
  15. 150  PRINT D$;"READ LOG,R0"
  16. 160  INPUT R$
  17. 170 R =  VAL(R$) -1
  18. 180  PRINT D$;"CLOSE LOG"
  19. 190  REM  PREPARE PRINTER
  20. 200  PRINT D$;"PR#1": REM  CHANGE SLOT NUMBER IF NECESSARY
  21. 210 LN = 0: REM  COUNTS LINES PRINTED ON PAGE
  22. 220  GOSUB 450: REM  PRINT PAGE HEADING
  23. 230  PRINT D$;"PR#0": REM  DESELECT PRINTER
  24. 240  FOR I = 1 TO R
  25. 250  PRINT D$;"OPEN LOG,L58"
  26. 260  PRINT D$;"READ LOG,R";I
  27. 270  INPUT REC$
  28. 280  PRINT D$;"CLOSE LOG"
  29. 290  PRINT D$;"PR#1"
  30. 300  GOSUB 530: REM  PRINT RECORD
  31. 310  PRINT D$;"PR#0"
  32. 330  IF LN <60  THEN 390
  33. 340  REM  NEW PAGE
  34. 350  PRINT D$;"PR#1"
  35. 360  PRINT  CHR$(12): REM  FORM FEED
  36. 365 LN = 0
  37. 370  GOSUB 450: REM  PRINT NEW PAGE HEADING
  38. 380  PRINT D$;"PR#0"
  39. 390  NEXT I
  40. 400  PRINT D$;"PR#1"
  41. 410  PRINT  CHR$(12)
  42. 420  PRINT D$;"PR#0"
  43. 430  HOME 
  44. 440  END 
  45. 450  REM  PRINT PAGE HEADINGS
  46. 460  PRINT : PRINT 
  47. 470  PRINT  TAB( 65);"TIME SPENT"
  48. 480  PRINT  SPC( 5);"DATE"; SPC( 4);"START TIME"; SPC( 5);"ACTIVITY DESCRIPTION"; SPC( 18);"HRS MIN"
  49. 490  PRINT  SPC( 5);: FOR J = 1 TO 68: PRINT "=";: NEXT : PRINT 
  50. 500  PRINT 
  51. 510 LN = LN +6
  52. 520  RETURN 
  53. 530  REM  PRINT A RECORD
  54. 540 MM$ =  LEFT$(REC$,4): REM  MONTH
  55. 550 DD$ =  MID$ (REC$,5,3): REM  DAY
  56. 560 HH$ =  MID$ (REC$,8,3): REM  HOUR
  57. 570 MIN$ =  MID$ (REC$,11,2): REM  MINUTE
  58. 580 PM$ =  MID$ (REC$,13,2): REM  AM/PM
  59. 590 DSCR$ =  MID$ (REC$,15,39): REM  DESCRIPTION
  60. 600 EH$ =  MID$ (REC$,54,2): REM  ELAPSED HOURS
  61. 610 EM$ =  MID$ (REC$,56,2): REM  ELAPSED MINUTES
  62. 620  PRINT  SPC( 5);MM$;DD$;"  ";HH$;":";MIN$;" ";PM$;"  ";DSCR$;"  ";EH$;"  ";EM$
  63. 630 LN = LN +1
  64. 640  RETURN