99 PRINT"[147]";:POKE53272,PEEK(53272)AND240OR2
100 IFY=0ANDA=0THENA=RND(-TI):A=18:GOSUB10032:GOSUB16000
101 Y=1
102 GOSUB5000:X=FRE(0):GOTO520
250 GH(H)=0:FORI=1TO20:GH(H)=GH(H)+MA(H,I,0)*12:NEXT:RETURN
520 FORH=1TOSP:IFY=1THEN522
521 GOSUB1000
522 POKE53265,11:PRINT"[147]"MID$(X$(SP(H)),3)"[146] "Y"[157]. [211]PIELTAG"
523 IFY=34THENPRINT"[204]ETZTER [194]UNDESLIGASPIELTAG"
525 PRINT"<1>  [205]ANNSCHAFTSAUFSTELLUNG ............";
526 PRINT"<2>  [212]RANSFERMARKT .....................";
527 PRINT"<3>  [194]UNDESLIGATABELLE .................";
528 PRINT"<4>  [211]PIELERREPORT .....................";
529 PRINT"<5>  [193]LLGEMEINES .......................";
530 PRINT"<6>  [214]EREINS]BERSICHT ..................";
531 PRINT"<7>  [211]PIELPAARUNGEN ....................";
532 PRINT"<8>  [215]EITER ............................"CHR$(13);
533 PRINT"<0>  [211]PIELABBRUCH MIT [193]BRECHNUNG ......."CHR$(13);
534 PRINT:PRINT"[194]ITTE W[HLEN [211]IE: ";
535 POKE198,0:POKE53265,27:POKE19,64:INPUTA$:POKE19,0:PRINT
536 IFA$="0"THENES=0:GOTO7000
537 IFA$<"1"ORA$>"8"THENPRINT"[145][145]";:GOTO534
538 ES=VAL(A$):ONESGOTO2000,2700,3580,4000,8000,6000,3000,645
645 QQ=0:TR=0:F=0:C=0:FORI=1TO5:T5(I)=0:NEXTI
646 NEXTH:GOSUB3000:Y=Y+1:IFY=<34THEN102
647 Y=34:GOTO7000
748 REM ENDE
750 PRINT"[147]";:POKE53265,11:IFY<4THEN753
751 FORH=1TOSP:PRINT""MID$(X$(SP(H)),3)"[146]   [211]PIELER"H:GOSUB9500:PRINT:NEXT
752 POKE53265,27:POKE198,0:WAIT198,1:POKE53265,11
753 POKE198,0:PRINT"[147]";"[196]AS WAR EINE [194]EGEGNUNG MIT DEM HARTEN   ";
754 PRINT"[199]ESCH[FT UM [199]ELD UND [211]PORT.            "CHR$(13);
755 PRINT"[215]AGEN [211]IE EINE ZWEITE [211]AISON";:POKE198,0:POKE53265,27:INPUTA$
756 A$=CHR$(ASC(A$)):IFA$="J"ORA$="[202]" THENRUN
757 PRINT"[147][211]O LONG, [200]OOLIGAN...":CLR:END
998 REM GELBE KARTEN,FORM
1000 PRINT"[147]";
1040 FORI=1TO20:IFMA(H,I,1)=0THEN1075
1041 MA(H,I,1)=MA(H,I,1)+RND(.)-RND(.):IFMA(H,I,1)<0 THENMA(H,I,1)=MA(H,I,1)+1:GOTO1075
1042 IFMA(H,I,1)<1THENMA(H,I,1)=1
1043 IFMA(H,I,1)>=6THENMA(H,I,1)=5.999
1044 IFRND(.)>.98THENMA(H,I,2)=MA(H,I,2)-(RND(.)*RND(.)*10):GOTO1070
1045 MA(H,I,2)=MA(H,I,2)-RND(.)+RND(.)
1070 IFMA(H,I,2)>5THENMA(H,I,2)=5
1071 IFMA(H,I,3)>99THENMA(H,I,3)=MA(H,I,3)-100
1075 NEXT:FORI=1TO11:X=0:IFRND(.)>.8 THENX=MA(H,EL(I,H),3):X=X+1:MA(H,EL(I,H),3)=X
1076 IFX=4ORX=7ORX=10ORX=12THENMA(H,EL(I,H),3)=MA(H,EL(I,H),3)+100
1077 NEXT
1078 X=0:FORI=12TO20:IFMA(H,BA(I,H),2)<0 THENMA(H,BA(I,H),2)=MA(H,BA(I,H),2)+RND(.)
1079 NEXT
1080 EF(H)=0:FORI=1TO11:IFMA(H,EL(I,H),2)<0ORMA(H,EL(I,H),3)>99THEN1082
1081 EF(H)=EF(H)+INT(MA(H,EL(I,H),1))
1082 NEXT
1090 A=1:IFEF(H)>=18THENA=2:IFEF(H)>=27THENA=3:IFEF(H)>=36THENA=4:IFEF(H)>=45THENA=5
1091 X$(SP(H))=STR$(A)+MID$(X$(SP(H)),3):RETURN
1998 REM AUFSTELLUNG
2000 PRINT"[147]";:POKE53265,11
2001 PRINT""MID$(X$(SP(H)),3)"[146]  [211]PIELERFORM"
2002 PRINTSPC(71)"[206]R. [211]PIEL";
2003 FORI=1TO20:PRINTRIGHT$(STR$(I),2)CHR$(32);:GOSUB8500:PRINTG$;INT(MA(H,I,1)*100)/100;
2004 PRINT:PRINT"[145]";
2110 IFMA(H,I,2)<0THENPRINTSPC(22)"[214]";:GOTO2113
2111 IFMA(H,I,3)>99THENPRINTSPC(22)"[199]";:GOTO2113
2112 PRINTSPC(22)" ";
2113 PRINT:NEXT:PRINT""SPC(40);
2114 I=0:FORJ=1TO11:I=I+1
2115 IFI<EL(J,H)THENI=I+1:PRINTSPC(40);:GOTO2115
2116 PRINTSPC(24)">";:I=EL(J,H):PRINTINT(MA(H,EL(J,H),1))SPC(5)RIGHT$(STR$(J),2);:GOSUB8530
2117 PRINTG$:NEXTJ:POKE211,0:POKE214,24:SYS58640:PRINT"[211]PIELST[RKE:"EF(H);
2118 POKE53265,27:POKE198,0:WAIT198,1:POKE198,0
2119 PRINT"[147]";:POKE53265,11
2120 PRINT""MID$(X$(SP(H)),3)"[146]   [193]UFGEBOT":PRINT
2121 PRINT"[205]ANNSCHAFT"TAB(19)"[194]ANK":PRINT
2122 FORJ=1TO11:PRINTRIGHT$(STR$(J),2)"  "INT(MA(H,EL(J,H),1)*100)/100:PRINT"[145]"SPC(9);
2123 I=EL(J,H):GOSUB8530:PRINTG$;:IFMA(H,EL(J,H),2)<0THENPRINT" [214]";
2124 GOSUB2223:PRINT:NEXTJ:PRINT"";:FORJ=12TO20:PRINTSPC(19)RIGHT$(STR$(J),2)"  ";
2125 PRINTINT(MA(H,BA(J,H),1)*100)/100:PRINT"[145]"SPC(28);:I=BA(J,H):GOSUB8530:GOSUB2220
2126 PRINT:NEXTJ:POKE211,0:POKE214,20:SYS58640:PRINT"[211]PIELST[RKE:"EF(H);
2127 POKE211,0:POKE214,20:SYS58640:PRINT"[211]OLL DIE [193]UFSTELLUNG GE[NDERT WERDEN";
2128 POKE53265,27:POKE198,0:INPUTA$:A$=CHR$(ASC(A$)):IFA$="N"ORA$="[206]" THEN522
2129 POKE211,0:POKE214,20:SYS58640:PRINT"[215]ELCHER [211]PIELER SOLL AUS DER [205]ANNSCHAFT ";
2130 PRINT"GENOMMEN WERDEN";:INPUTA$:X=VAL(A$):IFX<1ORX>11 THEN2129
2131 IFMA(H,EL(X,H),2)<0ORMA(H,EL(X,H),3)>99 THENV(EL(X,H),H)=0:GOTO2133
2132 EF(H)=EF(H)-INT(MA(H,EL(X,H),1)):V(EL(X,H),H)=0
2133 POKE211,0:POKE214,22:SYS58640:PRINT"[196]URCH WEN SOLL ER ERSETZT WERDEN";
2134 INPUTA$:IFVAL(A$)<12ORVAL(A$)>20 THEN2119
2135 R=VAL(A$):ONXGOTO2172,2174,2174,2174,2176,2176,2176,2176,2178,2178,2178
2172 IFMA(H,BA(R,H),4)=1THEN2180
2173 GOTO2179
2174 IFMA(H,BA(R,H),4)=2THEN2180
2175 GOTO2179
2176 IFMA(H,BA(R,H),4)=3THEN2180
2177 GOTO2179
2178 IFMA(H,BA(R,H),4)=4THEN2180
2179 POKE211,0:POKE214,24:SYS58640:PRINT"[198]ALSCHE [208]OSITION";:GOTO2200
2180 IFV(BA(R,H),H) THENPOKE211,0:POKE214,24:SYS58640:PRINT"[194]EREITS EINGESETZT";:GOTO2200
2181 FORI=0TO4:X(I)=MA(H,EL(X,H),I):MA(H,EL(X,H),I)=MA(H,BA(R,H),I)
2182 MA(H,BA(R,H),I)=X(I):NEXT:EF(H)=EF(H)+INT(MA(H,EL(X,H),1)):GOSUB1090:GOTO2119
2200 FORI=1TO2400:NEXT:POKE211,0:POKE214,24:SYS58640:PRINT"                  ";:GOTO2133
2220 PRINTG$;:IFMA(H,BA(J,H),2)<0THENPRINT" [214]";
2221 IFMA(H,BA(J,H),3)>99THENPRINT" [199]";
2222 RETURN
2223 IFMA(H,EL(J,H),3)>99THENPRINT" [199]";
2224 RETURN
2398 REM AUTOM.AUFSTELLUNG
2400 EL(1,H)=1:V(1,H)=1:FORJ=3TO5:EL(J-1,H)=J:V(J,H)=1:NEXT
2401 FORJ=7TO10:EL(J-2,H)=J:V(J,H)=1:NEXT
2402 FORJ=12TO14:EL(J-3,H)=J:V(J,H)=1:NEXT:GOSUB1080
2403 FORI=1TOSP:BA(12,I)=2:BA(13,I)=6:BA(14,I)=11:FORJ=15TO20:BA(J,I)=J:NEXTJ,I
2404 RETURN
2608 REM VERKAUFSPR]FUNG
2610 I=1:JJ=0
2611 IFT5(I)<>0THEN2613
2612 T5(I)=X:RETURN
2613 I=I+1:IFI=<5THEN2611
2614 IFA$="K"ORA$="[203]"THENRETURN
2615 JJ=-1:RETURN
2698 REM TRANSFERMARKT
2700 PRINT"[147]";:POKE53265,11:PRINT"[197]IGENE [205]ANNSCHAFT:":PRINT:TR=TR+1
2701 PRINT"[206]R. [208]OSITION      [198]ORM  [199]EHALT":PRINT
2702 FORI=1TO20:PRINTRIGHT$(STR$(I),2)"  ";:GOSUB8500:PRINTG$"  "INT(MA(H,I,1)*100)/100;
2703 PRINTTAB(24)MA(H,I,0);:IFMA(H,I,2)<0THENPRINT"[214] ";
2704 IFI<>2ANDI<>6ANDI<>11ANDI<15THENPRINT">";
2705 PRINT:NEXTI:IFAATHENRETURN
2706 IFTR>3THENGOSUB2805:POKE198,0:POKE53265,27:WAIT198,1:POKE198,0:GOTO522
2707 POKE198,0:POKE53265,27:WAIT198,1:POKE198,0
2708 PRINTCHR$(147);:POKE53265,11
2709 PRINT"[197]INKAUFSM\GLICHKEITEN:":PRINT
2710 PRINT"[206]R. [208]OSITION      [198]ORM  [203]OSTEN":PRINT
2711 FORI=1TO5:IFC=1THENGOSUB8501:TK$="     "+STR$(TK(I)):GOTO2715
2712 TS(I)=INT(RND(.)*4)+2
2713 TK(I)=INT(PR(TS(I))+(RND(.)*TS(I)*20000)-(RND(.)*TS(I)*20000))
2714 TA(I)=INT(RND(.)*4)+1:GOSUB8501:TK$="     "+STR$(TK(I))
2715 PRINTRIGHT$(STR$(I),2)"  "G$"  "TS(I)TAB(24)RIGHT$(TK$,6)
2716 NEXTI:C=1:POKE214,15:POKE211,0:SYS58640:PRINT"[203]APITAL:";:IFDM(H)<0 THENPRINTCHR$(32);
2717 PRINTDM(H):PRINT:PRINT"<[203]>  [211]PIELERKAUF .......................";
2718 PRINT"<[214]>  [211]PIELERVERKAUF ....................";
2719 PRINT"<[205]>  [210]]CKKEHR INS [200]AUPTMEN]  ..........";""
2720 PRINT"[194]ITTE W[HLEN: ";
2721 POKE53265,27:POKE198,0:POKE19,64:INPUTA$:POKE19,0:A$=CHR$(ASC(A$))
2722 IFA$="V"ORA$="[214]"THEN2739
2723 IFA$="K"ORA$="[203]"THEN2770
2724 GOTO522
2739 AA=-1:PRINT"[147]";:POKE53265,11:GOSUB2702:AA=0:POKE214,22:POKE211,0:SYS58640
2740 POKE53265,27
2741 PRINT"[215]ELCHEN [211]PIELER";:INPUTA$:X=VAL(A$):GOSUB2820:IFJJTHEN2830
2742 IFMA(H,X,1)=0 THENPOKE214,22:POKE211,0:SYS58640:PRINT"[211]PIELER EXISTIERT NICHT":GOTO2800
2743 IFMA(H,X,2)<0 THENPOKE214,22:POKE211,0:SYS58640:PRINT"[211]PIELER VERLETZT         ":GOTO2800
2744 J=1
2745 IFT5(J)<>XTHEN2747
2746 GOTO2777
2747 J=J+1:IFJ=<5THEN2745
2748 GOSUB2610:IFJJTHENJJ=0:GOTO2777
2749 R=INT(MA(H,X,1))
2750 VV=INT(PR(R)+(RND(.)*MA(H,X,1)*20000)-(RND(.)*MA(H,X,1)*20000))
2751 POKE214,22:POKE211,0:SYS58640:PRINT"[193]NGEBOT:"VV"[157] [196][205], VERKAUFEN [211]IE";
2752 INPUTA$:A$=CHR$(ASC(A$)):IFA$<>"J"ANDA$<>"[202]"THEN2708
2753 FORI=0TO4:MA(H,X,I)=0:NEXTI:BA(X,H)=0:DM(H)=DM(H)+VV:GOTO2700
2770 POKE214,22:POKE211,0:SYS58640:IFDM(H)<-999999 THENPRINT"[206]ICHT FINANZIERBAR";:GOTO2800
2771 PRINT"[215]ELCHEN [211]PIELER";"     [157][157][157][157][157]";:INPUTA$:X=VAL(A$):IFX<0ORX>5THEN2770
2772 J=1:IFTK(X)=0 THENPOKE214,22:POKE211,0:SYS58640:PRINT"[211]PIELER SCHON VERKAUFT":GOTO2800
2773 IFMA(H,J,1)<>0THENJ=J+1:IFJ<=20 GOTO2773
2774 IFJ>20 THENPOKE214,22:POKE211,0:SYS58640:PRINT"[205]ANNSCHAFT IST BESETZT":GOTO2800
2775 MA(H,J,1)=TS(X)+RND(.):MA(H,J,4)=TA(X):MA(H,J,2)=5:DM(H)=DM(H)-TK(X)
2776 TK(X)=0:MA(H,J,0)=INT(MA(H,J,1)*6000):Q=J:GOSUB2610:GOTO2778
2777 POKE214,22:POKE211,0:SYS58640:PRINT"[215]EITERE [214]ERHANDLUNGEN N[CHSTE [215]OCHE.":GOTO2800
2778 IFJ>14THENBA(J,H)=J
2779 IFJ=2THENBA(J,H)=12
2780 IFJ=6THENBA(J,H)=13
2781 IFJ=11THENBA(J,H)=14
2782 MA(H,J,3)=0:GOTO2700
2800 FORII=1TO2500:NEXTII:POKE214,22:POKE211,0:SYS58640
2801 PRINT"                                                               ";:GOTO2708
2805 PRINT"";"[212]RANSFERMARKT GESCHLOSSEN               ";:RETURN
2820 IFX>20THENJJ=-1:RETURN
2821 FORII=1TO11:IFX=EL(II,H)THENJJ=-1
2822 NEXTII:RETURN
2830 JJ=0:POKE214,22:POKE211,0:SYS58640:PRINT"";:GOTO2741
2998 REM N[CHSTE RUNDE
3000 PRINTCHR$(147);:POKE53265,11:IFES=7 THENPRINT"[206][CHSTER [194]UNDESLIGASPIELTAG:":PRINT
3001 IFES<>7THENPRINTRIGHT$(STR$(Y),LEN(STR$(Y))-1)". [194]UNDESLIGASPIELTAG":PRINT
3002 FORJ=1TO9:IFY>17THENZ=Y-17:GOTO3004
3003 Z(1)=VAL(MID$(M$(Y),(J-1)*4+1,2)):Z(2)=VAL(MID$(M$(Y),(J-1)*4+3,2)):GOTO3012
3004 Z(2)=VAL(MID$(M$(Z),(J-1)*4+1,2)):Z(1)=VAL(MID$(M$(Z),(J-1)*4+3,2))
3012 FORK=1TOSP:IFZ(1)=SP(K)THENTB(K)=VAL(LEFT$(X$(Z(2)),2))
3013 IFZ(2)=SP(K)THENTB(K)=-1
3014 NEXT
3015 PRINTXX$(Z(1))"-"XX$(Z(2));:IFES=7 THENPRINT:GOTO3300
3200 WA=INT(RND(.)*6)+1:WB=INT(RND(.)*6)+1:WC=WA+WB
3201 S1(1)=VAL(LEFT$(X$(Z(1)),2))
3202 S1(2)=VAL(LEFT$(X$(Z(2)),2))
3240 S=INT(RND(.)*5):N=INT(RND(.)*4):IFS=<N THEN3240
3241 WF=VAL(MID$(H$(S1(1),S1(2)),WC,1))
3242 PRINTTAB(34);:ONWF+1GOTO3270,3280,3290
3270 N(Z(1))=N(Z(1))+1:NP(Z(1))=NP(Z(1))+2
3271 S(Z(2))=S(Z(2))+1:PP(Z(2))=PP(Z(2))+2
3272 PT(Z(1))=PT(Z(1))+N
3273 NT(Z(1))=NT(Z(1))+S
3274 PT(Z(2))=PT(Z(2))+S
3275 NT(Z(2))=NT(Z(2))+N:PRINTSTR$(N)":"RIGHT$(STR$(S),1):GOTO3300
3280 U=INT(RND(.)*3):FORK=1TO2:U(Z(K))=U(Z(K))+1:PP(Z(K))=PP(Z(K))+1
3281 NP(Z(K))=NP(Z(K))+1:PT(Z(K))=PT(Z(K))+U:NT(Z(K))=NT(Z(K))+U:NEXTK
3282 PRINTSTR$(U)":"RIGHT$(STR$(U),1):GOTO3300
3290 S(Z(1))=S(Z(1))+1:PP(Z(1))=PP(Z(1))+2
3291 N(Z(2))=N(Z(2))+1:NP(Z(2))=NP(Z(2))+2:X=.4:IFS<4 THEN3293
3292 X=X-.08:IFRND(.)<XTHENS=S+1:GOTO3292
3293 PT(Z(1))=PT(Z(1))+S
3294 NT(Z(1))=NT(Z(1))+N
3295 PT(Z(2))=PT(Z(2))+N
3296 NT(Z(2))=NT(Z(2))+S:PRINTSTR$(S)":"RIGHT$(STR$(N),1)
3300 NEXT:IFES=7THENPOKE53265,27:POKE198,0:WAIT198,1:POKE198,0:GOTO522
3301 FORI=1TOSP:PRINT:PRINT""MID$(X$(SP(I)),3)"[146]":IFTB(I)<0THEN3327
3302 IFY=1THENPL(I)=10
3303 ZU=INT(((22-PL(I))*600*TB(I))+(RND(.)*2000*TB(I))-(RND(.)*2000*TB(I)))
3304 NE=INT(ZU*9+(RND(.)*5000*TB(I))-(RND(.)*5000*TB(I))):AZ(H)=AZ(H)+1
3305 PRINT"[218]USCHAUER .........."ZU:PRINT"[206]ETTOEINNAHME ......"NE:AZ(I)=AZ(I)+1
3306 ZU(I)=ZU(I)+ZU:DM(I)=DM(I)+NE:GOTO3328
3327 PRINT"[210]EISEUNKOSTEN ......";:Q=EF(I)*605:PRINTQ:DM(I)=DM(I)-Q
3328 NEXTI:POKE53265,27:POKE198,0:GOSUB3400
3329 GETA$:IFA$="" THEN3329
3330 POKE198,0:IFY<>34 THENGOSUB3580
3331 RETURN
3398 REM SORTIEREN
3400 FORI=1TO18:PA(I)=PP(I):VA(I)=I:NEXTI
3401 M=18
3402 M=INT(M/2):IFM=0 THENRETURN
3403 J=1:K=18-M:I=J:L=I+M
3404 IFPA(I)>PA(L) THEN3540
3405 IFPA(I)=PA(L) THEN3700
3406 T1=PA(I):PA(I)=PA(L):PA(L)=T1:X1=VA(I):VA(I)=VA(L):VA(L)=X1
3407 I=I-M:IFI<1 THEN3540
3408 L=I+M:GOTO3404
3540 J=J+1:IFJ>K THEN3402
3541 I=J:GOTO3408
3578 TABELLE
3580 PRINTCHR$(147);:POKE53265,11
3581 PRINT"[212]ABELLE DER [198]U^BALLBUNDESLIGA:       "
3590 X=Y:IFES=3ORES=0 THENX=Y-1
3591 PRINT"[211]TAND DES"X"[157]. [211]PIELTAGS":PRINT
3592 PRINTTAB(19)"[211]  [213]  [206]   [208]KT.  [212]ORE":PRINT
3593 FORI=1TO18:PRINTRIGHT$(STR$(I),2)CHR$(32)XX$(VA(I));:IFES=3 THEN3610
3594 FORK=1TOSP:IFVA(I)=SP(K) THENPL(K)=I
3595 NEXT
3610 PRINTTAB(18)RIGHT$(STR$(S(VA(I))),2);
3611 PRINTTAB(21)RIGHT$(STR$(U(VA(I))),2);
3612 PRINTTAB(24)RIGHT$(STR$(N(VA(I))),2);
3613 PRINTTAB(28)RIGHT$(STR$(PP(VA(I))),2)":";:A$=STR$(NP(VA(I))):A$=MID$(A$,2):PRINTA$;
3614 PRINTTAB(34)RIGHT$(STR$(PT(VA(I))),2)":";:A$=STR$(NT(VA(I))):A$=MID$(A$,2):PRINTA$
3615 NEXT:POKE53265,27:POKE198,0:WAIT198,1:POKE198,0:IFES=3ANDEN=0 THEN522
3616 RETURN
3698 TORDIFFERENZEN
3700 A=0:IFPT(VA(I))-NT(VA(I))>PT(VA(L))-NT(VA(L)) THEN3540
3701 IFPT(VA(I))-NT(VA(I))<PT(VA(L))-NT(VA(L)) THENA=-1
3702 IFAOR((PT(VA(I))-NT(VA(I))=PT(VA(L))-NT(VA(L))ANDPT(VA(I))<PT(VA(L)))) THENA=-2
3703 IFA=-2 THENA=0:GOTO3406
3704 A=0:GOTO3540
3998 GEHALT, VERLETZUNG, GELBSUCHT
4000 PRINTCHR$(147);:POKE53265,11
4001 PRINTCHR$(18)MID$(X$(SP(H)),3)CHR$(146)"   [221]BERSICHT":PRINT
4002 PRINT"[199]EHALT [205]ON./[202]AHR"TAB(20)"[198]ORM"TAB(25)"[199]ELBE [203]ARTE":J=0:PRINT
4003 FORI=1TO20:PRINTRIGHT$(STR$(I),2)CHR$(32)MA(H,I,0);:J=MA(H,I,0)*12:PRINTJ;
4004 IFMA(H,I,0)=0 THENPRINT"[157][157][157][157]     0":NEXT:GOTO4006
4005 PRINTTAB(20)INT(MA(H,I,2)*100)/100;TAB(28)MA(H,I,3):NEXT
4006 POKE53265,27:POKE198,0:WAIT198,1:POKE198,0:GOTO522
4998 UEFA-CUP UND DFB-POKAL
5000 EU=0:FU=0:L=0:EE=0:Q=0
5001 IFY=4ORY=6ORY=10ORY=12ORY=17ORY=19ORY=22ORY=24ORY=26ORY=28ORY=31ORY=33 THENQ=1
5002 IFQ THEN5040
5003 IFY=3ORY=9ORY=15ORY=21ORY=25ORY=32 THEN5200
5004 RETURN
5040 PRINTCHR$(147):POKE53265,11:PRINT"[213][197][198][193] [195]UP [211]PIELE:":PRINT
5041 X=0:FORI=1TOSP:PRINTMID$(X$(SP(I)),3):PRINTUP$(I)
5042 IFLEFT$(UP$(I),3)<>"AUS" THENX=X+1:GOSUB5100
5043 PRINT:NEXTI:POKE198,0:POKE53265,27:WAIT198,1:IFX=0 THENRETURN
5044 FORI=1TOSP:AU(I)=0:L=0:IFUP$(I)="AUSGESCHIEDEN" THENAU(I)=-1:GOTO5153
5045 X=INT(RND(.)*46)+1:IFX<19ORYY$(X)="" THEN5045
5046 FORII=1TOSP:IFA1$(II)=YY$(X) THEN5045
5047 NEXTII:IFA1$(I)="" THENA1$(I)=YY$(X):WW(I)=X
5048 X=-1:GOSUB5500:IFGU(I)=1 THENJU(I,1)=EU:JU(I,2)=FU
5049 IFGU(I)=2 THENJU(I,3)=EU:JU(I,4)=FU
5050 JU(I,0)=JU(I,0)+1:IFJU(I,0)<2 THEN5150
5051 IFJU(I,1)+JU(I,3)>JU(I,2)+JU(I,4) THEN5060
5052 IFJU(I,1)+JU(I,3)=JU(I,2)+JU(I,4)ANDJU(I,3)>JU(I,2) THEN5060
5053 IFJU(I,1)+JU(I,3)=JU(I,2)+JU(I,4)ANDJU(I,3)=JU(I,2) THEN5055
5054 UP$(I)="AUSGESCHIEDEN":GOTO5097
5055 IFL=0THENJ=91:II=120:AU=5:POKE214,21:POKE211,1:SYS58640:PRINT"[214]ERL[NGERUNG[144]",
5056 IFL=0 THENL=1:GOSUB5509:GOTO5049
5057 GOSUB5300:IFEU>FU THENL=0:GOTO5060
5058 IFFU>EU THENL=0:GOTO5054
5059 GOSUB5350:GOTO5057
5060 A$=UP$(I):GOSUB5418:UP$(I)=A$:UP(I)=A
5097 POKEVIC+21,0:PRINTCHR$(147)CHR$(14):NEXTI:GOSUB5400
5098 GETA$:IFA$="" THEN5098
5099 RETURN
5100 IFGU(I)<>1 THEN5103
5101 GU(I)=2:PRINT"[193]USW[RTSSPIEL":PRINT"[197]RGEBNIS DES [200]INSPIELS:"STR$(JU(I,1))":";
5102 PRINTRIGHT$(STR$(JU(I,2)),1):GOTO5109
5103 IFGU(I)=0 THEN5106
5104 PRINT"[200]EIMSPIEL":PRINT"[197]RGEBNIS DES [200]INSPIELS:"STR$(JU(I,3))":"RIGHT$(STR$(JU(I,4)),1)
5105 GU(I)=1:GOTO5109
5106 IFRND(.)>.499 THENGU(I)=1:PRINT"[200]EIMSPIEL":GOTO5109
5107 GU(I)=2:PRINT"[193]USW[RTSSPIEL"
5109 GU=GU(I):BU=6+RND(.)+UP(I)/16:CU=4-RND(.)*2+UP(I)/30:IFGU=2 THEN5117
5110 ZU=(12000*CU+RND(.)*2000*CU-RND(.)*2000*CU+5000):BU=BU+((33-EF(I))/11)
5111 IFUP$(I)="IM [200]ALBFINALE" THENZU=ZU*1.65
5112 IFUP$(I)="IM [198]INALE" THENZU=ZU*2.15
5113 K=VAL(MID$(UP$(I),8)):IFK>0 THENZU=ZU/3*K
5114 ZU=INT(ZU):NE=INT(ZU*9+RND(.)*5000*CU-RND(.)*5000*CU):DM(I)=DM(I)+NE
5115 PRINT"[218]USCHAUER:"ZU:PRINT"[206]ETTOEINNAHME:"NE:RETURN
5117 Q=EF(I)*904:DM(I)=DM(I)-Q:PRINT"[210]EISEKOSTEN:"Q:RETURN
5150 POKEVIC+21,0:PRINTCHR$(147)CHR$(14):NEXTI:GOSUB5404:GOTO5098
5153 JU(I,0)=JU(I,0)+1:NEXTI
5154 IFJU(1,0)>1 THENPOKEVIC+21,0:PRINTCHR$(147)CHR$(14):GOSUB5400:GOTO5098
5155 POKEVIC+21,0:PRINT"[147]":GOSUB5404:GOTO5098
5200 PRINT"[147]":POKE53265,11:PRINT"[196][198][194]-[208]OKALSPIELE:":PRINT
5201 X=0:FORI=1TOSP:PRINTMID$(X$(SP(I)),3):PRINTDP$(I)
5202 IFLEFT$(DP$(I),3)<>"AUS" THENX=X+1:GOSUB5270
5203 PRINT:NEXTI:POKE198,0:POKE53265,27:WAIT198,1:IFX=0 THENRETURN
5204 FORI=1TOSP:AU(I)=0:L=0:IFDP$(I)="AUSGESCHIEDEN" THENAU(I)=-1:NEXTI:GOTO5279
5205 X=INT(RND(.)*18)+1:IFX=SP(I) THENGOSUB5603:WW(I)=0:GOTO5208
5206 FORII=1TOSP:IFSP(II)=XORYY$(X)=A2$(II) THEN5205
5207 NEXTII:IFA2$(I)="" THENA2$(I)=YY$(X):WW(I)=X
5208 X=-2:L=0
5209 GOSUB5500
5210 IFEU>FUTHEN5260
5211 IFEU<FUTHENL=0:DP$(I)="AUSGESCHIEDEN":GOTO5297
5212 IFL=0THENJ=91:II=120:AU=5:POKE214,21:POKE211,1:SYS58640:PRINTCHR$(18)"[214]ERL[NGERUNG[144]";
5213 IFL=0THENL=1:GOSUB5509:IFEU=FUTHENGOSUB5300
5214 IFEU=FUTHENGOSUB5350:GOTO5210
5215 GOTO5210
5260 A$=DP$(I):GOSUB5418:DP$(I)=A$:DP(I)=A:IFA=25 THENDP$(I)="[196][198][194] [208]OKAL [211]IEGER"
5261 GOTO5297
5270 IFRND(.)>.499 THENGU=1:PRINT"[200]EIMSPIEL":GOTO5272
5271 GU=2:PRINT"[193]USW[RTSSPIEL"
5272 BU=5.8+RND(.)+DP(I)/12:CU=3.8-RND(.)*2.2+DP(I)/20
5273 ZU=(10000*CU+RND(.)*2000*CU-RND(.)*2000*CU+5000):BU=BU+((33-EF(I))/11)
5274 IFDP$(I)="IM [200]ALBFINALE"THENZU=ZU*1.65
5275 IFDP$(I)="IM [198]INALE"THENZU=ZU*2.15
5276 K=VAL(MID$(DP$(I),8)):IFK>0THENZU=ZU/3*K
5277 ZU=INT(ZU):NE=INT((ZU*9+RND(.)*5000*CU-RND(.)*5000*CU)/2):DM(I)=DM(I)+NE
5278 PRINT"[218]USCHAUER:"ZU:PRINT"[200][LFTE DER [197]INNAHMEN:"NE:RETURN
5279 POKEVIC+21,0:PRINT"[147]":GOSUB5600:RETURN
5280 :
5297 POKEVIC+21,0:PRINT"[147]":NEXTI:GOSUB5600:RETURN
5300 IFL=2THENRETURN
5301 POKE214,21:POKE211,1:SYS58640:PRINTCHR$(18)"[197]LFMETERSCHIE^EN: 0[144]";
5302 L=2:FU=0:EU=0:POKEVIC+21,2:FORJ=1TO5:FORII=1TO2
5303 IFII=1 THENPOKE214,21:POKE211,19:SYS58640:PRINTJ;:IFRND(.)<1-MA(I,1,1)/20 THENFU=FU+1
5304 IFII=1THENGOSUB5700:GOTO5306
5305 IFRND(.)<.85 THENEU=EU+1:GOSUB5700:FORK=1TO2000:NEXTK
5306 NEXTII,J:RETURN
5307 :
5350 J=J-1:FORII=1TO2:IFII=1THENJ=J+1:POKE214,21:POKE211,19:SYS58640:PRINTJ;
5351 IFII=1ANDRND(.)<1-MA(I,1,1)/25THENFU=FU+1
5352 IFII=1THENGOSUB5700:GOTO5354
5353 IFRND(.)<.85THENEU=EU+1:GOSUB5700:FORK=1TO2500:NEXTK
5354 NEXTII:RETURN
5400 FORI=1TOSP:IFUP$(I)<>"AUSGESCHIEDEN" THENYY$(WW(I))=""
5401 GU(I)=0:A1$(I)="":WW(I)=0:AU(I)=0:JU(I,0)=0:NEXTI
5404 POKE53265,11
5405 FORI=1TOSP:PRINTCHR$(18)MID$(X$(SP(I)),3)CHR$(146):PRINT:IFAU(I) THEN5411
5406 IFUP$(I)="AUSGESCHIEDEN"ANDJU(I,1)=0ANDJU(I,2)=0ANDJU(I,3)=0ANDJU(I,4)=0 THEN5411
5407 PRINT"[197]RGEBNIS";:IFWW(I) THENGOSUB5424:PRINTSTR$(A)":"RIGHT$(STR$(X),1)
5408 IFWW(I) THENPRINT"[211]IE SPIELEN ";:GOTO5411
5409 PRINT"SE:":PRINTRIGHT$(STR$(JU(I,1)),1)":"RIGHT$(STR$(JU(I,2)),1)" UND"STR$(JU(I,3))":";
5410 PRINTRIGHT$(STR$(JU(I,4)),1):PRINT"[196]AMIT SIND [211]IE ";
5411 PRINTUP$(I):PRINT
5412 IFUP$(I)="AUSGESCHIEDEN" THENFORII=1TO4:JU(I,II)=0:NEXTII
5413 NEXTI:POKE53265,27:RETURN
5418 IFA$="IN DER 1. [210]UNDE"THENA$="IN DER 2. [210]UNDE":A=5:RETURN
5419 IFA$="IN DER 2. [210]UNDE"THENA$="IN DER 3. [210]UNDE":A=8:RETURN
5420 IFA$="IN DER 3. [210]UNDE"THENA$="IN DER 4. [210]UNDE":A=12:RETURN
5421 IFA$="IN DER 4. [210]UNDE"THENA$="IM [200]ALBFINALE":A=16:RETURN
5422 IFA$="IM [200]ALBFINALE"THENA$="IM [198]INALE":A=20:RETURN
5423 IFA$="IM [198]INALE"THENA$="[213][197][198][193] [195]UP [211]IEGER":A=25:RETURN
5424 IFGU(I)=2THENA=JU(I,3):X=JU(I,4)
5425 IFGU(I)=1THENA=JU(I,1):X=JU(I,2)
5426 RETURN
5498 POKALERGEBNISSE
5500 GOSUB15000:POKE214,21:POKE211,0:SYS58640
5501 PRINTCHR$(18);:FORII=1TO159:PRINTCHR$(32);:NEXTII
5502 POKE2023,160:POKE56295,0
5503 AU=5:FU=0:EU=0:GC=30/(BU-CU):OC=AU
5504 IFX=-1 THENX=GU(I):A$=A1$(I):GOTO5506
5505 X=GU:A$=A2$(I)
5506 IFX=2 THENPOKE214,22:POKE211,1:SYS58640:PRINTCHR$(18)A$"  "YY$(SP(I))
5507 IFX=1 THENPOKE214,22:POKE211,1:SYS58640:PRINTCHR$(18)YY$(SP(I))"  "A$
5508 J=1:II=90:POKEVIC+21,3:PRINTCHR$(18)"  0"SPC(15)"  0";:POKE53265,27
5509 POKE214,22:POKE211,36:SYS58640:AU=AU+RND(.)-RND(.):NC=(AU-CU)*GC+5:IFNC<0 THENNC=0
5510 PRINTCHR$(18)J;:IFNC>39THENNC=39
5511 IFNC*8>255THENPOKEVIC+16,1:POKEVIC,NC*8-255:GOTO5513
5512 POKEVIC+16,0:POKEVIC,NC*8
5513 OC=NC:IFAU>BU+.8THENEU=EU+1:N=N+1:POKEVIC,73:GOSUB5700:OC=NC:GOTO5580
5514 IFAU<CU-.3THENFU=FU+1:N=N+1:POKEVIC,17:GOSUB5700:OC=NC
5580 IFJ=45THENGOSUB5700
5581 IFJ=105THENGOSUB5700
5582 J=J+1:IFJ=<II THEN5509
5583 GOSUB5700:IFL=1ANDGU(I)=1THENJU(I,1)=EU:JU(I,2)=FU
5584 RETURN
5600 FORI=1TOSP:IFDP$(I)<>"AUSGESCHIEDEN" THENYY$(WW(I))=""
5601 A2$(I)="":WW(I)=0:AU(I)=0:NEXTI
5603 Q9=Q9+1:ONQ9 GOTO5605,5606,5607,5608,5609,5610,5611,5612,5613,5614,5615,5616
5604 A2$(I)="WALDHOF MANNH.  ":RETURN
5605 A2$(I)="FSV MAINZ 05    ":RETURN
5606 A2$(I)="SV MEPPEN       ":RETURN
5607 A2$(I)="PREUSS. MUENSTER":RETURN
5608 A2$(I)="VFB OLDENBURG   ":RETURN
5609 A2$(I)="VFL OSNABRUECK  ":RETURN
5610 A2$(I)="1.FC SAARBRUECK.":RETURN
5611 A2$(I)="FC SCHALKE 04   ":RETURN
5612 A2$(I)="FC SCHWEINFURT  ":RETURN
5613 A2$(I)="STGT. KICKERS   ":RETURN
5614 A2$(I)="HANNOVER 96     ":RETURN
5615 A2$(I)="MSV DUISBURG    ":RETURN
5616 A2$(I)="ROT-WEISS ESSEN ":RETURN
5700 FORK=1TO500:NEXTK:POKE214,23:POKE211,1:SYS58640
5701 IFX=1THENPRINTCHR$(18)EU;SPC(15)FU;
5702 IFX=2THENPRINTCHR$(18)FU;SPC(15)EU;
5703 AU=5+RND(.)-RND(.):POKE198,0:FORK=1TO2000:NEXTK:RETURN
5998 UEBERSICHT
6000 IFF=2THEN6030
6001 IFY=1THENVV(H)=SK(H):GOTO6030
6002 VV(H)=0:FORI=1TO20:R=INT(MA(H,I,1))
6003 VV=INT(PR(R)+(RND(.)*MA(H,I,1)*20000)-(RND(.)*MA(H,I,1)*20000)):VV(H)=VV(H)+VV
6004 NEXT:VV(H)=VV(H)+DM(H):F=2
6030 PRINT"[147]";:POKE53265,11
6031 A$="[214]EREINS]BERSICHT":GOSUB6100
6032 PRINT"[211]TARTVERM\GEN ....."SK(H)
6033 PRINT"[214]EREINSVERM\GEN ..."VV(H):PRINT:X=Y:IFES=3 THENX=Y-1
6034 PRINT"[211]PIELTAG ..........."X
6035 PRINT"[203]APITAL ............"DM(H)
6036 PRINT"[212]ABELLENPLATZ ......"PL(H)
6037 PRINT"[196][198][194] [214]EREINSPOKAL ... "DP$(H)
6038 PRINT"[213][197][198][193] [195]UP ........... "UP$(H):PRINT
6039 PRINT"[199]ESAMTZUSCHAUER ...."ZU(H)
6040 PRINT"[200]EIMSPIELE ........."AZ(H)
6041 PRINT"[218]USCHAUERSCHNITT ...";
6042 X=0:IFAZ(H)>0THENX=INT(ZU(H)/AZ(H)+.5)
6043 GOSUB250:PRINTX:PRINT"[199]EH[LTER LFD.[211]AISON."GH(H)
6044 POKE198,0:POKE53265,27:WAIT198,1:POKE198,0:GOTO522
6100 PRINTCHR$(18)MID$(X$(SP(H)),3)CHR$(146)CHR$(32)A$:PRINT"";:RETURN
6998 ABSCHLUSSUEBERSICHT
7000 POKE53265,11:IFY=1ANDES=0THENES=3:EN=-1
7001 PRINTCHR$(147)"[193]BSCHLU^TABELLE DER [198]USSBALLBUNDESLIGA: ";:GOSUB3590
7002 FORH=1TOSP:PRINT"[147]";:POKE53265,11:A$="[211]CHLU^]BERSICHT":GOSUB6100
7003 VV(H)=0:PRINT"[145]";:FORI=1TO20:R=INT(MA(H,I,1))
7004 VV=INT(PR(R)+(RND(.)*MA(H,I,1)*20000)-(RND(.)*MA(H,I,1)*20000)):VV(H)=VV(H)+VV
7005 A$=STR$(VV):A$="      "+RIGHT$(A$,LEN(A$)-1):PRINT:PRINTRIGHT$(STR$(I),2)CHR$(32)RIGHT$(A$,7);:NEXT
7006 PRINT:PRINT"   [192][192][192][192][192][192][192]";:A$=STR$(VV(H)):A$="      "+RIGHT$(A$,LEN(A$)-1)
7007 PRINTSPC(33)RIGHT$(A$,7);"";
7008 PRINT"";SPC(15)"[205]ANNSCHAFTSWERT:":PRINTSPC(14)VV(H):PRINT
7009 PRINTSPC(15)"[212]ABELLENPLATZ:":PRINTSPC(14)PL(H)"MIT"STR$(PP(SP(H)))":";
7010 A$=STR$(NP(SP(H))):A$=RIGHT$(A$,LEN(A$)-1):PRINTA$" [208]UNKTEN UND":PRINTSPC(14);
7011 PRINTSTR$(PT(SP(H)))":";:A$=STR$(NT(SP(H))):A$=RIGHT$(A$,LEN(A$)-1):PRINTA$" [212]OREN"
7012 POKE53265,27:POKE198,0:WAIT198,1:POKE198,0:NEXT:PRINTCHR$(147);
7013 FORH=1TOSP:POKE53265,11
7014 PRINT"[147]";"[211]PIELER"STR$(H)":":PRINT"[212]RAINER VON "XX$(SP(H)):PRINT
7015 PRINT"[208]UNKTE F]R [194]UNDESLIGAERGEBNIS ...";:IFPL(H)<4THENG1=60+(4-PL(H))*5:GOTO7017
7016 G1=(19-PL(H))*4:IFPL(H)=0 THENG1=0
7017 PRINTG1:PRINT"[208]UNKTE F]R [214]ERM\GEN .............";:G2=INT((VV(H)-SK(H))/150000+.5)
7018 IFG2<0 THENG2=0
7019 PRINTG2:PRINT"[208]UNKTE F]R [213][197][198][193] [195]UP [212]EILNAHME ..."UP(H)
7020 PRINT"[208]UNKTE F]R [196][198][194] [208]OKAL [211]PIELE ....."DP(H)
7021 PRINT"[208]UNKTE F]R ERZIELTE [212]ORE ........";
7022 G3=INT(PT(SP(H))/10+.5)
7023 IFPT(SP(H))>NT(SP(H))THENG3=G3+INT((PT(SP(H))-NT(SP(H)))/10+.5)
7024 PRINTG3:PRINT"";"[199]ESAMTPUNKTZAHL";:G5=G1+G2+G3+DP(H)+UP(H):PRINTG5:G5(H)=G5
7025 POKE53265,27:POKE198,0:WAIT198,1:POKE198,0:NEXT:IFO<>1 THEN750
7026 RETURN
7998 STAERKE DER MANNSCHAFTEN
8000 PRINT"[147]";:POKE53265,11:FORI=5TO1STEP-1
8001 FORJ=1TO18:IFVAL(LEFT$(X$(J),2))=I THENPRINTMID$(X$(J),2,1)"  "MID$(X$(J),3)
8002 NEXTJ,I:PRINT
8003 PRINT"1  [193]BSTIEGSKANDIDATEN:      11-17 [208]UNKTE";
8004 PRINT"2  [213]NTERES [205]ITTELFELD:      18-26 [208]UNKTE";
8005 PRINT"3  [196]URCHSCHNITTSVEREINE:    27-35 [208]UNKTE";
8006 PRINT"4  [213][197][198][193] [195]UP [193]NW[RTER:       36-44 [208]UNKTE";
8007 PRINT"5  [211]PITZENMANNSCHAFTEN:     45-55 [208]UNKTE";
8008 POKE53265,27:POKE198,0:WAIT198,1:POKE198,0:GOTO522
8498 ART DER MANNSCHAFT
8500 ONMA(H,I,4)+1GOTO8519,8520,8521,8522,8523
8501 ONTA(I)GOTO8520,8521,8522,8523
8519 G$="           ":RETURN
8520 G$="[212]ORH]TER   ":RETURN
8521 G$="[214]ERTEIDIGER":RETURN
8522 G$="[205]ITTELFELD ":RETURN
8523 G$="[211]T]RMER    ":RETURN
8530 ONMA(H,I,4)+1GOTO8539,8540,8541,8542,8543
8531 ONTA(I)GOTO8540,8541,8542,8543
8539 G$="    ":RETURN
8540 G$="  [212]W":RETURN
8541 G$="  [214]T":RETURN
8542 G$="  [205]F":RETURN
8543 G$="  [211]T":RETURN
9500 PRINT:IFY=34THENPRINT"[201]HR [199]ESAMTERGEBNIS ";
9501 IFY<30 THENPRINT"[211]IE HABEN ZWAR NICHT SEHR LANGE DURCH-  GEHALTEN, IHR [197]RGEBNIS ";
9502 IFY>29ANDY<34THENPRINT"[201]HR [197]RGEBNIS ";
9503 IFY<30ANDG5(H)<85+Y/2THENPRINT"IST AUCH         DEMENTSPRECHEND.":GOTO9510
9504 IFY<30THENPRINT"IST DAF]R ABER  NICHT EINMAL SCHLECHT.":GOTO9510
9505 X=1:IFG5(H)>50 THENX=2:IFG5(H)>60 THENX=3:IFG5(H)>80 THENX=4:IFG5(H)>100 THENX=5
9506 ONXGOTO9512,9515,9518,9521,9524
9510 X=INT((G5(H)-84)/Y):IFX>5 THENX=5
9511 IFX>0 THENONX GOTO9513,9516,9519,9522,9525
9512 IFX>0THENPRINT"IST KATASTROPHAL."
9513 PRINT"[211]IE K\NNEN IN EINER [211]AISON JEDEN GUT"
9514 PRINT"SITUIERTEN [195]LUB IN DIE [208]LEITE SCHICKEN.":RETURN
9515 PRINT"IST NICHT"CHR$(13)"]BERW[LTIGEND."
9516 PRINT"[196]ER [198][195][160][194]AYERN BRAUCHT [211]IE, EINMAL IN DER";
9517 PRINT"[215]OCHE ZUM [210]ASENM[HEN NAT]RLICH.":RETURN
9518 PRINT"IST WOHL KAUM"CHR$(13)"BUNDESLIGAREIF."
9519 PRINT"[211]IE SOLLTEN ZUN[CHST EINMAL ZUM [221]BEN"
9520 PRINT"MIT EINER [202]UGENDMANNSCHAFT IN DER [203]REIS-KLASSE TRAINIEREN.":RETURN
9521 PRINT"IST BEINAHE"CHR$(13)"BUNDESLIGATAUGLICH."
9522 PRINT"[205]IT EIN BI^CHEN [199]L]CK SIND [211]IE BEIM"
9523 PRINT"N[CHSTEN [205]AL GANZ OBEN.":RETURN
9524 PRINT"IST BEACHTLICH."
9525 PRINT"[211]IND [211]IE SCHON BEI EINEM [214]EREIN DER"
9526 PRINT"[194]UNDESLIGA UNTER [214]ERTRAG?":RETURN
10030 START
10032 DIMX$(A),H$(5,5),U(A),S(A),N(A),PP(A),NP(A),PT(A),NT(A),PA(A),VA(A),M$(A)
10033 FORI=1TO5:READPR(I):NEXT
10034 FORI=1TO18:READX$(I):VA(I)=I
10035 D%=RND(.)*5+1:D=D%:W(D)=W(D)+1:IFW(D)>4OR(D=5ANDW(5)>2) THEN10035
10036 X$(I)=STR$(D)+X$(I):NEXT
10037 POKE53280,13:POKE53281,13
10038 POKE53265,11:POKE646,0
10039 PRINT"  [198][213][211][211][194][193][204][204]-[205][193][206][193][199][197][210]  ":PRINT
10040 PRINT"BY [202]\RG [194]\TEL"
10042 PRINT"[194]EI DIESEM [211]PIEL K\NNEN BIS ZU DREI    "
10043 PRINT"[211]PIELER IHRE [198][HIGKEITEN ALS [198]U^BALL-"
10044 PRINT"TRAINER UNTER [194]EWEIS STELLEN.[144]"CHR$(13)
10045 PRINT"[194]ITTE [193]NZAHL DER [211]PIELER EINGEBEN: ";
10046 POKE198,0:POKE53265,27:POKE19,64:INPUTA$:POKE19,0:PRINT
10047 SP=VAL(A$):PRINT"":IFSP>3THENSP=3
10048 PRINT"[151][211]IND DIE [211]PIELREGELN BEKANNT[144]";:INPUTA$:A$=CHR$(ASC(A$))
10049 IFA$="N"ORA$="[206]"THENGOSUB20002
10050 PRINT"[147]";
10051 POKE53265,11
10052 PRINT"[211]IE K\NNEN EINE DER FOLGENDEN [205]ANN-     SCHAFTEN TRAINIEREN:":PRINT
10053 FORI=1TO18:PRINTRIGHT$(STR$(I),2)CHR$(32)MID$(X$(I),3):NEXT
10054 POKE53265,27:IFSP=0 THENSP=1
10055 FORI=1TOSP
10056 POKE198,0:POKE214,23:POKE211,0:SYS58640:PRINT"[146]";"[211]PIELER"I"[157], BITTE W[HLEN [211]IE!"
10057 POKE19,64:INPUTA$:POKE19,0:A=VAL(A$):IFA<1ORA>18ORA=SP(1)ORA=SP(2) THEN10056
10058 SP(I)=A:PRINT"[146]";:FORJ=1TOA:PRINT"";:NEXT:PRINTCHR$(18)RIGHT$(STR$(A),2);:NEXT
10059 FORI=1TO17:READM$(I):NEXT:FORI=1TO5:FORJ=1TO5:READH$(I,J):NEXTJ,I
10060 REM PAARUNGEN,ERGEBNISSE
10061 FORI=1TO3000:NEXT:POKE53265,11:PRINTCHR$(147);
10062 PRINT"[146]";"[218]U [194]EGINN DER [211]AISON VERF]GEN [211]IE ]BER"
10063 PRINT"ZWEI [212]ORH]TER, VIER [214]ERTEIDIGER, F]NF"
10064 PRINT"[205]ITTELFELDSPIELER, VIER [211]T]RMER UND"
10065 PRINT"ZWEI [205]ILLIONEN [196]-[205]ARK [211]TARTKAPITAL."
10066 POKE53265,27:FORI=1TO3000:NEXT
10067 DIMXX$(18),MA(SP,20,4),EL(11,SP),V(20,SP),JU(SP,4),BA(20,SP),YY$(46)
10068 DIMA1$(46),A2$(19):FORI=1TO18:READXX$(I):NEXT
10069 FORH=1TOSP:FORJ=1TO2:MA(H,J,1)=2.2+RND(.):MA(H,J,4)=1
10070 MA(H,J,0)=INT(MA(H,J,1)*6000):NEXT
10071 FORJ=3TO6:MA(H,J,1)=2.2+RND(.):MA(H,J,4)=2:MA(H,J,0)=INT(MA(H,J,1)*6000):NEXT
10072 FORJ=7TO11:MA(H,J,1)=2.2+RND(.):MA(H,J,4)=3:MA(H,J,0)=INT(MA(H,J,1)*6000):NEXT
10073 FORJ=12TO15:MA(H,J,1)=2.2+RND(.):MA(H,J,4)=4:MA(H,J,0)=INT(MA(H,J,1)*6000):NEXT
10074 DM(H)=2000000:UP$(H)="IN DER 1. [210]UNDE":DP$(H)="IN DER 1. [210]UNDE"
10075 FORJ=1TO15:R=INT(MA(H,J,1)):VV=INT(PR(R)+(RND(.)*MA(H,J,1)*20000))
10076 VV=VV-(RND(.)*MA(H,J,1)*20000):SK(H)=SK(H)+VV:MA(H,J,2)=5:NEXT
10077 SK(H)=SK(H)+2000000:GOSUB2400:NEXT:RETURN
14998 REM SPIELFELD
15000 POKE53265,11:PRINT"[147]";
15001 PRINT" [176]";:FORII=1TO36:PRINT"[192]";:NEXTII:PRINT"[174]  _";
15002 FORII=1TO3:PRINTSPC(36)"_  _";:NEXTII
15003 PRINTSPC(36)"_  [171][192][192][192][174]"SPC(28)"[176][192][192][192][179]"
15004 FORII=1TO2:PRINT" _"SPC(3)"_"SPC(28)"_"SPC(3)"_":NEXT
15005 PRINT" [171][192][174]-_"SPC(28)"_+[176][192][179] ";
15006 PRINT"[176][179] _ _"SPC(28)"_ _ [171][174]";
15008 PRINT"[173][179] _ _"SPC(28)"_ _ [171][189]";
15009 PRINT" [171][192][189] _"SPC(28)"_ [173][192][179] ";
15010 FORII=1TO2:PRINT" _"SPC(3)"_"SPC(28)"_"SPC(3)"_":NEXT
15011 PRINT" [171][192][192][192][189]"SPC(28)"[173][192][192][192][179]":PRINT" _";
15012 FORII=1TO3:PRINTSPC(36)"_  _";:NEXTII:PRINTSPC(36)"_  [173]";
15013 FORII=1TO36:PRINT"[192]";:NEXTII:PRINT"[189]";
15014 PRINT""SPC(19)"[178]";:FORII=1TO18:PRINTSPC(39)"_";:NEXTII:PRINTSPC(39)"[177]"
15015 POKEVIC+21,1:POKE646,0:RETURN
15998 SPRITEGENERIEREN
16000 FORI=704TO766:READA:POKEI,A:NEXTI:POKE2041,11
16001 VIC=53248:POKEVIC+21,0:POKEVIC+40,1:POKEVIC+23,2:POKEVIC+29,2
16002 POKEVIC+2,159:POKEVIC+3,116
16003 FORI=1TO46:READYY$(I):NEXT
16004 FORI=832TO894:READA:POKEI,A:NEXTI:POKE2040,13
16005 POKEVIC+39,0:POKEVIC,172:POKEVIC+1,124
16006 RETURN
20000 SPIELREGELN
20002 PRINT"[147]";:POKE53265,11
20003 PRINT"[144][194]EI DIESEM [211]PIEL F]R MAXIMAL DREI [205]IT-"
20004 PRINT"SPIELER SIMULIERT DER [195]OMPUTER EINE"
20005 PRINT"[211]AISON DER [198]U^BALLBUNDESLIGA. [211]IE SIND"
20006 PRINT"ALS [212]RAINER AUF DER [194]ANK [201]HRES [214]EREINS"
20007 PRINT"F]R [205]ANNSCHAFTSAUFSTELLUNG, [212]RANSFERS"
20008 PRINT"UND [197]RGEBNISSE VERANTWORTLICH. [215]ICHTIG-"
20009 PRINT"STE [193]UFGABE IST ES, ZUN[CHST EINE"
20010 PRINT"M\GLICHST SCHLAGKR[FTIGE [212]RUPPE AUFZU-"
20011 PRINT"BAUEN, OHNE SICH DADURCH FINANZIELL ZU"
20012 PRINT"RUINIEREN. [202]E NACH [198]ORM [201]HRER UND DER"
20013 PRINT"[205]ANNSCHAFT DES [199]EGNERS WERDEN [211]IE IN DEN";
20014 PRINT"EINZELNEN [194]EGEGNUNGEN ABSCHNEIDEN."
20015 PRINT"[193]LLERDINGS SPIELT AUCH DER [218]UFALL EINE"
20016 PRINT"NICHT UNWESENTLICHE [210]OLLE!"
20017 PRINT"[144][201]N DEN EINZELNEN [213]NTERPROGRAMMEN K\NNEN"
20018 PRINT"[211]PIELER AUS- UND EINGEWECHSELT, BZW."
20019 PRINT"VER- UND GEKAUFT WERDEN. [205]AN KANN SICH"
20020 PRINT"DIE AKTUELLE [212]ABELLE DER [194]UNDESLIGA,"
20021 PRINT"[199]EH[LTER UND [199]ESUNDHEITSZUST[NDE DER"
20022 PRINT"EINZELNEN [211]PIELER, SOWIE DIE [204]ISTE IHRER";
20023 PRINT"GELBEN [203]ARTEN ANSEHEN. [205]AN KANN SICH"
20024 PRINT"FERNER EINE [221]BERSICHT ZUM AKTUELLEN"
20025 PRINT"[211]TAND DES [214]EREINS UND DIE [211]PIELPAARUNGEN";
20026 PRINT"DES N[CHSTEN [211]PIELTAGS AUSGEBEN LASSEN."
20028 POKE53265,27:POKE198,0:WAIT198,1:PRINTCHR$(147);:POKE53265,11
20029 PRINT"[218]WISCHEN DEN EINZELNEN [194]UNDESLIGASPIEL- ";
20030 PRINT"TAGEN WERDEN [213][197][198][193] [195]UP [211]PIELE UND DIE    ";
20031 PRINT"[194]EGEGNUNGEN DES [196][198][194] [214]EREINSPOKALS AUSGE-";
20032 PRINT"TRAGEN.":PRINT
20033 PRINT"[198]]R DIE [211]PIELE DER [194]UNDESLIGA UND DIE"
20034 PRINT"UM DIE [208]OKALE GELTEN DIE [211]PIELREGELN DES";
20035 PRINT"[196][198][194]. [211]O SIND ZUM [194]EISPIEL [211]PIELER MIT"
20036 PRINT"VIER GELBEN [203]ARTEN GESPERRT. [213]NENT-"
20037 PRINT"SCHIEDENE [208]OKALBEGEGNUNGEN WERDEN NACH  ";
20038 PRINT"NEUNZIG [205]INUTEN [211]PIELZEIT VERL[NGERT.":PRINT
20039 PRINT"[144][206]UN VIEL [199]L]CK BEIM [203]AMPF IM GRO^EN          [199]ESCH[FT DER [194]UNDESLIGA.";
20041 POKE53265,27:POKE198,0:WAIT198,1:PRINTCHR$(147);
20042 RETURN
32000 REMDATAS
32002 REM PR(I), 1 BIS 5
32003 DATA 100000,200000,350000,550000,800000
32005 REM X$(I), 1 BIS 18
32006 DATA "[198][195] [194]AYERN [205]]NCHEN    "
32007 DATA "[211][214] [215]ERDER [194]REMEN     "
32008 DATA "1. [198][195] [203]\LN           "
32009 DATA "[194]ORUSSIA [205]'GLADBACH  "
32010 DATA "[194]AYER 05 [213]ERDINGEN   "
32011 DATA "[200]AMBURGER [211][214]         "
32012 DATA "[211][199] [215]ATTENSCHEID 09   "
32013 DATA "[203]ARLSRUHER [211][195]        "
32014 DATA "[214]F[204] [194]OCHUM           "
32015 DATA "[214]F[194] [211]TUTTGART        "
32016 DATA "1. [198][195] [203]AISERSLAUTERN "
32017 DATA "[194]AYER 04 [204]EVERKUSEN  "
32018 DATA "[197]INTRACHT [198]RANKFURT  "
32019 DATA "[194]ORUSSIA [196]ORTMUND    "
32020 DATA "[198]ORTUNA [196]]SSELDORF   "
32021 DATA "[198][195] [211]T. [208]AULI         "
32022 DATA "[200]ERTHA [194][211][195] [194]ERLIN    "
32023 DATA "1. [198][195] [206]]RNBERG       "
32025 REM M$(I), 1 BIS 17
32026 DATA 011115180616031312100217050408070914
32027 DATA 140804021712100313061615180111090705
32028 DATA 011615130610031712040207051411180908
32029 DATA 140204031706101513011611180908050712
32030 DATA 151706040307121402081816111309050110
32031 DATA 140304151701101113181609050208120706
32032 DATA 010415070614030812051613181011170902
32033 DATA 141504111718101602120503080607011309
32034 DATA 011415080605030213101617180411070912
32035 DATA 141104161713100912030206051508010718
32036 DATA 010515020612101713041607181411080903
32037 DATA 141604101709030612150201051108180713
32038 DATA 011215031704100713141608180511020906
32039 DATA 141004090615030112110218051608130717
32040 DATA 010615091714100813051602181211030704
32041 DATA 140415010611031812160213051008170907
32042 DATA 010904081705100213121603180611150714
32044 REM H$(I,J), JEWEILS 1 BIS 5
32045 DATA 00011222222
32046 DATA 00001122222
32047 DATA 00000112222
32048 DATA 00000111222
32049 DATA 00000011222
32050 DATA 00112222222
32051 DATA 00011222222
32052 DATA 00001122222
32053 DATA 00000112222
32054 DATA 00000111222
32055 DATA 00122222222
32056 DATA 00112222222
32057 DATA 00011222222
32058 DATA 00001122222
32059 DATA 00000112222
32060 DATA 01122222222
32061 DATA 00112222222
32062 DATA 00111222222
32063 DATA 00011122222
32064 DATA 00001122222
32065 DATA 01222222222
32066 DATA 01122222222
32067 DATA 00112222222
32068 DATA 00011222222
32069 DATA 00011122222
32071 REM XX$(I), 1 BIS 18
32072 DATA "[205]]NCHEN"
32073 DATA "[215]ERDER [194]REMEN"
32074 DATA "1. [198][195] [203]\LN"
32075 DATA "[194]OR [205]'GLADBACH"
32076 DATA "[213]ERDINGEN 05"
32077 DATA "[200]AMBURGER [211][214]"
32078 DATA "[211][199] [215]ATTENSCH"
32079 DATA "[203]ARLSRUHER [211][195]"
32080 DATA "[214]F[204] [194]OCHUM"
32081 DATA "[214]F[194] [211]TUTTGART"
32082 DATA "[203]AISERSLAUTERN"
32083 DATA "[204]EVERKUSEN"
32084 DATA "[198]RANKFURT"
32085 DATA "[194]OR [196]ORTMUND"
32086 DATA "[196]]SSELDORF"
32087 DATA "[198][195] [211]T. [208]AULI"
32088 DATA "[200]ERTHA [194][211][195] "
32089 DATA "[206]]RNBERG"
32091 REM A, 0 BIS 62 (SPRITE DATA)
32092 DATA 0,248,0,7,7,0,8,0,128
32095 DATA 16,0,64,32,0,32,32,0,32
32098 DATA 32,0,32,32,0,32,32,0,32
32101 DATA 16,0,64,8,0,128,7,7,0
32104 DATA 0,248,0,0,0,0,0,0,0
32107 DATA 0,0,0,0,0,0,0,0,0
32110 DATA 0,0,0,0,0,0,0,0,0
32114 REM YY$(I), 1 BIS 46
32115 DATA "[194]AYERN [205]]NCHEN  "
32116 DATA "[215]ERDER [194]REMEN   "
32117 DATA "1. [198][195] [203]\LN      "
32118 DATA "[194]OR. [205]'[199]LADBACH "
32119 DATA "[213]ERDINGEN 05    "
32120 DATA "[200]AMBURGER [211][214]    "
32121 DATA "[211][199] [215]ATTENSCHEID "
32122 DATA "[203]ARLSRUHER [211][195]   "
32123 DATA "[214]F[204] [194]OCHUM      "
32124 DATA "[214]F[194] [211]TUTTGART   "
32125 DATA "[203]AISERSLAUTERN  "
32126 DATA "[204]EVERKUSEN      "
32127 DATA "[198]RANKFURT       "
32128 DATA "[194]OR. [196]ORTMUND   "
32129 DATA "[196]]SSELDORF      "
32130 DATA "[198][195] [211]T. [208]AULI    "
32131 DATA "[200]ERTHA [194][211][195]      "
32132 DATA "1. [198][195] [206]]RNBERG  "
32133 DATA "[201]NTER [205]AILAND   ","[202]UVENTUS [212]URIN  "
32134 DATA "[193][211] [210]OM          ","[215]EST [200]AM [213]NITED "
32135 DATA "[198][195] [204]IVERPOOL    ","[198][195] [197]VERTON      "
32136 DATA "[193]RSENAL [204]ONDON  ","[198][195] [193]BERDEEN     "
32137 DATA "[210]EAL [205]ADRID     ","[198][195] [194]ARCELONA    "
32138 DATA "[208][211][214] [197]INDHOVEN   ","[199]LASGOW [210]ANGERS "
32139 DATA "[193]JAX [193]MSTERDAM  ","[198][195] [194]R]GGE       "
32140 DATA "[210][211][195] [193]NDERLECHT  ","[198][195] [208]ORTO        "
32141 DATA "[196]UKLA [208]RAG      ","[204]EGIA [215]ARSCHAU  "
32142 DATA "[198][195] [194]ARCELONA    ","[211]ERVETTE [199]ENF   "
32143 DATA "[193]USTRIA [215]IEN    ","[193][211] [211]T. [197]TIENNE  "
32144 DATA "[196]YNAMO [194]UKAREST ","[211]PARTAK [205]OSKAU  "
32145 DATA "[207]LYMIP.[205]ARSEILLE","[193][201][203] [211]TOCKHOLM   "
32146 DATA "[211]PARTAK [205]OSKAU  ","[210]OTER [211]T.[194]ELGRAD"
32148 REM A, 0 BIS 62 (SPRITE DATA)
32149 DATA 0,0,0,0,56,0,0,254,0
32152 DATA 0,254,0,1,255,0,1,255,0
32155 DATA 1,255,0,0,254,0,0,254,0
32158 DATA 0,56,0,0,0,0,0,0,0
32161 DATA 0,0,0,0,0,0,0,0,0
32164 DATA 0,0,0,0,0,0,0,0,0
32167 DATA 0,0,0,0,0,0,0,0,0