10 IFA=0THENA=1:LOAD"GRAPHIC",8,1
20 CLR:DIMA$(15):A=RND(-TI/37)
30 AZ=INT(RND(1)*3):PS=1:BE=53280
40 IFAZ=0THENED$="BEING HID NEAR THE SEA.":SC=1:B(3)=2:B(6)=1
50 IFAZ=1THENED$="BEING HELD IN THE HOUSE.":SC=3:B(2)=2:B(4)=1
60 IFAZ=2THENED$="RIGHT HERE.":SC=5:B(1)=1:B(3)=2
70 FORI=0TO15:READA$(I):NEXT:DATA "[188]","[187]"
80 DATA "[190]","[172]","[184]","[184][146]","[161]","[161][146]","[191]","[191][146]","[190][146]","[188][146]","[187][146]","[172][146]"," "," [146]"
90 FORI=0TO2:READB$(I):NEXT:DATA NOTHING,A POUCH WITH GOLD,A MALLET
100 FORI=1TO6:READN$(I),D1$(I),D2$(I):NEXT
110 DATA BEACH,,E,TREE,W,N,HOUSE,S,E,ROAD,W,E,STEEP CLIFF,W,S,RIVER,N,
115 I=1
117 READEW:IFEW=-1THENI=I+1:ONIGOTO117,117,117,117,117,117,140
119 C$(I)=C$(I)+CHR$(EW-7):GOTO117
121 DATA 90,76,72,89,74,79,-1,74,83,80,84,73,-1,82,85,86,74,82,-1
123 DATA 83,86,86,82,-1,91,79,89,86,94,-1,90,94,80,84,-1
140 FORI=0TO2:READHE$(I):NEXT
150 DATA "WHAT TOOK YOU SO LONG?"
160 DATA "I'M SURE GLAD YOU FOUND ME. THANKS!"
170 DATA "NICE JOB SAVING ME.  THIS MAKES UP FOR  EVERYTHING I'VE DONE FOR YOU."
180 FORI=0TO1:READSA$(I):NEXT
190 DATA "WRONG-NOW I'M GOING TO FEED YOUR SISTER TO SOME CROCODILES."
200 DATA "WRONG-NOW YOUR SISTER IS MY SLAVE."
210 FORI=1TO6:READRS$(I):NEXT
220 DATA "YOU'RE LOOKING.  YOU FIND"
230 DATA "THERE'S A SMALL DWARF UP HERE.  YOU GIVEHIM GOLD.  HE OFFERS YOU"
240 DATA "A MAN HERE FEEDS YOU SOME STEW.  YOU    HAND HIM GOLD.  HE OFFERS"
250 DATA "YOU SEARCH AROUND.  THERE'S"
260 DATA "YOU HAVE REVEALED AN OPENING.  THERE'S AMAN BEHIND THE OPENING."
270 DATA "THIS FEELS GOOD.  WAIT, YOU FEEL SOME-  THING ON YOUR FEET.  OH, IT'S"
280 FORI=1TO6:READHI$(I):NEXT
290 DATA "THIS IS A LONG, SANDY STRETCH OF EMPTY  LAND."
300 DATA "THERE'S SUPPOSED TO BE A GREAT VIEW OF  THE VALLEY HERE."
310 DATA "YOU WONDER IF ANYONE IS HOME."
320 DATA "THERE SEEMS TO BE SOMETHING SPARKLING   IN THE GRASS."
330 DATA "YOU LOOK LIKE YOU NEED TO RELEASE SOME  TENSION."
340 DATA "IT SURE IS HOT OUT HERE!"
350 REM END SETUP
360 POKEBE,3:POKE53265,PEEK(53265)AND239:PRINT"[147] YOUR SISTER"
365 PRINT"[145][145]"TAB(27)"[144]CARRYING:"
370 PRINT"    HAS"
380 PRINT" DISAPPEARED";:IFHV>0THENPRINTTAB(28)"[151]POUCH/GOLD";
390 PRINT:PRINT"   AND YOU"
400 PRINT"  MUST FIND";:IFHV=2THENPRINTTAB(30)"[151]MALLET";
410 PRINT:PRINT"     HER."
420 PRINT"[150]"TAB(7)"[165][167] [165][167] [207][208] [207][208] [208][183] [206][183] [206][205][167][205] [165][207][183]"
430 PRINTTAB(7)"[207][208] [165][167] [204][206] [204][206] [167]  [165]  [204][186][167] [165][165][207]"
440 PRINTTAB(7)"[165][167] [204][186] [165][205] [165][205] [186][175] [205][175] [165][167][167] [205][165][204][175]"
445 PRINTTAB(12)"[153]BY: DAVID GARNER"
450 POKE53281,1:PRINT""TAB(14);
460 PRINT"[144][172]          [146][187]";:FORI=1TO9:PRINT"[157] [146]";:NEXT:PRINT"[157][157][157][157][157][157][157][157][157][157][157][157]";
470 PRINT"[188]          [146][190][157][157][157][157][157][157][157][157][157][157][157]";:FORI=1TO9:PRINT"[145][157] [146]";:NEXT
480 GF=49062+PS*90:PRINTTAB(15);:FORI=0TO8:POKEBE,(PEEK(BE)AND15)+LC:FORJ=0TO9
490 GD=PEEK(GF):GF=GF+1
500 POKE646,GDAND15:PRINTA$((GDAND240)/16);:NEXT
510 LC=1-LC:PRINTSPC(30);:NEXT
520 PRINT"[155]YOU HAVE COME TO A "N$(PS)".":PRINT"[159]*[155]"HI$(PS)
523 POKE53265,(PEEK(53265)AND239)+16:POKEBE,4
525 IFHF=1ANDSC=PSTHENGOTO890
530 PRINT"RECOMMENDED DIRECTIONS OF TRAVEL:[144]  "D1$(PS)" "D2$(PS)
535 POKE53265,(PEEK(53265)AND239)+16:POKE53280,4
540 POKE198,0:RS$="":PRINT"[129]: [215]"
541 GETNV$:IFNV$=""THEN541
542 IFNV$=CHR$(13)THEN550
543 IFNV$=CHR$(20)ANDLEN(RS$)>0THENRS$=LEFT$(RS$,LEN(RS$)-1):GOTO547
544 IFLEN(RS$)>8THEN541
545 IF(ASC(NV$)<65)OR(ASC(NV$)>90)THEN541
546 RS$=RS$+NV$
547 PRINT"[129][145]"RS$"[215] [155]":GOTO541
550 IFRS$=D1$(PS)THENIFRS$<>""THENPS=PS-1:GOTO360
560 IFRS$=D2$(PS)THENIFRS$<>""THENPS=PS+1:GOTO360
570 IFRS$<>C$(PS)THENPRINT"[145]                       ":PRINT"WHAT?[157][157][157][157][157][145]";:GOTO540
580 FORI=1663TO2023:POKEI,32:NEXT
590 IFHV<>1AND(PS=2ORPS=3)ORPS=5ANDHV<2THENGOTO6000
600 PRINT"[145][145][145][145][145]"RS$(PS):PRINTB$(B(PS))
610 IFB(PS)>0THENHV=HV+1:B(PS)=0:GOSUB7000
615 PRINT"[145]";
620 IFPS<>5THEN530
630 PRINT"HE TELLS YOU THAT IF YOU ANSWER THIS    RIDDLE, YOU CAN HAVE YOUR ";
640 PRINT"SISTER BACK.":FORI=1TO5000:NEXT
650 FORI=1663TO2023:POKEI,32:NEXT:PRINT"[145][145][145][145]";
660 I=INT(RND(1)*3):ONIGOTO720,770
670 PRINT"YOU WON'T KNOW WHAT I AM UNTIL YOU FEEL"
680 PRINT"ME FIRST HAND.  WHEN YOU FIRST FEEL OF"
690 PRINT"ME, YOU WILL JUMP BACK AMAZED."
700 INPUTG$:IFG$=CHR$(70)+CHR$(73)+CHR$(82)+CHR$(69)THENGOTO830
710 GOTO870
720 PRINT"EVERYTHING YOU SEE OR DO IS A PART OF   ";
730 PRINT"THIS.  IT CAN SEEM VERY SHORT OR REALLY ";
740 PRINT"LONG, DEPENDING ON WHAT YOU MAKE OF IT."
750 INPUTG$:IFG$=CHR$(76)+CHR$(73)+CHR$(70)+CHR$(69)THENGOTO830
760 GOTO870
770 PRINT"A MAN SCRAWLED HIS FIRST NAME ON THE TOP";
780 PRINT"OF A DOCUMENT AND THEN SIGNED HIS NAME  ";
790 PRINT"AT THE BOTTOM.  HE HAD SINCERE FEELINGS ";
800 PRINT"FOR EVERYBODY HE KNEW.  WHAT IS THIS    MAN'S NAME?"
810 INPUTG$:IFG$=CHR$(87)+CHR$(73)+CHR$(76)+CHR$(76)THENGOTO830
820 GOTO870
830 HF=1:FORI=1663TO2023:POKEI,32:NEXT
840 PRINT"CORRECT!  YOUR SISTER IS ":PRINTED$
850 IFSC=5THENGOTO890
860 GOTO530
870 FORI=1663TO2023:POKEI,32:NEXT
880 I=INT(RND(1)*2):PRINT"[145][145][145][145]";SA$(I):GOTO910
890 FORI=1663TO2023:POKEI,32:NEXT
900 I=INT(RND(1)*3):PRINT"[145][145]";HE$(I)
910 PRINT"(A)NOTHER GAME OR (R)ESET COMPUTER"
920 GETI$:IFI$="A"THENGOTO20
930 IFI$="R"THENSYS64738
940 GOTO920
6000 PRINT"[145][145][145][145][145]NOTHING HAPPENS RIGHT NOW.":GOTO530
7000 PRINT"";:IFHV>0THENPRINTTAB(28)"[151]POUCH/GOLD[155]"
7010 PRINT"";:IFHV=2THENPRINTTAB(30)"[145][151]MALLET[155]"
7020 PRINT"";:RETURN