10 REM ********************************
12 REM * KLIMA 64: DATEN KOPIEREN     *
14 REM ********************************
16 :
100 REM *** INDEX LESEN ***************
102 Z$=CHR$(0):DIMQQ$(255),A$(255)
104 POKE53280,6:POKE53281,6:PRINT"[147] [203][204][201][205][193] 64: [196]ATEN KOPIEREN "
106 PRINT"[209]UELL";:GOSUB900
108 OPEN1,8,15,"I"
110 OPEN2,8,2,"INDEX,P,R"
112 INPUT#1,A,A$,A1,A2:IFA=0THEN120
114 CLOSE2:CLOSE1
116 PRINT"[203]EINE [207]RTE ERFASST."
118 PRINT:END
120 INPUT#2,QQ:PRINT"[201]NDEX LESEN:"
122 FORI=1TOQQ
124 INPUT#2,QQ$(I):PRINT"/";QQ$(I):NEXT
126 CLOSE2
128 :
200 REM *** DATEN LESEN ***************
202 OPEN2,8,2,"DATEN,L,"+CHR$(38)
204 PRINT"[196]ATEN LESEN:"
206 FORI=1TOQQ:PRINT"/";QQ$(I)
208 PRINT#1,"P"+CHR$(I)+Z$+Z$
210 A$(I)=""
212 FORJ=1TO36:GET#2,A$
214 A$(I)=A$(I)+CHR$(ASC(A$+Z$)):NEXT
216 NEXT
218 CLOSE2
220 :
300 REM *** INDEX SCHREIBEN ***********
302 PRINT"[218]IEL";:GOSUB900
304 OPEN2,8,2,"INDEX,P,W"
306 INPUT#1,A,A$,A1,A2:IFA=0THEN316
308 CLOSE2:CLOSE1
310 PRINT"[196]ATENDISKETTE ENTHAELT BEREITS [196]ATEN."
312 PRINT"[208]ROGRAMM ERNEUT STARTEN."
314 PRINT:END
316 PRINT"[201]NDEX SCHREIBEN:"
320 PRINT#2,QQ
322 FORI=1TOQQ
324 PRINT"/";QQ$(I):PRINT#2,QQ$(I):NEXT
326 CLOSE2
328 :
400 REM *** DATEN SCHREIBEN ***********
402 OPEN2,8,2,"DATEN,L,"+CHR$(38)
404 PRINT"[196]ATEN SCHREIBEN:"
406 FORI=1TOQQ:PRINT"/";QQ$(I)
408 PRINT#1,"P"+CHR$(I)+Z$+Z$
410 PRINT#2,A$(I):NEXT
412 CLOSE2:CLOSE1
414 PRINT"[203]OPIERVORGANG BEENDET."
416 PRINT:END
418 :
900 REM *** "RETURN" ******************
902 PRINT"DISKETTE EINLEGEN, [[210][197][212][213][210][206]]."
904 GETA$:IFA$<>CHR$(13)THEN904
906 RETURN
908 :