100 PRINT "SOURCE - MAKESS - JIM B"
110 END
120 *=$2000   ; PROGRAM START ADDRS
130 START LDX #$01  ; FROM INFILE...
140  JSR $FFC6
150  JSR $FFE4      ; GET CHARACTER...
160  LDY $90        ; LOG END-OF-FILE
170  PHP
180  PHA
190  JSR $FFCC      ; DISCONNECT INFILE
200  PLA
205 ; PUT IN(null) INTO X;
206 ; USE A TO STAGE MODIFIED (null)S
210  JSR $FFD2      ; PRINT CHARACTER
220  TAX            ; COPY TO X REG
225 ; IF IT'S <RETURN>, OUTPUT '_'
230  LDA #$1F
240  CPX #$0D       ; IF <RETURN>
250  BEQ SEND       ; .. PRINT IT
260  TXA
270  SEC
280  SBC #$40       ; SUBTRACT 64..
290  BCC TEST2      ; < 64, SKIP
300  CPX #$60       ; 64 TO 95 ..
310  BCC SEND       ; .. YES, SEND IT
320  CPX #$A0       ; 96 TO 159 ..
330  BCC TEST2      ; .. YES, SKIP
340  CPX #$C0       ; 160 TO 191 ..
350  BCC SEND       ; .. YES, SEND IT
355 ; NOT ALPHA-GROUP CHARACTER...
356 ; (64-95 OR 160-191)...
358 ; TEST FOR 96-127; IF FOUND,
359 ; PRINT [ (null) - 32 ]
360 TEST2 TXA   ; THIS CODE AT 202C
370  BMI TEST3  ; IF 128 OR HIGHER
380  SEC
390  SBC #$20   ; SUBTRACT 32
400  CPX #$60   ; 96 OR HIGHER ..
410  BCS SEND  ; .. YES, SEND IT
415 ; NOT (null) 64-127 OR 160-191
416 ; TEST FOR 0 - 64, 128-159
417 ; IF FOUND, PRINT [ (null) ]
420 TEST3 TXA   ; THIS CODE AT 2036
430  CPX #$C0
440  BCC SEND
445 ; ALL THAT'S LEFT IS 160-255
446 ; PRINT [ CHR - 128 ]
450  SBC #$80
460 SEND PHA    ; AT 203D, WRITE FILE
470  LDX #$02
480  JSR $FFC9  ; SELECT OUTFILE
490  PLA
500  JSR $FFD2  ; SEND CHAR TO FILE
510  JSR $FFCC
520  JSR $FFE1  ; CHECK STOP (null)
530  BEQ STOP
540  PLP        ; RECALL E-O-F SIGNAL
550  BEQ START  ; (null) IF NOT EOF
560  RTS
570 STOP PLP    ; AT 2053
580  RTS