home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64-128BBS / STR39.PFILE1.ARC / ST / R.CASINO (.txt) next >
Encoding:
Commodore BASIC  |  2019-04-13  |  19.2 KB  |  537 lines
  1. 100 POKE152,PEEK(251)
  2. 110 GOTO480
  3. 120 :
  4. 130 :REM START OF USER JUMP TABLE.
  5. 140 :
  6. 150 GOTO670 :REM CHECK FOR CARRIER.
  7. 160 GOTO730 :REM SEND P$+CHR$(13) OUT.
  8. 170 GOTO740 :REM SEND P$ OUT.
  9. 180 GOTO780:REM GET L$ FROM MODEM.
  10. 190 GOTO870:REM CALL FOR CHAT.
  11. 200 GOTO910:REM ENGAGE CHAT MODE.
  12. 210 GOTO970:REM SEND 'P' TO USERFILE.
  13. 220 GOTO1010:REM READ ERROR CHANNEL.
  14. 230 GOTO1030:REM READ SYSTEM CLOCK.
  15. 240 GOTO1090:REM DISPLAY USER STATS.
  16. 250 GOTO1230:REM DISPLAY USER ONLINE.
  17. 260 GOTO1250:REM EDIT USER STATISTICS.
  18. 270 GOTO1620:REM REMOTE SYSOP MENU.
  19. 280 GOTO1840:REM DISPLAY DIR.
  20. 290 GOTO2140:REM BREAK RC INTO LO/HI.
  21. 300 GOTO2180:REM UPDATE (USER LOG).
  22. 310 GOTO2190:REM SAME AS 2330.
  23. 320 GOTO2200:REM GET U$() FROM DISK.
  24. 330 GOTO2210:REM GET N$() FROM DISK.
  25. 340 GOTO2220:REM SEND U$() TO DISK.
  26. 350 GOTO2230:REM SEND N$() TO DISK.
  27. 360 GOTO2260:REM FIND DV,DR$ IN DR%().
  28. 370 GOTO2280:REM FIND DV,DR$
  29. 380 GOTO2290:REM INCREMENT DV,DR$.
  30. 390 GOTO2350:REM HANG UP PHONE.
  31. 400 GOTO2420:REM FIND TIME CONNECTED.
  32. 410 GOTO2560:REM RETURN TO BBS.
  33. 420 GOTO2570:REM LOAD NEXT MODULE.
  34. 430 GOTO2450:REM GET SC() FROM DISK.
  35. 440 GOTO2530:REM SEND SC() TO DISK.
  36. 450 :
  37. 460 :REM END OF USER JUMP TABLE.
  38. 470 :
  39. 480 B1=56577:B2=56579:Q$=CHR$(34):B3=56590:B4=56588:DV=8:N$=CHR$(0):SI=54272
  40. 490 DIMU$(15),N$(15),DR%(7):DR$="0"
  41. 500 GOSUB510:GOTO560
  42. 510 OPEN1,8,5,"0:(BBS.CONFIG)":FORT=0TO9:INPUT#1,A:IFA=0THEN530
  43. 520 FORI=0TOA-1:INPUT#1,A$,A,A:NEXT
  44. 530 NEXT:INPUT#1,DR:FORI=0TODR-1:INPUT#1,DR%(I):NEXT:DR=DR+7
  45. 540 INPUT#1,RF:AA=-((RFAND128)=128):RF$=MID$(STR$(AA),2)+":(USERFILE)"
  46. 550 INPUT#1,SY$,BD$,MT%,RC,S1$,S2$,RR,P1$,P2$,D5,D6,MF,N5,N3,N4:CLOSE1:RETURN
  47. 560 F$=CHR$(13):P=0:POKE51972,P:SYS51976:BS=255:UL$=""
  48. 570 DC$="[149] --===[129]***[158]===[153]---===[159]***[154]===---[156]===***[158]===--[152]":GOTO2630
  49. 580 IFA$="[133]"THENSY=SY+1:GOSUB1620:SY=SY-1:RETURN
  50. 590 IFA$="[134]"THENGOSUB910:TI$="000000":RETURN
  51. 600 IFA$="[140]"THENCD=1:RETURN
  52. 610 IFL<>65535THENRETURN
  53. 620 OPEN1,8,5,"0:(USER LOG),A":PRINT#1,UL$:PRINT#1,"[212]IME [197]LAPSED![152]":CLOSE1
  54. 630 CD=1:UL$="":RETURN
  55. 640 IFA$=""ORZ$=""THENGOSUB660
  56. 650 RETURN
  57. 660 POKESI+4,21:POKESI+4,20:RETURN
  58. 670 CD=0:IFSYTHENRETURN
  59. 680 IF(PEEK(B1)AND16)<>HLTHENRETURN
  60. 690 TI$="000000"
  61. 700 IF(PEEK(B1)AND16)<>HLTHENRETURN
  62. 710 IFVAL(TI$)>5THENCD=1:RETURN
  63. 720 GOTO700
  64. 730 P$=P$+F$
  65. 740 IFL=55THENPRINT#4,P$;:RETURN
  66. 750 POKE52030,SY:POKE52031,CG:POKE52040,MM:SYS51994,P$
  67. 760 CD=PEEK(52033):A$=CHR$(PEEK(52034)):IFA$=CHR$(0)THENA$=""
  68. 770 RETURN
  69. 780 GOSUB2420:IFCO>VAL(U$(14))THEN820
  70. 790 POKE52030,SY:POKE52031,CG:POKE52038,EC:POKE52039,L:POKE52040,MM
  71. 800 L$="                                       ":SYS52003,L$:CD=PEEK(52033)
  72. 810 L=PEEK(52034)+256*PEEK(52036):A$=CHR$(PEEK(52034)):GOSUB580:RETURN
  73. 820 P$=F$+F$+"[217]OU [200]AVE [197]XCEEDED [217]OUR [212]IME [204]IMIT!!"+F$+"[199][207][207][196][194][217][197]!":GOSUB160
  74. 830 GOTO410
  75. 840 P$=F$+"[197]NTER [193]CCESS LEVEL: ":GOSUB740:L=5:GOSUB780:IFCDTHENRETURN
  76. 850 IFVAL(L$)<0ORVAL(L$)>65535ORL$=""THENRETURN
  77. 860 L=VAL(L$):A2=INT(L/256):A1=L-A2*256:A$=CHR$(A1)+CHR$(A2):RETURN
  78. 870 IFSA<>1THENP$=F$+F$+SY$+" IS NOT AVAILABLE RIGHT NOW.":GOSUB730:RETURN
  79. 880 P$="[195]ALLING "+SY$+"....":GOSUB730:FORI=1TO20:GETA$:IFA$="[134]"THEN910
  80. 890 GOSUB660:FORT=1TO600:NEXT:NEXT
  81. 900 P$="[212]RY AGAIN LATER....":GOSUB730:RETURN
  82. 910 P$=F$+F$+SY$+", CHATTING WITH "+U$(1)+F$:GOSUB730
  83. 920 SYS52012:A$=CHR$(PEEK(52034)):CD=PEEK(52033)
  84. 930 IFA$="[134]"ORCDTHENP$=F$+SY$+" HAS RETURNED TO "+BD$+".":GOSUB730:RETURN
  85. 940 IFA$="[133]"THENSY=SY+1:GOSUB1620:SY=SY-1
  86. 950 IFA$="[140]"THENCD=1:RETURN
  87. 960 RETURN
  88. 970 GOSUB2150:AA=RF:GOSUB2260
  89. 980 FORL=1TO2:PRINT#15-B,"P"CHR$(99)CHR$(R1)CHR$(R2)CHR$(1):GOSUB1010:NEXT
  90. 990 GOSUB1010:IFER$<"20"ORER$="50"THENRETURN
  91. 1000 PRINT"[197]RROR IN (USERFILE)!":GOSUB2350:STOP
  92. 1010 ES$="":GOSUB1020:ER$=LEFT$(ES$,2):RETURN
  93. 1020 GET#15-B,A$:ES$=ES$+A$:ON-(A$<>CHR$(13))GOTO1020:RETURN
  94. 1030 T1$="00:00:00.0 XX":SYS51982,T1$:TM$=T1$+""
  95. 1040 HO$=LEFT$(TM$,2):MI$=MID$(TM$,4,2):FZ$=RIGHT$(TM$,2)
  96. 1050 IFVAL(LEFT$(TM$,2))<>12ANDFZ$<>"AM"THENC2=1:GOTO1080
  97. 1060 IFC2THENOPEN1,8,5,"@0:(T.CALLERS),S,W":PRINT#1," ":CLOSE1:DT=DT+1
  98. 1070 IFC2THENC2=0:NT=0:IFSFTHENOPEN1,8,5,"@0:(USER LOG),S,W":CLOSE1
  99. 1080 DA$=M$+STR$(DT):RETURN
  100. 1090 P$=F$+"[217]OUR [211]TATISTICS...."+F$:GOSUB730
  101. 1100 P$="[206]AME          : "+U$(1):GOSUB730
  102. 1110 P$="[193]CCESS LEVEL  :"+STR$(AC):GOSUB730:GOSUB1030
  103. 1120 P$="[196]ATE/[212]IME     : "+DA$+" "+TM$:GOSUB730:GOSUB2420
  104. 1130 P$="[195]ONNECT [212]IME  :"+STR$(CO)+" MINS.":GOSUB730
  105. 1140 P$="[205]EMBER #      : "+R$:GOSUB730
  106. 1150 P$="[208]ASSWORD      : "+U$(4):GOSUB730
  107. 1160 P$="[193]GE           : "+U$(6):GOSUB730
  108. 1170 P$="[210]EAL [206]AME     : "+U$(7):GOSUB730
  109. 1180 P$="[212]OTAL [213]/[204]'S   : "+U$(9):GOSUB730
  110. 1190 P$="[212]OTAL [196]/[204]'S   : "+U$(10):GOSUB730
  111. 1200 P$="       [[210]ATIO - "+MID$(STR$(RR),2)+":1]":GOSUB730
  112. 1210 P$="[204]AST CALL DATE: "+U$(11):GOSUB730
  113. 1220 P$="[212]OTAL CALLS   : "+U$(12):GOSUB730:RETURN
  114. 1230 PRINT"[156]"F$U$(1)" <*> [204]VL-"+MID$(STR$(AC),2):GOSUB2420
  115. 1240 PRINTTM$" [195]ONNECTED:"STR$(CO)" MINS.[152]":ON(C5-CO>30)+2GOTO5440:RETURN
  116. 1250 P$=" [147][197]NTER ACCOUNT # OF USER.":GOSUB730
  117. 1260 P$="[193]CCOUNT # OF CURRENT USER: "+R$:GOSUB730
  118. 1270 P$="[214][213]:":GOSUB740:L=3:GOSUB780:IFCDTHENRETURN
  119. 1280 IFL$=""THENRETURN
  120. 1290 E$=L$+"":IFL$=R$THENFORL=1TO15:N$(L)=U$(L):NEXT:AA=AC:GOTO1310
  121. 1300 OPEN3,RF,3,RF$:RC=VAL(L$):GOSUB970:GOSUB2210:CLOSE3
  122. 1310 P$=" [147]1 - [206]AME      : "+N$(1)+F$+"2 - [208]HONE     : "+N$(2):GOSUB730:GOSUB2170
  123. 1320 P$="3 - [193]CCESS [204]VL:"+STR$(AA)+F$+"4 - [208]ASSWORD  : "+N$(4):GOSUB730
  124. 1330 P$="5 - # OF [197]MAIL: "+N$(5)+F$+"6 - [193]GE       : "+N$(6):GOSUB730
  125. 1340 P$="7 - [210]EAL NAME : "+N$(7)+F$+"8 - C/G MODE  : "+N$(8):GOSUB730
  126. 1350 P$="9 - [212]OTAL [213]/[204] : "+N$(9)+F$+"[193] - [212]OTAL [196]/[204] : "+N$(10):GOSUB730
  127. 1360 P$="[194] - [204]AST CALL : "+N$(11):GOSUB730
  128. 1370 P$="[195] - # CALLS   : "+N$(12):GOSUB730
  129. 1380 P$="[196] - [195]ALLS/[196]AY : "+N$(13)+F$+"[197] - [212]IME/[195]ALL : "+N$(14):GOSUB160
  130. 1390 P$="[198] - [195]ALLS[212]ODAY: "+N$(15):GOSUB160
  131. 1400 IFL=55THENL=0:PRINT#4:CLOSE4:GOTO1310
  132. 1410 P$=F$+"[215]HICH TO CHANGE:":GOSUB740:L=1:GOSUB780:IFCDTHENRETURN
  133. 1420 IFL$=""ANDR$=E$THENFORL=1TO15:U$(L)=N$(L):NEXT:AC=AA:GOTO1250
  134. 1430 IFL$=""THEN1250
  135. 1440 IFL$="S"ORL$="[211]"THEN1520
  136. 1450 IFL$="P"ORL$="[208]"THENL=55:OPEN4,4,7:GOTO1310
  137. 1460 S=(ASC(L$)AND127)-64:IFS=>1ANDS<=6THENS=S+9:GOTO1490
  138. 1470 S=VAL(L$):IFS<1ORS>9THEN1310
  139. 1480 IFS=3THENGOSUB840:N$(3)=A$:AA=A:GOTO1310
  140. 1490 P$=F$+"["+N$(S)+"]:[195]HANGE TO->":GOSUB740
  141. 1500 L=20:GOSUB780:IFCDTHENRETURN
  142. 1510 N$(S)=L$+"":GOTO1310
  143. 1520 P$=F$+"[211]AVE STATS WHERE? (DEFAULT="+E$+"):":GOSUB740
  144. 1530 L=3:GOSUB780:IFCDTHENRETURN
  145. 1540 IFL$<>""ANDVAL(L$)>0THENE$=L$+""
  146. 1550 P$=F$+"[211]AVE AT: "+E$:GOSUB730
  147. 1560 P$="[195]ORRECT? (Y/N):":GOSUB740:L=1:GOSUB780:IFCDTHENRETURN
  148. 1570 IFL$<>"Y"ANDL$<>"[217]"THEN1310
  149. 1580 OPEN3,RF,3,RF$:RC=VAL(E$):GOSUB970
  150. 1590 GOSUB2230
  151. 1600 CLOSE3
  152. 1610 RETURN
  153. 1620 AA=DV:GOSUB2260
  154. 1630 P$=" [147]":GOSUB730
  155. 1640 P$=DC$+F$+"   --**]> [210]EMOTE [211]YS-[207]P [205]ENU <[**--"+F$+DC$+F$:GOSUB730
  156. 1650 P$="[214] - [214]ALIDATE USER":GOSUB730
  157. 1660 P$="[193] - [211]CAN ANY SEQ ON DISK":GOSUB730
  158. 1670 P$="$ - [196]IRECTORY":GOSUB730
  159. 1680 P$="@ - [196]OS COMMANDS":GOSUB730
  160. 1690 P$="[213] - [211]CAN USER LOG":GOSUB730
  161. 1700 P$="[212] - [212]ODAY'S CALLERS":GOSUB730
  162. 1710 P$="# - [212]OGGLE DRIVE #"+STR$(DV)+";"+DR$:GOSUB730
  163. 1720 P$=F$+"[210][211][205]"+MID$(STR$(DV),2)+";"+DR$+":":GOSUB740:L=1:GOSUB780:IFCDTHENRETURN
  164. 1730 IFL$=""THENRETURN
  165. 1740 L$=CHR$(ASC(L$)AND127)
  166. 1750 GOSUB2180:UL$=UL$+"[211]YSOP-"+L$+CHR$(13)
  167. 1760 ON-(L$="U")-2*(L$="A")-3*(L$="V")-4*(L$="$")GOSUB1980,2090,1250,1840
  168. 1770 ON-(A$="#")-2*(L$="T")GOSUB2290,2080
  169. 1780 IFL$="?"THEN1630
  170. 1790 IFL$<>"@"THEN1720
  171. 1800 P$=F$+">":GOSUB740:L=39:GOSUB780:IFCDTHENRETURN
  172. 1810 IFL$=""THENGOSUB1010:P$=F$+ES$:GOSUB730:GOTO1720
  173. 1820 IFLEFT$(L$,4)=P2$+":"THENPRINT#15-B,RIGHT$(L$,LEN(L$)-4)
  174. 1830 GOTO1720
  175. 1840 P$=F$:GOSUB730:OPEN1,DV,0,"$"+DR$+":*"
  176. 1850 GOSUB1010:IFER$>"01"THENCLOSE1:P$=F$+ES$:GOSUB730:RETURN
  177. 1860 GET#1,A$:GET#1,A$
  178. 1870 GET#1,A$:GET#1,A$:IF(ST)AND64THENCLOSE1:RETURN
  179. 1880 GET#1,LO$:GET#1,HI$
  180. 1890 LO$=LO$+N$:HI$=HI$+N$
  181. 1900 P$=STR$(ASC(LO$+CHR$(0))+256*ASC(HI$+CHR$(0)))+" "
  182. 1910 GET#1,A$:IFA$=""THEN1950
  183. 1920 GET#5,Z$:IFZ$=""THENGETZ$
  184. 1930 IFZ$=" "THENCLOSE1:RETURN
  185. 1940 P$=P$+A$:GOTO1910
  186. 1950 IFECANDMID$(P$,8,1)="("THEN1870
  187. 1960 GOSUB730:IFA$=" "THENCLOSE1:RETURN
  188. 1970 GOTO1870
  189. 1980 FI$="(USER LOG)"
  190. 1990 OPEN1,DV,5,DR$+":"+FI$:P$="":GOSUB1010:IFER$>"01"THENCLOSE1:RETURN
  191. 2000 GET#1,A$:IF(ST)AND64THEN2050
  192. 2010 GET#5,Z$:IFZ$=""THENGETZ$
  193. 2020 IFZ$=" "ORZ$="/"THEN2050
  194. 2030 IFA$=CHR$(13)ORLEN(P$)=39THENGOSUB730:P$="":GOTO2000
  195. 2040 P$=P$+A$:GOTO2000
  196. 2050 GOSUB730:CLOSE1:P$=F$+"[211]CRATCH? (Y/N):":GOSUB740:L=1:GOSUB780
  197. 2060 IFL$=""OR(L$<>"Y"ANDL$<>"[217]")THENRETURN
  198. 2070 OPEN1,DV,5,"@"+DR$+":"+FI$+",S,W":PRINT#1," ":CLOSE1:RETURN
  199. 2080 FI$="(T.CALLERS)":GOTO1990
  200. 2090 P$=F$+"[211]CAN FILE: ":GOSUB740:L=16:GOSUB780
  201. 2100 FI$=L$+"":GOTO1990
  202. 2110 POKEB3,65:POKEB4,40:POKEB2,231:POKEB1,57:POKEB4,48:RETURN
  203. 2120 GOSUB2110:POKEB2,PEEK(B2)OR32:POKEB1,PEEK(B1)AND223:POKEB1,PEEK(B1)OR32
  204. 2130 POKEB1,PEEK(B1)AND223:POKEB4,40:POKEB4,47:POKEB2,230:GOSUB2110:RETURN
  205. 2140 HI=INT(RC/256):LO=RC-(HI*256):RETURN
  206. 2150 GOSUB2140:R1=LO:R2=HI:RETURN
  207. 2160 AC=VAL(U$(3)):A2=INT(AC/256):A1=AC-A2*256:RETURN
  208. 2170 AA=VAL(N$(3)):RETURN
  209. 2180 IFLEN(UL$)<230THENRETURN
  210. 2190 OPEN1,8,5,"0:(USER LOG),A":PRINT#1,UL$:CLOSE1:UL$="":RETURN
  211. 2200 GOSUB2210:FORI=1TO15:U$(I)=N$(I):NEXT:RETURN
  212. 2210 FORT=1TO15:INPUT#3,N$(T):NEXT:RETURN
  213. 2220 FORI=1TO15:N$(I)=U$(I):NEXT
  214. 2230 N$(0)="":FORT=1TO15:N$(0)=N$(0)+Q$+N$(T)+CHR$(13):NEXT
  215. 2240 PRINT#3,N$(0):RC=1:GOSUB970:RETURN
  216. 2250 RETURN
  217. 2260 B=AA-8:IFB<0THENB=0
  218. 2270 AA=-((DR%(B)AND128)=128):DR$=MID$(STR$(AA),2):RETURN
  219. 2280 GOSUB2260:AA=-((DVAND128)=128):DR$=MID$(STR$(AA),2):RETURN
  220. 2290 IFDR$="0"THENAA=DV:GOSUB2260:IFDR$="1"THENRETURN
  221. 2300 DV=DV+1:IFDV>15THENDV=8
  222. 2310 FORL=0TO(DR-8):IFDV<>(DR%(L)AND63)THENNEXT:GOTO2300
  223. 2320 IFA1AND32ORSYTHEN2340
  224. 2330 AA=DV:GOSUB2260:IFDR%(B)AND64THEN2300
  225. 2340 AA=DV:GOSUB2260:DR$="0":RETURN
  226. 2350 ON(MT%-1)GOTO2360,2370,2400,2410,2120,2120
  227. 2360 POKEB2,PEEK(B2)OR32:POKEB1,PEEK(B1)AND223:RETURN
  228. 2370 FORT=1TO2000:NEXT:PRINT#5,"+++";:FORT=1TO2000:NEXT:PRINT#5,"[193][212][200]"+CHR$(13)
  229. 2380 FORT=1TO2000:NEXT:PRINT#5,"[193][212][218]"+CHR$(13):FORT=1TO2000:NEXT
  230. 2390 PRINT#5,"[193][212][205]0"+CHR$(13)::FORT=1TO2000:NEXT:PRINT#5,"[193][212][214]0"+CHR$(13):RETURN
  231. 2400 POKEB2,38:POKEB1,38:RETURN
  232. 2410 POKEB1,PEEK(B1)OR32:RETURN
  233. 2420 GOSUB1030:CT=VAL(HO$):MI=VAL(MI$):CO=ABS((LH*60+LM)-(CT*60+MI))
  234. 2430 IFLH=12ANDC2THENCO=ABS(CO-720)
  235. 2440 RETURN
  236. 2450 OPEN3,8,3,"0:(SCORES)":GOSUB220:IFER$>"01"THENCLOSE3:RETURN
  237. 2460 RC=R:GOSUB2150:B=0:GOSUB980:GET#3,A$:IF(ST)AND64THENSC=0:GOTO2480
  238. 2470 INPUT#3,SC
  239. 2480 IFSC=0THENSC=I:CLOSE3:DIMSC(SC):RETURN
  240. 2490 IFI>SCTHENDIMSC(I):GOTO2510
  241. 2500 DIMSC(SC)
  242. 2510 FORT=1TOSC:INPUT#3,SC(T):NEXT:CLOSE3:IFI>SCTHENSC=I
  243. 2520 RETURN
  244. 2530 OPEN3,8,3,"0:(SCORES)":GOSUB220:IFER$>"01"THENCLOSE3:RETURN
  245. 2540 RC=R:GOSUB2140:B=0:GOSUB980:SC$=STR$(SC)+CHR$(13):FORT=1TOSC
  246. 2550 SC$=SC$+STR$(SC(T))+CHR$(13):NEXT:PRINT#3,SC$;:RC=1:GOSUB980:CLOSE3:RETURN
  247. 2560 FI$="(ST/R 3.7)":DV=D5
  248. 2570 OPEN1,8,5,"@0:(DATA),S,W":PRINT#1,R$:AA=DV:GOSUB2280:FORT=1TO15
  249. 2580 PRINT#1,Q$U$(T):NEXT:PRINT#1,LH:PRINT#1,LM:PRINT#1,SA:PRINT#1,SY
  250. 2590 PRINT#1,SF:PRINT#1,HL:PRINT#1,M$:PRINT#1,DT:PRINT#1,LEN(F$):PRINT#1,Q$LN$
  251. 2600 PRINT#1,DV:PRINT#1,NW:PRINT#1,L$:PRINT#1,HM$:CLOSE1:POKE252,32
  252. 2610 POKE251,PEEK(152):PRINT"[146][147]LOAD"Q$DR$":"FI$Q$","DVAND127""
  253. 2620 POKE631,131:POKE198,1:NEW
  254. 2630 OPEN1,8,5,"0:(DATA)":INPUT#1,R$:R=VAL(R$):FORT=1TO15
  255. 2640 INPUT#1,U$(T):NEXT:INPUT#1,LH,LM,SA,SY,SF,HL,M$,DT,T,LN$,DV,NW,L$
  256. 2650 HM$="":FORI=1TO200:GET#1,A$:IFA$=""THENA$=CHR$(0)
  257. 2660 HM$=HM$+A$:NEXT
  258. 2670 CLOSE1:GOSUB2160:CG=VAL(U$(8)):IFT=2THENF$=CHR$(13)+CHR$(10)
  259. 2680 REM -----------------------------
  260. 2690 REM -    YOUR PROGRAM SHOULD    -
  261. 2700 REM -    START AT LINE 3160!    -
  262. 2710 REM -----------------------------
  263. 2720 GOSUB2420:C5=CO
  264. 2730 T=RND(-RND(-TI)):GOSUB370:DZ=DV:I=18:GOSUB430
  265. 2740 SS=SC(18)
  266. 2750 P$=F$+U$(1)+", YOU HAVE $"+MID$(STR$(SS),2)+".00":GOSUB160
  267. 2760 OPEN1,DVAND127,5,DR$+":(TOPTEN)":GOSUB220
  268. 2770 DIMTT$(10),TT(10):IFER$>"01"THENCLOSE1:GOTO2790
  269. 2780 FORT=1TO10:INPUT#1,TT$(T),TT(T):NEXT:CLOSE1
  270. 2790 DEFFNR(X)=INT(RND(0)*X)+1:IFSS>0THEN2810
  271. 2800 SS=500:P$="[212]HE [200]OUSE HAS GIVEN A"+STR$(SS)+".00 CREDIT!":GOSUB160
  272. 2810 P$="? - [196]ISPLAY MENU.":GOSUB160
  273. 2820 GOSUB250:P$=F$+"[154]$"+MID$(STR$(SS),2)+":":GOSUB170:L=1:GOSUB180
  274. 2830 IFCDTHENGOSUB390:GOTO410
  275. 2840 IFL$=""THEN2820
  276. 2850 E$=CHR$(ASC(L$)AND127):IFE$="Q"THEN3020
  277. 2860 IFE$="?"THEN2920
  278. 2870 IFE$="Y"THENGOSUB190
  279. 2880 IFE$="H"THENGOSUB2980
  280. 2890 IFE$<"A"ORE$>"E"THEN2820
  281. 2900 ONASC(E$)-64GOSUB3030,3520,3880,4390,4790:GOTO2820
  282. 2910 RETURN
  283. 2920 P$=" [147]"+DC$+F$+"        -+*$[ [195]ASINO [205]ENU ]$*+-"+F$+DC$+F$:GOSUB160
  284. 2930 P$="[193] - [196]ICE               [196] - [193]CEY-[196]UCEY":GOSUB160
  285. 2940 P$="[129][194] - [195]RAPS              [197] - [194]LACK [202]ACK":GOSUB160
  286. 2950 P$="[158][195] - [211]LOTS              [200] - [200]IGH [211]CORES":GOSUB160
  287. 2960 P$="[217] - [217]ELL FOR [211]YSOP     ? - [212]HIS MENU":GOSUB160
  288. 2970 P$="[209] - [210]ETURN TO [194][194][211]":GOSUB160:GOTO2820
  289. 2980 P$=F$+"[212]OP [212]EN [200]IGH [211]CORES:"+F$:GOSUB160
  290. 2990 FORT=1TO10:P$=MID$(STR$(T),(-(T>9))+1)+". "
  291. 3000 P$=P$+LEFT$(TT$(T)+"                     ",20)+STR$(TT(T))+".00"
  292. 3010 GOSUB160:NEXT:RETURN
  293. 3020 DV=DZ:GOSUB370:SC(18)=SS:GOSUB440:GOTO410
  294. 3030 P$=F$+"[129][217]OU HAVE NOW ENTERED THE GAME OF [196]ICE!":GOSUB160
  295. 3040 P$=F$+"[212]HE [210]ULES ARE SIMPLE.  [217]OU PICK A":GOSUB160
  296. 3050 P$="NUMBER BETWEEN 1 AND 6.  [201] WILL ROLL":GOSUB160
  297. 3060 P$="THREE DICE.  [212]HE ODDS ARE:"+F$:GOSUB160
  298. 3070 P$="1 MATCH   = 1 TO 1 ODDS.":GOSUB160
  299. 3080 P$="2 MATCHES = 2 TO 1 ODDS.":GOSUB160
  300. 3090 P$="3 MATCHES = 5 TO 1 ODDS."+F$+F$+"[210][197][212][213][210][206] ABORTS GAME.":GOSUB160
  301. 3100 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: ":GOSUB170
  302. 3110 L=20:GOSUB180:IFCDORL$=""THENRETURN
  303. 3120 IFL$="?"THEN3040
  304. 3130 BT=VAL(L$):IFBT<1ORBT>SSTHEN3100
  305. 3140 P$=F$+"[217]OUR BET STANDS AT "+L$:GOSUB160
  306. 3150 P$="[206]UMBER TO BET ON? (1-6): ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  307. 3160 IFL$=""THENP$=F$+"[194]ET ABORTED, [195]HICKEN....":GOSUB160:GOTO3100
  308. 3170 IFL$<"1"ORL$>"6"THEN3150
  309. 3180 D0=VAL(L$):D2=0:FORT=1TO3:D1=FNR(6):N=D1:GOSUB3220:IFD1=D0THEND2=D2+1
  310. 3190 NEXT:IFD2=0THENSS=SS-BT:P$=F$+"[150][211]ORRY, NO MATCHES.  [217]OU LOSE!":GOSUB160:GOTO3100
  311. 3200 P$="[156][195]ONGRATULATIONS!!  [217]OU HAVE"+STR$(D2)+" MATCHES!!":GOSUB160
  312. 3210 SS=SS+BT*(-(D2=1)-2*(D2=2)-5*(D2=3)):GOSUB3440:GOTO3100
  313. 3220 P$=F$:GOSUB160:GOSUB3240:GOSUB3280:ONNGOSUB3380,3390,3400,3410,3420,3430
  314. 3230 GOSUB3280:GOSUB3260:RETURN
  315. 3240 P$=",-------,":IFCGTHENP$="[176][192][192][192][192][192][192][192][174]"
  316. 3250 GOSUB160:RETURN
  317. 3260 P$="'-------'":IFCGTHENP$="[173][192][192][192][192][192][192][192][189]"
  318. 3270 GOSUB160:RETURN
  319. 3280 P$="!       !":IFCGTHENP$="[221]       [221]"
  320. 3290 GOSUB160:RETURN
  321. 3300 P$="!   *   !":IFCGTHENP$="[221]   *   [221]"
  322. 3310 GOSUB160:RETURN
  323. 3320 P$="! *     !":IFCGTHENP$="[221] *     [221]"
  324. 3330 GOSUB160:RETURN
  325. 3340 P$="!     * !":IFCGTHENP$="[221]     * [221]"
  326. 3350 GOSUB160:RETURN
  327. 3360 P$="! *   * !":IFCGTHENP$="[221] *   * [221]"
  328. 3370 GOSUB160:RETURN
  329. 3380 GOSUB3280:GOSUB3300:GOSUB3280:RETURN
  330. 3390 GOSUB3320:GOSUB3280:GOSUB3340:RETURN
  331. 3400 GOSUB3320:GOSUB3300:GOSUB3340:RETURN
  332. 3410 GOSUB3360:GOSUB3280:GOSUB3360:RETURN
  333. 3420 GOSUB3360:GOSUB3300:GOSUB3360:RETURN
  334. 3430 GOSUB3360:GOSUB3360:GOSUB3360:RETURN
  335. 3440 FORT=1TO10:IFSS<=TT(T)THENNEXT:RETURN
  336. 3450 IFT=10THENTT(T)=SS:TT$(T)=U$(1):GOTO3470
  337. 3460 FORI=9TOTSTEP-1:TT(I+1)=TT(I):TT$(I+1)=TT$(I):NEXT:TT(T)=SS:TT$(T)=U$(1)
  338. 3470 P$=F$+F$+"[156][195][207][206][199][210][193][212][213][204][193][212][201][207][206][211]!!!!"+F$+"[153][217]OU ARE A TOP [212][197][206] WINNER!!!!"
  339. 3480 GOSUB160:P$=F$+"[217]OU NOW HOLD THE #"+MID$(STR$(T),2)+" POSITION."+F$
  340. 3490 GOSUB160:DV=DZ:GOSUB370:OPEN1,DVAND127,5,"@"+DR$+":(TOPTEN),S,W":GOSUB220
  341. 3500 IFER$>"01"THENRETURN
  342. 3510 FORT=1TO10:PRINT#1,TT$(T)","TT(T):NEXT:CLOSE1:RETURN
  343. 3520 P$=F$+"[159][217]OU ARE NOW ENTERING [195]RAPS.":GOSUB160
  344. 3530 P$=F$+"[201]F YOU ROLL A 2, 3 OR 12 ON YOUR FIRST":GOSUB160
  345. 3540 P$="ROLL, YOU LOSE.  [201]F YOU ROLL A 7 OR 11":GOSUB160
  346. 3550 P$="ON YOUR FIRST ROLL YOU WIN.":GOSUB160
  347. 3560 P$="[207]THERWISE, THE DICE ARE ROLLED UNTIL":GOSUB160
  348. 3570 P$="THE TOTAL OF THE FIRST ROLL IS ROLLED":GOSUB160
  349. 3580 P$="AGAIN.  [201]N WHICH CASE YOU WIN.":GOSUB160
  350. 3590 P$="[201]F, AFTER THE FIRST ROLL, YOU ROLL A":GOSUB160
  351. 3600 P$="7 OR 11, YOU LOSE (CRAP OUT).":GOSUB160
  352. 3610 P$=F$+"[210][197][212][213][210][206] AT BET ABORTS GAME.":GOSUB160
  353. 3620 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  354. 3630 GOSUB170:L=20:GOSUB180:IFCDORL$=""THENRETURN
  355. 3640 IFL$="?"THEN3530
  356. 3650 BT=VAL(L$):IFBT<1ORBT>SSTHEN3620
  357. 3660 P$=F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+"[208]RESS [210][197][212][213][210][206] TO ROLL. [209] - [209]UITS: "
  358. 3670 GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  359. 3680 IFL$="Q"ORL$="[209]"THEN3620
  360. 3690 D1=FNR(6):N=D1:GOSUB3220:D2=FNR(6):N=D2:GOSUB3220:D0=D1+D2
  361. 3700 P$=F$+"[217]OUR TOTAL IS:"+STR$(D0):GOSUB160
  362. 3710 IFD0=2ORD0=3ORD0=12THEN3790
  363. 3720 IFD0=7ORD0=11THEN3850
  364. 3730 P$=F$+"[208]RESS [210][197][212][213][210][206] TO ROLL AGAIN: ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  365. 3740 D1=FNR(6):N=D1:GOSUB3220:D2=FNR(6):N=D2:GOSUB3220:D3=D1+D2
  366. 3750 P$=F$+"[217]OUR TOTAL IS:"+STR$(D3):GOSUB160
  367. 3760 IFD3=7ORD3=11THEN3830
  368. 3770 IFD3=D0THEN3860
  369. 3780 P$=F$+"[196]OES NOT MATCH YOUR FIRST ROLL OF"+STR$(D0):GOSUB160:GOTO3730
  370. 3790 IFD0=2THENP$="[211]NAKE [197]YES!"
  371. 3800 IFD0=3THENP$="[195]OCK [197]YES!"
  372. 3810 IFD0=12THENP$="[194]OX [195]ARS!"
  373. 3820 GOSUB160:GOTO3840
  374. 3830 P$="[217]OU CRAPPED OUT!":GOSUB160
  375. 3840 P$="[217]OU LOSE YOUR BET!!":GOSUB160:SS=SS-BT:GOTO3620
  376. 3850 P$="[193] NATURAL!":GOSUB160:GOTO3870
  377. 3860 P$="[217]OU MATCHED YOUR FIRST ROLL!":GOSUB160
  378. 3870 P$="[217]OU [215][201][206] YOUR BET!":GOSUB160:SS=SS+BT:GOSUB3440:GOTO3620
  379. 3880 P$=F$+"[150][215]ELCOME TO [211]LOTS, [207]NE [193]RMED [194]ANDITS!":GOSUB160
  380. 3890 P$=F$+"[212]HE RULES ARE SIMPLE:  [217]OU MAY BET":GOSUB160
  381. 3900 P$="[199]OLD [195]HIPS WORTH $1.00, $2.00, $5.00,":GOSUB160
  382. 3910 P$="$10.00, $20.00.  [212]HE PAYOFFS ARE:"+F$:GOSUB160
  383. 3920 P$="3 [194]ARS --------------- 100 TO 1":GOSUB160
  384. 3930 P$="3 [194]ELLS --------------  80 TO 1":GOSUB160
  385. 3940 P$="3 [204]EMONS -------------  50 TO 1":GOSUB160
  386. 3950 P$="3 [208]LUMS --------------  30 TO 1":GOSUB160
  387. 3960 P$="3 [208]EACHES ------------  25 TO 1":GOSUB160
  388. 3970 P$="2 [194]ARS, 1 [194]ELL -------  10 TO 1":GOSUB160
  389. 3980 P$="2 [194]ELLS, 1 [204]EMON -----   9 TO 1":GOSUB160
  390. 3990 P$="2 [204]EMONS, 1 [208]LUM -----   8 TO 1":GOSUB160
  391. 4000 P$="2 [208]LUMS, 1 [208]EACH -----   7 TO 1":GOSUB160
  392. 4010 P$="2 [208]EACHES, 1 [207]RANGE --   5 TO 1":GOSUB160
  393. 4020 P$="2 [207]RANGES, [193]NYTHING --   2 TO 1":GOSUB160
  394. 4030 P$=F$+"[210][197][212][213][210][206] AT BET ABORTS GAME.":GOSUB160
  395. 4040 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  396. 4050 GOSUB170:L=2:GOSUB180:IFCDORL$=""THENRETURN
  397. 4060 IFL$="?"THEN3890
  398. 4070 BT=VAL(L$):IFBT<1ORBT>SSTHEN4040
  399. 4080 IFBT=1ORBT=2ORBT=5ORBT=10ORBT=20THEN4100
  400. 4090 P$=F$+"[207]NLY BET $1, $2, $5, $10, OR $20!!":GOSUB160:GOTO4040
  401. 4100 P$=F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+"[208]RESS [210][197][212][213][210][206] TO PULL LEVER. "
  402. 4110 P$=P$+F$+"[209] - [209]UITS: ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  403. 4120 IFL$="Q"ORL$="[209]"THEN4040
  404. 4130 H$(1)="[194]AR":H$(2)="[194]ELL":H$(3)="[204]EMON":H$(4)="[208]LUM":H$(5)="[208]EACH"
  405. 4140 H$(6)="[207]RANGE":D1=FNR(6):P$=F$+H$(D1):GOSUB160
  406. 4150 D2=FNR(6):P$="            "+H$(D2):GOSUB160
  407. 4160 D3=FNR(6):P$="                        "+H$(D3):GOSUB160:D0=0
  408. 4170 IF(D1=1)AND(D2=1)AND(D3=1)THEND0=100
  409. 4180 IF(D1=2)AND(D2=2)AND(D3=2)THEND0=80
  410. 4190 IF(D1=3)AND(D2=3)AND(D3=3)THEND0=50
  411. 4200 IF(D1=4)AND(D2=4)AND(D3=4)THEND0=30
  412. 4210 IF(D1=5)AND(D2=5)AND(D3=5)THEND0=25
  413. 4220 IF(D1=6)AND(D2=6)AND(D3=6)THEND0=2
  414. 4230 IFD0>0THEN4350
  415. 4240 FORT=1TO6:D(T)=0:NEXT
  416. 4250 D(D1)=D(D1)+1:D(D2)=D(D2)+1:D(D3)=D(D3)+1
  417. 4260 FORT=1TO6:IFD(T)<>2THENNEXT:GOTO4380
  418. 4270 FORI=1TO6:IFD(I)<>1THENNEXT:GOTO4380
  419. 4280 IFT=1ANDI=2THEND0=10
  420. 4290 IFT=2ANDI=3THEND0=9
  421. 4300 IFT=3ANDI=4THEND0=8
  422. 4310 IFT=4ANDI=5THEND0=7
  423. 4320 IFT=5ANDI=6THEND0=5
  424. 4330 IFT=6THEND0=2
  425. 4340 IFD0=0THEN4380
  426. 4350 IFD0=100THENP$=F$+F$+"              [202][129][193][158][195][203][159][208][207][156][212][152]!!!!"+F$:GOSUB160
  427. 4360 P$="[156][217]OU WIN AT"+STR$(D0)+" TO 1 ODDS!":GOSUB160:SS=SS+(BT*D0)
  428. 4370 GOSUB3440:GOTO4040
  429. 4380 P$=F$+"[217]OU LOSE YOUR BET.":GOSUB160:SS=SS-BT:GOTO4040
  430. 4390 P$=F$+"[158][211]O YOU WANT TO PLAY [193]CEY-[196]UCY!":GOSUB160
  431. 4400 P$=F$+"[212]HIS GAME IS SIMILAR TO THE ACTUAL":GOSUB160
  432. 4410 P$="CARD GAME, WITH THE EXCEPTION THAT":GOSUB160
  433. 4420 P$="NO [211]PLITS ARE ALLOWED.":GOSUB160
  434. 4430 P$=F$+"[217]OU WILL BE DEALT TWO CARDS.  [201]F THE":GOSUB160
  435. 4440 P$="THIRD CARD DEALT NUMERICALLY LIES":GOSUB160
  436. 4450 P$="BETWEEN THE FIRST TWO, YOU WIN YOUR":GOSUB160
  437. 4460 P$="BET.  [207]THERWISE, YOU LOSE.  [212]HE SECOND":GOSUB160
  438. 4470 P$="THE SECOND CARD CAN COUNT AS EITHER     1 OR 14.":GOSUB160
  439. 4480 P$=F$+"[210][197][212][213][210][206] AT BET ABORTS GAME.":GOSUB160
  440. 4490 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  441. 4500 GOSUB170:L=10:GOSUB180:IFCDORL$=""THENRETURN
  442. 4510 IFL$="?"THEN4400
  443. 4520 BT=VAL(L$):IFBT<1ORBT>SSTHEN4490
  444. 4530 P$=F$+"[217]OUR BET STANDS AT "+L$+F$+"[208]RESS [210][197][212][213][210][206] FOR DEAL. [209] - [209]UIT: "
  445. 4540 GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  446. 4550 IFL$="Q"ORL$="[209]"THENP$=F$+"[195]AN'T TAKE THE [200][197][193][212]?":GOSUB160:GOTO4490
  447. 4560 D$(1)="[202]ACK":D$(2)="[209]UEEN":D$(3)="[203]ING":D1=FNR(13):D2=FNR(13)
  448. 4570 IFD1=1THENP$="[193]CE":GOTO4590
  449. 4580 P$=MID$(STR$(D1),2):IFD1>10THENP$=D$(D1-10)
  450. 4590 P$=LEFT$(P$+"                    ",20)
  451. 4600 IFD2=1THEND$="[193]CE":GOTO4620
  452. 4610 D$=MID$(STR$(D2),2):IFD2>10THEND$=D$(D2-10)
  453. 4620 P$=F$+P$+D$:GOSUB170:IFD2>1THEN4660
  454. 4630 P$="=(1 OR 14): ":GOSUB170:L=2:GOSUB180:IFCDTHENRETURN
  455. 4640 IFL$<>"1"ANDL$<>"14"THENP$="":GOTO4570
  456. 4650 D2=VAL(L$)
  457. 4660 P$=F$+F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+"[210][197][212][213][210][206] FOR THIRD CARD."
  458. 4670 P$=P$+F$+"[196] - [196]OUBLE BET: ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  459. 4680 IFL$<>"D"ANDL$<>"[196]"THEN4710
  460. 4690 IFBT*2>SSTHENP$=F$+"[206]OT ENOUGH TO [196]OUBLE!":GOSUB160:GOTO4710
  461. 4700 BT=BT*2
  462. 4710 D3=FNR(13):IFD3=1THENP$="[193]CE":GOTO4730
  463. 4720 P$=MID$(STR$(D3),2):IFD3>10THENP$=D$(D3-10)
  464. 4730 L=10-INT(LEN(P$)/2):P$=F$+RIGHT$("          ",L)+P$:GOSUB160
  465. 4740 IF(D3<D1ORD3>D2)AND(D1<D2)THEN4780
  466. 4750 IF(D3<D2ORD3>D1)AND(D2<D1)THEN4780
  467. 4760 IFD1=D2ANDD3<>D1THEN4780
  468. 4770 P$=F$+"[156][217]OU WON YOUR BET!":GOSUB160:SS=SS+BT:GOSUB3440:GOTO4490
  469. 4780 P$=F$+"[211]ORRY, YOU LOSE.":GOSUB160:SS=SS-BT:GOTO4490
  470. 4790 P$=F$+"[217]OU'VE COME TO THE [194]LACK [202]ACK TABLE!":GOSUB160
  471. 4800 P$=F$+"[200]ERE, YOU TRY TO GET A HAND OF CARDS":GOSUB160
  472. 4810 P$="CLOSE OR EQUAL TO 21 WITHOUT GOING":GOSUB160
  473. 4820 P$="OVER.  [195]LOSER THAN THE [195]OMPUTER/[196]EALER":GOSUB160
  474. 4830 P$="IS.  [217]OU CAN DOUBLE YOUR BET IF YOU":GOSUB160
  475. 4840 P$="THINK YOU HAVE A WINNING HAND.  [207]N":GOSUB160
  476. 4850 P$="TIES, THE PLAYER WINS.  [212]HE [196]EALER":GOSUB160
  477. 4860 P$="ALWAYS WINS WITH A NATURAL BLACK [202]ACK.":GOSUB160
  478. 4870 P$="[201]F YOU HAVE 5 OR MORE CARDS WITH OUT":GOSUB160
  479. 4880 P$="GOING OVER 21, YOU AUTOMATICALLY WIN!":GOSUB160
  480. 4890 P$=F$+"[210][197][212][213][210][206] AT INITAL BET ABORTS.":GOSUB160
  481. 4900 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  482. 4910 GOSUB170:L=10:GOSUB180:IFCDORL$=""THENRETURN
  483. 4920 IFL$="?"THEN4800
  484. 4930 BT=VAL(L$):IFBT<1ORBT>SSTHEN4900
  485. 4940 D0=0:P0=0:C$(1)="[202]ACK":C$(2)="[209]UEEN":C$(3)="[203]ING":D=2:P=2
  486. 4950 D(1)=FNR(13):D(2)=FNR(13):C$=MID$(STR$(D(2)),2):IFD(2)>10THENC$=C$(D(2)-10)
  487. 4960 P(1)=FNR(13):P(2)=FNR(13):P0=P(1)+P(2):DB=1:IFD(2)=1THENC$="[193]CE"
  488. 4970 P$=F$+"[196]EALER HAS A "+C$+" SHOWING.":GOSUB160
  489. 4980 P$=F$+"[217]OU HAVE:":GOSUB160:P$=F$:FORT=1TOP
  490. 4990 C$=MID$(STR$(P(T)),2):IFP(T)>10THENC$=C$(P(T)-10)
  491. 5000 IFP(T)=1ORP(T)=14THENC$="[193]CE"
  492. 5010 P$=P$+C$+", ":NEXT:GOSUB160
  493. 5020 IFP>2THENJ=P:GOTO5040
  494. 5030 FORJ=1TOP:IFP(J)<>1THENNEXT:GOTO5080
  495. 5040 IFP(J)<>1THEN5080
  496. 5050 P$=F$+"[215]ILL YOUR [193]CE = (1 OR 11): ":GOSUB170:L=2:GOSUB180:IFCDTHENRETURN
  497. 5060 IFL$<>"1"ANDL$<>"11"THEN5050
  498. 5070 P(J)=VAL(L$)-3*(L$="11"):IFP=2THENNEXT
  499. 5080 P0=0:FORT=1TOP:P1=P(T):IFP1>10THENP1=10-1*(P1=14)
  500. 5090 P0=P0+P1:NEXT:P$=F$+"[217]OU HAVE A TOTAL OF"+STR$(P0)
  501. 5100 GOSUB160:IFP0>21THEN5370
  502. 5110 IFP=5THEN5360
  503. 5120 D$="":IFDBTHEND$="[196] - [196]OUBLE, "
  504. 5130 P$=F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+D$+"[200] - HIT, [211] - [211]TAND: "
  505. 5140 GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  506. 5150 IFL$="H"ORL$="[200]"THENP=P+1:P(P)=FNR(13):GOTO4980
  507. 5160 IFL$="S"ORL$="[211]"THEN5200
  508. 5170 IF(L$<>"D"ANDL$<>"[196]")ORDB=0THEN5080
  509. 5180 IFBT*2>SSTHENP$=F$+"[206]OT ENOUGH MONEY TO [196]OUBLE.":GOSUB160:GOTO5080
  510. 5190 BT=BT*2:DB=0:GOTO5080
  511. 5200 P1=P0-P(1):IFP(1)>10THENP1=P0-10-(P(1)=14):IFFNR(1)>.35THENP1=P0
  512. 5210 P$=F$+"[196]EALER HAS:":GOSUB160
  513. 5220 D0=0:FORT=1TOD:D1=D(T):IFD1>10THEND1=10-(D1=14)
  514. 5230 D0=D0+D1:NEXT
  515. 5240 IFD>2THEN5270
  516. 5250 IFD(1)=1ANDD0<12THEND(1)=14:GOTO5220
  517. 5260 IFD(2)=1ANDD0<12THEND(2)=14:GOTO5220
  518. 5270 P$=F$:FORT=1TOD:C$=MID$(STR$(D(T)),2):IFD(T)>10THENC$=C$(D(T)-10)
  519. 5280 IFD(T)=1ORD(T)=14THENC$="[193]CE"
  520. 5290 P$=P$+C$+", ":NEXT:GOSUB160
  521. 5300 P$=F$+"[198]OR A TOTAL OF"+STR$(D0):GOSUB160:IFD0>21THEN5350
  522. 5310 IFD0=21ANDD=2THENP$=F$+"[196]EALER HAS  A NATURAL 21! [217]OU LOSE.":GOTO5390
  523. 5320 IFD0>P1ANDD0>17THEN5410
  524. 5330 FORT=1TO3000:NEXT
  525. 5340 P$="[196]EALER TAKES A HIT.":GOSUB160:D=D+1:D(D)=FNR(13):GOTO5210
  526. 5350 P$=F$+"[212]HE [196]EALER [194][213][211][212][197][196]!!  [217]OU WIN!!":GOTO5400
  527. 5360 P$=F$+"[198]IVE CARDS!! [193]UTOMATIC WIN!!":GOTO5400
  528. 5370 P$=F$+"[217]OU [194]USTED! [196]EALER WINS!":GOTO5390
  529. 5380 P$=F$+"[212]HE [196]EALER WINS!!"
  530. 5390 GOSUB160:SS=SS-BT:GOTO4900
  531. 5400 GOSUB160:SS=SS+BT:GOSUB3440:GOTO4900
  532. 5410 P$=F$+"[212]HE [196]EALER STANDS AT"+STR$(D0):GOSUB160
  533. 5420 IFP0=>D0THENP$=F$+"[217]OU WIN YOUR BET!":GOTO5400
  534. 5430 GOTO5380
  535. 5440 P$=F$+"[217]OU HAVE EXCEDED YOUR TIME TO PLAY"+F$+"THE CASINO!!":GOSUB160
  536. 5450 P$=F$+"[210]ETURNING TO [194][194][211].":GOSUB160:POKE679,254:GOTO3020
  537.