home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
misc
/
hamscan
/
vhf-yagi.bas
< prev
Wrap
BASIC Source File
|
1987-03-25
|
4KB
|
86 lines
10 'This program calculates the demensions of a VHF Yagi antenna.
20 '
30 'Design assumptions are:
40 ' 1. Driven element length in inches is 5600/frequency in MHZ.
50 ' 2. The reflector is 5% longer than the driven element.
60 ' 3. Reflector and first director spacing is 0.2 wavelengths from driven.
70 ' 4. The first director is 5% shorter than the driven element.
80 ' Subsequent director lengths are calculated by adding 1% to
90 ' the shortening factor of the previous director. For example,
100 ' the 2nd director is 6% shorter than the driven element,
110 ' the 3rd is 7% shorter, the 4th, 8% shorter, etc.
120 ' 5. Director spacing is 110% of previous spacing. Spacing starts
130 ' at 0.2 wavelengths.
140 '
150 ' The program is well documented via remarks, so any of the above
160 ' assumptions may be easily changed.
170 '
180 '-------------------- PROGRAM BEGINS --------------------------------------
190 '
200 DEFINT I
210 CLS
220 PRINT:PRINT "This program calculates the demensions of a VHF Yagi antenna."
230 PRINT "YOU MAY SELECT FOR OUTPUT OF THIS PROGRAM TO GO TO A PRINTER,"
240 PRINT ,"OR TO GO TO THE SCREEN."
250 PRINT "WHICH WOULD YOU LIKE? <P/S>";:P$=INPUT$(1):IF INSTR("PSps",P$)=0 THEN 250
260 PRINT P$:IF P$="P" OR P$="p" THEN FL=0 ELSE FL=-1
270 IF NOT(FL) THEN PRINT "TURN PRINTER ON AND ALIGN PAPER BEFORE PROCEEDING."
280 INPUT"WHAT FREQUENCY (MHZ) ";FREQ
290 INPUT"HOW MANY ELEMENTS (3 MINIMUM) ";ELNO
300 WL = 11808/FREQ 'wavelength in free space (inches)
310 DR = 5600/FREQ 'driven element length (inches)
320 RF = DR * 1.05 'reflector length
330 SPR = WL * .2 'reflector spacing
340 PL(1) = DR * .95'first director length
350 SPP(1) = WL * .2 'first director spacing
360 FOR I = 2 TO (ELNO -2)
370 PRINT
380 SPP(I) = SPP(I-1) * 1.1 'each director spacing 10% greater than previous
390 PL(I) = DR * (100 - (4 + I))*.01 'director length
400 LN1 = LN1 + SPP(I) 'keep track of overall length
410 NEXT
420 DEF FNX(X) = INT(X*100+.5)*.01 'function to round off printing to 2 dec.
430 LNT = SPR + SPP(1) + LN1 'total beam length
440 IF FL THEN 650
450 LPRINT"DESIGN DATA FOR VHF YAGI BEAM ANTENNA: "
460 LPRINT
470 LPRINT"---- DESIGN FREQUENCY IS";FREQ;" MHZ"
480 LPRINT"---- TOTAL NUMBER OF ELEMENTS IS";ELNO
490 LPRINT
500 LPRINT
510 LPRINT TAB(35);"LENGTH IN INCHES"
520 LPRINT "REFLECTOR";TAB(40);FNX(RF)
530 LPRINT "REFLECTOR TO DRIVEN";TAB(41);FNX(SPR)
540 LPRINT "DRIVEN";TAB(40);FNX(DR)
550 LPRINT "DRIVEN TO 1st DIRECTOR";TAB(41);FNX(SPP(1))
560 LPRINT "1st DIRECTOR LENGTH";TAB(40);FNX(PL(1))
570 LPRINT
580 FOR I = 2 TO (ELNO -2)
590 LPRINT"DIRECTOR No.";I;" LENGTH IS";FNX(PL(I));" INCHES"
600 LPRINT "SPACED";FNX(SPP(I));" INCHES FROM DIRECTOR No.";I-1
610 LPRINT
620 NEXT
630 LPRINT "------ OVERALL BEAM LENGTH IS";FNX(LNT);" INCHES ------"
640 GOTO 840
650 PRINT"DESIGN DATA FOR VHF YAGI BEAM ANTENNA: "
660 PRINT
670 PRINT"---- DESIGN FREQUENCY IS";FREQ;" MHZ"
680 PRINT"---- TOTAL NUMBER OF ELEMENTS IS";ELNO
690 PRINT
700 PRINT
710 PRINT TAB(35);"LENGTH IN INCHES"
720 PRINT "REFLECTOR";TAB(40);FNX(RF)
730 PRINT "REFLECTOR TO DRIVEN";TAB(41);FNX(SPR)
740 PRINT "DRIVEN";TAB(40);FNX(DR)
750 PRINT "DRIVEN TO 1st DIRECTOR";TAB(41);FNX(SPP(1))
760 PRINT "1st DIRECTOR LENGTH";TAB(40);FNX(PL(1))
770 PRINT
780 FOR I = 2 TO (ELNO -2)
790 PRINT"DIRECTOR No.";I;" LENGTH IS";FNX(PL(I));" INCHES"
800 PRINT "SPACED";FNX(SPP(I));" INCHES FROM DIRECTOR No.";I-1
810 PRINT
820 NEXT
830 PRINT "------ OVERALL BEAM LENGTH IS";FNX(LNT);" INCHES ------"
840 PRINT "End of program."
850 END