5 POKE53280,0:POKE53281,11:PRINTCHR$(144)
10 PRINTCHR$(147):VIC=5376
20 FORZ=0TO7:A=2^Z
30 IF(PEEK(VIC+21)ANDA)=ATHENPRINT"*";
40 PRINTTAB(1)"SPRITE"Z;
50 IF(PEEK(VIC+29)ANDA)=ATHENPRINT"*";
55 IF(PEEK(VIC+16)ANDA)=ATHENB=255:GOTO60
58 B=0
60 PRINTTAB(11)"X-KOORD."PEEK(VIC+Z*2)+B;
70 IF(PEEK(VIC+23)ANDA)=ATHENPRINTTAB(24)"*";
80 PRINTTAB(25)"Y-KOORD."PEEK(VIC+(Z*2+1));
90 PRINT:NEXTZ:PRINT
100 PRINT"MSB-X-KOORDINATEN PRIORITAET MULTICOLOR"
110 PRINT"01234567          01234567   01234567"
120 FORZ=0TO7:A=2^Z
130 IF(PEEK(VIC+16)ANDA)=ATHENPRINTTAB(0+Z)"*";
140 IF(PEEK(VIC+27)ANDA)=ATHENPRINTTAB(18+Z)"*";
150 IF(PEEK(VIC+28)ANDA)=ATHENPRINTTAB(29+Z)"*";
160 PRINT:PRINT"[145]";:NEXTZ:PRINT:PRINT
170 FORZ=2TO9:PRINT" SPRITE"Z-2" FARBE: ";:GOSUB1000:PRINT:NEXTZ:PRINT
180 PRINT" SPRITE MC 0/1: ";:Z=0:GOSUB1000:PRINT"/";:Z=1:GOSUB1000
190 POKE198,0:WAIT198,1
200 PRINTCHR$(147)
210 PRINT"HOCHAUFLOESENDE GRAFIK: ";
220 IF(PEEK(VIC+17)AND32)=32THENPRINT"EIN":GOTO240
230 PRINT"AUS"
240 PRINT"MULTICOLOR MODUS: ";
250 IF(PEEK(VIC+22)AND16)=16THENPRINT"EIN":GOTO270
260 PRINT"AUS"
270 PRINT"EXTENDED COLOR MODUS: ";
280 IF(PEEK(VIC+17)AND64)=64THENPRINT"EIN":GOTO350
290 PRINT"AUS"
350 PRINT:PRINT"ADRESSE ZEICHENSATZ:";
360 PRINT(PEEK(VIC+24)AND14)*1024
370 PRINT"ADRESSE VIDEO-RAM:";
380 VD=(PEEK(VIC+24)AND240)*64:PRINTVD
383 PRINT"ADRESSE BITMAP:";
386 PRINT(PEEK(VIC+24)AND8)*1024
390 PRINT:PRINT"LETZTE RASTERZEILE:"(PEEK(VIC+17)AND128)+PEEK(VIC+18)
400 PRINT:PRINT"RAHMENFARBE:";:Z=-5:GOSUB 1000:PRINT
410 FORZ=-4TO-1STEP1:PRINT"HINTERGRUNDFARBE "Z+4;:GOSUB 1000:PRINT:NEXTZ
420 A=PEEK(5632):PRINT:PRINT"IRQ-QUELLEN:":PRINT
430 IF(AAND1)=1THENPRINT"RASTERZEILEN-IRQ"
440 IF(AAND2)=2THENPRINT"SPRITE-HINTERGRUND-KOLLISION"
450 IF(AAND4)=4THENPRINT"SPRITE-SPRITE-KOLLISION"
460 IF(AAND8)=8THENPRINT"LIGHTPEN-IRQ"
490 POKE198,0:WAIT198,1
500 PRINTCHR$(147)
510 PRINT"SPRITE-POINTER AB"VD+1016:PRINT
520 FORZ=0TO7
530 PRINT"SPRITE"Z"INFORMATIONEN AB"PEEK(16384+VD+1016+Z)*64
540 NEXTZ
999 POKE198,0:WAIT198,1:END
1000 RESTORE:A=(PEEK(VIC+37+Z)AND15):FORI=0TOA:READA$:NEXTI:PRINTA$;:RETURN
2000 DATASCHWARZ,WEISS,ROT,TUERKIS,VIOLETT,GRUEN,BLAU,GELB,ORANGE,BRAUN,HELLROT
2010 DATAGRAU 1,GRAU 2, HELLGRUEN,HELLBLAU,GRAU 3