10 REM ********************************
20 REM *  COPYRIGHT CDU OCTOBER 1990  *
30 REM *  PROGRAM WRITTEN BY J.FINCH  *
40 REM *    (CDU TECHNICAL DEPT.)     *
50 REM *                              *
60 REM * DISPLAYS I.S. PICTURE FILES  *
70 REM ********************************
80 :
90 A=A+1:IFA=2THEN180
100 POKE53280,14:POKE53281,6:PRINT"[147][142]PLEASE ENTER NAME OF PICTURE FILE",":";
110 OPEN1,0:INPUT#1,A$:CLOSE1:PRINT:PRINT"IS THIS PICTURE HI-RES OR MULTICOLOUR?"
120 PRINT"PRESS 'H' OR 'M'":POKE198,0:T=0
130 GETZ$:IFZ$="M"THENT=1
140 IFZ$<>"H"ANDZ$<>"M"THEN130
150 OPEN2,8,0,A$:CLOSE2:OPEN15,8,15:INPUT#15,E,E$:CLOSE15
160 IFE=0THEN LOAD A$,8,1
170 PRINT"[147]DISK ERROR: "E$:PRINT"PRESS ANY KEY":POKE198,0:WAIT198,1:POKE198,0:RUN
180 IF T=1 THEN 340
190 :
200 REM **********
210 REM * HI-RES *
220 REM **********
230 :
240 POKE 53270,200: POKE 53272,128
250 POKE 53265,59:  POKE 56576,194
260 POKE 53280,0
270 GOTO400
280 :
290 :
300 REM *******************************
310 REM * MULTICOLOUR (VERY SIMILAR!!)*
320 REM *******************************
330 :
340 POKE 53270,216: POKE 53272,128
350 POKE 53265,59:  POKE 56576,194
360 POKE 53280,0
370 FOR C=0 TO 999: POKE 55296+C,PEEK(15360+C): NEXT
380 :
390 :
400 POKE 198,0: WAIT 198,1: POKE198,0: REM ** WAIT FOR A KEY TO BE PRESSED
410 :
420 POKE 53272,21: POKE 53265,27
430 POKE 53270,200:POKE 56576,195
440 PRINT CHR$(147)