10 N1$="NL-10 EINFACH":N2$="NL-10 VIERFACH":N3$="NL-10 VIERFACH/D"
15 N4$="NL-10 VIERFACH/V":U=8:D=0
60 PRINT "BITTE DRUCKERTREIBER DISK IN LAUFWERK 8 EINLEGEN UND TASTE DRUECKEN"
65 POKE198,0:WAIT 198,1
70 FOR IX=1TO4:
80 IF IX=1THEN N$=N1$:P=1024
85 IF IX=2THEN N$=N2$:P=1024
90 IF IX=3THEN N$=N3$:P=1024
95 IF IX=4THEN N$=N4$:P=1024
110 V=16: Q=32: F=256: N$=LEFT$(N$,V)
120 H$="0123456789ABCDEF": Z$=CHR$(0)
130 T$=RIGHT$(STR$(D),1): OPEN 1,U,15,"I"+T$: GOSUB 620
140 T$=T$+":"+N$: OPEN 2,U,2,T$+",P,R"
150 INPUT#1,E,M$,J,K: IF E=0 THEN 240
160 CLOSE 1: CLOSE 2: PRINT " PROGRAMM ";N$;
170 IF E=62 THEN PRINT " NICHT GEFUNDEN ":
180 IF E=64 THEN PRINT " FALSCHER FILETYP":
190 PRINT " DISK READ-ERROR";E: END
210 J=INT(C/V): K=C-J*V
220 M$=M$+MID$(H$,J+1,1)+MID$(H$,K+1,1)
230 RETURN
240 GET#2,A$,B$: IF ST THEN 190
250 CLOSE 2: CLOSE 1: M$=""
260 A=ASC(A$+Z$): B=ASC(B$+Z$)
270 C=B: GOSUB 210: C=A: GOSUB 210
280 PRINT"DIE STARTADRESSE VON ";N$;" IST: ";
290 PRINT"HEXADEZIMAL: ";M$;" DEZIMAL:  ";B*F+A
300 PRINT"UND WIRD GEAENDERT AUF DEZIMAL: ";P
340 B=INT(P/F): A=P-B*F: P$=CHR$(A)+CHR$(B): M$=""
350 C=B: GOSUB 210: C=A: GOSUB 210
360 PRINT " HEX:  ";M$;"    DECIMAL: ";B*F+A
390 J=LEN(N$): IF J=V THEN 410
400 FOR X=J+1 TO V:N$=N$+CHR$(160):NEXT
410 OPEN 1,U,15: OPEN 2,U,2,"#"
420 GOSUB 620: T=18: S=1
430 PRINT#1,"U1:";2;D;T;S: GOSUB 620
440 PRINT#1,"B-P:";2;0: GET#2,A$,B$
450 T=ASC(A$+Z$): S=ASC(B$+Z$): H=2
460 PRINT#1,"B-P:";2;H: GET#2,T$
470 C=ASC(T$+Z$): IF C<>130 THEN 510
480 GET#2,A$,B$: F$="": FOR X=1 TO V
490 GET#2,T$: F$=F$+T$: NEXT
500 IF F$=N$ THEN 530
510 H=H+Q: IF H<F THEN 460
520 GOTO 430
530 A=ASC(A$+Z$): B=ASC(B$+Z$)
540 PRINT#1,"U1:";2;D;A;B: GOSUB 620
550 PRINT#1,"B-P:";2;2: PRINT#2,P$;
560 PRINT#1,"U2:";2;D;A;B: GOSUB 620
570 CLOSE 2: GOSUB 620: CLOSE 1
600 NEXT IX
610 PRINT"FERTIG! DIE DRUCKERTREIBER SIND NUN MIT DER RICHTIGEN STARTADRESSE"
615 PRINT"VERSEHEN.":END
620 INPUT#1,E,M$,J,K:IF E=0 THEN RETURN
630 PRINT " ERROR: ";E;M$;J;K
640 CLOSE 2: CLOSE 1: END