1 REM ******************
2 REM * DISK-UTILITIES *
3 REM *      VON       *
4 REM *  VOLKER MAAHS  *
5 REM * (W) 01.02.1988 *
6 REM ******************
7 :
8 :
9 :
10 G=8
20 POKE53280,0:POKE53281,0:POKE646,10:PRINTCHR$(8)CHR$(142)CHR$(147);
30 PRINT"    (W) 01.02.1988 VON VOLKER MAAHS     [146]";
40 PRINT"           * DISK-UTILITIES *           [146]";:POKE646,7
50 PRINT"========================================";
60 PRINTSPC(3)"GERAETENUMMER:";G:PRINTSPC(2):GOSUB830:POKE646,6:PRINT
70 PRINTSPC(3)"F1  FORMATIEREN":PRINT:POKE646,14
80 PRINTSPC(3)"F3  DISKNAME/ID AENDERN":PRINT:POKE646,2:
90 PRINTSPC(3)"F5  FILE LOESCHEN":PRINT:POKE646,1
100 PRINTSPC(3)"F7  DIRECTORY":PRINT:POKE646,4
110 PRINTSPC(3)"F2  GERAETEADRESSE AENDERN":PRINT:POKE646,5
120 PRINTSPC(3)"F4  INITIALISIEREN":PRINT:POKE646,13
130 PRINTSPC(3)"F6  FILENAMEN AENDERN":PRINT:POKE646,12
140 PRINTSPC(3)"F8  VALIDIEREN":PRINT:POKE646,15
150 PRINTSPC(3)"E   PROGRAMM BEENDEN":PRINT:
160 GETF$:IFF$=CHR$(133)THEN310
170 IFF$=CHR$(134)THEN880
180 IFF$=CHR$(135)THEN580
190 IFF$=CHR$(136)THENPOKE646,10:GOTO750
200 IFF$=CHR$(137)THEN270
210 IFF$=CHR$(138)THEN560
220 IFF$=CHR$(139)THEN660
230 IFF$=CHR$(140)THEN480
240 IFF$="E"THENGOSUB1190:PRINT"ENDE.":END
250 GOTO160
260 REM * GERAETENUMMER AENDERN *
270 GOSUB1190:PRINT"        * GERAETENUMMER AENDERN *       [146]"
280 PRINT:PRINT:PRINT:PRINTSPC(2)"WIE LAUTET DIE NEUE GERAETENUMMER";:INPUTG
290 GOTO20
300 REM * FORMATIEREN *
310 GOSUB1190:PRINT"            * FORMATIEREN *             [146]":PRINT
320 POKE646,7:PRINTSPC(11)"DISKETTE EINLEGEN!":POKE646,10
330 PRINT:PRINT:PRINTSPC(7)"DISKNAME (MAX. 16 ZEICHEN):"
340 PRINT:PRINT:PRINTSPC(12)"................"
350 PRINT"[145][145]"SPC(10);:INPUTD$:PRINT:PRINT:PRINT
360 PRINTSPC(16)"ID: "
370 PRINTSPC(22)"..":PRINT"[145][145]"SPC(20);:INPUTID$
380 PRINT:PRINT:PRINT:PRINTSPC(6)"WIRKLICH FORMATIEREN (J/N)?"
390 GETZ$:IFZ$="J"THEN420
400 IFZ$="N"THEN20
410 IFZ$<>"J"ORZ$<>"N"THEN390
420 OPEN7,G,15,"N:"+D$+","+ID$:CLOSE7
430 PRINT:PRINTSPC(7)"NOCH EINE DISKETTE (J/N)?"
440 GETZ$:IFZ$="J"THEN310
450 IFZ$="N"THEN20
460 IFZ$<>"J"ORZ$<>"N"THEN440
470 REM * VALIDIEREN *
480 GOSUB1190:PRINT"             * VALIDIEREN *             [146]";
490 PRINT:PRINT:PRINTSPC(12)"VALIDIEREN (J/N)?"
500 GETZ$:IFZ$="N"THEN20
510 IFZ$="J"THEN530
520 IFZ$<>"J"ORZ$<>"N"THEN500
530 FORT=1TO9:PRINT:NEXT:POKE646,7:PRINTSPC(13)"VALIDIERE DISK!"
540 OPEN7,G,15,"V":CLOSE7:GOTO20
550 REM * INITIALISIEREN *
560 OPEN7,G,15,"I":CLOSE7:GOTO20
570 REM * FILE LOESCHEN *
580 GOSUB1190:PRINT"           * FILE LOESCHEN *            [146]"
590 PRINT:PRINT:PRINTSPC(3)"FILENAME";:INPUTNA$
600 OPEN7,G,15,"S:"+NA$:CLOSE7
610 PRINT:PRINTSPC(3)"WEITERE FILES LOESCHEN (J/N)?"
620 GETZ$:IFZ$="J"THEN580
630 IFZ$="N"THEN20
640 IFZ$<>"J"ORZ$<>"N"THEN620
650 REM * FILENAMEN AENDERN *
660 GOSUB1190:PRINT"         * FILENAMEN AENDERN *          [146]";
670 PRINT:PRINT:PRINT:PRINTSPC(3)"ALTER FILENAME";:INPUTAF$
680 PRINT:PRINTSPC(3)"NEUER FILENAME";:INPUTNF$
690 OPEN7,G,15,"R:"+NF$+"="+AF$:CLOSE7
700 PRINT:PRINTSPC(3)"WEITERE FILES AENDERN (J/N)?"
710 GETZ$:IFZ$="J"THEN660
720 IFZ$="N"THEN20
730 IFZ$<>"J"ORZ$<>"N"THEN710
740 REM * DIRECTORY *
750 PRINT"[147] 0 ";:OPEN1,G,0,"$":POKE781,1:SYS65478:GETA$,A$,A$,A$:X$=CHR$(0)
760 FORI=1TO7:GETA$,B$,C$,D$:PRINTA$B$C$D$;:NEXT:PRINT:GETA$,A$,A$,B$
770 IFST THEN SYS65484:CLOSE1:GOTO790
780 PRINTASC(A$+X$)+256*ASC(B$+X$);:GOTO760
790 POKE646,7:PRINT" RETURN[146]"
800 GETZ$:IFZ$<>CHR$(13)THEN800
810 GOTO20
820 REM * FEHLERKANAL *
830 OPEN1,G,15
840 INPUT#1,A,B$,C,D
850 PRINTA;"[157], ";B$","C;"[157],"D
860 CLOSE1:RETURN
870 REM * DISKNAME/ID AENDERN *
880 GOSUB1190:PRINT"          * DISKNAMEN AENDERN *         [146]";
890 DN$="":A$="":B$=""
900 OPEN15,G,15
910 PRINT#15,"I"+DV$:OPEN1,G,3,"#":PRINT#15,"U1:3"DV",18,0"
920 PRINT#15,"B-P:3,144":DN$="":FORL=1TO16:GET#1,A$:DN$=DN$+A$:NEXT
930 PRINT"    DISKETTENNAME:[158]"DN$"[146]"
940 POKE646,10:PRINT"    AENDERN (J/N)?"
950 GETQ$:IFQ$=""THEN 950
960 IFQ$="N"THEN1010
970 IF Q$<>"J"THEN950:GOTO980
980 PRINT"    NEUER NAME(MAX. 16 ZEICHEN): ":INPUT"    ";N$
990 N$=LEFT$(N$+"              ",16)
1000 PRINT#15,"B-P:3,144":PRINT#1,N$:PRINT#15,"U2:3"DV",18,0"
1010 PRINTCHR$(147);:PRINT"          * DISK-ID  AENDERN *          [146]"
1020 PRINT#15,"B-P:3,162":GET#1,A$,B$,C$,D$,E$
1030 PRINT"    DISK ID:      [158]"A$B$C$D$E$"[146]"
1040 POKE646,10:PRINT"    AENDERN (J/N)?"
1050 GETZ$:IFZ$=""THEN1050
1060 IFZ$="N"THEN1110
1070 IFZ$<>"J"THEN1050:GOTO1080
1080 INPUT"    NEUE ID (MAX. 5 ZEICHEN): ";ID$
1090 IFLEN(ID$)<>4THENID$=LEFT$(ID$+" ",5)
1100 PRINT#15,"B-P:3,162":PRINT#1,ID$;:PRINT#15,"U2:"3;0;18;0
1110 I$="I"+MID$(STR$(DV),5):PRINT#15,I$
1120 CLOSE1:CLOSE15
1130 PRINT"       NOCH EINE DISKETTE (J/N)?"
1140 GETZ$:IFZ$=""THEN1140
1150 IFZ$="N"THEN1180
1160 IFZ$<>"J"THEN1140
1170 GOTO 880
1180 GOTO20
1190 POKE646,10:PRINTCHR$(147);:RETURN