home *** CD-ROM | disk | FTP | other *** search
/ Pokey's Magazine 11 & 12 / Pokeys_Magazine_11__12_1991_08___nl_Side_B.atr / scrol3.src < prev    next >
Text File  |  2023-02-26  |  2KB  |  127 lines
  1. * IDEM ALS SCROL2.SRC, MAAR NU MET
  2. * EIGEN DISPLAY LIST
  3. * EN EEN BEKEND GEINTJE IN DE
  4. * HOOFDLUS
  5.  
  6. SCREEN    EQU $BC40
  7. HSCROL    EQU $D404
  8. SETVBV    EQU $E45C
  9. SYSVBV    EQU $E45F
  10. DLST    EQU $230
  11.  
  12. RTCLOK    EQU $14
  13. TEXTADR    EQU $CB
  14. ZP    EQU $CB
  15.  
  16.     ORG $A800
  17.  
  18. * INTIALISEER DISPLAY LIST
  19.  
  20.     LDA #DL:L
  21.     STA DLST
  22.     LDA #DL:H
  23.     STA DLST+1
  24.  
  25. * BEGIN VAN TEXT IN (TEXTADR)
  26.  
  27.     LDA #TEXT:L
  28.     STA TEXTADR
  29.     LDA #TEXT:H
  30.     STA TEXTADR+1
  31.  
  32. * VERTICAL BLANK INTERRUPT INIT
  33.  
  34.     LDA #6
  35.     LDY #VBI:L
  36.     LDX #VBI:H
  37.     JSR SETVBV
  38.  
  39. * NOG EEN KLEURTJE
  40.  
  41.     LDA #15        FELLE
  42.     STA 709        LETTERS
  43.  
  44. * GEINTJE IN HOODLUS
  45.  
  46. MAIN    LDA $D40B    LINE COUNT
  47.     ASL        ;*2
  48.     AND #%11110000
  49.     STA $D40A    WSYNC
  50.     STA $D018    ALS 710
  51.     ORA #%00001000
  52.     STA $D01A    ALS 712
  53.     JMP MAIN
  54.  
  55. * VERTICAL BLANK INTERRUPT:
  56. * COPIEER 40 BYTES VAN (TEXTADR)
  57. * TOT (TEXTADR)+40 NAAR $BC40
  58. * EN VERHOOG (TEXTADR)
  59. * OM DE TEXT NIET TE SNEL TE LATEN
  60. * GAAN (DEZE INTERRUPT WORDT 50
  61. * KEER PER SECONDE AANGEROEPEN)
  62. * WORDT ER MAAR TIJDENS 1 VAN DE 4
  63. * INTERRUPTS DAADWERKELIJK IETS
  64. * OP HET SCHERM GEKOPIEERD.
  65.  
  66. VBI    LDA RTCLOK    VAN 0-$FF
  67.     AND #%00000011    VAN 0-3
  68.     EOR #%00000011    VAN 3-0
  69.     STA HSCROL
  70.     CMP #3
  71.     BNE EXIT
  72.  
  73. * COPY TEXT NAAR SCREEN
  74.  
  75.     LDY #39+4
  76. COPTXT    LDA (TEXTADR),Y
  77.     STA SCREEN,Y
  78.     DEY
  79.     BPL COPTXT
  80.  
  81.     INC TEXTADR
  82.     BNE EXIT
  83.     INC TEXTADR+1
  84.  
  85. EXIT    JMP SYSVBV
  86.  
  87. * EN DE TEKST NATUURLIJK!
  88. * DEZE MOET NATUURLIJK NIET IN ASCII
  89. * MAAR IN INTERNE CODE GEASSEMBLEERD
  90. * WORDEN!
  91.  
  92. TEXT    ASC %                    %
  93.     ASC %                    %
  94.     ASC %EN ZIEDAAR, DE PROG%
  95.     ASC %RAMMEUR HAD DE EERSTE%
  96.     ASC % VAN VELE SCHERM %
  97.     ASC %ROLLERS GEMAAKT! %
  98.     ASC %HET SPREEKT VOOR ZICH%
  99.     ASC % DAT HIJ ER HEEL %
  100.     ASC %TROTS OP WAS EN %
  101.     ASC %BLA BLA BLA....  %
  102.  
  103. * EN NU ZELFS MET EEN EIGEN DISPLAY
  104. * LIST!!
  105.  
  106. DL    DFB 112,112,112,112,112,112
  107.     DFB 112,112,112,112,112
  108. * DAT WAREN ELF * 8 LEGE SCANLINES
  109.  
  110.     DFB 2+16+64
  111.     DFW SCREEN
  112. * GR. 0 REGEL+HARDWAREMATIGE SCROL+!!
  113. * EEN LMS!! WAT STAAT VOOR LOAD MEMORY
  114. * SCAN. KLINKT MOEILIJK, IS HET NIET:
  115. * DE COMPUTER MOET WETEN WAAR HIJ DE
  116. * DATA VOOR DE REGEL VANDAAN MOET
  117. * HALEN. JE RAAD HET AL, DE VOLGENDE
  118. * TWEE BYTES UIT DE DISPLAY LIST ZIJN
  119. * HET LO EN HET HI BYTE VAN DAT ADRES.
  120.     DFB 112,112,112,112,112,112
  121.     DFB 2+64+16
  122.     DFW SCREEN
  123.  
  124.     DFB 65
  125.     DFW DL
  126. * VERPLICHT AAN EINDE. (DOE MAAR ES
  127. * NIET, KUN JE LACHEN)¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯