home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DOS/V Power Report 2000 August
/
VPR0008B.BIN
/
DRIVER
/
IODATA
/
DVABS100
/
DVABS100.EXE
/
UPDATE.BAT
< prev
next >
Wrap
DOS Batch File
|
2000-05-26
|
4KB
|
157 lines
@echo off
echo -------------------------------------------------------------------
echo DVD-ABシリーズ
echo DVD-AB2/AB6T/AB8T/AB16T Ver. 1.00 ~ 1.01
echo → 1.00 差分更新バッチファイル
echo COPYRIGHT (C) 1996-2000 I-O DATA DEVICE,INC. All Rights Reserved.
rem 99/03/02
rem 00/01/18
echo -------------------------------------------------------------------
rem ------------------------------------------------
rem 引数のチェック %1:書き換えるドライブ
rem ------------------------------------------------
if "%1" == "" goto help
rem ------------------------------------------------
rem 差分ファイルがカレントにない場合はヘルプへ
rem ------------------------------------------------
if not exist diskdif.exe goto help
rem ------------------------------------------------
rem ディスク チェック 開始
rem ------------------------------------------------
:insert
echo.
echo 作成したサポートソフトのバックアップディスクをフロッピーディスク
echo ドライブ %1にセットしてください。
echo.
echo [はい、 作成してあります]...[Enter]キー
echo [いいえ、まだ作成していません]...中止...[Ctrl]+[C]
echo.
pause
rem ------------------------------------------------
rem ディスク チェック 開始
rem ------------------------------------------------
if not exist %1\win9x\cdselect.ex_ goto insert
rem ------------------------------------------------
rem ディスク チェック 終了
rem ------------------------------------------------
echo.
echo ----- 更新開始 -----
echo 更新終了までキー操作をしないでください。
echo.
rem ------------------------------------------------
rem 作業用ディレクトリを作成
rem ------------------------------------------------
md $work
cd $work
rem ------------------------------------------------
rem キーファイルを作業用ディレクトリにコピー
rem ------------------------------------------------
copy %1\win9x\cdselect.ex_
rem ------------------------------------------------
rem 差分データファイルをディスクデータファイルにコンバート
rem ------------------------------------------------
..\diskdif
rem ------------------------------------------------
rem コンバートが正常かどうかチェック
rem ------------------------------------------------
if not exist .\disk.exe goto baddisk
echo.
echo ディスクデータへの更新完了。フロッピーディスクの内容を更新します。
echo.
rem ------------------------------------------------
rem 更新先ディスクの不要ファイル/ディレクトリ削除終了
rem (ディレクトリをチェック )
rem ------------------------------------------------
del %1\dos\dosv\*.* < ..\y
rd %1\dos\dosv
del %1\dos\9821\*.* < ..\y
rd %1\dos\9821
del %1\win9x\*.* < ..\y
rd %1\win9x
del %1\dos\*.* < ..\y
rd %1\dos
del %1\*.* < ..\y
rem ------------------------------------------------
rem ディスクデータを指定ドライブに解凍
rem ------------------------------------------------
disk %1
rem ------------------------------------------------
rem 作業ディレクトリと中のファイルを削除
rem (ディレクトリをチェック )
rem ------------------------------------------------
del cdselect.ex_
del disk.exe
cd ..
rd $work
rem ------------------------------------------------
rem 注意事項等を表示
rem ------------------------------------------------
echo.
echo ----- 更新完了 -----
echo.
rem ------------------------------------------------
rem 正常終了
rem ------------------------------------------------
goto end
rem ------------------------------------------------
rem 異常終了
rem ------------------------------------------------
rem ------------------------------------------------
rem サポートソフト内容不備
rem ------------------------------------------------
:baddisk
echo.
del cdselect.ex_
echo 正しいサポートソフトディスクではありません。中止します。
echo.
cd ..
rd $work
goto end
rem ------------------------------------------------
rem ドライブ指定が不正
rem ------------------------------------------------
:help
echo 書式 update [サポートソフトFDD]
echo 例 update a: ... フロッピーディスクドライブがA: の場合
rem ------------------------------------------------
rem 終了
rem ------------------------------------------------
:end