home *** CD-ROM | disk | FTP | other *** search
/ GEMini Atari / GEMini_Atari_CD-ROM_Walnut_Creek_December_1993.iso / files / gnu / libsrc87 / _addsubd.cpp next >
Encoding:
Text File  |  1993-07-30  |  6.7 KB  |  300 lines
  1. |
  2. | double floating point add/subtract routine
  3. |
  4. #ifndef __M68881__
  5.     .text
  6.     .even
  7.     .globl    __subdf3, ___subdf3
  8.     .globl    __adddf3, ___adddf3
  9. # ifndef    sfp004
  10. |
  11. | written by Kai-Uwe Bloem (I5110401@dbstu1.bitnet).
  12. | Based on a 80x86 floating point packet from comp.os.minix, written by P.Housel
  13. | patched by Olaf Flebbe (flebbe@tat.physik.uni-tuebingen.de)
  14. |
  15. | Revision 1.3.4 olaf 11-92 :
  16. |  + added support for NaN and infinities
  17. |    > floating point is now excellent!
  18. |
  19. |  -- still lacks trap handling for exceptions
  20. |  -- dont know the external representation of quiet and signaling NaN
  21. |     I decided 0x7fffffff,ffffffff to be a quiet NaN
  22. |     the rest should be signaling (but isnt)
  23. |
  24. | Revision 1.3.3 olaf 11-92 :
  25. |  + changed to get rid of rounding bits. a sticky register (d3) is
  26. |    sufficient. 
  27. | 
  28. | Revision 1.3.2 olaf 10-92 :
  29. |  + increased comparson by one again. (Dont understand, but it works)
  30. |  + corrected negation of rounding bits and mantissa
  31. |     >enquire now detects correct IEEE precision
  32. |     >paranoia now qualifies add/sub as correctly rounded
  33. |
  34. | Revision 1.3.1 olaf 10-92 :
  35. |  + increased comparison of exponents by one.
  36. |  + initialized sticky byte
  37. |  + corrected handling of rounding bits
  38. |     >paranoia now detects no SERIOUS DEFECTS any more
  39. |     ** Patches need _normdf Rev 1.6.1 (or higher) **
  40. |
  41. | Revision 1.3, kub 01-90 :
  42. | added support for denormalized numbers
  43. |
  44. | Revision 1.2, kub 01-90 :
  45. | replace far shifts by swaps to gain speed
  46. |
  47. | Revision 1.1, kub 12-89 :
  48. | Ported over to 68k assembler
  49. |
  50. | Revision 1.0:
  51. | original 8088 code from P.S.Housel
  52.  
  53. __subdf3:
  54. ___subdf3:
  55.     eorb    #0x80,sp@(12)    | reverse sign of v
  56. __adddf3:
  57. ___adddf3:
  58.     lea    sp@(4),a0    | pointer to u and v parameter
  59.     moveml    d2-d7,sp@-    | save registers
  60.     moveml    a0@,d4-d5/d6-d7    | d4-d5 = v, d6-d7 = u
  61.  
  62.     movel    d6,d0        | d0 = u.exp
  63.     swap    d0
  64.     movel    d6,d2        | d2.h = u.sign
  65.     movew    d0,d2
  66.     lsrw    #4,d0
  67.     andw    #0x07ff,d0    | kill sign bit
  68.  
  69.     movel    d4,d1        | d1 = v.exp
  70.     swap    d1
  71.     eorw    d1,d2        | d2.l = u.sign ^ v.sign
  72.     lsrw    #4,d1
  73.     andw    #0x07ff,d1    | kill sign bit
  74.  
  75.     andl    #0x0fffff,d6    | remove exponent from u.mantissa
  76.     andl    #0x0fffff,d4    | remove exponent from v.mantissa
  77. |
  78. | Now perform testing of NaN And infinities
  79. |
  80.     cmpw    #0x07ff,d0
  81.     beq    0f
  82.     cmpw    #0x07ff,d1
  83.     bne    nospec
  84.     bra    1f
  85. |    first operand is special
  86. |
  87. 0:    cmpw    d0,d1
  88.     beq    bothspec
  89. |
  90. |    u is special
  91. | 
  92.     movel    d7,d0
  93.     orl    d6,d0
  94.     bne    retnan        | arith with Nan gives always Nan
  95.  
  96.     movel    a0@(8),d0        | copy infinity
  97.     clrl    d1
  98.     bra     return
  99. |
  100. |    v is special
  101. |
  102. 1:    movel    d5,d0
  103.     orl    d4,d0
  104.     bne    retnan
  105.     movel    a0@,d0
  106.     clrl    d1
  107.     bra    return
  108. |
  109. |    u and v are both special
  110. |
  111. bothspec:
  112.     movel    d7,d0
  113.     orl    d6,d0
  114.     orl    d5,d0
  115.     orl    d4,d0
  116.     beq    bothinf
  117.     bra    retnan    
  118. |
  119. | Both are infinities Test if cancellation
  120. | 
  121. bothinf:
  122.     tstw    d2
  123.     bpl    retinf    
  124. |
  125. | return a quiet NaN
  126. |
  127. retnan:    movel    #0x7fffffff,d0
  128.     moveql  #-1,d1
  129.     bra    return
  130.  
  131. retinf: movel   #0x7ff00000,d0
  132.     clrl    d1
  133.     tstl    d2
  134.     bpl    return
  135.     bchg    #31,d0
  136. return:    moveml    sp@+,d2-d7
  137.     rts
  138. |    
  139. | Ok, no inifinty or Nan involved..
  140. |
  141. nospec:    tstw    d0        | check for zero exponent - no leading "1"
  142.     beq    0f
  143.     orl    #0x100000,d6    | restore implied leading "1"
  144.     bra    1f
  145. 0:    addw    #1,d0        | "normalize" exponent
  146. 1:
  147.     tstw    d1        | check for zero exponent - no leading "1"
  148.     beq    0f
  149.     orl    #0x100000,d4    | restore implied leading "1"
  150.     bra    1f
  151. 0:    addw    #1,d1        | "normalize" exponent
  152. 1:
  153.     clrl    d3        | init sticky register
  154.     negw    d1        | d1 = u.exp - v.exp
  155.     addw    d0,d1
  156.     beq    5f        | exponents are equal - no shifting neccessary
  157.     bgt    1f        | not equal but no exchange neccessary
  158.     exg    d4,d6        | exchange u and v
  159.     exg    d5,d7
  160.     subw    d1,d0        | d0 = u.exp - (u.exp - v.exp) = v.exp
  161.     negw    d1
  162.     tstw    d2        | d2.h = u.sign ^ (u.sign ^ v.sign) = v.sign
  163.     bpl    1f
  164.     bchg    #31,d2
  165. 1:
  166.     cmpw    #55,d1        | is u so much bigger that v is not
  167.     bge    7f        | significant ?
  168. |
  169. | shift mantissa left two digits, to allow cancellation of
  170. | most significant digit, while gaining an additional digit for
  171. | rounding.
  172. |
  173.     moveql  #1,d3    
  174. 2:    addl    d7,d7
  175.     addxl    d6,d6
  176.     subw    #1,d0        | decrement exponent
  177.     subw    #1,d1        | decrement counter
  178.     dbeq    d3,2b
  179.     clrl    d3
  180. |
  181. | now shift other mantissa right as fast as possible (almost).
  182. |
  183. 3:    
  184.     cmpw    #16,d1        | see if fast rotate possible
  185.     blt    4f
  186.     orw    d5,d3        | set sticky word
  187.     movew    d4,d5        | rotate by swapping register halfs
  188.     swap    d5
  189.     clrw    d4
  190.     swap    d4
  191.     subw    #16,d1
  192.     bra    3b
  193.  
  194. 0:    moveb   d5,d2        | use d2.b as scratch
  195.     andb    #1,d2        | test if 1 is shifted out
  196.     orb    d2,d3        | and put it in sticky 
  197.     lsrl    #1,d4        | shift v.mant right the rest of the way
  198.     roxrl    #1,d5        | to line it up with u.mant
  199. 4:    dbra    d1,0b        | loop
  200.     
  201. 5:
  202.     tstw    d2        | are the signs equal ?
  203.     bpl    6f        | yes, no negate necessary
  204. |
  205. | negate secand mantissa. One has to check the sticky word in order
  206. | to correct the twos complement.
  207. |
  208.     tstw    d3        | 
  209.     beq     9f        | No cerrection necessary
  210.     clrl    d1
  211.     addql   #1,d5
  212.     addxl   d1,d4
  213. 9:    negl    d5
  214.     negxl    d4
  215.         
  216. 6:
  217.     addl    d5,d7        | u.mant = u.mant + v.mant
  218.     addxl    d4,d6
  219.     bcs    7f        | need not negate
  220.     tstw    d2        | opposite signs ?
  221.     bpl    7f        | do not need to negate result
  222.  
  223.     negl    d7
  224.     negxl    d6
  225.     notl    d2        |     switch sign
  226. 7:
  227.     movel    d6,d4        | move result for normalization
  228.     movel    d7,d5
  229.     clrl    d1
  230.     tstl    d3
  231.     beq     8f
  232.     moveql   #-1,d1
  233. 8:    swap    d2        | put sign into d2 (exponent is in d0)
  234.     jmp    norm_df        | leave registers on stack for norm_df
  235. #else    sfp004
  236. | double precision floating point stuff for Atari-gcc using the SFP004
  237. | developed with gas
  238. |
  239. | double floating point add/subtract routine
  240. |
  241. | M. Ritzert (mjr at dmzrzu71)
  242. |
  243. | 4.10.1990
  244. |
  245. | no NAN checking implemented since the 68881 treats this situation "correct",
  246. | i.e. according to IEEE
  247.  
  248. | addresses of the 68881 data port. This choice is fastest when much data is
  249. | transferred between the two processors.
  250.  
  251. comm =     -6
  252. resp =    -16
  253. zahl =      0
  254.  
  255. | waiting loop ...
  256. |
  257. | wait:
  258. | ww:    cmpiw    #0x8900,a0@(resp)
  259. |     beq    ww
  260. | is coded directly by
  261. |    .long    0x0c688900, 0xfff067f8
  262.  
  263. __subdf3:
  264. ___subdf3:
  265. | double precision subtraction
  266. | sub second arg from fp0
  267.     lea    0xfffffa50:w,a0
  268.     movew    #0x5400,a0@(comm)    | load first argument to fp0
  269.     cmpiw    #0x8900,a0@(resp)    | check
  270.     movel    a7@(4),a0@
  271.     movel    a7@(8),a0@
  272.     movew    #0x5428,a0@(comm)
  273.     .long    0x0c688900, 0xfff067f8
  274.     movel    a7@(12),a0@
  275.     movel    a7@(16),a0@
  276.     movew    #0x7400,a0@(comm)    | result to d0/d1
  277.     .long    0x0c688900, 0xfff067f8
  278.     movel    a0@,d0
  279.     movel    a0@,d1
  280.      rts
  281.  
  282. __adddf3:
  283. ___adddf3:
  284.     lea    0xfffffa50:w,a0
  285.     movew    #0x5400,a0@(comm)        | load fp0
  286.     cmpiw    #0x8900,a0@(resp)        | got it?
  287.     movel    a7@(4),a0@            | take a hi from stack to FPU
  288.     movel    a7@(8),a0@            | take a lo from stack to FPU
  289.     movew    #0x5422,a0@(comm)        | add second arg to fp0
  290.     .long    0x0c688900, 0xfff067f8
  291.     movel    a7@(12),a0@            | move b hi from stack to FPU
  292.     movel    a7@(16),a0@            | move b lo from stack to FPU
  293.     movew    #0x7400,a0@(comm)        | result to d0/d1
  294.     .long    0x0c688900, 0xfff067f8
  295.     movel    a0@,d0                | download result
  296.     movel    a0@,d1                | download result
  297.      rts
  298. #endif    sfp004
  299. #endif    __M68881__
  300.