home *** CD-ROM | disk | FTP | other *** search
/ Boldly Go Collection / version40.iso / TS / 05B / PPSTOCK4.ZIP / CIS6.ASP next >
Encoding:
Text File  |  1992-02-24  |  3.1 KB  |  114 lines
  1. ;  Get CIS STOCK STATISTICS, version 0.4
  2. ;     by Jim Robeson
  3. ;     2-24-92
  4. ;
  5. ;  - Modify all lines containing "<==="
  6. ;  - Requires a file named STOCKS.CFG containing stock names
  7. ;    (1 per line)
  8. ;
  9. PROC MAIN
  10. ;                         **** INITIALIZE LOG FILE ****
  11. LOG CLOSE                       ; Close any open log file
  12. LOG OPEN "C:\AI\STOCKS.DLY"     ; <=== the named log file
  13. LOG SUSPEND                     ; Immediatly idle it til we need it
  14. ;
  15. ;                         **** START UP STOCKS.CFG FILE ****
  16. STRING STOCK
  17. SET FGETS_CRLF OFF
  18. FOPEN 0 "STOCKS.CFG" "RT"        ; Enable stock file
  19. IF NOT SUCCESS
  20.   ASSIGN S1 "(1) CAN'T OPEN THE STOCKS.CFG FILE"
  21.   GOTO PROBLEM
  22.   ENDIF
  23. FGETS 0 STOCK                   ; Read in first STOCK var
  24. IF NOT SUCCESS
  25.   ASSIGN S1 "(2) ERROR READING STOCKS.CFG FILE "
  26.   GOTO PROBLEM
  27.   ENDIF
  28. IF EOF 0
  29.   ASSIGN S1 "(3) FOUND AN EMPTY STOCKS.CFG FILE"
  30.   GOTO PROBLEM
  31.   ENDIF
  32. ;
  33. ;                         **** DIAL CIS AND LOG ON ****
  34. TRYAGAIN:
  35.   IF NOT FROMDDIR               ; Handle coming in from BATch call
  36.     DIAL "100"                  ; <=== dialing directory entry number
  37.     ENDIF
  38. PAUSE 1
  39. TRANSMIT "^M"
  40. WAITFOR "Host Name:" 5          ; wait 5 seconds, else try again
  41.   IF NOT WAITFOR
  42.     HANGUP
  43.     GOTO TRYAGAIN
  44.     ENDIF
  45. PAUSE 1
  46. TRANSMIT "cis^M"
  47. WAITFOR "User ID:" 5
  48.   IF NOT WAITFOR
  49.     HANGUP
  50.     GOTO TRYAGAIN
  51.     ENDIF
  52. PAUSE 1
  53. TRANSMIT "xxxxxxxxxx^M"         ; <=== your User ID
  54. WAITFOR "Password:"
  55. PAUSE 1
  56. TRANSMIT "xxxxxxxxxx^M"         ; <=== your password
  57. WAITFOR " !"                    ; "Enter choice !" or "Enter choice number !"
  58. PAUSE 1
  59. TRANSMIT "go basicquotes^M"
  60. ;                         **** DO AT LEAST ONE TIME ****
  61. WAITFOR "Issue:"
  62. PAUSE 1
  63. TRANSMIT STOCK                  ; send FIRST stock name
  64. TRANSMIT "^M"
  65.   WAITFOR "------^M^J"          ; 1st time must have CR & LF
  66.   LOG RESUME                    ; or will have a leading blank line
  67.   WAITFOR "^M"                  ; in the output file
  68.   LOG SUSPEND
  69.   WAITFOR "Issue:"
  70. ;                         **** LOOP THROUGH THE REST ****
  71. CYCLE:
  72. FGETS 0 STOCK                   ; Read in next STOCK var
  73. IF NOT SUCCESS
  74.   ASSIGN S1 "(4) ERROR READING STOCKS.CFG FILE "
  75.   ERRORMSG S1
  76.   GOTO DONE
  77.   ENDIF
  78. IF EOF 0                        ; quit CIS when file empty
  79.   GOTO DONE
  80.   ENDIF
  81. PAUSE 1
  82. TRANSMIT STOCK                  ; send next stock name
  83. TRANSMIT "^M"
  84.   WAITFOR "------^M"
  85.   LOG RESUME
  86.   WAITFOR "^M"
  87.   LOG SUSPEND
  88.   WAITFOR "Issue:"
  89. GOTO CYCLE
  90. ;                         **** ALL DONE, SHUT HER DOWN ****
  91. DONE:
  92. LOG CLOSE                       ; Close the log entirely for today
  93.    PAUSE 1
  94.    TRANSMIT "/exit^M"
  95.    WAITFOR "Enter choice !"
  96.    PAUSE 1
  97.    TRANSMIT "off^M"
  98.    WAITFOR "Host Name:"
  99. IF NOT NULL S1
  100.   GOTO PROBLEM
  101.   ENDIF
  102. USERMSG "FINIS"
  103. QUIT                            ; Hang up telephone & exit ProComm
  104. ;                         **** ABORTING, TELL BATCH FILE ABOUT IT ****
  105. PROBLEM:
  106. LOG CLOSE
  107. ERRORMSG S1
  108. FOPEN 1 "C:\AI\STOCKS.ERR" "WT"        ; Enable error file
  109. FWRITE 1 S1 34
  110. FPUTC 1 10
  111. FCLOSE 1
  112. QUIT
  113. ENDPROC
  114.