home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Pokey's Magazine 11 & 12
/
Pokeys_Magazine_11__12_1991_08___nl_Side_B.atr
/
scrol3.src
< prev
next >
Wrap
Text File
|
2023-02-26
|
2KB
|
127 lines
* IDEM ALS SCROL2.SRC, MAAR NU MET
* EIGEN DISPLAY LIST
* EN EEN BEKEND GEINTJE IN DE
* HOOFDLUS
SCREEN EQU $BC40
HSCROL EQU $D404
SETVBV EQU $E45C
SYSVBV EQU $E45F
DLST EQU $230
RTCLOK EQU $14
TEXTADR EQU $CB
ZP EQU $CB
ORG $A800
* INTIALISEER DISPLAY LIST
LDA #DL:L
STA DLST
LDA #DL:H
STA DLST+1
* BEGIN VAN TEXT IN (TEXTADR)
LDA #TEXT:L
STA TEXTADR
LDA #TEXT:H
STA TEXTADR+1
* VERTICAL BLANK INTERRUPT INIT
LDA #6
LDY #VBI:L
LDX #VBI:H
JSR SETVBV
* NOG EEN KLEURTJE
LDA #15 FELLE
STA 709 LETTERS
* GEINTJE IN HOODLUS
MAIN LDA $D40B LINE COUNT
ASL ;*2
AND #%11110000
STA $D40A WSYNC
STA $D018 ALS 710
ORA #%00001000
STA $D01A ALS 712
JMP MAIN
* VERTICAL BLANK INTERRUPT:
* COPIEER 40 BYTES VAN (TEXTADR)
* TOT (TEXTADR)+40 NAAR $BC40
* EN VERHOOG (TEXTADR)
* OM DE TEXT NIET TE SNEL TE LATEN
* GAAN (DEZE INTERRUPT WORDT 50
* KEER PER SECONDE AANGEROEPEN)
* WORDT ER MAAR TIJDENS 1 VAN DE 4
* INTERRUPTS DAADWERKELIJK IETS
* OP HET SCHERM GEKOPIEERD.
VBI LDA RTCLOK VAN 0-$FF
AND #%00000011 VAN 0-3
EOR #%00000011 VAN 3-0
STA HSCROL
CMP #3
BNE EXIT
* COPY TEXT NAAR SCREEN
LDY #39+4
COPTXT LDA (TEXTADR),Y
STA SCREEN,Y
DEY
BPL COPTXT
INC TEXTADR
BNE EXIT
INC TEXTADR+1
EXIT JMP SYSVBV
* EN DE TEKST NATUURLIJK!
* DEZE MOET NATUURLIJK NIET IN ASCII
* MAAR IN INTERNE CODE GEASSEMBLEERD
* WORDEN!
TEXT ASC % %
ASC % %
ASC %EN ZIEDAAR, DE PROG%
ASC %RAMMEUR HAD DE EERSTE%
ASC % VAN VELE SCHERM %
ASC %ROLLERS GEMAAKT! %
ASC %HET SPREEKT VOOR ZICH%
ASC % DAT HIJ ER HEEL %
ASC %TROTS OP WAS EN %
ASC %BLA BLA BLA.... %
* EN NU ZELFS MET EEN EIGEN DISPLAY
* LIST!!
DL DFB 112,112,112,112,112,112
DFB 112,112,112,112,112
* DAT WAREN ELF * 8 LEGE SCANLINES
DFB 2+16+64
DFW SCREEN
* GR. 0 REGEL+HARDWAREMATIGE SCROL+!!
* EEN LMS!! WAT STAAT VOOR LOAD MEMORY
* SCAN. KLINKT MOEILIJK, IS HET NIET:
* DE COMPUTER MOET WETEN WAAR HIJ DE
* DATA VOOR DE REGEL VANDAAN MOET
* HALEN. JE RAAD HET AL, DE VOLGENDE
* TWEE BYTES UIT DE DISPLAY LIST ZIJN
* HET LO EN HET HI BYTE VAN DAT ADRES.
DFB 112,112,112,112,112,112
DFB 2+64+16
DFW SCREEN
DFB 65
DFW DL
* VERPLICHT AAN EINDE. (DOE MAAR ES
* NIET, KUN JE LACHEN)¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯