home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magic Disk 64
/
Magic_Disk_64_89-02_1989_-_de_Side_B.d64
/
cia-uhr
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
863b
|
31 lines
10 rem stellen der uhr
20 c=56328:rem basisadresse der cia-uhr
30 pokec+7,peek(c+7)and127:rem uhrzeit setzen
40 pokec+6,peek(c+6)or128:rem f=50 hz
50 input"[147]zeit (hhmmss)";ti$
60 h=val(left$(ti$,2))
70 ifh>11thenh=h+68:rem pm-flag
80 pokec+3,16*int(h/10)+h-int(h/10)*10
90 m=val(mid$(ti$,3,2))
100 pokec+2,16*int(m/10)+m-int(m/10)*10
110 s=val(right$(ti$,2))
120 pokec+1,16*int(s/10)+s-int(s/10)*10
130 pokec,0:rem zehntelsekunden auf 0 setzen und uhr starten
140 :
150 :
160 rem uhr auslesen
170 data 173,8,220,173,9,220,141,82,3,173,10,220,141,83,3,173,11,220,141
180 data84,3,96:rem maschinenprogramm
190 fori=49152to49173:reada:pokei,a:next
200 c=850:poke53281,0:poke53280,0:print"[147]"
210 sys49152:h=peek(c+2):m=peek(c+1):s=peek(c):rem uhr auslesen
220 f$="am":if(hand128)thenh=hand127:f$="pm"
230 print"";:a=h:gosub270:print":";:a=m:gosub270:print":";:a=s:gosub270
240 print" ";f$:goto210
250 :
260 :
270 rem ausgabe von a in hexadezimal
280 a$=str$(int(a/16)):printright$(a$,1);
290 a=a-16*val(a$):a$=str$(a):printright$(a$,1);
300 return