10 IF PEEK(49152) <> 32 THEN LOAD"QUICKSCREEN",8,1
20 D$="":A$="***************************************"
30 POKE53280,0:POKE53281,0
40 PRINT"[147]":FOR X=0 TO 250:NEXT X
50 PRINT"[158]"SPC(14)"QUICKSCREEN![146]"
60 PRINT"[159]     BORING TEXT DISPLAYS COME ALIVE!"
70 PRINT"[150]     CHARACTER GRAPHIC DISPLAYS ZOOM!"
80 PRINT""SPC(14)"SELECT DEMO:[146]"
90 PRINT"[153]"SPC(5)"1) DEMO # 1 - SCREEN ROLL IN"
100 PRINT"[153]"SPC(5)"2) DEMO # 2 - SCREEN SPLIT"
110 PRINT"[153]"SPC(5)"3) DEMO # 3 - SCREEN MERGE"
120 GET K$:IF K$="1"THEN 310
130 IF K$="2"THEN 370
140 IF K$="3"THEN 430
150 GOTO120
160 REM ** DRAW & STORE SCREEN **
170 SYS 49152,7: REM *** SCREEN OFF
180 PRINT"[159][147]"A$;D$;A$
190 FOR X=1024 TO 1984 STEP 40:POKE X,42:NEXT
200 FOR X=1063 TO 2023 STEP 40:POKE X,42:NEXT
210 PRINT""SPC(12)"[150]QUICKSCREEN DEMO"
220 PRINT""SPC(6)"A QUICK SYS COMMAND MOVES THE"
230 PRINT""SPC(12)"SCREEN IN OR OUT."
240 PRINT"[158]CAN BE USED IN BASIC OR MACHINE"
250 PRINT""SPC(12)"LANGUAGE PROGRAMS."
260 PRINT"[156]"SPC(9)" PRESS A KEY CONTINUE "
270 SYS 49152,0: REM *** STORE SCREEN
280 PRINT"[147]":    REM *** CLEAR SCREEN
290 SYS 49152,8: REM *** SCREEN ON
300 RETURN
310 REM ** DEMO # 1 **
320 GOSUB 160: REM *** DRAW & STORE SCR
330 SYS 49152,1: REM *** MOVE IN # 1
340 GET K$:IFK$=""THEN 340
350 SYS 49152,2: REM *** MOVE OUT # 1
360 GOTO 40
370 REM ** DEMO # 2 **
380 GOSUB 160: REM *** DRAW & STORE SCR
390 SYS 49152,3: REM *** MOVE IN # 2
400 GET K$:IFK$=""THEN 400
410 SYS 49152,4: REM *** MOVE OUT # 2
420 GOTO 40
430 REM ** DEMO # 3 **
440 GOSUB 160: REM *** DRAW & STORE SCR
450 SYS 49152,5: REM *** MOVE IN # 3
460 GET K$:IFK$=""THEN 460
470 SYS 49152,6: REM *** MOVE OUT # 3
480 GOTO 40