home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware 1 2 the Maxx
/
sw_1.zip
/
sw_1
/
COMM
/
MBBS12D.ZIP
/
MACROCFG.MAC
< prev
next >
Wrap
Text File
|
1992-06-23
|
21KB
|
732 lines
MACROCFG.MAC v1.2d
by Jeff Oberlee (C)opyright 1992
{:alr} {MACL MACROBBS.MAC,WF3} {:alu} {MACL MACROBBS.MAC,bbs}
{:start}
{SPOC n} {CURS y} {LOCA y}
{PUSH}
{SETE-P0 exit2}
{IFEX %_hom%MACROBBS.CFG,,I}
{ROPE %_hom%MACROBBS.CFG,I}
{READ bbs}
{READ sysop}
{READ syspass}
{READ datadir}
{READ msgsdir}
{READ max}
{READ userdir}
{READ filedir}
{READ dszdir}
{READ mspeed}
{READ initstr}
{READ bw}
{READ asan}
{READ cb}
{READ dal}
{READ sal}
{READ ring}
{READ connect}
{READ tlc}
{READ lock}
{RCLO}
{:I} {CLEA} {STAT n}
{DISP 2,36,4E, ╔ ▄ ▄ ▄▄▄ ▄▄▄ ▄▄▄ ▄▄▄▄ (tm) ═══════════╗}
{DISP 3,36,4E, ║ ██▄██ █▄█ █ █▄█▄ █ █ Version 1.2d ║}
{DISP 4,36,4E, ║ █ ▀ █ █ █ █▄▄ █ █ █▄▄█ CONFIGURATION ║}
{DISP 5,36,4E, ╚═════════ B B S ═════════════════════════╝
{DISP 7 ,2,0F,1.} {DISP 7,5,07,BBS System Data}
{DISP 8 ,2,0F,2.} {DISP 8,5,07,Modem Config}
{DISP 9 ,2,0F,3.} {DISP 9,5,07,Toggles}
{DISP 10,2,0F,4.} {DISP 10,5,07,DONE!}
{DISP 12,2,0F,X.} {DISP 12,5,0C,ABORT to COMMO}
{DISP 14,5,0E,Your choice? }
{SETG 0,,}
{:I1} {GETS ch,1,I1}
{COMP ch,1} {IFCO C}
{COMP ch,2} {IFCO M}
{COMP ch,3} {IFCO T}
{COMP ch,4} {IFCO S}
{COMP ch,X} {IFCO exit3}
{SEND ^H} {GOTO I1}
{:C} {CLEA}
{DISP 1,35,4E,System Data}
{DISP 4,2,0F,BBS name? }
{DISP 4,12,0E,%bbs}
{:C1} {GETS-A bbs,50,C1}
{DISP 5,2,0F,Sysop handle? (the name you wish to go by)}
{DISP 5,16,0E,%sysop}
{:C2} {GETS-A sysop,30,C2}
{DISP 6,2,0F,System password? (word that protects important stuff)}
{DISP 6,19,0E,%syspass}
{:C3} {GETS-A syspass,15,C3}
{DISP 7,2,0F,The disk directory for the main data files? (Full path) MUST have \ at end.}
{DISP 8,2,0E,%datadir}
{:C4} {GETS-A datadir,70,C4}
{DISP 9,2,0F,The disk dir for MESSAGE BASE data files? (Full path) MUST have \ at end.}
{DISP 10,2,0E,%msgsdir}
{:C5} {GETS-A msgsdir,70,C5}
{DISP 11,2,0F,Maximum number of lines that can be entered into a message?}
{DISP 12,2,0E,%max}
{:C6} {GETS-A max,3,C6}
{DISP 13,2,0F,The disk directory for the userfiles? (Full path) MUST have \ at end.}
{DISP 14,2,0E,%userdir}
{:C7} {GETS-A userdir,70,C7}
{DISP 15,2,0F,The disk dir for FILE BASE data files? (Full path) MUST have \ at end.}
{DISP 16,2,0E,%filedir}
{:C8} {GETS-A filedir,70,C8}
{DISP 17,2,0F,The directory AND name of your DSZ executable? (eg. C:\COMMO\dsz.com)}
{DISP 18,2,0E,%dszdir}
{:C9} {GETS-A dszdir,70,C9}
{DISP 20,2,0F,(D)OS DOORWAY Access Level? (1-999) : }
{DISP 20,40,0E,%dal}
{:C10} {GETS-A dal,3,C10}
{DISP 21,2,0F,MESSAGE (S)ysop functions Access Level? (1-999) : }
{DISP 21,52,0E,%sal}
{:C11} {GETS-A sal,3,C11}
{DISP 22,2,0F,Time limit per call (in minutes) : }
{DISP 22,37,0E,%tlc}
{:C12} {GETS-A tlc,3,C12}
{GOTO I}
{:M} {CLEA}
{DISP 1,33,4E,Modem Config}
{DISP 4,2,0F,Your modem's highest baud rate? }
{DISP 4,34,0E,%mspeed}
{:M1} {GETS-A mspeed,5,M1}
{DISP 5,2,0F,Modem init string? }
{DISP 5,21,0E,%initstr}
{:M2} {GETS-A initstr,40,M2}
{DISP 6,2,0F,The EXACT string your modem returns when the phone rings? (Eg. RING)}
{DISP 7,2,0E,%ring}
{:M3} {GETS-A ring,15,M3}
{DISP 8,2,0F,The EXACT string your modem returns upon connection? Exclude speed.}
{DISP 9,2,0F,(Eg. CONNECT)}
{DISP 10,2,0E,%connect}
{:M4} {GETS-A connect,15,M4}
{GOTO I}
{:T} {CLEA}
{SETV dline,yn}
{DISP 1,33,4E,System Toggles}
{:T1} {DISP 4,2,0F,Would you like the wait screen to blank? (y/n) [%bw] : ^H}
{SETV ch,%bw}
{GETS ch,1,T2}
{INST %dline,%ch} {IFCO ,T1}
{SETV bw,%ch}
{:T2} {DISP 5,2,0F,Does your system accept ANSI color codes? (y/n) [%asan] : ^H}
{SETV ch,%asan}
{GETS ch,1,T3}
{INST %dline,%ch} {IFCO ,T2}
{SETV asan,%ch}
{:T3} {DISP 6,2,0F,Capture chat sessions? (y/n) [%cb] : ^H}
{SETV ch,%cb}
{GETS ch,1,T4}
{INST %dline,%ch} {IFCO ,T3}
{SETV cb,%ch}
{:T4} {DISP 7,2,0F,Lock serial port at highest baud rate? (y/n) [%lock] : ^H}
{SETV ch,%lock}
{GETS ch,1,T5}
{INST %dline,%ch} {IFCO ,T4}
{SETV lock,%ch}
{:T5} {GOTO I}
{:S} {DISP 16,5,0F,Ok to save? (Y,n) : ^H}
{GETS-H %ch,1,S1}
{COMP ch,y} {IFCO S1}
{COMP ch,n} {IFCO exit,S}
{:S1} {DISP 17,5,03,Saving...} {PAUS 1}
{WOPE %_hom%MACROBBS.CFG}
{WRIT %bbs}
{WRIT %sysop}
{WRIT %syspass}
{WRIT %datadir}
{WRIT %msgsdir}
{WRIT %max}
{WRIT %userdir}
{WRIT %filedir}
{WRIT %dszdir}
{WRIT %mspeed}
{WRIT %initstr}
{WRIT %bw}
{WRIT %asan}
{WRIT %cb}
{WRIT %dal}
{WRIT %sal}
{WRIT %ring}
{WRIT %connect}
{WRIT %tlc}
{WRIT %lock}
{WCLO}
{:exit}
{MACL MACROBBS.MAC,bbs}
{:exit2}
{SETE-P0 EX1} {SETV ch}
{INPU ch,Return to MacroBBS now? (no save) y/N}
{COMP ch,y} {IFCO exit}
{:EX1} {RETURN}
{:exit3} {CLEA} {STAT y} {SPOC y}
{DISP 2,1,0E,Exiting to COMMO ...^J^M}
{INIT}
{MACL COMMO.MAC}
///////////////////////////////////////////////////////////////////////////
{:read_user}
{ROPE %userdir%%userno.MHS,RU1}
{READ login_name}
{READ password}
{READ al}
{READ protocol}
{READ expert}
{READ a}
{READ fa}
{RCLO}
{:RU1} {RETURN}
{:write_user}
{WOPE %userdir%%userno.MHS}
{WRIT %login_name}
{WRIT %password}
{WRIT %al}
{WRIT %protocol}
{WRIT %expert}
{WRIT %a}
{WRIT %fa}
{WCLO}
{RETURN}
{:update_clist}
{ROPE %datadir%CALLERS.LST,UC1}
{WOPE %datadir%TEMP.000}
{:UC2} {READ ch} {READ cline} {READ dline}
{COMP ch,%userno} {IFCO UC3}
{WRIT %ch} {WRIT %cline} {WRIT %dline} {GOTO UC2}
{:UC3} {COMP s,1} {IFCO UC5}
{:UC4} {WRIT %ch}
{WRIT %login_name}
{WRIT %password}
{:UC5} {READ dline} {WRIT %dline} {GOTO UC5}
{:UC1} {WCLO}
{EXEC-N COPY %datadir%TEMP.000 %datadir%CALLERS.LST}
{EXEC-N DEL %datadir%TEMP.000}
{RETURN}
{:read_data}
{ROPE %datadir%CALLER.DAT,RD1}
{READ %callno}
{READ %tdcalls}
{READ pub}
{READ pvt}
{READ ttu}
{READ tf}
{READ ldate}
{READ stime}
{READ ftime}
{READ l_caller}
{READ luserno}
{READ uhigh}
{READ mhigh}
{READ fhigh}
{RCLO}
{:RD1} {RETURN}
{:write_data}
{WOPE %datadir%CALLER.DAT}
{WRIT %callno}
{WRIT %tdcalls}
{WRIT %pub}
{WRIT %pvt}
{WRIT %ttu}
{WRIT %tf}
{WRIT %ldate}
{WRIT %stime}
{WRIT %ftime}
{WRIT %login_name}
{WRIT %userno}
{WRIT %uhigh}
{WRIT %mhigh}
{WRIT %fhigh}
{WCLO}
{RETURN}
{:read_baseinfo}
{ROPE %msgsdir%A%a.BAS,RB1}
{READ bname}
{READ %bal}
{READ maxmsg}
{READ lomsgno}
{READ himsgno}
{RCLO}
{ROPE %msgsdir%A%a.IND,RB1}
{SETV mic,0}
{:RB2} {READ msgno} {INCR mic}
{COMP mic,%userno} {IFCO ,RB2}
{RCLO}
{:RB1} {SETV mic}
{RETURN}
{:update_baseinfo}
{WOPE %msgsdir%A%a.BAS}
{WRIT %bname}
{WRIT %bal}
{WRIT %maxmsg}
{WRIT %lomsgno}
{WRIT %himsgno}
{WCLO}
{RETURN}
{:match_name_userno}
{IFEX %datadir%CALLERS.LST,,MNU2}
{ROPE %datadir%CALLERS.LST,MNU2}
{:MNU1} {READ ch} {READ lname} {READ dline}
{COMP to,%ch} {IFCO MNU5}
{COMP to,%lname} {IFCO ,MNU1}
{:MNU5} {SETV to,%lname}
{SETV tono,%ch}
{RCLO}
{SETV t,1}
{GOTO MNU4}
{:MNU2} {SEND %an1%ID not found.} {PAUS 1}
{:MNU4} {RETURN}
{:add_index}
{SETV mic,0}
{:AI1} {INCR mic}
{COMP mic,%mhigh} {IFCO-G AI2}
{WOPE-A %msgsdir%A%mic.IND} {WRIT 1} {WCLO}
{GOTO AI1}
{:AI2} {SETV mic}
{RETURN}
{:update_index}
{IFEX %msgsdir%A%a.IND,,UIX5}
{ROPE %msgsdir%A%a.IND,UIX4}
{WOPE %datadir%TEMP.000}
{SETV mic,0}
{:UIX1} {INCR mic} {READ mi}
{COMP mic,%userno} {IFCO UIX2}
{WRIT %mi} {GOTO UIX1}
{:UIX2} {WRIT %msgno}
{:UIX3} {READ mi} {WRIT %mi} {GOTO UIX3}
{:UIX4} {WCLO}
{EXEC-N COPY %datadir%TEMP.000 %msgsdir%A%a.IND}
{SETV mic} {SETV mi}
{:UIX5} {RETURN}
{:EO2}
{DISP 14,1,07, ╔════════════════════════════════╗}
{DISP 15,1,07, ║ ║}
{DISP 16,1,07, ╚════════════════════════════════╝}
{DISP 17,1,, }
{RETURN}
///////////////////////////////////////////////////////////////////////////
{:EMA}
{SETE exit5}
{SEND %an0}
{DISP 15,3,,%an7%%an9 Scanning...}
{SETV dline,Message Area(s)}
{CALL get_minfo}
{CALL EO2}
{:EM2} {SEND %an0}
{SETV dline,Message Area(s)}
{CALL AE1}
{COMP ch,e} {IFCO EM6}
{COMP ch,d} {IFCO EM3,EM4}
{:get_minfo}
{SETV high,0} {SETV total,0} {SETV na,0} {SETV temp,0}
{:EM} {INCR temp} {COMP temp,%mhigh} {IFCO-G EM0}
{IFEX %msgsdir%A%temp.BAS,,EM}
{SETV high,%temp}
{INCR total} {GOTO EM}
{:EM0} {INCR na} {IFEX %msgsdir%A%na.BAS,EM0}
{RETURN}
{:EM4} {CALL blank_box}
{DISP 7 ,49,0E,Add a Message Area}
{DISP 9 ,38,07,Name? %an7%%an12 } {DISP 9 ,44,,} {SEND %an7%%an12}
{SETG 120,EM11}
{GETS bname,30,EM2}
{SEND %an0} {DISP 10,38,07,MAX msg #? }
{:EM1} {GETS maxmsg,3,EM1}
{DISP 11,38,07,Access Level? }
{:EM20} {GETS bal,3,EM20}
{:EM10} {DISP 13,38,0C,Ok to save? (%an0%Y%an1,n) :%an0 ^H}
{GETS-H ch,1,EM5}
{COMP ch,y} {IFCO EM5}
{COMP ch,n} {IFCO EM4,EM10}
{:EM5} {SETV lomsgno,1} {SETV himsgno,0}
{SETV a,%na}
{DISP 14,38,07,Saving area #%a...}
{COMP a,%mhigh} {IFCO-LE EM19}
{CALL read_data}
{SETV mhigh,%a} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data}
{:EM19} {CALL update_baseinfo}
{SETV count,0}
{WOPE %msgsdir%A%a.IND}
{:EM13} {INCR count} {WRIT 1}
{COMP count,%uhigh} {IFCO ,EM13}
{WCLO}
{EXEC-N MD %msgsdir%A%a}
{GOTO EMA}
{:EM6} {CALL blank_box}
{DISP 7 ,49,0E,Edit a Message Area}
{DISP 9 ,38,0F,Edit which? (1 - %mhigh) : }
{SETG 120,EM11}
{GETS a,2,EM2}
{COMP a,1} {IFCO-L EM6}
{COMP a,%mhigh} {IFCO-G EM6}
{IFEX %msgsdir%A%a.BAS,,EM6}
{CALL read_baseinfo}
{CALL msgdspl}
{DISP 11,38,0D,(Press ENTER to keep same info)}
{:EM8} {DISP 12,38,07,Name? %an7%%an12 } {DISP 12,44,,} {SEND %an7%%an12}
{SETG 120,EM17}
{GETS ch,30,EM9}
{SETV bname,%ch} {SEND %an0}
{:EM9} {SEND %an0} {DISP 13,38,07,MAX message #? }
{GETS ch,3,EM15}
{SETV maxmsg,%ch}
{:EM15} {DISP 14,38,07,Access Level? }
{GETS ch,3,EM12}
{SETV bal,%ch}
{:EM12} {DISP 15,38,0C,Saving...}
{CALL update_baseinfo}
{GOTO EM6}
{:EM11} {SEND %an0}
{GOTO AE5}
{:EM3} {CALL blank_box}
{DISP 7 ,49,,%an7%%an9%DELETE%an3 a Message Area}
{DISP 9 ,38,0F,Delete which? (1 - %mhigh) : }
{SETG 120,EM11}
{GETS a,2,EM2}
{COMP a,1} {IFCO-L EM3}
{COMP a,%mhigh} {IFCO-G EM3}
{IFEX %msgsdir%A%a.BAS,,EM3}
{CALL read_baseinfo}
{CALL msgdspl}
{:EM14} {DISP 12,38,,%an7%DELETE%an3 this area? %an0(y,%an7%N%an0) ; ^H}
{GETS ch,1,EM2}
{COMP ch,n} {IFCO EM2}
{COMP ch,y} {IFCO ,EM14}
{DISP 14,38,,%an7%%an9%DELETING}
{EXEC-N DEL %msgsdir%A%a.*}
{EXEC-N DEL %msgsdir%A%a\*.msg}
{EXEC-N RD %msgsdir%A%a}
{CALL get_minfo}
{COMP mhigh,%high} {IFCO-LE EM2}
{CALL read_data)
{SETV mhigh,%high} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data)
{GOTO EM2}
{:msgdspl}
{CALL blank_box}
{SETV temp,0}
{COMP himsgno,0} {IFCO MD1}
{SETV temp,%himsgno} {DECR temp,%lomsgno} {INCR temp}
{:MD1} {DISP 6 ,38,0E, Message Area #%a - %temp msg(s) }
{DISP 8 ,38,07,Name : %an7%%bname}
{DISP 9 ,38,07,MAXmsg: %an7%%maxmsg}
{DISP 10,38,07,AL : %an7%%bal}
{RETURN}
{:ECI}
{SETE exit5}
{SEND %an0}
{DISP 15,3,,%an7%%an9 Scanning...}
{CALL get_cinfo)
{CALL EO2}
{:EC1} {SEND %an0}
{SETV dline,Caller Files}
{CALL AE1}
{COMP ch,e} {IFCO EC5}
{COMP ch,d} {IFCO EC13,EC2}
{:get_cinfo}
{SETV high,0} {SETV total,0} {SETV na,0} {SETV temp,0}
{:EC} {INCR temp} {COMP temp,%uhigh} {IFCO-G EC0}
{IFEX %userdir%%temp.MHS,,EC}
{SETV high,%temp}
{INCR total} {GOTO EC}
{:EC0} {INCR na} {IFEX %userdir%%na.MHS,EC0}
{RETURN}
{:EC2} {CALL blank_box}
{DISP 7 ,49,0E,Add a Caller}
{DISP 9 ,38,07,Handle? %an7%%an12 } {DISP 9,46,,} {SEND %an7%%an12}
{SETG 120,EM11}
{GETS temp,30,EC1}
{DISP 10,38,,%an3%Checking...}
{LENG %temp} {COMP %_len,3} {IFCO-L EC2}
{COMP temp,new} {IFCO EC2}
{COMP temp,1} {IFCO-GE EC2}
{SETV to,%temp}
{CALL match_name_userno}
{COMP t,1} {SETV t} {IFCO EC2}
{SEND %an0} {DISP 10,38,07,Password? }
{DISP 10,38,07,Password? }
{:EC11} {GETS password,15,EC11}
{DISP 11,38,07,Access Level? }
{SETV protocol,z}
{:EC16} {GETS al,3,EC16}
{:EC3} {DISP 13,38,0C,Ok to save? (%an0%Y%an1,n) :%an0 ^H}
{GETS-H ch,1,EC4}
{COMP ch,y} {IFCO EC4}
{COMP ch,n} {IFCO EC2,EC3}
{:EC4} {DISP 14,38,07,Saving #%na...}
{SETV login_name,%temp} {SETV userno,%na}
{COMP userno,%uhigh} {IFCO-LE EC17}
{CALL read_data}
{SETV uhigh,%na} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data}
{SETV login_name,%temp} {SETV userno,%na}
{CALL add_index}
{:EC17} {CALL write_user}
{WOPE-A %datadir%CALLERS.LST}
{WRIT %userno}
{WRIT %login_name}
{WRIT %password}
{WCLO}
{GOTO ECI}
{:EC5} {CALL blank_box}
{DISP 7 ,49,0E,Edit Caller Info}
{DISP 9 ,38,0F,Enter a Handle or ID#.}
{DISP 10,38,07,: } {SEND %an3}
{SETG 120,EM11}
{GETS ch,30,EC1}
{DISP 11,38,,}
{SETV to,%ch}
{CALL match_name_userno}
{COMP t,1} {IFCO ,EC5} {SETV t}
{:EC6} {DISP 12,38,07,Edit%an4 %to%%an0?}
{DISP 13,43,0C,(%an0%Y%an1,n) : ^H}
{GETS-H ch,1,EC7}
{COMP ch,y} {IFCO EC7}
{COMP ch,n} {IFCO EC5,EC6}
{:EC7} {CALL blank_box}
{SETV userno,%tono}
{CALL read_user}
{DISP 7 ,50,07,Account #%userno}
{DISP 8 ,38,07,Handle: %an7%%login_name}
{DISP 9 ,38,07,Proto : %an7%%protocol}
{DISP 10,38,07,AL : %an7%%al}
{DISP 11,38,0D,(Press ENTER to keep the same)}
{DISP 12,38,07,Handle? %an7%%an12 } {DISP 12,46,,} {SEND %an7%%an12}
{SETG 120,EM11}
{GETS ch,30,EC8}
{DISP 13,38,07,}
{SETV login_name,%ch}
{CALL update_clist}
{:EC8} {SEND %an0}
{DISP 13,38,07,Protocol? }
{GETS ch,1,EC9}
{SETV protocol,%ch}
{:EC9} {DISP 14,38,07,Access Level? }
{GETS ch,3,EC10}
{SETV al,%ch}
{:EC10} {DISP 15,38,0C,Saving...}
{CALL write_user}
{GOTO EC5}
{:EC13} {CALL blank_box}
{DISP 7 ,49,0F,%an7%%an9%DELETE%an3 a Caller}
{DISP 9 ,38,0F,Enter a Handle or ID#.}
{DISP 10,38,07,: } {SEND %an1}
{SETG 120,EM11}
{GETS ch,30,EC1}
{SETV to,%ch}
{DISP 7 ,49,0F,%an7%DELETE%an3 a Caller}
{DISP 11,38,,}
{CALL match_name_userno}
{COMP t,1} {IFCO ,EC13} {SETV t}
{:EC14} {DISP 12,38,,%an7%DELETE%an1 %to%%an7?}
{DISP 13,45,07,(y/%an7%N%an0) : ^H}
{GETS ch,1,EC13}
{COMP ch,n} {IFCO EC13}
{COMP ch,y} {IFCO ,EC14}
{DISP 15,38,,%an7%%an9%DELETING}
{SETV userno,%tono}
{EXEC-N DEL %userdir%%userno.*}
{EXEC-N DEL %msgsdir%E%userno-*.*}
{SETV s,1} {CALL update_clist} {SETV s}
{SETV a,0}
{:EC15} {INCR a}
{SETV msgno,1}
{CALL update_index}
{COMP a,%mhigh} {IFCO-L EC15}
{SETV a,1}
{CALL get_cinfo}
{COMP uhigh,%high} {IFCO-LE EC1}
{CALL read_data)
{SETV uhigh,%high} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data)
{GOTO EC1}
{:EFA}
{SETE exit5}
{SEND %an0}
{DISP 15,3,,%an7%%an9 Scanning...}
{CALL get_finfo}
{CALL EO2}
{:EF1} {SEND %an0}
{SETV dline,File Area(s)}
{CALL AE1}
{COMP ch,e} {IFCO EF5}
{COMP ch,d} {IFCO EF13,EF2}
{:get_finfo}
{SETV high,0} {SETV total,0} {SETV na,0} {SETV temp,0}
{:EF} {INCR temp} {COMP temp,%fhigh} {IFCO-G EF0}
{IFEX %filedir%F%temp.BAS,,EF}
{SETV high,%temp}
{INCR total} {GOTO EF}
{:EF0} {INCR na} {IFEX %filedir%F%na.BAS,EF0}
{RETURN}
{:EF2} {CALL blank_box}
{DISP 7 ,49,0E,Add a File Area}
{DISP 9 ,38,07,Name? %an7%%an12 } {DISP 9 ,44,,} {SEND %an7%%an12}
{SETG 120,EM11}
{GETS bname,30,EF1}
{SEND %an0} {DISP 10,38,07,Access Level? }
{:EF11} {GETS bal,3,EF11}
{:EF3} {DISP 12,38,0C,Ok to save? (%an0%Y%an1,n) :%an0 ^H}
{GETS-H ch,1,EF12}
{COMP ch,y} {IFCO EF12}
{COMP ch,n} {IFCO EF2,EF3}
{:EF12} {SETV fa,%na}
{DISP 14,38,07,Saving area #%fa...}
{COMP fa,%fhigh} {IFCO-LE EF16}
{CALL read_data}
{SETV fhigh,%fa} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data}
{:EF16} {WOPE %filedir%F%fa.BAS} {WRIT %bname} {WRIT %bal} {WCLO}
{WOPE %filedir%F%fa.LST}
{WRIT Φ = unvalidated}
{WRIT Filename Size Description}
{WRIT ------------------------------------------------------------------------------}
{WCLO}
{EXEC-N MD %filedir%F%fa}
{GOTO EFA}
{:EF5} {CALL blank_box}
{DISP 7 ,49,0E,Edit a File Area}
{DISP 9 ,38,0F,Edit which? (1 - %fhigh) : }
{SETG 120,EM11}
{GETS fa,2,EF1}
{COMP fa,1} {IFCO-L EF5}
{COMP fa,%fhigh} {IFCO-G EF5}
{IFEX %filedir%F%fa.BAS,,EF5}
{ROPE %filedir%F%fa.BAS,EF5} {READ bname} {READ bal} {RCLO}
{:EF7} {CALL blank_box}
{DISP 7 ,50,0F,File Area %fa}
{DISP 9 ,38,0F,Name: %an0%%bname}
{DISP 10,38,07,AL : %an0%%bal}
{DISP 11,38,0D,(Press ENTER to keep same info)}
{DISP 12,38,07,Name? %an7%%an12 } {DISP 12,44,,} {SEND %an12}
{SETG 120,EM11}
{GETS ch,30,EF9}
{SETV bname,%ch}
{:EF9} {SEND %an0} {DISP 13,38,07,AL : }
{GETS ch,3,EF10}
{SETV bal,%ch}
{:EF10} {DISP 15,38,0C, Saving...}
{WOPE %filedir%F%fa.BAS} {WRIT %bname} {WRIT %bal} {WCLO}
{GOTO EF5}
{:EF13} {CALL blank_box}
{DISP 7 ,49,0F,%an7%%an9%DELETE%an3 a File Area}
{DISP 9 ,38,0F,DELETE which? (1 - %fhigh) : }
{SETG 120,EM11}
{GETS fa,2,EF1}
{COMP fa,1} {IFCO-L EF13}
{COMP fa,%fhigh} {IFCO-G EF13}
{IFEX %filedir%F%fa.BAS,,EF13}
{DISP 7 ,49,0F,%an7%DELETE%an3 a File Area}
{ROPE %filedir%F%fa.BAS,EF13} {READ bname} {READ bal} {RCLO}
{CALL blank_box}
{DISP 7 ,38,0E, File Area #%fa}
{DISP 9 ,38,07,Name: %an0%%bname}
{DISP 10,38,07,AL : %an0%%bal}
{:EF14} {DISP 12,38,,%an7%DELETE? %an0(y,%an7%N%an0) : ^H}
{GETS ch,1,EF13}
{COMP ch,n} {IFCO EF13}
{COMP ch,y} {IFCO ,EF14}
{EXEC-N DEL %filedir%F%fa\*.*}
{DISP 14,38,,%an7%%an9%DELETING}
{EXEC-N DEL %filedir%F%fa.*}
{EXEC-N RD %filedir%F%fa}
{CALL get_finfo}
{COMP fhigh,%high} {IFCO-LE EF1}
{CALL read_data)
{SETV fhigh,%high} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data)
{GOTO EF1}
{:AE1} {CALL blank_box}
{DISP 7 ,38,0E,%dline:}
{DISP 10,38,07,High # .............%an7 %high}
{DISP 9 ,38,07,In use .............%an7 %total}
{DISP 11,38,07,Next available .....%an7 %na}
{:AE2} {DISP 15,42,07,Press ENTER to quit}
{DISP 13,38,07,(%an7%A%an0%)dd, (%an7%E%an0%)dit or (%an7%D%an0%)elete? ^H}
{SETG 120,AE3}
{GETS-H ch,1,AE3}
{SETV dline,aed}
{INST dline,%ch} {IFCO AE4,AE2}
{:AE3} {POPS}
{:AE5} {SETV total} {SETV high} {SETV temp} {SETV na}
{CALL WF5}
{GOTO exit4}
{:AE4} {RETURN}
{:exit4}
{MACL MACROBBS.MAC,m_init_w}
{:exit5}
{MACL MACROBBS.MAC,m_init}
///////////////////////////////////////////////////////////////////////////
{:blank_box}
{SETV mic,6}
{DISP 6 ,36,07,╔═════════════════════════════════════════╗
{DISP 7 ,36,07,║ ║}
{DISP 8 ,36,07,║ ║}
{DISP 9 ,36,07,║ ║}
{DISP 10,36,07,║ ║}
{DISP 11,36,07,║ ║}
{DISP 12,36,07,║ ║}
{DISP 13,36,07,║ ║}
{DISP 14,36,07,║ ║}
{DISP 15,36,07,║ ║}
{DISP 16,36,07,╚═════════════════════════════════════════╝}
{SETV mic}
{RETURN}
{:WF5}
{DISP 6 ,36,17,╔═════════════════════════════════════════╗
{DISP 7 ,36,17,║ Embryo ____ by Shad Muegge ║}
{DISP 8 ,36,17,║ ---------^|\/ o \------------------ ║}
{DISP 9 ,36,17,║ ____^| ,__^| Association of ║}
{DISP 10,36,17,║ / o \/^|____/ Babble Fish ║}
{DISP 11,36,17,║ ^|__, ^|____ Programmers ║}
{DISP 12,36,17,║ \____^|\/ o \ ║}
{DISP 13,36,17,║ ^| ,__^| MEMBER ║}
{DISP 14,36,17,║ ---------^|/\____/------------------ ║}
{DISP 15,36,17,║ ║}
{DISP 16,36,17,╚═════════════════════════════════════════╝}
{RETURN}