Amiga MA Magazine 1998 #3/amigamamagazinepolishissue1998.iso/bazy/bancabase_13/install_ita

Text File | 1997-01-16 | 5KB | 195 lines

;   -----------------------------
;       Install BancaBase
;   -----------------------------
;   Description:
;
;   Commodore Installer Script for BancaBase 1.3
;   $VER: 1.01 (c) 1997 by Stefano Dardari

; some useful variables
    (set
        newline         "\n"
        #bbprogname     "BancaBase13.lha"
        #bb3-path       "BancaBase/"
        #patternsname     "Patterns.lha"
        #soundsname     "Sounds.lha"
        #BBdocname      "BBase_doc.lha"
        #bb3-dest       "SYS:"
        #bb3-key        "BBase.key"
        #bb3-prefs      "BancaBase.prefs"
        #bb3-icon-MWB   "Icons/MagicWB/"
        #bb3-icon-NI    "Icons/NewIcon/"
        #bb3-icon-STD   "Icons/Standard/"
        #STDTYPE        0
        #NITYPE         1
        #MWBTYPE        2
        #iconpattern    "#?.info"
    )

; some strings
(set #omp (cat "Un momento prego..." newline))

(set #installtext (cat "Benvenuti nello script di installazione di BancaBase.\n\nBancaBase3 V 1.3 (C) 1997 by Stefano Dardari\n\nAll rights reserved"))
(set #BB3dest-prompt "Prego selezionare la directory dove si desidera installare il cassetto BancaBase.\n(Vedere l'HELP per ulteriori dettagli)")
(set #BB3dest-help (cat "Selezionare la directory (o il disco) dove si desidera installare il programma. Verra' creata una directory con il nome di BancaBase."))
(set #BB3patt-prompt "\n\n\nSi desidera installare alcuni sfondi da utilizzare con l'interfaccia grafica ?\n\nNOTA: Sono utilizzabili solo con WorkBench 3.0 o superiore.")
(set #BB3patt-help (cat "Gli sfondi (o backdrop patterns) vanno considerati come extra. Infatti non sono necessari per il corretto funzionamento di BancaBase, ma sono molto carini se utilizzati con l'interfaccia grafica.\n\nNota che il programma utilizza i Datatypes per gestire i pattern. Quindi se non si utilizza una versione V39 (o suberiore) del kickstart ... selezionare il gadget NO."))
(set #BB3end (cat "Installazione completata. Leggere il file readme prima di iniziare."))
(set #BB3icon-prompt "\nQuale tipo di ICONE si desidera installare tra quelle disponibili ?")
(set #BB3icon-help "Selezionare il tipo di Icona desiderata per il programma e tutti gli accessori forniti. Se ad esempio nel vostro WorkBench utilizzate normalmente le icone stile Magic WorkBench, selezionate MagicWB. Lo stesso vale per gli altri tipi di icona.")
(set #coping-icon-prompt "Attendere prego ... installo le icone selezionate.")

(welcome #installtext)

(procedure set_icon
   (set #def-icon
      (askchoice
         (prompt #BB3icon-prompt)
         (help   #bb3icon-help)
         (choices "Icone Standard" "Icone NewIcon" "Icone MagicWB")
         (default 0)
      )
   )
)

(procedure set_dir
   (set #bb3-dest
      (askdir
         (prompt #BB3dest-prompt)
         (help #BB3dest-help)
         (default #bb3-dest)
         (newpath)
      )
   )
)

(set_dir)
(set #dest-path (tackon #bb3-dest #bb3-path))
(set @default-dest #dest-path)


(if (exists #dest-path (noreq))
   (
      (set #file-exist (cat "Spiacente ma la directory " #dest-path " esiste gia'.\nSelezionare una directory destinazione differente.\n"))
      (message #file-exist)
      (set_dir)
      (set #dest-path (tackon #bb3-dest #bb3-path))
      (set @default-dest #dest-path)
   )
)

(makedir #dest-path (infos))

(working #omp "Scompatto e copio i files.")

(run "lha -x x "#bbprogname" "#dest-path )

(complete 50)


( if (exists #BBdocname (noreq))
   (
      (working #omp "Scompatto e copio la documentazione.")
      (run "lha -x x "#BBdocname" "#dest-path )
   )
)

(complete 60)

(if (exists #patternsname (noreq))
   (
      (if (askbool (prompt #BB3patt-prompt) (help #BB3patt-help) (default 1))
          (
             (working #omp "Scompatto e copio i files.")
             (run "lha -x x "#patternsname" "#dest-path )
          )
      )
   )
)

(complete 70)

(set_icon)
(if (= #def-icon #STDTYPE)
    (set #src-icon #bb3-icon-STD)
    )
(if (= #def-icon #NITYPE)
    (set #src-icon #bb3-icon-NI)
    )
(if (= #def-icon #MWBTYPE)
    (set #src-icon #bb3-icon-MWB)
    )

(copyfiles
   (prompt #coping-icon-prompt)
   (source #src-icon)
   (dest  #dest-path)
   (pattern #iconpattern)
   (noposition)
)

(set #src-path (tackon #src-icon "Docs"))
(set #dst-path (tackon #dest-path "Docs"))


(copyfiles
   (prompt #coping-icon-prompt)
   (source #src-path)
   (dest  #dst-path)
   (all)
   (noposition)
)

(set #src-path (tackon #src-icon "Register"))
(set #dst-path (tackon #dest-path "Register"))

(copyfiles
   (prompt #coping-icon-prompt)
   (source #src-path)
   (dest  #dst-path)
   (all)
   (noposition)
)

(complete 80)

(if (exists #soundsname (noreq))
       (
          (working #omp "Scompatto e copio i files.")
          (run "lha -x x "#soundsname" "#dest-path )
       )
)


(complete 90)

(if (exists #bb3-prefs (noreq))
    (copyfiles
        (prompt #omp "Copio il file preferenze.")
        (source #bb3-prefs)
        (dest #dest-path)
        (files)
    )
)

(if (exists #bb3-key (noreq))
    (copyfiles
        (prompt #omp "Copio il KeyFile.")
        (source #bb3-key)
        (dest #dest-path)
        (files)
    )
)

(complete 100)

; The last message
    (set end_text (cat "\nSpero che BancaBase ti piaccia!\n"
                       "Non esitare a mandarmi commenti, suggerimenti e bugreports."))

; the end
(set @default-dest #dest-path)
    (exit end_text)
;EOF