50000 REM ********************
50010 REM * LIBRARY V 1.0    *
50020 REM * ZUSAMMENGESTELLT *
50030 REM *       VON:       *
50040 REM *  THOMAS  KOLBE   *
50050 REM ********************
50060 :
50100 \PROC CLS:PRINT"[147]";:\END
50110 :
50150 \PROC CURSOR X,Y
50160 POKE781,Y:POKE782,X:POKE783,PEEK(783)AND254:SYS65520
50170 \END
50180 :
50200 \PROC PRTAT X,Y,A$:!CURSOR X,Y:PRINTA$;:\END
50210 :
50220 \PROC WAITKEY #ZQ$,ER$,MODUS:\VAR I:IFMODUSTHENPRINT" [146][157]";
50230 GETZQ$:IFZQ$=""THEN50230
50235 IF ER$=""THEN 50245
50240 !POSITION ZQ$,ER$,I:IFI=0 THEN 50230
50245 IFMODUSTHENPRINTZQ$;
50250 \END
50260 :
50300 \PROC POSITION A$,B$,#ZQ
50310 FORZQ=1TO(LEN(B$)-LEN(A$)+1)
50320 IFA$<>MID$(B$,ZQ,LEN(A$))THEN:NEXTZQ:ZQ=0
50330 \END
50340 :
50350 \PROC CLREOL:\VAR I
50360 I=40-PEEK(211)
50370 PRINTLEFT$("                                        ",I);:\END
50380 :
50400 \PROC LINIE A:FOR A=ATO1STEP-1:PRINT"[164]";:NEXTA:\END
50410 :
50450 \PROC COLOR RA,HI:POKE53280,RA:POKE53281,HI:\END
50460 :
50500 \PROC CENTER A$
50510 !PRTAT INT((40-LEN(A$))/2),PEEK(214),A$:\END
50520 :
50550 \PROC FETCH #ZY$,L:\VAR I,T$:ZY$=""
50560 !LINIE L:FORI=1TOL:PRINT"[157]";:NEXTI
50570 PRINT" [146][157]";
50575 !WAITKEY T$,"",0
50580 IFT$>=" "ANDT$<="_"ANDL>LEN(ZY$)THENPRINTT$;:ZY$=ZY$+T$:GOTO50570
50590 IFT$=CHR$(20)ANDLEN(ZY$)>0THENZY$=LEFT$(ZY$,LEN(ZY$)-1):PRINT"[157] [164][157][157]";
50600 IFT$=CHR$(20)THEN50570
50610 IFT$<>CHR$(13)THEN50575
50620 PRINT"[164]":\END
50630 :
50650 \PROC LPRINT SEK,A$:OPEN 1,4,SEK:PRINT#1,A$:CLOSE1:\END
50660 :
50670 \PROC STATUS #QN,#QE$,#QT,#QS:CLOSE15:OPEN15,8,15
50680 INPUT#15,QN,QE$,QT,QS:CLOSE15:\END
50690 :
50700 \PROC BEEP H,L:\VAR I:POKE54296,15:POKE54295,0:POKE54272,H-INT(H/256)*256
50710 POKE54273,H/256:POKE54277,26:POKE54278,230:POKE54276,33
50720 FORI=1TOL:NEXTI:POKE54276,32:\END
50730 :
50740 \PROC CATALOG:\VAR A$,B$:CLOSE3
50750 OPEN3,8,0,"$":GET#3,A$,A$
50760 GET#3,A$,A$:IFST=64THENCLOSE3:\END
50770 GET#3,A$,B$:PRINTMID$(STR$(ASC(A$+CHR$(0))+256*ASC(B$+CHR$(0))),2)" ";
50780 GET#3,A$:PRINTA$;:IFA$<>""THEN50780
50790 PRINT:GOTO50760