home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magic Disk 64
/
Magic_Disk_64_92-10_1992_-_de_Side_A.d64
/
fk.namechange
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
906b
|
47 lines
10 print"[147] disknamen und -id aendern "
20 print"moechten sie:"
30 print"-------------"
40 print"(n)amen der diskette aendern"
50 print"(i)d und formatkennung aendern"
60 print"(p)rogramm beenden"
70 getx$:ifx$=""then70
80 if x$="n" then gosub200:run
90 if x$="i" then gosub400:run
100 if x$="p" then end
110 goto70
120 :
130 :
200 open1,8,15,"i":open2,8,2,"#"
210 print#1,"u1 2 0 18 0"
220 print#1,"b-p 2 144"
230 na$=""
240 for i=1 to 16
250 get#2,a$:na$=na$+a$
260 next
270 print"aktueller name: ";na$
280 input " neuer name";na$
285 if len(na$)>16 then na$=left$(na$,16)
290 if len(na$)<16 then na$=na$+chr$(160):goto290
300 print#1,"b-p 2 144"
310 print#2,na$;
320 print#1,"u2 2 0 18 0"
330 print#1,"i"
340 close1:close2:return
350 :
360 :
400 open1,8,15,"i":open2,8,2,"#"
410 print#1,"u1 2 0 18 0"
420 print#1,"b-p 2 162"
430 id$=""
440 for i=1 to 16
450 get#2,a$:id$=id$+a$
460 next
470 print"aktuelle id:";id$
480 input " neue id";id$
490 if len(id$)>5 then id$=left$(id$,5)
500 print#1,"b-p 2 162"
510 print#2,id$;
520 print#1,"u2 2 0 18 0"
530 print#1,"i"
540 close1:close2:return