home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-scene-files / Coverdisks / CS / CSCD023B.D64 / dskenveloper.exe (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  10.6 KB  |  287 lines
  1. 5 REM MAKE DISK ENVELOPES WITH THE DISK DIRECTORY ON IT
  2. 10 REM JOSEPH SHAUGHNESSY  1985
  3. 15 B=53280:SC=53281:CC=646:PRINT"[147]"CHR$(14)CHR$(8)
  4. 20 M=(PEEK(B)AND15):N=(PEEK(SC)AND15):O=PEEK(CC)
  5. 25 S1=54273:S2=54278:S3=54296:S4=54276
  6. 30 Z$="         ":M0$="     [196]ELETE PROGRAMS AT YOUR OPTION!   [146]"
  7. 35 CD$="":DC$="                                      "
  8. 40 M1$=" [208]ROGRAMS MUST BE DELETED TO FIT [146]":FL$="                    "
  9. 45 NP$=CHR$(15):EX$=CHR$(14):GX$=CHR$(8):LF$=CHR$(10)
  10. 50 PRINTZ$"[176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174]"
  11. 55 PRINTZ$"[221]                     [221]"
  12. 60 PRINTZ$"[221] [196]ISK [197]NVELOPE [205]AKER [221]"
  13. 65 PRINTZ$"[221]        WITH         [221]"
  14. 70 PRINTZ$"[221]  [196]IRECTORY [208]RINTER  [221]"
  15. 75 PRINTZ$"[221]       FOR THE       [221]"
  16. 80 PRINTZ$"[221]     [195][207][205][205][207][196][207][210][197] 64    [221]"
  17. 85 PRINTZ$"[221]                     [221]"
  18. 90 PRINTZ$"[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]"
  19. 95 PRINTZ$Z$"BY"
  20. 100 PRINTZ$"[202]OSEPH [202]. [211]HAUGHNESSY"
  21. 105 PRINT"  [211]ERENDIPITY'S [211]HAREWAIRE [196]ISK [214]OL. 1 "
  22. 110 PRINTZ$"      (C) 1985":KIZIAK=49408
  23. 115 SZ=61:DIMA$(SZ),B$(SZ),D$(145)
  24. 120 FORX=0TOSZ:A$(X)=" ":B$(X)=" ":NEXT
  25. 125 FORX=0TO145:D$(X)=FL$:NEXT:IFRP=1THEN1035
  26. 130 GOSUB1240:GOSUB63999:GOTO1035
  27. 135 REM SUBROUTINES
  28. 140 POKES1,70:POKES2,247:POKES3,15:POKES4,17:POKES4,16:GOTO150
  29. 145 POKES1,30:POKES2,249:POKES3,15:POKES4,17:POKES4,16:GOTO150
  30. 150 RETURN
  31. 155 POKE198,0:REM WAIT FOR KEYSTROKE
  32. 160 GETW$:IFW$=""THEN160
  33. 165 RETURN
  34. 170 REM CHECK DISK ERROR CONDITION
  35. 175 INPUT#15,E,E$,E1,E2
  36. 180 IFE=0THEN210
  37. 185 PRINT"[196]ISK [197]RROR # :"E
  38. 190 PRINT"[197]RROR [212]YPE :"E$
  39. 195 PRINT"[212]RACK   :"E1"  [211]ECTOR   :"E2
  40. 200 FORWW=1TO20:GOSUB145:FORTT=1TO100:NEXT:NEXT
  41. 205 PRINT"[198]IX THE PROBLEM, AND THEN TYPE [210][213][206] TO   BEGIN AGAIN!":END
  42. 210 RETURN
  43. 215 REM READ DISK DIRECTORY
  44. 220 CLOSE1:CLOSE15:OPEN15,8,15,"I0":GOSUB175:OPEN1,8,0,"$":GOSUB175
  45. 225 GET#1,M$,M$:S$="                ":S=0
  46. 230 GET#1,M$,M$,M$,N$:C=0
  47. 235 IFM$<>""THENC=ASC(M$)
  48. 240 IFN$<>""THENC=C+ASC(N$)*256
  49. 245 D$(S)=MID$(STR$(C)+S$,2,3):C$=""
  50. 250 GET#1,N$:IFST<>0THEN305
  51. 255 IFN$<>CHR$(34)THEN250
  52. 260 GET#1,N$:IFN$<>CHR$(34)THENC$=C$+N$:GOTO260
  53. 265 GET#1,N$:IFN$<>CHR$(32)THEN265
  54. 270 D$(S)=D$(S)+LEFT$(C$+S$,16):C$=""
  55. 275 C$=C$+N$:GET#1,N$:IFN$<>""THEN275
  56. 280 IFS=0THEN295
  57. 285 IFRIGHT$(C$,1)=" "THENC$=LEFT$(C$,LEN(C$)-1):GOTO280
  58. 290 C$=RIGHT$(C$,3):C$=LEFT$(C$,1):CP=ASC(C$)+128:C$=CHR$(CP)
  59. 295 D$(S)=D$(S)+C$:IFS=0THEND$(S)=MID$(D$(S),4,19)
  60. 300 PRINTS,D$(S):IFST=0THENS=S+1:GOSUB175:GOTO230:REM S=ITEMS IN ARRAY
  61. 305 A=INT(100*C/664):Q$=STR$(A):Q$=RIGHT$(Q$,2)
  62. 310 D$(S)=D$(S)+" [194]LKS [198]REE ("+Q$+"%)":CLOSE1:GOSUB175:CLOSE15:RETURN
  63. 315 REM "[197]DIT THE [196]IRECTORY"
  64. 320 IFSL=1ANDS<2*SZ-1THEN340
  65. 325 IFSL=2ANDS<SZTHEN340
  66. 330 IFSL=3THEN340
  67. 335 GOTO355
  68. 340 PRINT"[196]O YOU WANT TO [197]DIT THE [196]IRECTORY? (Y/N)[146]"
  69. 345 GOSUB155:IFW$<>"Y"THENRETURN
  70. 350 GOTO410
  71. 355 PRINT"   [196]IRECTORY IS TOO LARGE TO FIT ON THE"
  72. 360 PRINT"ENVELOPE. [217]OU MUST [197]DIT THE DIRECTORY"
  73. 365 PRINT"NOW, TO REMOVE NON-ESSENTIAL FILES FROM"
  74. 370 PRINT"THE PRINTED DIRECTORY LISTING. [212]HIS WILL";
  75. 375 PRINT"ONLY AFFECT THE PRINTOUT. [201]T WILL NOT"
  76. 380 PRINT"CHANGE YOUR DISK OR [211]CRATCH ANY OF YOUR"
  77. 385 PRINT"FILES OR PROGRAMS"
  78. 390 PRINT"";
  79. 395 PRINT"[208]RESS ANY KEY TO CONTINUE, OR [209] TO QUIT"
  80. 400 GOSUB155:IFW$="Q"THENCLR:RP=1:GOTO15
  81. 405 IFSB=1THENRETURN
  82. 410 PRINT"[147]    [197]DIT THE [196]IRECTORY   [205]ESSAGE-[194]AR    [146]";
  83. 415 PRINT"  [212]HE [196]ISK [196]IRECTORY WILL BE DISPLAYED "
  84. 420 PRINT"TO YOU, A SECTION AT A TIME. [212]O VIEW THE";
  85. 425 PRINT"NEXT SECTION, PRESS THE F7[146] FUNCTION KEY.";
  86. 430 PRINT"  [201]F YOU REACH THE END OF THE DIRECTORY,";
  87. 435 PRINT"THE F7[146] KEY WILL TAKE YOU BACK TO THE "
  88. 440 PRINT"FIRST SECTION ([204]IST WILL 'WRAP-AROUND').";
  89. 445 PRINT"  [212]O DELETE A PROGRAM FROM THE PRINTOUT,";
  90. 450 PRINT"TYPE IN IT'S IDENTIFYING NUMBER, AND"
  91. 455 PRINT"THEN PRESS [210][197][212][213][210][206][146]. [217]OU MUST CONTINUE "
  92. 460 PRINT"TO DELETE PROGRAMS UNTIL THE MESSAGE-BAR";
  93. 465 PRINT"AT THE TOP OF THE SCREEN ADVISES THAT"
  94. 470 PRINT"YOU CAN DELETE PROGRAMS AT YOUR OPTION,"
  95. 475 PRINT"INSTEAD OF TELLING YOU THAT YOU [205][213][211][212]"
  96. 480 PRINT"DELETE PROGRAMS FROM THE PRINTED LIST."
  97. 485 PRINT"  [215]HEN YOU ARE THROUGH DELETING PROGRAMS";
  98. 490 PRINT"FROM THE LIST, PRESS THE F1[146] FUNCTION KEY";
  99. 495 PRINT"TO RETURN FROM THE [197]DIT MODE. [217]OU CANNOT";
  100. 500 PRINT"LEAVE THE [197]DIT MODE, UNTIL THE [196]IRECTORY";
  101. 505 PRINT"IS SMALL ENOUGH TO FIT ON THE ENVELOPE."
  102. 510 SB=1:GOSUB395:SB=0
  103. 515 BG=1:ED=20:IFED>S-1THENED=S-1
  104. 520 PRINT"[147]";
  105. 525 IFSL=2ANDS>SZTHENPRINT""S-SZ"[146]";M1$:GOTO540
  106. 530 IFSL=1ANDS>2*SZ-1THENPRINT""S-(2*SZ-1)"[146]";M1$:GOTO540
  107. 535 PRINTM0$
  108. 540 FORX=BGTOED:PRINTX,D$(X):NEXT
  109. 545 PRINTCD$DC$:PRINT"[145][215]HICH [208]ROGRAM NUMBER TO DELETE?: [146]"
  110. 550 GOSUB155:GOSUB140
  111. 555 IFW$=CHR$(136)THENBG=BG+20:ED=BG+19:GOTO565
  112. 560 GOTO580
  113. 565 IFBG>S-1THENBG=1:ED=20
  114. 570 IFED>S-1THENED=S-1
  115. 575 PRINT"[147]";:GOTO525
  116. 580 IFW$=CHR$(133)THEN590
  117. 585 GOTO615
  118. 590 IF(SL=1ANDS<=2*SZ-1)THENRETURN
  119. 595 IF(SL=2ANDS<=SZ)THENRETURN
  120. 600 IFSL=3THENRETURN
  121. 605 FORWW=1TO20:GOSUB145:PRINTCD$DC$:PRINT"[145] [195]AN'T LEAVE UNTIL YOU DELETE!!"
  122. 610 FORWX=1TO100:NEXT:NEXT:PRINTCD$:PRINT"    ":NM$="":GOTO545
  123. 615 IFW$=CHR$(13)THEN670
  124. 620 IFW$=CHR$(20)THENZ=LEN(NM$):GOTO630
  125. 625 GOTO640
  126. 630 IFZ>0THENNM$=LEFT$(NM$,Z-1)
  127. 635 PRINTCD$:PRINT"    [145]":PRINTNM$:GOTO550
  128. 640 IFPEEK(653)=4ANDASC(W$)=18THEN695
  129. 645 IFW$<CHR$(48)ORW$>CHR$(57)THEN550
  130. 650 NM$=NM$+W$:NM=VAL(NM$):PRINTCD$:PRINTNM$:IFNM>S-1ORNM=0THENNM$="":GOTO660
  131. 655 GOTO550
  132. 660 FORWW=1TO20:GOSUB145:PRINTCD$DC$:PRINT"[145] [201]NVALID NUMBER, TRY AGAIN !!"
  133. 665 FORWX=1TO100:NEXT:NEXT:PRINTCD$:PRINTFL$:NM$="":GOTO545
  134. 670 IFNM$=""THEN550
  135. 675 GOSUB145:FORX=NMTOS-1:D$(X)=D$(X+1):NEXT
  136. 680 D$(S)=FL$:IFED-BG<19ANDNM>=BGTHENED=ED-1
  137. 685 S=S-1:NM$="":NM=0:IFED<BGTHEN515
  138. 690 GOTO520
  139. 695 REM ** DELETE A RANGE OF NUMBERS **
  140. 700 NM$="":PRINTCD$DC$:INPUT"[145] [211]TARTING # ?: [146]";SN
  141. 705 PRINTCD$:INPUT" [197]NDING # ?:   [146]";EN
  142. 710 IFEN<SN OR EN>S-1 OR SN>S-2 OR SN<1 THEN660
  143. 715 DF=EN-SN
  144. 720 FORX=ENTOS-1:D$(X-DF)=D$(X+1):NEXT
  145. 725 FORX=S-DFTOS:D$(X)=FL$:NEXT:S=S-DF-1
  146. 730 GOTO515
  147. 735 REM SORT THE DIRECTORY SUBROUTINE
  148. 740 REM MANY THANKS TO GARY G. KIZIAK FOR THIS MACHINE LANGUAGE SORT ROUTINE
  149. 745 REM !! PLEASE NOTE THAT THIS SORT ROUTINE IS NOT IN THE PUBLIC DOMAIN !!
  150. 750 PRINT"[147][196]O YOU WANT TO [211]ORT THE [196]IRECTORY? (Y/N)[146]"
  151. 755 PRINT"****************************************"
  152. 760 PRINT" [212]YPING "CHR$(34)"Y"CHR$(34)" WILL ALPHABETICALLY SORT THE";
  153. 765 PRINT"DIRECTORY BEFORE IT IS PRINTED OUT. [201]T"
  154. 770 PRINT"WILL NOT REARRANGE YOUR DIRECTORY ON THE";
  155. 775 PRINT"DISK. [212]HE FIRST PROGRAM ON DISK IS [206][207][212]"
  156. 780 PRINT"SORTED, IT REMAINS THE FIRST PROGRAM ON"
  157. 785 PRINT"THE PRINTED DIRECTORY LISTING. [212]HIS IS"
  158. 790 PRINT"FOR THE CONVENIENCE OF THOSE [213]SERS WHO"
  159. 795 PRINT"FREQUENTLY LOAD THE FIRST PROGRAM ON THE";
  160. 800 PRINT"DISK, WITH THE COMMAND:  [204][207][193][196] "CHR$(34)":*"CHR$(34)",8"
  161. 805 PRINT"****************************************"
  162. 810 GOSUB155:IFW$<>"Y"THENRETURN
  163. 815 REM 1ST PROGRAM ON DISK IS NOT SORTED
  164. 820 SYSKIZIAK,D$,2,S-1,4,20,A
  165. 825 RETURN
  166. 830 PRINT"[147]*****************************************";
  167. 835 PRINT"  [206][207][215][160][215][197][160][193][210][197][160][210][197][193][196][217][160][198][207][210][160][212][200][197][160][208][210][201][206][212][207][213][212][160]! **";
  168. 840 PRINT"  [205]AKE SURE THE [208]RINTER IS TURNED ON, **";
  169. 845 PRINT"  AND THAT THE PAPER IS POSITIONED !  *";
  170. 850 PRINT"****************************************"
  171. 855 SB=1:GOSUB390:SB=0:RETURN
  172. 860 PRINT"[147]         [210]EADING THE [196]IRECTORY ! [146]":RETURN
  173. 865 IFSL=1THENIFS<SZTHEND$(SZ)=D$(S):D$(S)=FL$:GOTO880
  174. 870 IFSL=1THENIFS<2*SZ-1THEND$(2*SZ-1)=D$(S):D$(S)=FL$
  175. 875 IFSL=2THENIFS<SZTHEND$(SZ)=D$(S):D$(S)=FL$
  176. 880 RETURN
  177. 885 REM SIMPLE DIRECTORY PRINTOUT ROUTINE
  178. 890 OPEN4,4,7:IFDC=0THEN920
  179. 895 C2=INT(S/2+.5)
  180. 900 PRINT#4,D$(0)
  181. 905 FORX=1TOC2
  182. 910 PRINT#4,D$(X)"   "D$(X+C2)
  183. 915 GOTO930
  184. 920 FORX=0TOS
  185. 925 PRINT#4,D$(X)
  186. 930 NEXT
  187. 935 PRINT#4
  188. 940 CLOSE4:GOTO1030
  189. 945 REM PRINT DISK ENVELOPE SUBROUTINE
  190. 950 OPEN4,4,7
  191. 955 PRINT#4,NP$"-------------------------------------[174]"
  192. 960 PRINT#4," [212]UCK FLAP INSIDE ENVELOPE AND TAPE   [191]"
  193. 965 PRINT#4,"---------------------------------------[178]";
  194. 970 PRINT#4,"----------------------------------------"
  195. 975 PRINT#4,EX$A$(0)"  "B$(0)NP$:QZ=(SZ-1)/2
  196. 980 FORX=1TOQZ
  197. 985 PRINT#4," "RIGHT$(A$(X),17)"  "RIGHT$(A$(X+QZ),17)"  [221]  ";
  198. 990 PRINT#4,RIGHT$(B$(X),17)"  "RIGHT$(B$(X+QZ),17)
  199. 995 NEXT
  200. 1000 PRINT#4,EX$A$(SZ)"  "B$(SZ)NP$
  201. 1005 PRINT#4,"---------------------------------------[177]";
  202. 1010 PRINT#4,"----------------------------------------";
  203. 1015 PRINT#4," [212]UCK FLAP INSIDE ENVELOPE AND TAPE   /"
  204. 1020 PRINT#4,"-------------------------------------[189]"
  205. 1025 PRINT#4,LF$:CLOSE4
  206. 1030 CLR:RP=1:GOTO15
  207. 1035 PRINT"[147]       [207][208][212][201][207][206][211]   ([195]HOOSE A [206]UMBER !)    ":SS=0
  208. 1040 PRINTZ$"1[146] [205]AKE DISK ENVELOPE FOR"
  209. 1045 PRINTZ$"  A SINGLE SIDED DISK"
  210. 1050 PRINTZ$"2[146] [205]AKE DISK ENVELOPE FOR"
  211. 1055 PRINTZ$"  A DOUBLE SIDED DISK"
  212. 1060 PRINTZ$"3[146] [208]RINT A DISK DIRECTORY"
  213. 1065 PRINTZ$"4[146] [209][213][201][212] !"
  214. 1070 PRINT"[217]OU CAN SELECT COLORS NOW,FOR THE [194]ORDER"
  215. 1075 PRINT"[211]CREEN AND [195]HARACTERS WITH [194][146],[211][146],& [195][146] KEYS"
  216. 1080 GOSUB155
  217. 1085 IFW$="B"THENCH=1:M=(PEEK(B)AND15)+1:IFM=16THENM=0
  218. 1090 IFW$="S"THENCH=1:N=(PEEK(SC)AND15)+1:IFN=16THENN=0
  219. 1095 IFW$="C"THENCH=2:O=PEEK(CC)+1:IFO=16THENO=0
  220. 1100 IFCH=1THENCH=0:POKEB,M:POKESC,N:GOTO1080
  221. 1105 IFCH=2THENCH=0:POKECC,O:GOTO1035
  222. 1110 SL=VAL(W$):IFSL<1ORSL>4THEN1080
  223. 1115 IFSL=4THENPRINTCHR$(9):END
  224. 1120 IFSL=2THENSS=1
  225. 1125 IFSL<4THENPRINT"[201]NSERT THE DISK ";:IFSL=3THEN1135
  226. 1130 IFSS>0THENPRINT"(SIDE"SS") ";:SS=SS+1
  227. 1135 PRINT"INTO THE DRIVE"
  228. 1140 PRINT"        [200]IT ANY KEY WHEN READY[146]":GOSUB155:GOSUB860:GOSUB220
  229. 1145 GOSUB320:GOSUB750:GOSUB865
  230. 1150 IFSL=2ANDSS=2THENFORX=0TOSZ:A$(X)=D$(X):NEXT:GOTO1160
  231. 1155 GOTO1165
  232. 1160 FORX=0TO145:D$(X)=FL$:NEXT
  233. 1165 IFSL=2ANDSS=3THENFORX=0TOSZ:B$(X)=D$(X):NEXT:GOTO1235
  234. 1170 IFSS=2THENPRINT"[147]":GOTO1125:REM GO BACK FOR FLIP SIDE*******
  235. 1175 IFSL=1THEN1220
  236. 1180 PRINT"[147]     [196]O YOU WANT A [211][146]INGLE OR [196][146]OUBLE"
  237. 1185 PRINT"     COLUMN, [208]RINTER OUTPUT?"
  238. 1190 GOSUB155
  239. 1195 IFW$="S"THENDC=0:GOTO1235
  240. 1200 IFW$="D"THENDC=1:GOTO1235
  241. 1205 FORWW=1TO20:GOSUB145:PRINTCD$DC$:PRINT"[145] [208]RESS THE 'S' OR 'D' KEYS !!"
  242. 1210 FORWX=1TO100:NEXT:NEXT
  243. 1215 GOTO1190
  244. 1220 IFS<=SZTHENFORX=0TOSZ:A$(X)=D$(X):NEXT:GOTO1235
  245. 1225 FORX=0TOSZ-1:A$(X)=D$(X):NEXT:FORX=1TOSZ:B$(X)=D$(X+SZ-1):NEXT
  246. 1230 A$(SZ)=LEFT$(FL$,19)
  247. 1235 GOSUB830:ONSLGOTO950,950,890
  248. 1240 POKE209,000:POKE210,193:POKE211,0:POKE213,255
  249. 1245 PRINT" [189].[146] [217][194]%[146][223]X[169]GM[146]@[192]%[146][160][169]@M[146]A[192][146] [189].[146] ^-[146] [183]7%[146]TM[146]B[192]%";
  250. 1250 PRINT"[146]UM[146]C[192][146] [189].[146] ^-[146] [183]7%[146]TM[146]D[192]%[146]UM[146]E[192])[146]@E[190][146] [177]7J$[190]Y[146] ";
  251. 1255 PRINT"[192][146] [177]7J$[190]Y[146][192][192][146] [189].[201][146][193][176][146]G[201][146][196][176][146]F[204]H/)[146]A,)[146]@$[190]Y[146][160][192][146] ";
  252. 1260 PRINT"[179]@[201][146],[208][146]D[166][190][208][203][146][184]";
  253. 1265 PRINT""CHR$(34)CHR$(34)CHR$(20)"[146]^ &[195][146]8%'[165]%E)%([165]&E*[166])";
  254. 1270 PRINT"[208][146]B[166]*";
  255. 1275 PRINT""CHR$(34)CHR$(34)CHR$(20)"[146]A=[193][194][197])=[205][194][165]*0[146]C[168][208][177][202][208][146]G";
  256. 1280 PRINT""CHR$(34)CHR$(34)CHR$(20)"";
  257. 1285 PRINT"[146]^ &[195][146][216][160]=[193][194]E/=[205][194]E0[146]X%/[146][165]%E1%0[146][165]&E2[146]8%1[165]/E3%2[165]0E4[146]X%";
  258. 1290 PRINT"3[146][165]/E5%4[146][165]0E6[146] L[194][208][146]\ 1[194][146]8%3[165]/E3%4[165]0E4P[146]J%3[197]%%4[165]&0[210][166]";
  259. 1295 PRINT"1[208][146]B[166]"
  260. 1300 POKE209,255:POKE210,193:POKE211,0:POKE213,255
  261. 1305 PRINT"2%'[197]1%([165]205PRJ[146][200]";
  262. 1310 PRINT""CHR$(34)CHR$(34)CHR$(20)"[146]@53M[193][194]54M[205][194][146]N[193][194][146].[205][194]";
  263. 1315 PRINT"[146]X53[146][173][193][194]M[193][194]54[146][173][205][194]M[205][194][146]X-[193][194][146][165]#U7-[205][194][146][165]$U8[168][168][160][146]D[208][202] [146]B1";
  264. 1320 PRINT"7Y;[146]@19Y>[146]@H[146]P[179][146][168]*)[191]E[189][166][189]$[189][196][190][176][146]B0[146][193]9[146] [192]E+9[146][192][192]E,9[146][160]";
  265. 1325 PRINT"[192]E-%;[197]+P[146],E.%>[197]+P[146]*[197].0[146]BE.%,[197].0[146]BE.$+H1<[209]?[176][146]F0[146]Q)[146]@";
  266. 1330 PRINT"[176][146]O[200][196].[208][175][176]5%;[197]>P[175])[146]A[197]-[146][160] [146]B9;[146]@Q99>[146]@Q7H[146]P[179][146][160]3ADM(";
  267. 1335 PRINT"[185][172][197][208][146][177][212]@@@@@@@ADL&[179]@[146] ^-[146] O-%[146]/E[146][223]%[146]0E[146][160] [146]@1[146][223][197]";
  268. 1340 PRINT"[146][197][208][146]P[200]1[146][223][197][146][198][208][146]I [146]D1[146][223][201][146]A[208][146]A"
  269. 1345 POKE209,254:POKE210,194:POKE211,0:POKE213,150
  270. 1350 PRINT"[160] [146]BX1[146][223][165][223][200][200]1[146][223][165][160]E[146][160][168]E[146][223][197][146]1%[146][160][165][146]2P[206])%E[146]";
  271. 1355 PRINTCHR$(34)CHR$(34)CHR$(20)"";
  272. 1360 PRINT")";
  273. 1365 PRINT""CHR$(34)CHR$(34)CHR$(20)"E[146]#[204][199]$";
  274. 1370 PRINT""CHR$(34)CHR$(34)CHR$(20)"[146]H5#[146][200]=[146]@[192]U#[146][168]";
  275. 1375 PRINT"][146]@[192][202][146]P[177][146][160]"
  276. 1380 SYS64931:PRINT"[147]"
  277. 1385 RETURN
  278. 63999 REM PLEASE LEAVE THE MESSAGE ALONE
  279. 64246 PRINT"[147] [211]ERENDIPITY [211]OFTWARE'S [211]HAREWAIRE [196]ISK ";:PRINT"              [214]OLUME # 1                [146]";:PRINT"  [212]HIS PROGRAM IS FEATURED ON THE ABOVE":PRINT"DISK. [201]F THIS PROGRAM PLEASES YOU, AND"
  280. 64247 PRINT"YOU DO NOT HAVE THE OTHER FINE PROGRAMS":PRINT"IN [214]OLUME # 1, YOU ARE MISSING OUT!":PRINT"  [211]HAREWAIRE DISKS ARE DISTRIBUTED FREE":PRINT"FOR THE COPYING, BUT [193][210][197] [195][207][208][217][210][201][199][200][212][197][196].":PRINT"[201]F YOU RECEIVE A COPY OF THE DISK, AND"
  281. 64248 PRINT"THINK THE PROGRAMS ARE USEFUL, PLEASE":PRINT"SEND A $ 10.00 DONATION (WE WILL SEND":PRINT"YOU THE DOCUMENTATION, & THE MONEY WILL":PRINT"BE SHARED BY THE AUTHORS ON [214]OLUME 1)":PRINT"  [201]F YOU DO NOT HAVE A COMPLETE COPY OF"
  282. 64249 PRINT"THE [211]HAREWAIRE DISK, WE WILL SEND YOU A":PRINT"COPY FOR A $ 10.00 DONATION PLUS $ 5.00;";:PRINT"(PAYS FOR DISK, DOCUMENTATION, COPYING ":PRINT"TIME, MAILER & POSTAGE = $ 15.00 TOTAL)"
  283. 64250 PRINT"  [217]OU WILL ALSO GET ADVANCE NOTICE OF":PRINT"FUTURE [214]OLUMES OF THE [211]HAREWAIRE [196]ISKS!":PRINT"  [205]AIL YOUR DONATION TO:":PRINT"        [211]ERENDIPITY [211]OFTWARE":PRINT"        8438 [204]YNDA [211]UE [204]ANE [215]."
  284. 64251 PRINT"        [202]ACKSONVILLE, [198]LA. 32217  [213][211][193]":PRINT"        [208]RESS [193]NY [203]EY TO [195]ONTINUE"
  285. 64252 POKE198,0:WAIT198,1
  286. 64253 RETURN
  287.